sysdeps/i386/__longjmp.S

   1 /* longjmp for i386.
   2    Copyright (C) 1995-1998,2000,2002,2005,2006,2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <jmpbuf-offsets.h>
  23 #include <asm-syntax.h>
  24 #include <bp-sym.h>
  25 #include <bp-asm.h>
  26
  27 #define PARMS   LINKAGE         /* no space for saved regs */
  28 #define JBUF    PARMS
  29 #define VAL     JBUF+PTR_SIZE
  30
  31         .text
  32 ENTRY (BP_SYM (__longjmp))
  33         ENTER
  34
  35 #ifdef PTR_DEMANGLE
  36         movl JBUF(%esp), %eax   /* User's jmp_buf in %eax.  */
  37         CHECK_BOUNDS_BOTH_WIDE (%eax, JBUF(%esp), $JB_SIZE)
  38
  39         /* Save the return address now.  */
  40         movl (JB_PC*4)(%eax), %edx
  41         /* Get the stack pointer.  */
  42         movl (JB_SP*4)(%eax), %ecx
  43         PTR_DEMANGLE (%edx)
  44         PTR_DEMANGLE (%ecx)
  45 # ifdef CHECK_ESP
  46         CHECK_ESP (%ecx)
  47 # endif
  48         cfi_def_cfa(%eax, 0)
  49         cfi_register(%eip, %edx)
  50         cfi_register(%esp, %ecx)
  51         cfi_offset(%ebx, JB_BX*4)
  52         cfi_offset(%esi, JB_SI*4)
  53         cfi_offset(%edi, JB_DI*4)
  54         cfi_offset(%ebp, JB_BP*4)
  55         /* Restore registers.  */
  56         movl (JB_BX*4)(%eax), %ebx
  57         movl (JB_SI*4)(%eax), %esi
  58         movl (JB_DI*4)(%eax), %edi
  59         movl (JB_BP*4)(%eax), %ebp
  60         cfi_restore(%ebx)
  61         cfi_restore(%esi)
  62         cfi_restore(%edi)
  63         cfi_restore(%ebp)
  64
  65         movl VAL(%esp), %eax    /* Second argument is return value.  */
  66         movl %ecx, %esp
  67 #else
  68         movl JBUF(%esp), %ecx   /* User's jmp_buf in %ecx.  */
  69         CHECK_BOUNDS_BOTH_WIDE (%ecx, JBUF(%esp), $JB_SIZE)
  70
  71 # ifdef CHECK_ESP
  72         movl (JB_SP*4)(%ecx), %eax
  73         CHECK_ESP (%eax)
  74 # endif
  75
  76         movl VAL(%esp), %eax    /* Second argument is return value.  */
  77         /* Save the return address now.  */
  78         movl (JB_PC*4)(%ecx), %edx
  79         /* Restore registers.  */
  80         movl (JB_BX*4)(%ecx), %ebx
  81         movl (JB_SI*4)(%ecx), %esi
  82         movl (JB_DI*4)(%ecx), %edi
  83         movl (JB_BP*4)(%ecx), %ebp
  84         movl (JB_SP*4)(%ecx), %esp
  85 #endif
  86         /* Jump to saved PC.  */
  87         jmp *%edx
  88 END (BP_SYM (__longjmp))