configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memusagestat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 228 # Unify this here.
 229 if test "$machine" = rs6000; then
 230   machine="powerpc"
 231 fi
 232
 233 ###
 234 ### I put this here to prevent those annoying emails from people who cannot
 235 ### read and try to compile glibc on unsupported platforms.  --drepper
 236 ###
 237 ### By using the undocumented --enable-hacker-mode option for configure
 238 ### one can skip this test to make the configuration not fail for unsupported
 239 ### platforms.
 240 ###
 241 if test -z "$enable_hacker_mode"; then
 242   case "$machine-$host_os" in
 243   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 244     ;;
 245   *)
 246     echo "*** The GNU C library is currently not available for this platform."
 247     echo "*** So far nobody cared to port it and if there is no volunteer it"
 248     echo "*** might never happen.  So, if you have interest to see glibc on"
 249     echo "*** this platform visit"
 250     echo "***   http://www.gnu.org/software/libc/porting.html"
 251     echo "*** and join the group of porters"
 252     exit 1
 253     ;;
 254   esac
 255 fi
 256
 257 dnl We need to use [ and ] for other purposes for a while now.
 258 changequote(,)dnl
 259 # Expand the configuration machine name into a subdirectory by architecture
 260 # type and particular chip.
 261 case "$machine" in
 262 a29k | am29000) base_machine=a29k machine=a29k ;;
 263 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 264 arm*)           base_machine=arm machine=arm/$machine ;;
 265 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 266 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 267 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 268 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 269 ia64)           base_machine=ia64 machine=ia64 ;;
 270 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 271 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 272 m88???)         base_machine=m88k machine=m88k/$machine ;;
 273 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 274 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 275 mips*)          base_machine=mips
 276                 case "`uname -m`" in
 277                 IP22) machine=mips/mips3 ;;
 278                 *)    machine=mips/$machine ;;
 279                 esac ;;
 280 sh3*)           base_machine=sh machine=sh/sh3 ;;
 281 sh4*)           base_machine=sh machine=sh/sh4 ;;
 282 sparc | sparcv[67])
 283                 base_machine=sparc machine=sparc/sparc32 ;;
 284 sparcv8 | supersparc | hypersparc)
 285                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 286 sparcv8plus | sparcv8plusa | sparcv9)
 287                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 288 sparc64 | ultrasparc)
 289                 base_machine=sparc machine=sparc/sparc64 ;;
 290 esac
 291 changequote([,])dnl
 292 AC_SUBST(base_machine)
 293
 294 if test "$base_machine" = "i386"; then
 295   AC_DEFINE(USE_REGPARMS)
 296 fi
 297
 298 # Compute the list of sysdep directories for this configuration.
 299 # This can take a while to compute.
 300 sysdep_dir=$srcdir/sysdeps
 301 AC_MSG_CHECKING(sysdep dirs)
 302 dnl We need to use [ and ] for other purposes for a while now.
 303 changequote(,)dnl
 304 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 305 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 306
 307 case "$os" in
 308 gnu*)
 309   base_os=mach/hurd ;;
 310 netbsd* | 386bsd* | freebsd* | bsdi*)
 311   base_os=unix/bsd/bsd4.4 ;;
 312 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 313   base_os=unix/bsd ;;
 314 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 315   base_os=unix/sysv ;;
 316 irix6*)
 317   base_os=unix/sysv/irix6/$os ;;
 318 solaris[2-9]*)
 319   base_os=unix/sysv/sysv4 ;;
 320 hpux*)
 321   base_os=unix/sysv/hpux/$os ;;
 322 aix4.3*)
 323   base_os=unix/sysv/aix/aix4.3 ;;
 324 none)
 325   base_os=standalone ;;
 326 *)
 327   base_os='' ;;
 328 esac
 329
 330 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 331 tail=$os
 332 ostry=$os
 333 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 334   ostry="$ostry /$o"
 335   tail=$o
 336 done
 337 o=`echo $tail | sed 's/[0-9]*$//'`
 338 if test $o != $tail; then
 339   ostry="$ostry /$o"
 340 fi
 341 # For linux-gnu, try linux-gnu, then linux.
 342 o=`echo $tail | sed 's/-.*$//'`
 343 if test $o != $tail; then
 344   ostry="$ostry /$o"
 345 fi
 346
 347 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 348 base=
 349 tail=$base_os
 350 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 351   set $b
 352   base="$base /$1"
 353   tail="$2"
 354 done
 355
 356 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 357 mach=
 358 tail=$machine
 359 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 360   set $m
 361   # Prepend the machine's FPU directory unless --without-fp.
 362   if test "$with_fp" = yes; then
 363     mach="$mach /$1/fpu"
 364   fi
 365   mach="$mach /$1"
 366   tail="$2"
 367 done
 368
 369 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 370 changequote([,])dnl
 371
 372 # Find what sysdep directories exist.
 373 sysnames=
 374 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 375 for d in $add_ons_pfx ''; do
 376   for b in $base ''; do
 377     for m0 in $mach ''; do
 378       for v in /$vendor ''; do
 379         test "$v" = / && continue
 380         for o in /$ostry ''; do
 381           test "$o" = / && continue
 382           for m in $mach ''; do
 383             if test "$m0$b$v$o$m"; then
 384               try="${d}sysdeps$m0$b$v$o$m"
 385               test -n "$enable_debug_configure" &&
 386               echo "$0 [DEBUG]: try $try" >&2
 387               if test -d $srcdir/$try; then
 388                 sysnames="$sysnames $try"
 389                 { test -n "$o" || test -n "$b"; } && os_used=t
 390                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 391               fi
 392             fi
 393           done
 394         done
 395       done
 396     done
 397   done
 398 done
 399 IFS="$ac_save_ifs"
 400
 401 if test -z "$os_used" && test "$os" != none; then
 402   AC_MSG_ERROR(Operating system $os is not supported.)
 403 fi
 404 if test -z "$machine_used" && test "$machine" != none; then
 405   AC_MSG_ERROR(The $machine is not supported.)
 406 fi
 407
 408 # We have now validated the configuration.
 409
 410
 411 # If using ELF, look for an `elf' subdirectory of each machine directory.
 412 # We prepend these rather than inserting them whereever the machine appears
 413 # because things specified by the machine's ELF ABI should override
 414 # OS-specific things, and should always be the same for any OS on the
 415 # machine (otherwise what's the point of an ABI?).
 416 if test "$elf" = yes; then
 417   elf_dirs=
 418   for d in $add_ons_pfx ''; do
 419     for m in $mach; do
 420       if test -d $srcdir/${d}sysdeps$m/elf; then
 421         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 422       fi
 423     done
 424   done
 425   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 426 fi
 427
 428
 429 # Expand the list of system names into a full list of directories
 430 # from each element's parent name and Implies file (if present).
 431 set $sysnames
 432 names=
 433 while test $# -gt 0; do
 434   name=$1
 435   shift
 436
 437   case " $names " in *" $name "*)
 438     # Already in the list.
 439     continue
 440   esac
 441
 442   # Report each name as we discover it, so there is no long pause in output.
 443   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 444
 445   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 446
 447   case $name in
 448     /*) xsrcdir= ;;
 449     *)  xsrcdir=$srcdir/ ;;
 450   esac
 451   test -n "$enable_debug_configure" &&
 452   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 453
 454   if test -f $xsrcdir$name/Implies; then
 455     # Collect more names from the `Implies' file (removing comments).
 456     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 457     implied=
 458     for x in $implied_candidate; do
 459       if test -d $xsrcdir$name_base/$x; then
 460         implied="$implied $name_base/$x";
 461       else
 462         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 463       fi
 464     done
 465   else
 466     implied=
 467   fi
 468
 469   # Add NAME to the list of names.
 470   names="$names $name"
 471
 472   # Find the parent of NAME, using the empty string if it has none.
 473 changequote(,)dnl
 474   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 475 changequote([,])dnl
 476
 477   # Add the names implied by NAME, and NAME's parent (if it has one), to
 478   # the list of names to be processed (the argument list).  We prepend the
 479   # implied names to the list and append the parent.  We want implied
 480   # directories to come before further directories inferred from the
 481   # configuration components; this ensures that for sysv4, unix/common
 482   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 483   # after sysv4).
 484   sysnames="`echo $implied $* $parent`"
 485   test -n "$sysnames" && set $sysnames
 486 done
 487
 488 # Add the default directories.
 489 default_sysnames=sysdeps/generic
 490 if test "$elf" = yes; then
 491   default_sysnames="sysdeps/generic/elf $default_sysnames"
 492 fi
 493 sysnames="$names $default_sysnames"
 494 AC_SUBST(sysnames)
 495 # The other names were emitted during the scan.
 496 AC_MSG_RESULT($default_sysnames)
 497
 498
 499 ### Locate tools.
 500
 501 AC_PROG_INSTALL
 502 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 503   # The makefiles need to use a different form to find it in $srcdir.
 504   INSTALL='\$(..)./scripts/install-sh -c'
 505 fi
 506 AC_PROG_LN_S
 507
 508 # We need the physical current working directory.  We cannot use the
 509 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 510 # find a pwd binary.  Note that assigning to the PWD environment
 511 # variable might have some interesting side effects, so we don't do
 512 # that.
 513 AC_PATH_PROG(PWD_P, pwd, no)
 514 if test "$PWD_P" = no; then
 515   AC_MSG_ERROR(*** A pwd binary could not be found.)
 516 fi
 517
 518 # These programs are version sensitive.
 519 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 520 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 521   [version \([egcygnustpi-]*[0-9.]*\)],
 522   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 523   critic_missing=t)
 524 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 525   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 526   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 527
 528 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 529   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 530   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 531 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 532   [GNU texinfo.* \([0-9][0-9.]*\)],
 533   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 534 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 535   [GNU sed version \([0-9]*\.[0-9.]*\)],
 536   [3.0[2-9]|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 537
 538 if test -n "$critic_missing"; then
 539 AC_MSG_ERROR([
 540 *** Some critical program is missing or too old.
 541 *** Check the INSTALL file for required versions.])
 542 fi
 543
 544 test -n "$aux_missing" && AC_MSG_WARN([
 545 *** An auxiliary program is missing or too old;
 546 *** some features will be disabled.
 547 *** Check the INSTALL file for required versions.])
 548
 549 # glibcbug.in wants to know the compiler version.
 550 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 551 AC_SUBST(CCVERSION)
 552
 553 AC_PROG_CC_LOCAL
 554 AC_CANONICAL_BUILD
 555 if test $host != $build; then
 556   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 557 fi
 558 AC_SUBST(cross_compiling)
 559 AC_PROG_CPP
 560 LIBC_PROG_BINUTILS
 561 AC_CHECK_TOOL(MIG, mig)
 562
 563 # if using special system headers, find out the compiler's sekrit
 564 # header directory and add that to the list.  NOTE: Only does the right
 565 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 566 if test -n "$sysheaders"; then
 567   ccheaders=`$CC -print-file-name=include`
 568   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 569 fi
 570 AC_SUBST(SYSINCLUDES)
 571
 572 # check if ranlib is necessary
 573 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 574 cat > conftest.c <<EOF
 575 int a;
 576 char b;
 577 void c(void) {}
 578 EOF
 579 $CC $CFLAGS -c conftest.c
 580 $AR cr conftest.a conftest.c
 581 cp conftest.a conftest2.a
 582 $RANLIB conftest.a
 583 if cmp -s conftest.a conftest2.a; then
 584   libc_cv_ranlib_necessary=no
 585 else
 586   libc_cv_ranlib_necessary=yes
 587 fi
 588 rm -rf conftest*])
 589 if test "$libc_cv_ranlib_necessary" = no; then
 590  RANLIB=:
 591 fi
 592
 593 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 594 # since this would lead to problems installing/building glibc.
 595 # LD_LIBRARY_PATH contains the current directory if one of the following
 596 # is true:
 597 # - one of the terminals (":" and ";") is the first or last sign
 598 # - two terminals occur directly after each other
 599 # - the path contains an element with a dot in it
 600 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 601 changequote(,)dnl
 602 case ${LD_LIBRARY_PATH} in
 603   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 604     ld_library_path_setting="contains current directory"
 605     ;;
 606   *)
 607     ld_library_path_setting="ok"
 608     ;;
 609 esac
 610 changequote([,])dnl
 611 AC_MSG_RESULT($ld_library_path_setting)
 612 if test "$ld_library_path_setting" != "ok"; then
 613 AC_MSG_ERROR([
 614 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 615 *** building glibc. Please change the environment variable
 616 *** and run configure again.])
 617 fi
 618
 619 AC_PATH_PROG(BASH, bash, no)
 620 if test "$BASH" != no &&
 621    $BASH -c 'test "$BASH_VERSINFO" \
 622              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 623   libc_cv_have_bash2=yes
 624 else
 625   libc_cv_have_bash2=no
 626 fi
 627 AC_SUBST(libc_cv_have_bash2)
 628
 629 dnl We need a ksh compatible shell for tzselect.
 630 if test "$BASH" = no; then
 631   AC_PATH_PROG(KSH, ksh, no)
 632   if test "$KSH" = no; then
 633     libc_cv_have_ksh=no
 634   else
 635     libc_cv_have_ksh=yes
 636   fi
 637 else
 638   KSH="$BASH"
 639   AC_SUBST(KSH)
 640   libc_cv_have_ksh=yes
 641 fi
 642 AC_SUBST(libc_cv_have_ksh)
 643
 644 AC_PROG_AWK
 645 AC_PATH_PROG(PERL, perl, no)
 646 if test "$PERL" != no &&
 647    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 648   PERL=no
 649 fi
 650 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 651              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 652 if test "$INSTALL_INFO" != "no"; then
 653 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 654  [mkdir conftest.d
 655   # There is a hard ^_ on the next line.  I am open to better ideas.
 656   (echo '\x1f'
 657   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 658   echo '* Menu:') >conftest.d/dir
 659   (echo 'INFO-DIR-SECTION i-d-s works'
 660   echo 'START-INFO-DIR-ENTRY'
 661   echo '* Prog: (prog).   Program.'
 662   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 663   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 664   then
 665     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 666     then libc_cv_old_debian_install_info=no
 667     else libc_cv_old_debian_install_info=yes
 668     fi
 669   else libc_cv_old_debian_install_info=no testfailed=t
 670   fi
 671   rm -fr conftest.d])
 672 if test -n "$testfailed"
 673 then AC_MSG_WARN([install-info errored out, check config.log])
 674 fi
 675 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 676 fi
 677 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 678
 679 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 680 echo '#include <stddef.h>
 681 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 682 if eval "$ac_cpp conftest.c 2>/dev/null" \
 683 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 684   libc_cv_signed_size_t=no
 685 else
 686   libc_cv_signed_size_t=yes
 687 fi
 688 rm -f conftest*])
 689 if test $libc_cv_signed_size_t = yes; then
 690   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 691   cat >> confdefs.h <<\EOF
 692 #undef __SIZE_TYPE__
 693 #define __SIZE_TYPE__ unsigned
 694 EOF
 695 fi
 696
 697 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 698 AC_TRY_COMPILE(dnl
 699 [#define __need_size_t
 700 #define __need_wchar_t
 701 #include <stddef.h>
 702 #define __need_NULL
 703 #include <stddef.h>], [size_t size; wchar_t wchar;
 704 #ifdef offsetof
 705 #error stddef.h ignored __need_*
 706 #endif
 707 if (&size == NULL || &wchar == NULL) abort ();],
 708                libc_cv_friendly_stddef=yes,
 709                libc_cv_friendly_stddef=no)])
 710 if test $libc_cv_friendly_stddef = yes; then
 711   config_vars="$config_vars
 712 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 713 fi
 714
 715 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 716                libc_cv_need_minus_P, [dnl
 717 cat > conftest.S <<EOF
 718 #include "confdefs.h"
 719 /* Nothing whatsoever.  */
 720 EOF
 721 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 722   libc_cv_need_minus_P=no
 723 else
 724   libc_cv_need_minus_P=yes
 725 fi
 726 rm -f conftest*])
 727 if test $libc_cv_need_minus_P = yes; then
 728   config_vars="$config_vars
 729 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 730 fi
 731
 732 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 733 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 734 cat > conftest.s <<EOF
 735 .text
 736 EOF
 737 libc_cv_dot_text=
 738 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 739   libc_cv_dot_text=.text
 740 fi
 741 rm -f conftest*])
 742 if test -z "$libc_cv_dot_text"; then
 743   AC_MSG_RESULT(no)
 744 else
 745   AC_MSG_RESULT(yes)
 746 fi
 747
 748 AC_CACHE_CHECK(for assembler global-symbol directive,
 749                libc_cv_asm_global_directive, [dnl
 750 libc_cv_asm_global_directive=UNKNOWN
 751 for ac_globl in .globl .global .EXPORT; do
 752   cat > conftest.s <<EOF
 753         ${libc_cv_dot_text}
 754         ${ac_globl} foo
 755 foo:
 756 EOF
 757   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 758     libc_cv_asm_global_directive=${ac_globl}
 759   fi
 760   rm -f conftest*
 761   test $libc_cv_asm_global_directive != UNKNOWN && break
 762 done])
 763 if test $libc_cv_asm_global_directive = UNKNOWN; then
 764   AC_MSG_ERROR(cannot determine asm global directive)
 765 else
 766   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 767 fi
 768
 769 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 770 cat > conftest.s <<EOF
 771 ${libc_cv_dot_text}
 772 foo:
 773 .set glibc_conftest_frobozz,foo
 774 $libc_cv_asm_global_directive glibc_conftest_frobozz
 775 EOF
 776 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 777 # (but it doesn't work), so we must do a linking check to be sure.
 778 cat > conftest1.c <<\EOF
 779 extern int glibc_conftest_frobozz;
 780 main () { printf ("%d\n", glibc_conftest_frobozz); }
 781 EOF
 782 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 783             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 784   libc_cv_asm_set_directive=yes
 785 else
 786   libc_cv_asm_set_directive=no
 787 fi
 788 rm -f conftest*])
 789 if test $libc_cv_asm_set_directive = yes; then
 790   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 791 fi
 792
 793 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 794 [cat > conftest.s <<EOF
 795 ${libc_cv_dot_text}
 796 _sym:
 797 .symver _sym,sym@VERS
 798 EOF
 799 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 800   libc_cv_asm_symver_directive=yes
 801 else
 802   libc_cv_asm_symver_directive=no
 803 fi
 804 rm -f conftest*])
 805 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 806 if test $libc_cv_asm_symver_directive = yes; then
 807   cat > conftest.s <<EOF
 808 ${libc_cv_dot_text}
 809 _sym:
 810 .symver _sym,sym@VERS
 811 EOF
 812   cat > conftest.map <<EOF
 813 VERS_1 {
 814         global: sym;
 815 };
 816
 817 VERS_2 {
 818         global: sym;
 819 } VERS_1;
 820 EOF
 821   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 822     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 823                                         -nostartfiles -nostdlib
 824                                         -Wl,--version-script,conftest.map
 825                        1>&AC_FD_CC]);
 826     then
 827       libc_cv_ld_version_script_option=yes
 828     else
 829       libc_cv_ld_version_script_option=no
 830     fi
 831   else
 832     libc_cv_ld_version_script_option=no
 833   fi
 834 else
 835   libc_cv_ld_version_script_option=no
 836 fi
 837 rm -f conftest*])
 838 if test $shared != no &&
 839    test $libc_cv_asm_symver_directive = yes &&
 840    test $libc_cv_ld_version_script_option = yes &&
 841    test $enable_versioning = yes; then
 842   VERSIONING=yes
 843   AC_DEFINE(DO_VERSIONING)
 844 else
 845   VERSIONING=no
 846 fi
 847 AC_SUBST(VERSIONING)
 848
 849 if test $shared != no && test $VERSIONING = no; then
 850   echo "\
 851 *** WARNING: You should not compile GNU libc without versioning. Not using
 852 *** versioning will introduce incompatibilities so that old binaries
 853 *** will not run anymore.
 854 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 855 fi
 856 if test $elf = yes; then
 857   AC_CACHE_CHECK(for .previous assembler directive,
 858                  libc_cv_asm_previous_directive, [dnl
 859   cat > conftest.s <<EOF
 860 .section foo_section
 861 .previous
 862 EOF
 863   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 864     libc_cv_asm_previous_directive=yes
 865   else
 866     libc_cv_asm_previous_directive=no
 867   fi
 868   rm -f conftest*])
 869   if test $libc_cv_asm_previous_directive = yes; then
 870     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 871   else
 872     AC_CACHE_CHECK(for .popsection assembler directive,
 873                    libc_cv_asm_popsection_directive, [dnl
 874     cat > conftest.s <<EOF
 875 .pushsection foo_section
 876 .popsection
 877 EOF
 878     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 879       libc_cv_asm_popsection_directive=yes
 880     else
 881       libc_cv_asm_popsection_directive=no
 882     fi
 883     rm -f conftest*])
 884     if test $libc_cv_asm_popsection_directive = yes; then
 885       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 886     fi
 887   fi
 888   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 889                  libc_cv_asm_protected_directive, [dnl
 890   cat > conftest.s <<EOF
 891 .protected foo
 892 foo:
 893 .hidden bar
 894 bar:
 895 EOF
 896   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 897     libc_cv_asm_protected_directive=yes
 898   else
 899     libc_cv_asm_protected_directive=no
 900   fi
 901   rm -f conftest*])
 902   AC_SUBST(libc_cv_asm_protected_directive)
 903 fi
 904
 905 if test $elf != yes; then
 906   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 907                  [AC_TRY_COMPILE(, [asm (".section .init");
 908                                     asm (".section .fini");
 909                                     asm ("${libc_cv_dot_text}");],
 910                                  libc_cv_have_initfini=yes,
 911                                  libc_cv_have_initfini=no)])
 912   AC_SUBST(libc_cv_have_initfini)dnl
 913   if test $libc_cv_have_initfini = yes; then
 914     AC_DEFINE(HAVE_INITFINI)
 915   fi
 916 fi
 917
 918 if test $elf = yes -a $gnu_ld = yes; then
 919   AC_CACHE_CHECK(whether cc puts quotes around section names,
 920                  libc_cv_have_section_quotes,
 921                  [cat > conftest.c <<EOF
 922                   static const int foo
 923                   __attribute__ ((section ("bar"))) = 1;
 924 EOF
 925                   if ${CC-cc} -S conftest.c -o conftest.s; then
 926                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
 927                       libc_cv_have_section_quotes=yes
 928                     else
 929                       libc_cv_have_section_quotes=no
 930                     fi
 931                   else
 932                     libc_cv_have_section_quotes=unknown
 933                   fi
 934                   rm -f conftest.[cs]
 935                  ])
 936   if test $libc_cv_have_section_quotes = yes; then
 937     AC_DEFINE(HAVE_SECTION_QUOTES)
 938   fi
 939 fi
 940
 941 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 942 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 943 [cat > conftest.$ac_ext <<EOF
 944 dnl This sometimes fails to find confdefs.h, for some reason.
 945 dnl [#]line __oline__ "[$]0"
 946 [#]line __oline__ "configure"
 947 #include "confdefs.h"
 948 void underscore_test(void) {
 949 return; }
 950 EOF
 951 if AC_TRY_EVAL(ac_compile); then
 952   if grep _underscore_test conftest* >/dev/null; then
 953     ifelse([$1], , :, [rm -f conftest*
 954     $1])
 955   else
 956     ifelse([$2], , , [rm -f conftest*
 957     $2])
 958   fi
 959 else
 960   echo "configure: failed program was:" >&AC_FD_CC
 961   cat conftest.$ac_ext >&AC_FD_CC
 962   ifelse([$2], , , [rm -f conftest*
 963   $2])
 964 fi
 965 rm -f conftest*])
 966
 967 if test $elf = yes; then
 968   libc_cv_asm_underscores=no
 969 else
 970   if test $ac_cv_prog_cc_works = yes; then
 971     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 972                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 973                                 libc_cv_asm_underscores=yes,
 974                                 libc_cv_asm_underscores=no)])
 975   else
 976     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 977                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 978                                             libc_cv_asm_underscores=no)])
 979   fi
 980 fi
 981 if test $libc_cv_asm_underscores = no; then
 982   AC_DEFINE(NO_UNDERSCORES)
 983 fi
 984
 985 if test $elf = yes; then
 986   libc_cv_weak_symbols=yes
 987 fi
 988
 989 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 990                [dnl
 991 cat > conftest.s <<EOF
 992 ${libc_cv_dot_text}
 993 ${libc_cv_asm_global_directive} foo
 994 foo:
 995 .weak foo
 996 .weak bar; bar = foo
 997 EOF
 998 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 999   libc_cv_asm_weak_directive=yes
1000 else
1001   libc_cv_asm_weak_directive=no
1002 fi
1003 rm -f conftest*])
1004
1005 if test $libc_cv_asm_weak_directive = no; then
1006   AC_CACHE_CHECK(for assembler .weakext directive,
1007                  libc_cv_asm_weakext_directive,
1008                  [dnl
1009 cat > conftest.s <<EOF
1010 ${libc_cv_dot_text}
1011 ${libc_cv_asm_global_directive} foo
1012 foo:
1013 .weakext bar foo
1014 .weakext baz
1015 ${libc_cv_asm_global_directive} baz
1016 baz:
1017 EOF
1018   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1019     libc_cv_asm_weakext_directive=yes
1020   else
1021     libc_cv_asm_weakext_directive=no
1022   fi
1023   rm -f conftest*])
1024
1025 fi # no .weak
1026
1027 if test $libc_cv_asm_weak_directive = yes; then
1028   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1029 elif test $libc_cv_asm_weakext_directive = yes; then
1030   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1031 fi
1032
1033 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1034 cat > conftest.c <<\EOF
1035 _start () {}
1036 int __eh_pc;
1037 __throw () {}
1038 EOF
1039 dnl No \ in command here because it ends up inside ''.
1040 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1041                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1042                             -o conftest conftest.c 1>&AC_FD_CC]); then
1043   libc_cv_ld_no_whole_archive=yes
1044 else
1045   libc_cv_ld_no_whole_archive=no
1046 fi
1047 rm -f conftest*])
1048 if test $libc_cv_ld_no_whole_archive = yes; then
1049   no_whole_archive=-Wl,--no-whole-archive
1050 fi
1051 AC_SUBST(no_whole_archive)dnl
1052
1053 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1054 cat > conftest.c <<\EOF
1055 _start () {}
1056 int __eh_pc;
1057 __throw () {}
1058 EOF
1059 dnl No \ in command here because it ends up inside ''.
1060 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1061                             -nostdlib -nostartfiles -fexceptions
1062                             -o conftest conftest.c 1>&AC_FD_CC]); then
1063   libc_cv_gcc_exceptions=yes
1064 else
1065   libc_cv_gcc_exceptions=no
1066 fi
1067 rm -f conftest*])
1068 if test $libc_cv_gcc_exceptions = yes; then
1069   exceptions=-fexceptions
1070 fi
1071 AC_SUBST(exceptions)dnl
1072
1073 if test "$base_machine" = alpha ; then
1074 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1075 cat > conftest.c <<\EOF
1076 foo () { }
1077 EOF
1078 dnl
1079 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1080 then
1081   libc_cv_gcc_alpha_ng_prefix=yes
1082 else
1083   libc_cv_gcc_alpha_ng_prefix=no
1084 fi
1085 rm -f conftest* ])
1086 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1087   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1088 else
1089   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1090 fi
1091 fi
1092
1093 if test "$host_cpu" = powerpc ; then
1094 # Check for a bug present in at least versions 2.8.x of GCC
1095 # and versions 1.0.x of EGCS.
1096 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1097 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1098                libc_cv_c_asmcr0_bug='no',
1099                libc_cv_c_asmcr0_bug='yes')])
1100 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1101   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1102 fi
1103 fi
1104
1105 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1106 [cat > conftest.c <<EOF
1107 #line __oline__ "configure"
1108 static char __EH_FRAME_BEGIN__[];
1109 _start ()
1110 {
1111 #ifdef CHECK__register_frame
1112   __register_frame (__EH_FRAME_BEGIN__);
1113   __deregister_frame (__EH_FRAME_BEGIN__);
1114 #endif
1115 #ifdef CHECK__register_frame_info
1116   __register_frame_info (__EH_FRAME_BEGIN__);
1117   __deregister_frame_info (__EH_FRAME_BEGIN__);
1118 #endif
1119 }
1120 int __eh_pc;
1121 __throw () {}
1122 /* FIXME: this is fragile.  */
1123 malloc () {}
1124 strcmp () {}
1125 strlen () {}
1126 memcpy () {}
1127 memset () {}
1128 free () {}
1129 abort () {}
1130 __bzero () {}
1131 EOF
1132 dnl No \ in command here because it ends up inside ''.
1133 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1134                             -nostdlib -nostartfiles
1135                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1136   libc_cv_gcc_dwarf2_unwind_info=static
1137 else
1138   libc_cv_gcc_dwarf2_unwind_info=no
1139 fi
1140 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1141   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1142                               -nostdlib -nostartfiles
1143                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1144     libc_cv_gcc_dwarf2_unwind_info=yes
1145   else
1146     libc_cv_gcc_dwarf2_unwind_info=no
1147   fi
1148 fi
1149 rm -f conftest*])
1150 case $libc_cv_gcc_dwarf2_unwind_info in
1151 yes)
1152   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1153   ;;
1154 static)
1155   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1156   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1157   ;;
1158 esac
1159
1160 dnl Check whether compiler understands __builtin_expect.
1161 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1162 [cat > conftest.c <<EOF
1163 #line __oline__ "configure"
1164 int foo (int a)
1165 {
1166   a = __builtin_expect (a, 10);
1167   return a == 10 ? 0 : 1;
1168 }
1169 EOF
1170 dnl No \ in command here because it ends up inside ''.
1171 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1172                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1173   libc_cv_gcc_builtin_expect=yes
1174 else
1175   libc_cv_gcc_builtin_expect=no
1176 fi
1177 rm -f conftest*])
1178 if test "$libc_cv_gcc_builtin_expect" = yes; then
1179   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1180 fi
1181
1182 dnl Check whether the compiler supports subtraction of local labels.
1183 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1184 [cat > conftest.c <<EOF
1185 changequote(,)dnl
1186 #line __oline__ "configure"
1187 int foo (int a)
1188 {
1189   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1190   void *p = &&l1 + ar[a];
1191   goto *p;
1192  l1:
1193   return 1;
1194  l2:
1195   return 2;
1196 }
1197 changequote([,])dnl
1198 EOF
1199 dnl No \ in command here because it ends up inside ''.
1200 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1201                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1202   libc_cv_gcc_subtract_local_labels=yes
1203 else
1204   libc_cv_gcc_subtract_local_labels=no
1205 fi
1206 rm -f conftest*])
1207 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1208   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1209 fi
1210
1211 dnl Check whether we have the gd library available.
1212 AC_MSG_CHECKING(for libgd)
1213 old_CFLAGS="$CFLAGS"
1214 CFLAGS="$CFLAGS $libgd_include"
1215 old_LDFLAGS="$LDFLAGS"
1216 LDFLAGS="$LDFLAGS $libgd_ldflags"
1217 old_LIBS="$LIBS"
1218 LIBS="$LIBS -lgd -lpng -lz"
1219 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1220 CFLAGS="$old_CFLAGS"
1221 LDFLAGS="$old_LDFLAGS"
1222 LIBS="$old_LIBS"
1223 AC_MSG_RESULT($LIBGD)
1224 AC_SUBST(LIBGD)
1225
1226 dnl check for the size of 'long double'.
1227 AC_CHECK_SIZEOF(long double, 0)
1228 sizeof_long_double=$ac_cv_sizeof_long_double
1229 AC_SUBST(sizeof_long_double)
1230
1231 ### End of automated tests.
1232 ### Now run sysdeps configure fragments.
1233
1234 # sysdeps configure fragments may set these with files to be linked below.
1235 libc_link_dests=
1236 libc_link_sources=
1237
1238 # They also can set these variables.
1239 use_ldconfig=no
1240 ldd_rewrite_script=no
1241
1242 # Iterate over all the sysdep directories we will use, running their
1243 # configure fragments, and looking for a uname implementation.
1244 uname=
1245 for dir in $sysnames; do
1246   case $dir in
1247     /*) dest=$dir ;;
1248     *)  dest=$srcdir/$dir ;;
1249   esac
1250   if test -r $dest/configure; then
1251     AC_MSG_RESULT(running configure fragment for $dest)
1252     . $dest/configure
1253   fi
1254 [
1255   if test -z "$uname"; then
1256     if test -r $dest/uname.c ||
1257        test -r $dest/uname.S ||
1258        { test -r $dest/syscalls.list &&
1259          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1260       uname=$dir
1261     fi
1262   fi
1263 ]dnl
1264 done
1265
1266 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1267
1268 # If we will use the generic uname implementation, we must figure out what
1269 # it will say by examining the system, and write the results in config-name.h.
1270 if test "$uname" = "sysdeps/generic"; then
1271
1272 changequote(,)dnl
1273   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1274 changequote([,])dnl
1275   if test $uname_sysname != $config_os; then
1276     config_release=`echo $config_os | sed s/$uname_sysname//`
1277   fi
1278 dnl
1279 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1280     if test -r /vmunix; then
1281       kernel_id=`strings /vmunix | grep UNIX`
1282     elif test -r /dynix; then
1283       kernel_id=`strings /dynix | grep DYNIX`
1284     else
1285       kernel_id=
1286     fi
1287 ])dnl
1288
1289   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1290 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1291 changequote(,)dnl
1292   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1293 changequote([,])dnl
1294   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1295          != x$config_release; then
1296     # The configuration release is a substring of the kernel release.
1297     libc_cv_uname_release=$kernel_release
1298   elif test x$config_release != x; then
1299     libc_cv_uname_release=$config_release
1300   elif test x$kernel_release != x; then
1301     libc_cv_uname_release=$kernel_release
1302   else
1303     libc_cv_uname_release=unknown
1304   fi])
1305   uname_release="$libc_cv_uname_release"
1306
1307   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1308 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1309 changequote(,)dnl
1310   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1311 changequote([,])dnl
1312   if test -n "$kernel_version"; then
1313     libc_cv_uname_version="$kernel_version"
1314   else
1315     libc_cv_uname_version=unknown
1316   fi])
1317   uname_version="$libc_cv_uname_version"
1318
1319 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1320   config_uname=config-name.h:config-name.in
1321 else
1322   # For non-generic uname, we don't need to create config-name.h at all.
1323   config_uname=
1324 fi
1325
1326 AC_MSG_CHECKING(stdio selection)
1327 AC_SUBST(stdio)
1328 case $stdio in
1329 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1330 default) stdio=stdio ;;
1331 esac
1332 AC_MSG_RESULT($stdio)
1333
1334 # Test for old glibc 2.0.x headers so that they can be removed properly
1335 # Search only in includedir.
1336 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1337 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1338 then
1339   old_glibc_headers=yes
1340 else
1341   old_glibc_headers=no
1342 fi
1343 AC_MSG_RESULT($old_glibc_headers)
1344 if test ${old_glibc_headers} = yes; then
1345   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1346   AC_MSG_WARN(*** be removed.)
1347 fi
1348 AC_SUBST(old_glibc_headers)
1349
1350 AC_SUBST(libc_cv_slibdir)
1351 AC_SUBST(libc_cv_localedir)
1352 AC_SUBST(libc_cv_sysconfdir)
1353 AC_SUBST(libc_cv_rootsbindir)
1354
1355 AC_SUBST(use_ldconfig)
1356 AC_SUBST(ldd_rewrite_script)
1357
1358 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1359 if test $gnu_ld = yes; then
1360   AC_DEFINE(HAVE_GNU_LD)
1361 fi
1362 if test $gnu_as = yes; then
1363   AC_DEFINE(HAVE_GNU_AS)
1364 fi
1365 if test $elf = yes; then
1366   AC_DEFINE(HAVE_ELF)
1367 fi
1368
1369 AC_SUBST(static)
1370 AC_SUBST(shared)
1371 if test $shared = default; then
1372   if test $gnu_ld = yes; then
1373     shared=$elf
1374   else
1375     # For now we do not assume shared libs are available.  In future more
1376     # tests might become available.
1377     shared=no
1378   fi
1379 fi
1380
1381 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1382 [pic_default=yes
1383 cat > conftest.c <<EOF
1384 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1385 # error PIC is default.
1386 #endif
1387 EOF
1388 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1389   pic_default=no
1390 fi
1391 rm -f conftest.*])
1392 AC_SUBST(pic_default)
1393
1394 AC_SUBST(profile)
1395 AC_SUBST(omitfp)
1396 AC_SUBST(bounded)
1397 AC_SUBST(static_nss)
1398 AC_SUBST(nopic_initfini)
1399
1400 AC_SUBST(DEFINES)
1401
1402 case "$add_ons" in
1403   *door*) linux_doors=yes ;;
1404   *) linux_doors=no ;;
1405 esac
1406 AC_SUBST(linux_doors)
1407
1408 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1409   config_makefile=
1410 else
1411   config_makefile=Makefile
1412 fi
1413
1414 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1415 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1416 AC_SUBST(VERSION)
1417 AC_SUBST(RELEASE)
1418
1419 echo '*** Do NOT install this release on any production system!'
1420 echo '*** We are in early testing stages.'
1421
1422 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1423 case $CONFIG_FILES in *config.make*)
1424 echo "$config_vars" >> config.make;;
1425 esac
1426 test -d bits || mkdir bits], [config_vars='$config_vars'])