ports/sysdeps/unix/sysv/linux/arm/setcontext.S

   1 /* Copyright (C) 2012 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #include <rtld-global-offsets.h>
  20
  21 #include "ucontext_i.h"
  22
  23         .syntax unified
  24         .text
  25
  26 /* int setcontext (const ucontext_t *ucp) */
  27
  28 ENTRY(__setcontext)
  29         mov     r4, r0
  30         add     r0, r0, #UCONTEXT_REGSPACE
  31
  32         /* Restore the VFP registers.  Copied from arm/__longjmp.S.  */
  33 #ifdef PIC
  34         ldr     r2, 1f
  35         ldr     r1, Lrtld_global_ro
  36 0:      add     r2, pc, r2
  37         ldr     r2, [r2, r1]
  38         ldr     r2, [r2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  39 #else
  40         ldr     r2, Lhwcap
  41         ldr     r2, [r2, #0]
  42 #endif
  43
  44         tst     r2, #HWCAP_ARM_VFP
  45         beq     Lno_vfp_sc
  46
  47         /* Following instruction is vldmia r0!, {d8-d15}.  */
  48         ldc     p11, cr8, [r0], #64
  49         /* Restore the floating-point status register.  */
  50         ldr     r1, [r0], #4
  51         /* Following instruction is fmxr fpscr, r1.  */
  52         mcr     p10, 7, r1, cr1, cr0, 0
  53 Lno_vfp_sc:
  54         tst     r2, #HWCAP_ARM_IWMMXT
  55         beq     Lno_iwmmxt_sc
  56
  57         /* Restore the call-preserved iWMMXt registers.  */
  58         /* Following instructions are wldrd wr10, [r0], #8 (etc.)  */
  59         ldcl    p1, cr10, [r0], #8
  60         ldcl    p1, cr11, [r0], #8
  61         ldcl    p1, cr12, [r0], #8
  62         ldcl    p1, cr13, [r0], #8
  63         ldcl    p1, cr14, [r0], #8
  64         ldcl    p1, cr15, [r0], #8
  65 Lno_iwmmxt_sc:
  66
  67         /* Now bring back the signal status.  */
  68         mov     r0, #SIG_SETMASK
  69         add     r1, r4, #UCONTEXT_SIGMASK
  70         mov     r2, #0
  71         bl      PLTJMP(__sigprocmask)
  72
  73         /* Loading r0-r3 makes makecontext easier.  */
  74         add     r14, r4, #MCONTEXT_ARM_R0
  75         ldmia   r14, {r0-r12}
  76         ldr     r13, [r14, #(MCONTEXT_ARM_SP - MCONTEXT_ARM_R0)]
  77         add     r14, r14, #(MCONTEXT_ARM_LR - MCONTEXT_ARM_R0)
  78         ldmia   r14, {r14, pc}
  79
  80 END(setcontext)
  81 weak_alias(__setcontext, setcontext)
  82
  83         /* Called when a makecontext() context returns.  Start the
  84            context in R4 or fall through to exit().  */
  85 ENTRY(__startcontext)
  86         movs    r0, r4
  87         bne     PLTJMP(__setcontext)
  88
  89         @ New context was 0 - exit
  90         b       PLTJMP(HIDDEN_JUMPTARGET(_exit))
  91 END(__startcontext)
  92
  93 #ifdef PIC
  94 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  95 Lrtld_global_ro:
  96         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
  97 #else
  98 Lhwcap:
  99         .long   C_SYMBOL_NAME(_dl_hwcap)
 100 #endif
 101