ports/sysdeps/unix/sysv/linux/mips/getcontext.S

   1 /* Save current context.
   2    Copyright (C) 2009 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Maciej W. Rozycki <macro@codesourcery.com>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <sys/asm.h>
  22 #include <sys/fpregdef.h>
  23 #include <sys/regdef.h>
  24
  25 #include "ucontext_i.h"
  26
  27 /* int getcontext (ucontext_t *ucp) */
  28
  29         .text
  30 LOCALSZ = 0
  31 MASK = 0x00000000
  32 #ifdef __PIC__
  33 LOCALSZ = 1                                             /* save gp */
  34 # if _MIPS_SIM != _ABIO32
  35 MASK = 0x10000000
  36 # endif
  37 #endif
  38 FRAMESZ = ((LOCALSZ * SZREG) + ALSZ) & ALMASK
  39 GPOFF = FRAMESZ - (1 * SZREG)
  40
  41 NESTED (__getcontext, FRAMESZ, ra)
  42         .mask   MASK, 0
  43         .fmask  0x00000000, 0
  44
  45 #ifdef __PIC__
  46         SETUP_GP
  47
  48         move    a2, sp
  49 # define _SP a2
  50
  51 # if _MIPS_SIM != _ABIO32
  52         move    a3, gp
  53 #  define _GP a3
  54 # endif
  55
  56         PTR_ADDIU sp, -FRAMESZ
  57         SETUP_GP64 (GPOFF, __getcontext)
  58         SAVE_GP (GPOFF)
  59
  60 #else  /* ! __PIC__ */
  61 # define _SP sp
  62 # define _GP gp
  63
  64 #endif /* ! __PIC__ */
  65
  66 #ifdef PROF
  67         .set    noat
  68         move    AT, ra
  69         jal     _mcount
  70         .set    at
  71 #endif
  72
  73         /* Store a magic flag.  */
  74         li      v1, 1
  75         REG_S   v1, (0 * SZREG + MCONTEXT_GREGS)(a0)    /* zero */
  76
  77         REG_S   s0, (16 * SZREG + MCONTEXT_GREGS)(a0)
  78         REG_S   s1, (17 * SZREG + MCONTEXT_GREGS)(a0)
  79         REG_S   s2, (18 * SZREG + MCONTEXT_GREGS)(a0)
  80         REG_S   s3, (19 * SZREG + MCONTEXT_GREGS)(a0)
  81         REG_S   s4, (20 * SZREG + MCONTEXT_GREGS)(a0)
  82         REG_S   s5, (21 * SZREG + MCONTEXT_GREGS)(a0)
  83         REG_S   s6, (22 * SZREG + MCONTEXT_GREGS)(a0)
  84         REG_S   s7, (23 * SZREG + MCONTEXT_GREGS)(a0)
  85 #if ! defined (__PIC__) || _MIPS_SIM != _ABIO32
  86         REG_S   _GP, (28 * SZREG + MCONTEXT_GREGS)(a0)
  87 #endif
  88         REG_S   _SP, (29 * SZREG + MCONTEXT_GREGS)(a0)
  89         REG_S   fp, (30 * SZREG + MCONTEXT_GREGS)(a0)
  90         REG_S   ra, (31 * SZREG + MCONTEXT_GREGS)(a0)
  91         REG_S   ra, MCONTEXT_PC(a0)
  92
  93 #ifdef __mips_hard_float
  94 # if _MIPS_SIM == _ABI64
  95         s.d     fs0, (24 * SZREG + MCONTEXT_FPREGS)(a0)
  96         s.d     fs1, (25 * SZREG + MCONTEXT_FPREGS)(a0)
  97         s.d     fs2, (26 * SZREG + MCONTEXT_FPREGS)(a0)
  98         s.d     fs3, (27 * SZREG + MCONTEXT_FPREGS)(a0)
  99         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 100         s.d     fs5, (29 * SZREG + MCONTEXT_FPREGS)(a0)
 101         s.d     fs6, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 102         s.d     fs7, (31 * SZREG + MCONTEXT_FPREGS)(a0)
 103
 104 # else  /* _MIPS_SIM != _ABI64 */
 105         s.d     fs0, (20 * SZREG + MCONTEXT_FPREGS)(a0)
 106         s.d     fs1, (22 * SZREG + MCONTEXT_FPREGS)(a0)
 107         s.d     fs2, (24 * SZREG + MCONTEXT_FPREGS)(a0)
 108         s.d     fs3, (26 * SZREG + MCONTEXT_FPREGS)(a0)
 109         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 110         s.d     fs5, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 111
 112 # endif /* _MIPS_SIM != _ABI64 */
 113
 114         cfc1    v1, fcr31
 115         sw      v1, MCONTEXT_FPC_CSR(a0)
 116 #endif /* __mips_hard_float */
 117
 118 /* rt_sigprocmask (SIG_BLOCK, NULL, &ucp->uc_sigmask, _NSIG8) */
 119         li      a3, _NSIG8
 120         PTR_ADDU a2, a0, UCONTEXT_SIGMASK
 121         move    a1, zero
 122         li      a0, SIG_BLOCK
 123
 124         li      v0, SYS_ify (rt_sigprocmask)
 125         syscall
 126         bnez    a3, 99f
 127
 128 #ifdef __PIC__
 129         RESTORE_GP64
 130         PTR_ADDIU sp, FRAMESZ
 131 #endif
 132         move    v0, zero
 133         jr      ra
 134
 135 99:
 136 #ifdef __PIC__
 137         PTR_LA  t9, JUMPTARGET (__syscall_error)
 138         RESTORE_GP64
 139         PTR_ADDIU sp, FRAMESZ
 140         jr      t9
 141
 142 #else  /* ! __PIC__ */
 143
 144         j       JUMPTARGET (__syscall_error)
 145 #endif /* ! __PIC__ */
 146 PSEUDO_END (__getcontext)
 147
 148 weak_alias (__getcontext, getcontext)