sysdeps/unix/sysv/linux/s390/s390-64/swapcontext.S

   1 /* Copyright (C) 2002 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <features.h>
  22
  23 #include "ucontext_i.h"
  24
  25 /*  __swapcontext (ucontext_t *oucp, const ucontext_t *ucp)
  26
  27   Saves the machine context in oucp such that when it is activated,
  28   it appears as if __swapcontextt() returned again, restores the
  29   machine context in ucp and thereby resumes execution in that
  30   context.
  31
  32   This implementation is intended to be used for *synchronous* context
  33   switches only.  Therefore, it does not have to save anything
  34   other than the PRESERVED state.  */
  35
  36 ENTRY(__swapcontext)
  37         lgr     %r1,%r2
  38         lgr      %r5,%r3
  39
  40         /* sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask).  */
  41         la      %r2,SIG_BLOCK
  42         slgr    %r3,%r3
  43         la      %r4,SC_MASK(%r1)
  44         svc     SYS_ify(rt_sigprocmask)
  45
  46         /* Store fpu context.  */
  47         stfpc   SC_FPC(%r1)
  48         std     %f0,SC_FPRS(%r1)
  49         std     %f1,SC_FPRS+8(%r1)
  50         std     %f2,SC_FPRS+16(%r1)
  51         std     %f3,SC_FPRS+24(%r1)
  52         std     %f4,SC_FPRS+32(%r1)
  53         std     %f5,SC_FPRS+40(%r1)
  54         std     %f6,SC_FPRS+48(%r1)
  55         std     %f7,SC_FPRS+56(%r1)
  56         std     %f8,SC_FPRS+64(%r1)
  57         std     %f9,SC_FPRS+72(%r1)
  58         std     %f10,SC_FPRS+80(%r1)
  59         std     %f11,SC_FPRS+88(%r1)
  60         std     %f12,SC_FPRS+96(%r1)
  61         std     %f13,SC_FPRS+104(%r1)
  62         std     %f14,SC_FPRS+112(%r1)
  63         std     %f15,SC_FPRS+120(%r1)
  64
  65         /* Set __swapcontext return value to 0.  */
  66         slgr     %r2,%r2
  67
  68         /* Store access registers.  */
  69         stam    %a0,%a15,SC_ACRS(%r1)
  70
  71         /* Store general purpose registers.  */
  72         stmg    %r0,%r15,SC_GPRS(%r1)
  73
  74         /* sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL).  */
  75         la      %r2,SIG_BLOCK
  76         la      %r3,SC_MASK(%r5)
  77         slgr    %r4,%r4
  78         svc     SYS_ify(rt_sigprocmask)
  79
  80         /* Load fpu context.  */
  81         lfpc    SC_FPC(%r5)
  82         ld      %f0,SC_FPRS(%r5)
  83         ld      %f1,SC_FPRS+8(%r5)
  84         ld      %f2,SC_FPRS+16(%r5)
  85         ld      %f3,SC_FPRS+24(%r5)
  86         ld      %f4,SC_FPRS+32(%r5)
  87         ld      %f5,SC_FPRS+40(%r5)
  88         ld      %f6,SC_FPRS+48(%r5)
  89         ld      %f7,SC_FPRS+56(%r5)
  90         ld      %f8,SC_FPRS+64(%r5)
  91         ld      %f9,SC_FPRS+72(%r5)
  92         ld      %f10,SC_FPRS+80(%r5)
  93         ld      %f11,SC_FPRS+88(%r5)
  94         ld      %f12,SC_FPRS+96(%r5)
  95         ld      %f13,SC_FPRS+104(%r5)
  96         ld      %f14,SC_FPRS+112(%r5)
  97         ld      %f15,SC_FPRS+120(%r5)
  98
  99         /* Don't touch %a0 and %a1, used for thread purposes.  */
 100         lam     %a2,%a15,SC_ACRS+8(%r5)
 101
 102         /* Load general purpose registers.  */
 103         lmg     %r0,%r15,SC_GPRS(%r5)
 104
 105         /* Return.  */
 106         br      %r14
 107 END(__swapcontext)
 108 weak_alias (__swapcontext, swapcontext)