sysdeps/i386/i686/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=6.
   3    Copyright (C) 1999,2000,2003,2005,2006 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1999.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <sysdep.h>
  23 #include "asm-syntax.h"
  24 #include "bp-sym.h"
  25 #include "bp-asm.h"
  26
  27 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  28 #define BZERO_P (defined memset)
  29
  30 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  31 #if BZERO_P
  32 # define DEST   PARMS
  33 # define LEN    DEST+PTR_SIZE
  34 #else
  35 # define RTN    PARMS
  36 # define DEST   RTN+RTN_SIZE
  37 # define CHR    DEST+PTR_SIZE
  38 # define LEN    CHR+4
  39 #endif
  40
  41         .text
  42 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
  43 ENTRY (__memset_chk)
  44         movl    12(%esp), %eax
  45         cmpl    %eax, 16(%esp)
  46         jb      HIDDEN_JUMPTARGET (__chk_fail)
  47 END (__memset_chk)
  48 #endif
  49 ENTRY (BP_SYM (memset))
  50         ENTER
  51
  52         cld
  53         pushl   %edi
  54         cfi_adjust_cfa_offset (4)
  55         movl    DEST(%esp), %edx
  56         movl    LEN(%esp), %ecx
  57         CHECK_BOUNDS_BOTH_WIDE (%edx, DEST(%esp), %ecx)
  58 #if BZERO_P
  59         xorl    %eax, %eax      /* fill with 0 */
  60 #else
  61         movzbl  CHR(%esp), %eax
  62 #endif
  63         jecxz   1f
  64         movl    %edx, %edi
  65         cfi_rel_offset (edi, 0)
  66         andl    $3, %edx
  67         jz      2f      /* aligned */
  68         jp      3f      /* misaligned at 3, store just one byte below */
  69         stosb           /* misaligned at 1 or 2, store two bytes */
  70         decl    %ecx
  71         jz      1f
  72 3:      stosb
  73         decl    %ecx
  74         jz      1f
  75         xorl    $1, %edx
  76         jnz     2f      /* was misaligned at 2 or 3, now aligned */
  77         stosb           /* was misaligned at 1, store third byte */
  78         decl    %ecx
  79 2:      movl    %ecx, %edx
  80         shrl    $2, %ecx
  81         andl    $3, %edx
  82 #if !BZERO_P
  83         imul    $0x01010101, %eax
  84 #endif
  85         rep
  86         stosl
  87         movl    %edx, %ecx
  88         rep
  89         stosb
  90
  91 1:
  92 #if !BZERO_P
  93         movl DEST(%esp), %eax   /* start address of destination is result */
  94         RETURN_BOUNDED_POINTER (DEST(%esp))
  95 #endif
  96         popl    %edi
  97         cfi_adjust_cfa_offset (-4)
  98         cfi_restore (edi)
  99
 100         LEAVE
 101 #if BZERO_P
 102         ret
 103 #else
 104         RET_PTR
 105 #endif
 106 END (BP_SYM (memset))
 107 libc_hidden_builtin_def (memset)
 108
 109 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
 110 strong_alias (__memset_chk, __memset_zero_constant_len_parameter)
 111         .section .gnu.warning.__memset_zero_constant_len_parameter
 112         .string "memset used with constant zero length parameter; this could be due to transposed parameters"
 113 #endif