sysdeps/i386/i686/add_n.S

   1 /* Add two limb vectors of the same length > 0 and store sum in a third
   2    limb vector.
   3    Copyright (C) 1992,94,95,97,98,2000,2005 Free Software Foundation, Inc.
   4    This file is part of the GNU MP Library.
   5
   6    The GNU MP Library is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU Lesser General Public License as published by
   8    the Free Software Foundation; either version 2.1 of the License, or (at your
   9    option) any later version.
  10
  11    The GNU MP Library is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  14    License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public License
  17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  19    MA 02111-1307, USA. */
  20
  21 #include "sysdep.h"
  22 #include "asm-syntax.h"
  23 #include "bp-sym.h"
  24 #include "bp-asm.h"
  25
  26 #define PARMS   LINKAGE+8               /* space for 2 saved regs */
  27 #define RES     PARMS
  28 #define S1      RES+PTR_SIZE
  29 #define S2      S1+PTR_SIZE
  30 #define SIZE    S2+PTR_SIZE
  31
  32         .text
  33 #ifdef PIC
  34 L(1):   addl    (%esp), %eax
  35         ret
  36 #endif
  37 ENTRY (BP_SYM (__mpn_add_n))
  38         ENTER
  39
  40         pushl %edi
  41         cfi_adjust_cfa_offset (4)
  42         pushl %esi
  43         cfi_adjust_cfa_offset (4)
  44
  45         movl    RES(%esp),%edi
  46         cfi_rel_offset (edi, 4)
  47         movl    S1(%esp),%esi
  48         cfi_rel_offset (esi, 0)
  49         movl    S2(%esp),%edx
  50         movl    SIZE(%esp),%ecx
  51 #if __BOUNDED_POINTERS__
  52         shll    $2, %ecx        /* convert limbs to bytes */
  53         CHECK_BOUNDS_BOTH_WIDE (%edi, RES(%esp), %ecx)
  54         CHECK_BOUNDS_BOTH_WIDE (%esi, S1(%esp), %ecx)
  55         CHECK_BOUNDS_BOTH_WIDE (%edx, S2(%esp), %ecx)
  56         shrl    $2, %ecx
  57 #endif
  58         movl    %ecx,%eax
  59         shrl    $3,%ecx                 /* compute count for unrolled loop */
  60         negl    %eax
  61         andl    $7,%eax                 /* get index where to start loop */
  62         jz      L(oop)                  /* necessary special case for 0 */
  63         incl    %ecx                    /* adjust loop count */
  64         shll    $2,%eax                 /* adjustment for pointers... */
  65         subl    %eax,%edi               /* ... since they are offset ... */
  66         subl    %eax,%esi               /* ... by a constant when we ... */
  67         subl    %eax,%edx               /* ... enter the loop */
  68         shrl    $2,%eax                 /* restore previous value */
  69 #ifdef PIC
  70 /* Calculate start address in loop for PIC.  */
  71         leal    (L(oop)-L(0)-3)(%eax,%eax,8),%eax
  72         call    L(1)
  73 L(0):
  74 #else
  75 /* Calculate start address in loop for non-PIC.  */
  76         leal    (L(oop) - 3)(%eax,%eax,8),%eax
  77 #endif
  78         jmp     *%eax                   /* jump into loop */
  79         ALIGN (3)
  80 L(oop): movl    (%esi),%eax
  81         adcl    (%edx),%eax
  82         movl    %eax,(%edi)
  83         movl    4(%esi),%eax
  84         adcl    4(%edx),%eax
  85         movl    %eax,4(%edi)
  86         movl    8(%esi),%eax
  87         adcl    8(%edx),%eax
  88         movl    %eax,8(%edi)
  89         movl    12(%esi),%eax
  90         adcl    12(%edx),%eax
  91         movl    %eax,12(%edi)
  92         movl    16(%esi),%eax
  93         adcl    16(%edx),%eax
  94         movl    %eax,16(%edi)
  95         movl    20(%esi),%eax
  96         adcl    20(%edx),%eax
  97         movl    %eax,20(%edi)
  98         movl    24(%esi),%eax
  99         adcl    24(%edx),%eax
 100         movl    %eax,24(%edi)
 101         movl    28(%esi),%eax
 102         adcl    28(%edx),%eax
 103         movl    %eax,28(%edi)
 104         leal    32(%edi),%edi
 105         leal    32(%esi),%esi
 106         leal    32(%edx),%edx
 107         decl    %ecx
 108         jnz     L(oop)
 109
 110         sbbl    %eax,%eax
 111         negl    %eax
 112
 113         popl %esi
 114         cfi_adjust_cfa_offset (-4)
 115         cfi_restore (esi)
 116         popl %edi
 117         cfi_adjust_cfa_offset (-4)
 118         cfi_restore (edi)
 119
 120         LEAVE
 121         ret
 122 END (BP_SYM (__mpn_add_n))