sysdeps/x86_64/start.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 /* This is the canonical entry point, usually the first thing in the text
  38    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  39    point runs, most registers' values are unspecified, except for:
  40
  41    %rdx         Contains a function pointer to be registered with `atexit'.
  42                 This is how the dynamic linker arranges to have DT_FINI
  43                 functions called for shared libraries that have been loaded
  44                 before this code runs.
  45
  46    %rsp         The stack contains the arguments and environment:
  47                 0(%rsp)                         argc
  48                 LP_SIZE(%rsp)                   argv[0]
  49                 ...
  50                 (LP_SIZE*argc)(%rsp)            NULL
  51                 (LP_SIZE*(argc+1))(%rsp)        envp[0]
  52                 ...
  53                                                 NULL
  54 */
  55
  56 #include <sysdep.h>
  57 #include "bp-sym.h"
  58
  59         .text
  60         .globl _start
  61         .type _start,@function
  62 _start:
  63         cfi_startproc
  64         /* Clearing frame pointer is insufficient, use CFI.  */
  65         cfi_undefined (rip)
  66         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  67            the outermost frame obviously.  */
  68         xorl %ebp, %ebp
  69
  70         /* Extract the arguments as encoded on the stack and set up
  71            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  72                    int argc, char *argv,
  73                    void (*init) (void), void (*fini) (void),
  74                    void (*rtld_fini) (void), void *stack_end).
  75            The arguments are passed via registers and on the stack:
  76         main:           %rdi
  77         argc:           %rsi
  78         argv:           %rdx
  79         init:           %rcx
  80         fini:           %r8
  81         rtld_fini:      %r9
  82         stack_end:      stack.  */
  83
  84         mov %RDX_LP, %R9_LP     /* Address of the shared library termination
  85                                    function.  */
  86 #ifdef __ILP32__
  87         mov (%rsp), %esi        /* Simulate popping 4-byte argument count.  */
  88         add $4, %esp
  89 #else
  90         popq %rsi               /* Pop the argument count.  */
  91 #endif
  92         /* argv starts just at the current stack top.  */
  93         mov %RSP_LP, %RDX_LP
  94         /* Align the stack to a 16 byte boundary to follow the ABI.  */
  95         and  $~15, %RSP_LP
  96
  97         /* Push garbage because we push 8 more bytes.  */
  98         pushq %rax
  99
 100         /* Provide the highest stack address to the user code (for stacks
 101            which grow downwards).  */
 102         pushq %rsp
 103
 104 #ifdef SHARED
 105         /* Pass address of our own entry points to .fini and .init.  */
 106         mov __libc_csu_fini@GOTPCREL(%rip), %R8_LP
 107         mov __libc_csu_init@GOTPCREL(%rip), %RCX_LP
 108
 109         mov BP_SYM (main)@GOTPCREL(%rip), %RDI_LP
 110
 111         /* Call the user's main function, and exit with its value.
 112            But let the libc call main.    */
 113         call BP_SYM (__libc_start_main)@PLT
 114 #else
 115         /* Pass address of our own entry points to .fini and .init.  */
 116         mov $__libc_csu_fini, %R8_LP
 117         mov $__libc_csu_init, %RCX_LP
 118
 119         mov $BP_SYM (main), %RDI_LP
 120
 121         /* Call the user's main function, and exit with its value.
 122            But let the libc call main.    */
 123         call BP_SYM (__libc_start_main)
 124 #endif
 125
 126         hlt                     /* Crash if somehow `exit' does return.  */
 127         cfi_endproc
 128
 129 /* Define a symbol for the first piece of initialized data.  */
 130         .data
 131         .globl __data_start
 132 __data_start:
 133         .long 0
 134         .weak data_start
 135         data_start = __data_start