sysdeps/i386/i686/memcpy.S

   1 /* Copy memory block and return pointer to beginning of destination block
   2    For Intel 80x86, x>=6.
   3    This file is part of the GNU C Library.
   4    Copyright (C) 1999, 2000, 2003, 2004, 2008 Free Software Foundation, Inc.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1999.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <sysdep.h>
  23 #include "asm-syntax.h"
  24 #include "bp-sym.h"
  25 #include "bp-asm.h"
  26
  27 #define PARMS   LINKAGE         /* no space for saved regs */
  28 #define RTN     PARMS
  29 #define DEST    RTN+RTN_SIZE
  30 #define SRC     DEST+PTR_SIZE
  31 #define LEN     SRC+PTR_SIZE
  32
  33         .text
  34 #if defined PIC && !defined NOT_IN_libc
  35 ENTRY (__memcpy_chk)
  36         movl    12(%esp), %eax
  37         cmpl    %eax, 16(%esp)
  38         jb      HIDDEN_JUMPTARGET (__chk_fail)
  39 END (__memcpy_chk)
  40 #endif
  41 ENTRY (BP_SYM (memcpy))
  42         ENTER
  43
  44         movl    %edi, %eax
  45         movl    DEST(%esp), %edi
  46         movl    %esi, %edx
  47         movl    SRC(%esp), %esi
  48
  49         movl    %edi, %ecx
  50         xorl    %esi, %ecx
  51         andl    $3, %ecx
  52         movl    LEN(%esp), %ecx
  53         cld
  54         jne     .Lunaligned
  55
  56         cmpl    $3, %ecx
  57         jbe     .Lunaligned
  58
  59         testl   $3, %esi
  60         je      1f
  61         movsb
  62         decl    %ecx
  63         testl   $3, %esi
  64         je      1f
  65         movsb
  66         decl    %ecx
  67         testl   $3, %esi
  68         je      1f
  69         movsb
  70         decl    %ecx
  71 1:      pushl   %eax
  72         movl    %ecx, %eax
  73         shrl    $2, %ecx
  74         andl    $3, %eax
  75         rep
  76         movsl
  77         movl    %eax, %ecx
  78         rep
  79         movsb
  80         popl    %eax
  81
  82 .Lend:  movl    %eax, %edi
  83         movl    %edx, %esi
  84         movl    DEST(%esp), %eax
  85         RETURN_BOUNDED_POINTER (DEST(%esp))
  86
  87         LEAVE
  88         RET_PTR
  89
  90         /* When we come here the pointers do not have the same
  91            alignment or the length is too short.  No need to optimize for
  92            aligned memory accesses. */
  93 .Lunaligned:
  94         shrl    $1, %ecx
  95         jnc     1f
  96         movsb
  97 1:      shrl    $1, %ecx
  98         jnc     2f
  99         movsw
 100 2:      rep
 101         movsl
 102         jmp     .Lend
 103 END (BP_SYM (memcpy))
 104 libc_hidden_builtin_def (memcpy)