ports/sysdeps/arm/strlen.S

   1 /* Copyright (C) 1998, 2003 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Code contributed by Matthew Wilcox <willy@odie.barnet.ac.uk>
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 /* size_t strlen(const char *S)
  22  * entry: r0 -> string
  23  * exit: r0 = len
  24  */
  25
  26 ENTRY(strlen)
  27         bic     r1, r0, $3              @ addr of word containing first byte
  28         ldr     r2, [r1], $4            @ get the first word
  29         ands    r3, r0, $3              @ how many bytes are duff?
  30         rsb     r0, r3, $0              @ get - that number into counter.
  31         beq     Laligned                @ skip into main check routine if no
  32                                         @ more
  33 #ifdef __ARMEB__
  34         orr     r2, r2, $0xff000000     @ set this byte to non-zero
  35         subs    r3, r3, $1              @ any more to do?
  36         orrgt   r2, r2, $0x00ff0000     @ if so, set this byte
  37         subs    r3, r3, $1              @ more?
  38         orrgt   r2, r2, $0x0000ff00     @ then set.
  39 #else
  40         orr     r2, r2, $0x000000ff     @ set this byte to non-zero
  41         subs    r3, r3, $1              @ any more to do?
  42         orrgt   r2, r2, $0x0000ff00     @ if so, set this byte
  43         subs    r3, r3, $1              @ more?
  44         orrgt   r2, r2, $0x00ff0000     @ then set.
  45 #endif
  46 Laligned:                               @ here, we have a word in r2.  Does it
  47         tst     r2, $0x000000ff         @ contain any zeroes?
  48         tstne   r2, $0x0000ff00         @
  49         tstne   r2, $0x00ff0000         @
  50         tstne   r2, $0xff000000         @
  51         addne   r0, r0, $4              @ if not, the string is 4 bytes longer
  52         ldrne   r2, [r1], $4            @ and we continue to the next word
  53         bne     Laligned                @
  54 Llastword:                              @ drop through to here once we find a
  55 #ifdef __ARMEB__
  56         tst     r2, $0xff000000         @ word that has a zero byte in it
  57         addne   r0, r0, $1              @
  58         tstne   r2, $0x00ff0000         @ and add up to 3 bytes on to it
  59         addne   r0, r0, $1              @
  60         tstne   r2, $0x0000ff00         @ (if first three all non-zero, 4th
  61         addne   r0, r0, $1              @  must be zero)
  62 #else
  63         tst     r2, $0x000000ff         @ word that has a zero byte in it
  64         addne   r0, r0, $1              @
  65         tstne   r2, $0x0000ff00         @ and add up to 3 bytes on to it
  66         addne   r0, r0, $1              @
  67         tstne   r2, $0x00ff0000         @ (if first three all non-zero, 4th
  68         addne   r0, r0, $1              @  must be zero)
  69 #endif
  70         DO_RET(lr)
  71 END(strlen)
  72 libc_hidden_builtin_def (strlen)