| blob | e5ff6bdb10a3b91936384d0633f1051e189237c0 |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
4 AC_INIT([GNU C Library], [(see version.h)], [glibc])
5 AC_CONFIG_SRCDIR([include/features.h])
6 AC_CONFIG_HEADERS([config.h])
7 AC_CONFIG_AUX_DIR([scripts])
9 dnl This is here so we can set $subdirs directly based on configure fragments.
10 AC_CONFIG_SUBDIRS()
12 AC_CANONICAL_HOST
14 AC_PROG_CC
15 if test $host != $build; then
16 AC_CHECK_PROGS(BUILD_CC, gcc cc)
17 fi
18 AC_SUBST(cross_compiling)
19 AC_PROG_CPP
20 # We need the C++ compiler only for testing.
21 AC_PROG_CXX
23 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
24 AC_MSG_ERROR([you must configure in a separate build directory])
25 fi
27 # This will get text that should go into config.make.
28 config_vars=
30 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
31 AC_ARG_WITH([gd],
32 AC_HELP_STRING([--with-gd=DIR],
33 [find libgd include dir and library with prefix DIR]),
34 [dnl
35 case "$with_gd" in
36 yes|''|no) ;;
37 *) libgd_include="-I$withval/include"
38 libgd_ldflags="-L$withval/lib" ;;
39 esac
40 ])
41 AC_ARG_WITH([gd-include],
42 AC_HELP_STRING([--with-gd-include=DIR],
43 [find libgd include files in DIR]),
44 [dnl
45 case "$with_gd_include" in
46 ''|no) ;;
47 *) libgd_include="-I$withval" ;;
48 esac
49 ])
50 AC_ARG_WITH([gd-lib],
51 AC_HELP_STRING([--with-gd-lib=DIR],
52 [find libgd library files in DIR]),
53 [dnl
54 case "$with_gd_lib" in
55 ''|no) ;;
56 *) libgd_ldflags="-L$withval" ;;
57 esac
58 ])
60 if test -n "$libgd_include"; then
61 config_vars="$config_vars
62 CFLAGS-memusagestat.c = $libgd_include"
63 fi
64 if test -n "$libgd_ldflags"; then
65 config_vars="$config_vars
66 libgd-LDFLAGS = $libgd_ldflags"
67 fi
69 dnl Arguments to specify presence of other packages/features.
70 AC_ARG_WITH([fp],
71 AC_HELP_STRING([--with-fp],
72 [if using floating-point hardware @<:@default=yes@:>@]),
73 [with_fp=$withval],
74 [with_fp=yes])
75 AC_SUBST(with_fp)
76 AC_ARG_WITH([binutils],
77 AC_HELP_STRING([--with-binutils=PATH],
78 [specify location of binutils (as and ld)]),
79 [path_binutils=$withval],
80 [path_binutils=''])
81 AC_ARG_WITH([elf],
82 AC_HELP_STRING([--with-elf],
83 [if using the ELF object format]),
84 [elf=$withval],
85 [elf=no])
86 AC_ARG_WITH([selinux],
87 AC_HELP_STRING([--with-selinux],
88 [if building with SELinux support]),
89 [with_selinux=$withval],
90 [with_selinux=auto])
91 AC_ARG_WITH([xcoff],
92 AC_HELP_STRING([--with-xcoff],
93 [if using the XCOFF object format]),
94 [xcoff=$withval],
95 [xcoff=no])
96 AC_ARG_WITH([cvs],
97 AC_HELP_STRING([--without-cvs],
98 [if CVS should not be used]),
99 [with_cvs=$withval],
100 [with_cvs=yes])
101 if test "$with_cvs" = yes; then
102 if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
103 then
104 with_cvs=no
105 fi
106 fi
107 AC_SUBST(with_cvs)
109 AC_ARG_WITH([headers],
110 AC_HELP_STRING([--with-headers=PATH],
111 [location of system headers to use
112 (for example /usr/src/linux/include)
113 @<:@default=compiler default@:>@]),
114 [sysheaders=$withval],
115 [sysheaders=''])
117 AC_ARG_ENABLE([sanity-checks],
118 AC_HELP_STRING([--disable-sanity-checks],
119 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
120 [enable_sanity=$enableval],
121 [enable_sanity=yes])
123 AC_SUBST(enable_check_abi)
124 AC_ARG_ENABLE([check-abi],
125 AC_HELP_STRING([--enable-check-abi],
126 [do "make check-abi" in "make check" (no/warn/yes)
127 @<:@default=no@:>@]),
128 [enable_check_abi=$enableval],
129 [enable_check_abi=no])
131 dnl Arguments to enable or disable building the static, shared, profiled,
132 dnl and -fomit-frame-pointer libraries.
133 dnl I've disabled this for now since we cannot build glibc without static
134 dnl libraries built in the moment.
135 dnl AC_ARG_ENABLE([static],
136 dnl AC_HELP_STRING([--enable-static],
137 dnl [build static library @<:@default=yes@:>@]),
138 dnl [static=$enableval],
139 dnl [static=yes])
140 static=yes
141 AC_ARG_ENABLE([shared],
142 AC_HELP_STRING([--enable-shared],
143 [build shared library @<:@default=yes if GNU ld & ELF@:>@]),
144 [shared=$enableval],
145 [shared=default])
146 AC_ARG_ENABLE([profile],
147 AC_HELP_STRING([--enable-profile],
148 [build profiled library @<:@default=no@:>@]),
149 [profile=$enableval],
150 [profile=no])
151 AC_ARG_ENABLE([omitfp],
152 AC_HELP_STRING([--enable-omitfp],
153 [build undebuggable optimized library @<:@default=no@:>@]),
154 [omitfp=$enableval],
155 [omitfp=no])
156 AC_ARG_ENABLE([bounded],
157 AC_HELP_STRING([--enable-bounded],
158 [build with runtime bounds checking @<:@default=no@:>@]),
159 [bounded=$enableval],
160 [bounded=no])
161 AC_ARG_ENABLE([versioning],
162 AC_HELP_STRING([--disable-versioning],
163 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
164 [enable_versioning=$enableval],
165 [enable_versioning=yes])
167 AC_ARG_ENABLE([oldest-abi],
168 AC_HELP_STRING([--enable-oldest-abi=ABI],
169 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
170 [oldest_abi=$enableval],
171 [oldest_abi=no])
172 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
173 oldest_abi=default
174 else
175 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
176 fi
177 AC_SUBST(oldest_abi)
179 AC_ARG_ENABLE([stackguard-randomization],
180 AC_HELP_STRING([--enable-stackguard-randomization],
181 [initialize __stack_chk_guard canary with a random number at program start]),
182 [enable_stackguard_randomize=$enableval],
183 [enable_stackguard_randomize=no])
184 if test "$enable_stackguard_randomize" = yes; then
185 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
186 fi
188 dnl Generic infrastructure for drop-in additions to libc.
189 AC_ARG_ENABLE([add-ons],
190 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
191 [configure and build add-ons in DIR1,DIR2,...
192 search for add-ons if no parameter given]),
193 , [enable_add_ons=yes])
195 dnl Let the user avoid using TLS. Don't know why but...
196 AC_ARG_WITH([tls],
197 AC_HELP_STRING([--with-tls],
198 [enable support for TLS]),
199 [usetls=$withval],
200 [usetls=yes])
202 AC_ARG_WITH([__thread],
203 AC_HELP_STRING([--without-__thread],
204 [do not use TLS features even when supporting them]),
205 [use__thread=$withval],
206 [use__thread=yes])
208 AC_ARG_ENABLE([hidden-plt],
209 AC_HELP_STRING([--disable-hidden-plt],
210 [do not hide internal function calls to avoid PLT]),
211 [hidden=$enableval],
212 [hidden=yes])
213 if test "x$hidden" = xno; then
214 AC_DEFINE(NO_HIDDEN)
215 fi
217 AC_ARG_ENABLE([bind-now],
218 AC_HELP_STRING([--enable-bind-now],
219 [disable lazy relocations in DSOs]),
220 [bindnow=$enableval],
221 [bindnow=no])
222 AC_SUBST(bindnow)
224 dnl On some platforms we cannot use dynamic loading. We must provide
225 dnl static NSS modules.
226 AC_ARG_ENABLE([static-nss],
227 AC_HELP_STRING([--enable-static-nss],
228 [build static NSS modules @<:@default=no@:>@]),
229 [static_nss=$enableval],
230 [static_nss=no])
231 dnl Enable static NSS also if we build no shared objects.
232 if test x"$static_nss" = xyes || test x"$shared" = xno; then
233 static_nss=yes
234 AC_DEFINE(DO_STATIC_NSS)
235 fi
237 AC_ARG_ENABLE([force-install],
238 AC_HELP_STRING([--disable-force-install],
239 [don't force installation of files from this package, even if they are older than the installed files]),
240 [force_install=$enableval],
241 [force_install=yes])
242 AC_SUBST(force_install)
244 dnl On some platforms we allow dropping compatibility with all kernel
245 dnl versions.
246 AC_ARG_ENABLE([kernel],
247 AC_HELP_STRING([--enable-kernel=VERSION],
248 [compile for compatibility with kernel not older than VERSION]),
249 [minimum_kernel=$enableval],
250 [])
251 dnl Prevent unreasonable values.
252 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
253 # Better nothing than this.
254 minimum_kernel=""
255 else
256 if test "$minimum_kernel" = current; then
257 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
258 fi
259 fi
261 dnl For the development we sometimes want gcc to issue even more warnings.
262 dnl This is not the default since many of the extra warnings are not
263 dnl appropriate.
264 AC_ARG_ENABLE([all-warnings],
265 AC_HELP_STRING([--enable-all-warnings],
266 [enable all useful warnings gcc can issue]),
267 [all_warnings=$enableval],
268 [])
269 AC_SUBST(all_warnings)
271 AC_ARG_ENABLE([multi-arch],
272 AC_HELP_STRING([--enable-multi-arch],
273 [enable single DSO with optimizations for multiple architectures]),
274 [multi_arch=$enableval],
275 [multi_arch=default])
277 AC_ARG_ENABLE([experimental-malloc],
278 AC_HELP_STRING([--enable-experimental-malloc],
279 [enable experimental malloc features]),
280 [experimental_malloc=$enableval],
281 [])
282 AC_SUBST(experimental_malloc)
284 AC_ARG_ENABLE([nss-crypt],
285 AC_HELP_STRING([--enable-nss-crypt],
286 [enable libcrypt to use nss]),
287 [nss_crypt=$enableval],
288 [nss_crypt=no])
289 if test x$nss_crypt = xyes; then
290 nss_includes=-I$(nss-config --includedir 2>/dev/null)
291 if test $? -ne 0; then
292 AC_MSG_ERROR([cannot find include directory with nss-config])
293 fi
294 old_CFLAGS="$CFLAGS"
295 CFLAGS="$CFLAGS $nss_includes"
296 AC_COMPILE_IFELSE([typedef int PRBool;
297 #include <hasht.h>
298 #include <nsslowhash.h>
299 void f (void) { NSSLOW_Init (); }],
300 libc_cv_nss_crypt=yes,
301 AC_MSG_ERROR([
302 cannot find NSS headers with lowlevel hash function interfaces]))
303 old_LIBS="$LIBS"
304 LIBS="$LIBS -lfreebl3"
305 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
306 #include <hasht.h>
307 #include <nsslowhash.h>],
308 [NSSLOW_Init();])],
309 libc_cv_nss_crypt=yes,
310 AC_MSG_ERROR([
311 cannot link program using lowlevel NSS hash functions]))
312 CFLAGS="$old_CFLAGS"
313 LIBS="$old_LIBS"
314 else
315 libc_cv_nss_crypt=no
316 fi
317 AC_SUBST(libc_cv_nss_crypt)
319 # The way shlib-versions is used to generate soversions.mk uses a
320 # fairly simplistic model for name recognition that can't distinguish
321 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
322 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
323 # tell. This doesn't get used much beyond that, so it's fairly safe.
324 case "$host_os" in
325 linux*)
326 ;;
327 gnu*)
328 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
329 ;;
330 esac
332 # We keep the original values in `$config_*' and never modify them, so we
333 # can write them unchanged into config.make. Everything else uses
334 # $machine, $vendor, and $os, and changes them whenever convenient.
335 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
337 # Don't allow vendor == "unknown"
338 test "$config_vendor" = unknown && config_vendor=
339 config_os="`echo $config_os | sed 's/^unknown-//'`"
341 # Some configurations imply other options.
342 case "$host_os" in
343 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
344 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
345 ;;
346 gnu* | linux* | freebsd* | netbsd* | sysv4* | solaris2* | irix6*)
347 # These systems (almost) always use the ELF format.
348 elf=yes
349 ;;
350 aix*)
351 # These systems are always xcoff
352 xcoff=yes
353 elf=no
354 ;;
355 esac
357 # The configure fragment of an add-on port can modify these to supplement
358 # or override the table in the case statement below. No fragment should
359 # ever change the config_* variables, however.
360 machine=$config_machine
361 vendor=$config_vendor
362 os=$config_os
363 base_os=''
365 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
366 # Unify this here.
367 if test "$machine" = rs6000; then
368 machine="powerpc"
369 fi
371 # Braindead PowerPC box with absolutely no FPU.
372 case "$machine-$host_os" in
373 powerpc*-*soft)
374 with_fp=no
375 ;;
376 esac
378 submachine=
379 AC_ARG_WITH([cpu],
380 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
381 [dnl
382 case "$withval" in
383 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
384 no) ;;
385 *) submachine="$withval" ;;
386 esac
387 ])
389 # An add-on can set this when it wants to disable the sanity check below.
390 libc_config_ok=no
392 dnl Having this here, though empty, makes sure that if add-ons' fragments
393 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
394 dnl our AC_OUTPUT will actually use it.
395 AC_CONFIG_SUBDIRS()
397 case "$enable_add_ons" in
398 ''|no) add_ons= ;;
399 yes|'*')
400 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
401 sed 's@/[[^/]]*$@@' | sort | uniq`
402 add_ons_automatic=yes
403 ;;
404 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
405 add_ons_automatic=no ;;
406 esac
408 configured_add_ons=
409 add_ons_sfx=
410 add_ons_pfx=
411 if test x"$add_ons" != x; then
412 for f in $add_ons; do
413 # Some sanity checks
414 case "$f" in
415 crypt)
416 AC_MSG_ERROR([
417 *** It seems that you're using an old \`crypt' add-on. crypt is now
418 *** part of glibc and using the old add-on will not work with this
419 *** release. Start again with fresh sources and without the old
420 *** \`crypt' add-on.])
421 ;;
422 localedata)
423 AC_MSG_ERROR([
424 *** It seems that you're using an old \`localedata' add-on. localedata
425 *** is now part of glibc and using the old add-on will not work with
426 *** this release. Start again with fresh sources and without the old
427 *** \`localedata' add-on.])
428 ;;
429 esac
430 done
432 # Now source each add-on's configure fragment.
433 # The fragments can use $srcdir/$libc_add_on to find themselves,
434 # and test $add_ons_automatic to see if they were explicitly requested.
435 # A fragment can clear (or even change) $libc_add_on to affect
436 # whether it goes into the list to be actually used in the build.
437 use_add_ons=
438 for libc_add_on in $add_ons; do
439 # Test whether such a directory really exists.
440 # It can be absolute, or relative to $srcdir, or relative to the build dir.
441 case "$libc_add_on" in
442 /*)
443 libc_add_on_srcdir=$libc_add_on
444 ;;
445 *)
446 test -d "$srcdir/$libc_add_on" || {
447 if test -d "$libc_add_on"; then
448 libc_add_on="`pwd`/$libc_add_on"
449 else
450 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
451 fi
452 }
453 libc_add_on_srcdir=$srcdir/$libc_add_on
454 ;;
455 esac
457 libc_add_on_frag=$libc_add_on_srcdir/configure
458 libc_add_on_canonical=
459 libc_add_on_config_subdirs=
460 if test -r "$libc_add_on_frag"; then
461 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
462 libc_add_on_canonical=unknown
463 libc_add_on_subdirs=
464 . "$libc_add_on_frag"
465 test -z "$libc_add_on" || {
466 configured_add_ons="$configured_add_ons $libc_add_on"
467 if test "x$libc_add_on_canonical" = xunknown; then
468 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
469 fi
470 for d in $libc_add_on_subdirs; do
471 case "$libc_add_on" in
472 /*) subdir_srcdir="$libc_add_on" ;;
473 *) subdir_srcdir="\$(..)$libc_add_on" ;;
474 esac
475 case "$d" in
476 .)
477 d="${libc_add_on_canonical:-$libc_add_on}"
478 ;;
479 /*)
480 subdir_srcdir="$d"
481 ;;
482 *)
483 subdir_srcdir="$subdir_srcdir/$d"
484 ;;
485 esac
486 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
487 add_on_subdirs="$add_on_subdirs $d"
488 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
489 $d-srcdir = $subdir_srcdir"
490 done
491 for d in $libc_add_on_config_subdirs; do
492 case "$d" in
493 /*) AC_MSG_ERROR(dnl
494 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
495 esac
496 if test ! -d "$libc_add_on_srcdir/$d"; then
497 AC_MSG_ERROR(fragment wants to configure missing directory $d)
498 fi
499 case "$libc_add_on" in
500 /*) AC_MSG_ERROR(dnl
501 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
502 esac
503 subdirs="$subdirs $libc_add_on/$d"
504 done
505 }
506 fi
507 if test -n "$libc_add_on"; then
508 if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
509 then
510 AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
511 for frag in $frags; do
512 name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
513 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
514 . "$frag"
515 done
516 AC_MSG_RESULT()
517 fi
518 use_add_ons="$use_add_ons $libc_add_on"
519 add_ons_pfx="$add_ons_pfx $libc_add_on/"
520 test -z "$libc_add_on_canonical" ||
521 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
522 fi
523 done
524 # Use echo to strip excess whitespace.
525 add_ons="`echo $use_add_ons`"
526 fi
527 AC_SUBST(add_ons)
528 AC_SUBST(add_on_subdirs)
531 ###
532 ### I put this here to prevent those annoying emails from people who cannot
533 ### read and try to compile glibc on unsupported platforms. --drepper
534 ###
535 ### By using the undocumented --enable-hacker-mode option for configure
536 ### one can skip this test to make the configuration not fail for unsupported
537 ### platforms.
538 ###
539 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
540 case "$machine-$host_os" in
541 *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
542 ;;
543 *)
544 echo "*** The GNU C library is currently not available for this platform."
545 echo "*** So far nobody cared to port it and if there is no volunteer it"
546 echo "*** might never happen. So, if you have interest to see glibc on"
547 echo "*** this platform visit"
548 echo "*** http://www.gnu.org/software/libc/porting.html"
549 echo "*** and join the group of porters"
550 exit 1
551 ;;
552 esac
553 fi
555 dnl We need to use [ and ] for other purposes for a while now.
556 changequote(,)dnl
557 # Expand the configuration machine name into a subdirectory by architecture
558 # type and particular chip. If an add-on configure fragment already set
559 # base_machine, we don't change it.
560 test -n "$base_machine" || case "$machine" in
561 a29k | am29000) base_machine=a29k machine=a29k ;;
562 c3[012]) base_machine=cx0 machine=cx0/c30 ;;
563 c4[04]) base_machine=cx0 machine=cx0/c40 ;;
564 i[34567]86) base_machine=i386 machine=i386/$machine ;;
565 ia64) base_machine=ia64 machine=ia64 ;;
566 m88???) base_machine=m88k machine=m88k/$machine ;;
567 m88k) base_machine=m88k machine=m88k/m88100 ;;
568 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
569 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
570 s390) base_machine=s390 machine=s390/s390-32 ;;
571 s390x) base_machine=s390 machine=s390/s390-64 ;;
572 sh3*) base_machine=sh machine=sh/sh3 ;;
573 sh4*) base_machine=sh machine=sh/sh4 ;;
574 sparc | sparcv[67])
575 base_machine=sparc machine=sparc/sparc32 ;;
576 sparcv8 | supersparc | hypersparc)
577 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
578 sparcv8plus | sparcv8plusa | sparcv9)
579 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
580 sparcv8plusb | sparcv9b)
581 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
582 sparcv9v)
583 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
584 sparcv9v2)
585 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
586 sparc64)
587 base_machine=sparc machine=sparc/sparc64 ;;
588 sparc64b)
589 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
590 sparc64v)
591 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
592 sparc64v2)
593 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
594 *) base_machine=$machine ;;
595 esac
596 changequote([,])dnl
597 AC_SUBST(base_machine)
599 if test "$base_machine" = "i386"; then
600 AC_DEFINE(USE_REGPARMS)
601 fi
603 # For the multi-arch option we need support in the assembler.
604 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
605 libc_cv_asm_gnu_indirect_function, [dnl
606 cat > conftest.s <<EOF
607 .type foo,%gnu_indirect_function
608 EOF
609 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
610 then
611 libc_cv_asm_gnu_indirect_function=yes
612 else
613 libc_cv_asm_gnu_indirect_function=no
614 fi
615 rm -f conftest*])
617 AC_MSG_CHECKING(whether .text pseudo-op must be used)
618 AC_CACHE_VAL(libc_cv_dot_text, [dnl
619 cat > conftest.s <<EOF
620 .text
621 EOF
622 libc_cv_dot_text=
623 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
624 libc_cv_dot_text=.text
625 fi
626 rm -f conftest*])
627 if test -z "$libc_cv_dot_text"; then
628 AC_MSG_RESULT(no)
629 else
630 AC_MSG_RESULT(yes)
631 fi
633 AC_CACHE_CHECK(for assembler global-symbol directive,
634 libc_cv_asm_global_directive, [dnl
635 libc_cv_asm_global_directive=UNKNOWN
636 for ac_globl in .globl .global .EXPORT; do
637 cat > conftest.s <<EOF
638 ${libc_cv_dot_text}
639 ${ac_globl} foo
640 foo:
641 EOF
642 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
643 libc_cv_asm_global_directive=${ac_globl}
644 fi
645 rm -f conftest*
646 test $libc_cv_asm_global_directive != UNKNOWN && break
647 done])
648 if test $libc_cv_asm_global_directive = UNKNOWN; then
649 AC_MSG_ERROR(cannot determine asm global directive)
650 else
651 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
652 fi
654 AC_CACHE_CHECK(for assembler .type directive prefix,
655 libc_cv_asm_type_prefix, [dnl
656 libc_cv_asm_type_prefix=no
657 for ac_try_prefix in '@' '%' '#'; do
658 cat > conftest.s <<EOF
659 ${libc_cv_dot_text}
660 ${libc_cv_asm_global_directive} foo
661 .type foo, ${ac_try_prefix}object
662 .size foo, 1
663 foo:
664 .byte 1
665 EOF
666 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
667 libc_cv_asm_type_prefix=${ac_try_prefix}
668 fi
669 rm -f conftest*
670 test "x$libc_cv_asm_type_prefix" != xno && break
671 done])
672 if test "x$libc_cv_asm_type_prefix" != xno; then
673 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
674 fi
676 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -a x"$libc_cv_asm_type_prefix" = xno; then
677 if test x"$multi_arch" = xyes; then
678 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
679 else
680 multi_arch=no
681 fi
682 fi
683 if test x"$multi_arch" != xno; then
684 multi_arch_d=/multiarch
685 fi
687 # Compute the list of sysdep directories for this configuration.
688 # This can take a while to compute.
689 sysdep_dir=$srcdir/sysdeps
690 AC_MSG_CHECKING(sysdep dirs)
691 dnl We need to use [ and ] for other purposes for a while now.
692 changequote(,)dnl
693 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
694 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
696 test "x$base_os" != x || case "$os" in
697 gnu*)
698 base_os=mach/hurd ;;
699 netbsd* | 386bsd* | freebsd* | bsdi*)
700 base_os=unix/bsd/bsd4.4 ;;
701 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
702 base_os=unix/bsd ;;
703 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
704 base_os=unix/sysv ;;
705 irix6*)
706 base_os=unix/sysv/irix6/$os ;;
707 solaris[2-9]*)
708 base_os=unix/sysv/sysv4 ;;
709 hpux*)
710 base_os=unix/sysv/hpux/$os ;;
711 aix4.3*)
712 base_os=unix/sysv/aix/aix4.3 ;;
713 none)
714 base_os=standalone ;;
715 esac
717 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
718 tail=$os
719 ostry=$os
720 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
721 ostry="$ostry /$o"
722 tail=$o
723 done
724 o=`echo $tail | sed 's/[0-9]*$//'`
725 if test $o != $tail; then
726 ostry="$ostry /$o"
727 fi
728 # For linux-gnu, try linux-gnu, then linux.
729 o=`echo $tail | sed 's/-.*$//'`
730 if test $o != $tail; then
731 ostry="$ostry /$o"
732 fi
734 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
735 base=
736 tail=$base_os
737 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
738 set $b
739 base="$base /$1"
740 tail="$2"
741 done
743 # For sparc/sparc32, try sparc/sparc32 and then sparc.
744 mach=
745 tail=$machine${submachine:+/$submachine}
746 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
747 set $m
748 # Prepend the machine's FPU directory unless --without-fp.
749 if test "$with_fp" = yes; then
750 mach="$mach /$1/fpu"
751 else
752 mach="$mach /$1/nofpu"
753 fi
754 mach="$mach /$1"
755 tail="$2"
756 done
758 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
759 changequote([,])dnl
761 # Find what sysdep directories exist.
762 sysnames_add_ons=
763 sysnames=
764 for b in $base ''; do
765 for m0 in $mach ''; do
766 for v in /$vendor ''; do
767 test "$v" = / && continue
768 for o in /$ostry ''; do
769 test "$o" = / && continue
770 for m in $multi_arch_d $mach ''; do
771 for d in $add_ons_pfx ''; do
772 for a in $add_ons_sfx ''; do
773 if test -n "$m0$m0sub$b$v$o$m$msub"; then
774 try_srcdir="${srcdir}/"
775 case "$d" in
776 /*) try_srcdir= ;;
777 esac
778 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
779 test -n "$enable_debug_configure" &&
780 echo "$0 [DEBUG]: try $try" >&2
781 if test -d "$try_srcdir$try"; then
782 sysnames="$sysnames $try"
783 { test -n "$o" || test -n "$b"; } && os_used=t
784 { test -n "$m" || test -n "$m0"; } && machine_used=t
785 case x${m0:-$m} in
786 x*/$submachine) submachine_used=t ;;
787 esac
788 if test -n "$d"; then
789 case "$sysnames_add_ons" in
790 *" $d "*) ;;
791 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
792 esac
793 fi
794 fi
795 fi
796 done
797 done
798 done
799 done
800 done
801 done
802 done
804 # If the assembler supports gnu_indirect_function symbol type and the
805 # architecture supports multi-arch, we enable multi-arch by default.
806 case $sysnames_add_ons$sysnames in
807 *"$multi_arch_d"*)
808 ;;
809 *)
810 test x"$multi_arch" = xdefault && multi_arch=no
811 ;;
812 esac
813 if test x"$multi_arch" != xno; then
814 AC_DEFINE(USE_MULTIARCH)
815 fi
816 AC_SUBST(multi_arch)
818 if test -z "$os_used" && test "$os" != none; then
819 AC_MSG_ERROR(Operating system $os is not supported.)
820 fi
821 if test -z "$machine_used" && test "$machine" != none; then
822 AC_MSG_ERROR(The $machine is not supported.)
823 fi
824 if test -z "$submachine_used" && test -n "$submachine"; then
825 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
826 fi
827 AC_SUBST(submachine)
829 # We have now validated the configuration.
832 # If using ELF, look for an `elf' subdirectory of each machine directory.
833 # We prepend these rather than inserting them whereever the machine appears
834 # because things specified by the machine's ELF ABI should override
835 # OS-specific things, and should always be the same for any OS on the
836 # machine (otherwise what's the point of an ABI?).
837 if test "$elf" = yes; then
838 elf_dirs=
839 for d in $add_ons_pfx ''; do
840 for m in $mach; do
841 if test -d $srcdir/${d}sysdeps$m/elf; then
842 elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
843 fi
844 done
845 done
846 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
847 fi
850 # Expand the list of system names into a full list of directories
851 # from each element's parent name and Implies file (if present).
852 set $sysnames
853 names=
854 while test $# -gt 0; do
855 name=$1
856 shift
858 case " $names " in *" $name "*)
859 # Already in the list.
860 continue
861 esac
863 # Report each name as we discover it, so there is no long pause in output.
864 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
866 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
868 case $name in
869 /*) xsrcdir= ;;
870 *) xsrcdir=$srcdir/ ;;
871 esac
872 test -n "$enable_debug_configure" &&
873 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
875 if test -f $xsrcdir$name/Implies; then
876 # Collect more names from the `Implies' file (removing comments).
877 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
878 implied=
879 for x in $implied_candidate; do
880 found=no
881 if test -d $xsrcdir$name_base/$x; then
882 implied="$implied $name_base/$x";
883 found=yes
884 fi
885 for d in $add_ons_pfx ''; do
886 try="${d}sysdeps/$x"
887 case $d in
888 /*) try_srcdir= ;;
889 *) try_srcdir=$srcdir/ ;;
890 esac
891 test -n "$enable_debug_configure" &&
892 echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
893 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
894 then
895 implied="$implied $try"
896 found=yes
897 case "$sysnames_add_ons" in
898 *" $d "*) ;;
899 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
900 esac
901 fi
902 done
903 if test $found = no; then
904 AC_MSG_WARN($name/Implies specifies nonexistent $x)
905 fi
906 done
907 else
908 implied=
909 fi
911 # Add NAME to the list of names.
912 names="$names $name"
914 # Find the parent of NAME, using the empty string if it has none.
915 changequote(,)dnl
916 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
917 changequote([,])dnl
919 # Add the names implied by NAME, and NAME's parent (if it has one), to
920 # the list of names to be processed (the argument list). We prepend the
921 # implied names to the list and append the parent. We want implied
922 # directories to come before further directories inferred from the
923 # configuration components; this ensures that for sysv4, unix/common
924 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
925 # after sysv4).
926 sysnames="`echo $implied $* $parent`"
927 test -n "$sysnames" && set $sysnames
928 done
930 # Add the default directories.
931 default_sysnames=sysdeps/generic
932 if test "$elf" = yes; then
933 default_sysnames="sysdeps/generic/elf $default_sysnames"
934 fi
935 sysnames="$names $default_sysnames"
936 AC_SUBST(sysnames)
937 # The other names were emitted during the scan.
938 AC_MSG_RESULT($default_sysnames)
940 # Collect the list of add-ons that supply partial sysdeps trees.
941 sysdeps_add_ons=
942 for add_on in $add_ons; do
943 case "$add_on" in
944 /*) xsrcdir= ;;
945 *) xsrcdir="$srcdir/" ;;
946 esac
948 test -d "$xsrcdir$add_on/sysdeps" || {
949 case "$configured_add_ons " in
950 *" $add_on "*) ;;
951 *|'')
952 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
953 ;;
954 esac
955 continue
956 }
958 sysdeps_add_ons="$sysdeps_add_ons $add_on"
959 case "$sysnames_add_ons" in
960 *" $add_on/ "*) ;;
961 *|'')
962 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
963 continue ;;
964 esac
966 found=no
967 for d in $sysnames; do
968 case "$d" in
969 $add_on/sysdeps/*) ;;
970 *) continue ;;
971 esac
972 (cd "$xsrcdir$d" && for f in *[[!~]]; do
973 case "$f" in
974 sys|bits)
975 for ff in $f/*.h; do
976 test -d "$ff" || { test -e "$ff" && exit 88; }
977 done
978 ;;
979 *)
980 test -d "$f" || { test -e "$f" && exit 88; }
981 ;;
982 esac
983 done)
984 if test $? -eq 88; then
985 found=yes
986 break
987 fi
988 done
989 if test $found = no; then
990 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
991 fi
992 done
993 AC_SUBST(sysdeps_add_ons)
996 ### Locate tools.
998 AC_PROG_INSTALL
999 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
1000 # The makefiles need to use a different form to find it in $srcdir.
1001 INSTALL='\$(..)./scripts/install-sh -c'
1002 fi
1003 AC_PROG_LN_S
1005 LIBC_PROG_BINUTILS
1006 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
1008 # Accept binutils 2.13 or newer.
1009 AC_CHECK_PROG_VER(AS, $AS, --version,
1010 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
1011 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
1012 AC_CHECK_PROG_VER(LD, $LD, --version,
1013 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1014 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
1016 # We need the physical current working directory. We cannot use the
1017 # "pwd -P" shell builtin since that's not portable. Instead we try to
1018 # find a pwd binary. Note that assigning to the PWD environment
1019 # variable might have some interesting side effects, so we don't do
1020 # that.
1021 AC_PATH_PROG(PWD_P, pwd, no)
1022 if test "$PWD_P" = no; then
1023 AC_MSG_ERROR(*** A pwd binary could not be found.)
1024 fi
1026 # These programs are version sensitive.
1027 AC_CHECK_TOOL_PREFIX
1028 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
1029 [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
1030 critic_missing="$critic_missing gcc")
1031 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1032 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1033 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
1035 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1036 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1037 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1038 MSGFMT=: aux_missing="$aux_missing msgfmt")
1039 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1040 [GNU texinfo.* \([0-9][0-9.]*\)],
1041 [4.*],
1042 MAKEINFO=: aux_missing="$aux_missing makeinfo")
1043 AC_CHECK_PROG_VER(SED, sed, --version,
1044 [GNU sed version \([0-9]*\.[0-9.]*\)],
1045 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1046 SED=: aux_missing="$aux_missing sed")
1048 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1049 case "x$AUTOCONF" in
1050 xno|x|x:) AUTOCONF=no ;;
1051 *)
1052 AC_CACHE_CHECK(dnl
1053 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1054 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
1055 libc_cv_autoconf_works=yes
1056 else
1057 libc_cv_autoconf_works=no
1058 fi])
1059 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1060 ;;
1061 esac
1062 if test "x$with_cvs" = xyes && test "x$AUTOCONF" = xno; then
1063 # If --without-cvs they probably won't change configure.in, so no complaints.
1064 aux_missing="$aux_missing autoconf"
1065 fi
1067 test -n "$critic_missing" && AC_MSG_ERROR([
1068 *** These critical programs are missing or too old:$critic_missing
1069 *** Check the INSTALL file for required versions.])
1071 test -n "$aux_missing" && AC_MSG_WARN([
1072 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1073 *** some features will be disabled.
1074 *** Check the INSTALL file for required versions.])
1076 # if using special system headers, find out the compiler's sekrit
1077 # header directory and add that to the list. NOTE: Only does the right
1078 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1079 if test -n "$sysheaders"; then
1080 SYSINCLUDES=-nostdinc
1081 for d in include include-fixed; do
1082 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1083 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1084 done
1085 SYSINCLUDES="$SYSINCLUDES \
1086 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1087 if test -n "$CXX"; then
1088 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1089 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1090 cxxheaders=`$CXX -print-file-name=../../../../include/c++/`"$cxxversion" &&
1091 CXX_SYSINCLUDES="-isystem $cxxheaders \
1092 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1093 fi
1094 fi
1095 AC_SUBST(SYSINCLUDES)
1096 AC_SUBST(CXX_SYSINCLUDES)
1098 # ranlib is never necessary on Linux and Hurd systems
1099 RANLIB=:
1101 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1102 # since this would lead to problems installing/building glibc.
1103 # LD_LIBRARY_PATH contains the current directory if one of the following
1104 # is true:
1105 # - one of the terminals (":" and ";") is the first or last sign
1106 # - two terminals occur directly after each other
1107 # - the path contains an element with a dot in it
1108 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1109 changequote(,)dnl
1110 case ${LD_LIBRARY_PATH} in
1111 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1112 ld_library_path_setting="contains current directory"
1113 ;;
1114 *)
1115 ld_library_path_setting="ok"
1116 ;;
1117 esac
1118 changequote([,])dnl
1119 AC_MSG_RESULT($ld_library_path_setting)
1120 if test "$ld_library_path_setting" != "ok"; then
1121 AC_MSG_ERROR([
1122 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1123 *** building glibc. Please change the environment variable
1124 *** and run configure again.])
1125 fi
1127 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1128 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1129 libc_cv_gcc_static_libgcc=
1130 else
1131 libc_cv_gcc_static_libgcc=-static-libgcc
1132 fi])
1133 AC_SUBST(libc_cv_gcc_static_libgcc)
1135 AC_PATH_PROG(BASH_SHELL, bash, no)
1136 if test "$BASH_SHELL" != no &&
1137 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1138 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1139 libc_cv_have_bash2=yes
1140 else
1141 libc_cv_have_bash2=no
1142 fi
1143 AC_SUBST(libc_cv_have_bash2)
1145 dnl We need a ksh compatible shell for tzselect.
1146 if test "$BASH_SHELL" = no; then
1147 AC_PATH_PROG(KSH, ksh, no)
1148 if test "$KSH" = no; then
1149 libc_cv_have_ksh=no
1150 else
1151 libc_cv_have_ksh=yes
1152 fi
1153 else
1154 KSH="$BASH_SHELL"
1155 AC_SUBST(KSH)
1156 libc_cv_have_ksh=yes
1157 fi
1158 AC_SUBST(libc_cv_have_ksh)
1160 AC_PROG_AWK
1161 AC_PATH_PROG(PERL, perl, no)
1162 if test "$PERL" != no &&
1163 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1164 PERL=no
1165 fi
1166 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1167 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1168 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1170 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
1171 echo '#include <stddef.h>
1172 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
1173 if eval "$ac_cpp conftest.c 2>/dev/null" \
1174 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
1175 libc_cv_signed_size_t=no
1176 else
1177 libc_cv_signed_size_t=yes
1178 fi
1179 rm -f conftest*])
1180 if test $libc_cv_signed_size_t = yes; then
1181 dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
1182 cat >> confdefs.h <<\EOF
1183 #undef __SIZE_TYPE__
1184 #define __SIZE_TYPE__ unsigned
1185 EOF
1186 fi
1188 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1189 AC_TRY_COMPILE(dnl
1190 [#define __need_size_t
1191 #define __need_wchar_t
1192 #include <stddef.h>
1193 #define __need_NULL
1194 #include <stddef.h>], [size_t size; wchar_t wchar;
1195 #ifdef offsetof
1196 #error stddef.h ignored __need_*
1197 #endif
1198 if (&size == NULL || &wchar == NULL) abort ();],
1199 libc_cv_friendly_stddef=yes,
1200 libc_cv_friendly_stddef=no)])
1201 if test $libc_cv_friendly_stddef = yes; then
1202 config_vars="$config_vars
1203 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1204 fi
1206 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1207 libc_cv_need_minus_P, [dnl
1208 cat > conftest.S <<EOF
1209 #include "confdefs.h"
1210 /* Nothing whatsoever. */
1211 EOF
1212 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1213 libc_cv_need_minus_P=no
1214 else
1215 libc_cv_need_minus_P=yes
1216 fi
1217 rm -f conftest*])
1218 if test $libc_cv_need_minus_P = yes; then
1219 config_vars="$config_vars
1220 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1221 fi
1223 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1224 cat > conftest.s <<EOF
1225 ${libc_cv_dot_text}
1226 foo:
1227 .set glibc_conftest_frobozz,foo
1228 $libc_cv_asm_global_directive glibc_conftest_frobozz
1229 EOF
1230 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1231 # (but it doesn't work), so we must do a linking check to be sure.
1232 cat > conftest1.c <<\EOF
1233 extern int glibc_conftest_frobozz;
1234 void _start() { glibc_conftest_frobozz = 1; }
1235 EOF
1236 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1237 -nostartfiles -nostdlib \
1238 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1239 libc_cv_asm_set_directive=yes
1240 else
1241 libc_cv_asm_set_directive=no
1242 fi
1243 rm -f conftest*])
1244 if test $libc_cv_asm_set_directive = yes; then
1245 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1246 fi
1248 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1249 libc_cv_asm_unique_object, [dnl
1250 cat > conftest.s <<EOF
1251 ${libc_cv_dot_text}
1252 _sym:
1253 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1254 EOF
1255 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1256 libc_cv_asm_unique_object=yes
1257 else
1258 libc_cv_asm_unique_object=no
1259 fi
1260 rm -f conftest*])
1261 if test $libc_cv_asm_unique_object = yes; then
1262 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1263 fi
1265 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1266 [cat > conftest.s <<EOF
1267 ${libc_cv_dot_text}
1268 _sym:
1269 .symver _sym,sym@VERS
1270 EOF
1271 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1272 libc_cv_asm_symver_directive=yes
1273 else
1274 libc_cv_asm_symver_directive=no
1275 fi
1276 rm -f conftest*])
1277 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1278 if test $libc_cv_asm_symver_directive = yes; then
1279 cat > conftest.s <<EOF
1280 ${libc_cv_dot_text}
1281 _sym:
1282 .symver _sym,sym@VERS
1283 EOF
1284 cat > conftest.map <<EOF
1285 VERS_1 {
1286 global: sym;
1287 };
1289 VERS_2 {
1290 global: sym;
1291 } VERS_1;
1292 EOF
1293 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1294 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1295 -o conftest.so conftest.o
1296 -nostartfiles -nostdlib
1297 -Wl,--version-script,conftest.map
1298 1>&AS_MESSAGE_LOG_FD]);
1299 then
1300 libc_cv_ld_version_script_option=yes
1301 else
1302 libc_cv_ld_version_script_option=no
1303 fi
1304 else
1305 libc_cv_ld_version_script_option=no
1306 fi
1307 else
1308 libc_cv_ld_version_script_option=no
1309 fi
1310 rm -f conftest*])
1311 if test $shared != no &&
1312 test $libc_cv_asm_symver_directive = yes &&
1313 test $libc_cv_ld_version_script_option = yes &&
1314 test $enable_versioning = yes; then
1315 VERSIONING=yes
1316 AC_DEFINE(DO_VERSIONING)
1317 else
1318 VERSIONING=no
1319 fi
1320 AC_SUBST(VERSIONING)
1322 if test $elf = yes && test $shared != no && test $VERSIONING = no; then
1323 echo "\
1324 *** WARNING: You should not compile GNU libc without versioning. Not using
1325 *** versioning will introduce incompatibilities so that old binaries
1326 *** will not run anymore.
1327 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1328 fi
1329 if test $elf = yes; then
1330 AC_CACHE_CHECK(for .previous assembler directive,
1331 libc_cv_asm_previous_directive, [dnl
1332 cat > conftest.s <<EOF
1333 .section foo_section
1334 .previous
1335 EOF
1336 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1337 libc_cv_asm_previous_directive=yes
1338 else
1339 libc_cv_asm_previous_directive=no
1340 fi
1341 rm -f conftest*])
1342 if test $libc_cv_asm_previous_directive = yes; then
1343 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1344 else
1345 AC_CACHE_CHECK(for .popsection assembler directive,
1346 libc_cv_asm_popsection_directive, [dnl
1347 cat > conftest.s <<EOF
1348 .pushsection foo_section
1349 .popsection
1350 EOF
1351 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1352 libc_cv_asm_popsection_directive=yes
1353 else
1354 libc_cv_asm_popsection_directive=no
1355 fi
1356 rm -f conftest*])
1357 if test $libc_cv_asm_popsection_directive = yes; then
1358 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1359 fi
1360 fi
1361 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1362 libc_cv_asm_protected_directive, [dnl
1363 cat > conftest.s <<EOF
1364 .protected foo
1365 foo:
1366 .hidden bar
1367 bar:
1368 EOF
1369 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1370 libc_cv_asm_protected_directive=yes
1371 else
1372 AC_MSG_ERROR(assembler support for symbol visibility is required)
1373 fi
1374 rm -f conftest*])
1376 if test $libc_cv_asm_protected_directive = yes; then
1377 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1378 libc_cv_visibility_attribute,
1379 [cat > conftest.c <<EOF
1380 int foo __attribute__ ((visibility ("hidden"))) = 1;
1381 int bar __attribute__ ((visibility ("protected"))) = 1;
1382 EOF
1383 libc_cv_visibility_attribute=no
1384 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1385 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1386 if grep '\.protected.*bar' conftest.s >/dev/null; then
1387 libc_cv_visibility_attribute=yes
1388 fi
1389 fi
1390 fi
1391 rm -f conftest.[cs]
1392 ])
1393 if test $libc_cv_visibility_attribute != yes; then
1394 AC_MSG_ERROR(compiler support for visibility attribute is required)
1395 fi
1396 fi
1398 if test $libc_cv_visibility_attribute = yes; then
1399 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1400 libc_cv_broken_visibility_attribute,
1401 [cat > conftest.c <<EOF
1402 int foo (int x);
1403 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1404 int bar (int x) { return x; }
1405 EOF
1406 libc_cv_broken_visibility_attribute=yes
1407 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s1>&AS_MESSAGE_LOG_FD); then
1408 changequote(,)dnl
1409 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1410 changequote([,])dnl
1411 libc_cv_broken_visibility_attribute=no
1412 fi
1413 fi
1414 rm -f conftest.c conftest.s
1415 ])
1416 if test $libc_cv_broken_visibility_attribute = yes; then
1417 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1418 fi
1419 fi
1421 AC_CACHE_CHECK(for broken __attribute__((alias())),
1422 libc_cv_broken_alias_attribute,
1423 [cat > conftest.c <<EOF
1424 extern int foo (int x) __asm ("xyzzy");
1425 int bar (int x) { return x; }
1426 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1427 extern int dfoo;
1428 extern __typeof (dfoo) dfoo __asm ("abccb");
1429 int dfoo = 1;
1430 EOF
1431 libc_cv_broken_alias_attribute=yes
1432 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1433 if grep 'xyzzy' conftest.s >/dev/null &&
1434 grep 'abccb' conftest.s >/dev/null; then
1435 libc_cv_broken_alias_attribute=no
1436 fi
1437 fi
1438 rm -f conftest.c conftest.s
1439 ])
1440 if test $libc_cv_broken_alias_attribute = yes; then
1441 AC_MSG_ERROR(working alias attribute support required)
1442 fi
1444 if test $libc_cv_visibility_attribute = yes; then
1445 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1446 libc_cv_have_sdata_section,
1447 [echo "int i;" > conftest.c
1448 libc_cv_have_sdata_section=no
1449 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1450 | grep '\.sdata' >/dev/null; then
1451 libc_cv_have_sdata_section=yes
1452 fi
1453 rm -f conftest.c conftest.so
1454 ])
1455 if test $libc_cv_have_sdata_section = yes; then
1456 AC_DEFINE(HAVE_SDATA_SECTION)
1457 fi
1458 fi
1460 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1461 libc_cv_initfini_array, [dnl
1462 cat > conftest.c <<EOF
1463 int _start (void) { return 0; }
1464 int __start (void) { return 0; }
1465 int foo (void) { return 1; }
1466 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1467 EOF
1468 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1469 -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1470 then
1471 if readelf -S conftest | fgrep INIT_ARRAY > /dev/null; then
1472 libc_cv_initfini_array=yes
1473 else
1474 libc_cv_initfini_array=no
1475 fi
1476 else
1477 libc_cv_initfini_array=no
1478 fi
1479 rm -f conftest*])
1480 if test $libc_cv_initfini_array != yes; then
1481 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1482 elif AC_TRY_COMMAND([${CC-cc} -Wl,--verbose 2>&1|grep SORT_BY_INIT_PRIORITY 1>&AS_MESSAGE_LOG_FD]); then
1483 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1484 fi
1486 AC_CACHE_CHECK(for libunwind-support in compiler,
1487 libc_cv_cc_with_libunwind, [
1488 cat > conftest.c <<EOF
1489 int main (void) { return 0; }
1490 EOF
1491 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1492 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1493 libc_cv_cc_with_libunwind=yes
1494 else
1495 libc_cv_cc_with_libunwind=no
1496 fi
1497 rm -f conftest*])
1498 AC_SUBST(libc_cv_cc_with_libunwind)
1499 if test $libc_cv_cc_with_libunwind = yes; then
1500 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1501 fi
1503 AC_CACHE_CHECK(for -z nodelete option,
1504 libc_cv_z_nodelete, [dnl
1505 cat > conftest.c <<EOF
1506 int _start (void) { return 42; }
1507 EOF
1508 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1509 -fPIC -shared -o conftest.so conftest.c
1510 -nostartfiles -nostdlib
1511 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1512 then
1513 libc_cv_z_nodelete=yes
1514 else
1515 AC_MSG_ERROR(linker with -z nodelete support required)
1516 fi
1517 rm -f conftest*])
1519 AC_CACHE_CHECK(for -z nodlopen option,
1520 libc_cv_z_nodlopen, [dnl
1521 cat > conftest.c <<EOF
1522 int _start (void) { return 42; }
1523 EOF
1524 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1525 -fPIC -shared -o conftest.so conftest.c
1526 -nostartfiles -nostdlib
1527 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1528 then
1529 libc_cv_z_nodlopen=yes
1530 else
1531 AC_MSG_ERROR(linker with -z nodlopen support required)
1532 fi
1533 rm -f conftest*])
1535 AC_CACHE_CHECK(for -z initfirst option,
1536 libc_cv_z_initfirst, [dnl
1537 cat > conftest.c <<EOF
1538 int _start (void) { return 42; }
1539 EOF
1540 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1541 -fPIC -shared -o conftest.so conftest.c
1542 -nostartfiles -nostdlib
1543 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1544 then
1545 libc_cv_z_initfirst=yes
1546 else
1547 AC_MSG_ERROR(linker with -z initfirst support required)
1548 fi
1549 rm -f conftest*])
1551 case "$base_machine" in
1552 changequote(,)dnl
1553 i[34567]86 | x86_64 | powerpc* | s390* | sparc* | alpha*)
1554 changequote([,])dnl
1555 AC_CACHE_CHECK(for -z relro option,
1556 libc_cv_z_relro, [dnl
1557 libc_cv_z_relro=no
1558 if AC_TRY_COMMAND([${CC-cc} -v --help 2>&1|grep "z relro" 1>&AS_MESSAGE_LOG_FD])
1559 then
1560 if AC_TRY_COMMAND([${CC-cc} -Wl,--verbose 2>&1|grep DATA_SEGMENT_RELRO_END 1>&AS_MESSAGE_LOG_FD])
1561 then
1562 libc_cv_z_relro=yes
1563 fi
1564 fi])
1565 if test "$libc_cv_z_relro" = no; then
1566 AC_MSG_ERROR(linker with -z relro support required)
1567 fi
1568 ;;
1569 *) ;;
1570 esac
1572 AC_CACHE_CHECK(for -Bgroup option,
1573 libc_cv_Bgroup, [dnl
1574 cat > conftest.c <<EOF
1575 int _start (void) { return 42; }
1576 EOF
1577 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1578 -fPIC -shared -o conftest.so conftest.c
1579 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1580 then
1581 libc_cv_Bgroup=yes
1582 else
1583 libc_cv_Bgroup=no
1584 fi
1585 rm -f conftest*])
1586 AC_SUBST(libc_cv_Bgroup)
1588 AC_CACHE_CHECK(for libgcc_s suffix,
1589 libc_cv_libgcc_s_suffix, [dnl
1590 cat > conftest.c <<EOF
1591 int main (void) { return 0; }
1592 EOF
1593 changequote(,)dnl
1594 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1595 -fPIC -shared -shared-libgcc -o conftest.so \
1596 conftest.c -v 2>&1 >/dev/null \
1597 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1598 changequote([,])dnl
1599 rm -f conftest*])
1600 AC_SUBST(libc_cv_libgcc_s_suffix)
1602 AC_CACHE_CHECK(for --as-needed option,
1603 libc_cv_as_needed, [dnl
1604 cat > conftest.c <<EOF
1605 int main (void) { return 0; }
1606 EOF
1607 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1608 -fPIC -shared -o conftest.so conftest.c
1609 -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1610 -nostdlib 1>&AS_MESSAGE_LOG_FD])
1611 then
1612 libc_cv_as_needed=yes
1613 else
1614 libc_cv_as_needed=no
1615 fi
1616 rm -f conftest*])
1617 AC_SUBST(libc_cv_as_needed)
1619 ASFLAGS_config=
1620 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1621 libc_cv_as_noexecstack, [dnl
1622 cat > conftest.c <<EOF
1623 void foo (void) { }
1624 EOF
1625 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1626 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1627 && grep -q .note.GNU-stack conftest.s \
1628 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1629 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1630 then
1631 libc_cv_as_noexecstack=yes
1632 else
1633 libc_cv_as_noexecstack=no
1634 fi
1635 rm -f conftest*])
1636 if test $libc_cv_as_noexecstack = yes; then
1637 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1638 fi
1639 AC_SUBST(ASFLAGS_config)
1641 AC_CACHE_CHECK(for -z combreloc,
1642 libc_cv_z_combreloc, [dnl
1643 cat > conftest.c <<EOF
1644 extern int bar (int);
1645 extern int mumble;
1646 int foo (void) { return bar (mumble); }
1647 EOF
1648 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1649 -fPIC -shared -o conftest.so conftest.c
1650 -nostdlib -nostartfiles
1651 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1652 then
1653 dnl The following test is a bit weak. We must use a tool which can test
1654 dnl cross-platform since the gcc used can be a cross compiler. Without
1655 dnl introducing new options this is not easily doable. Instead use a tool
1656 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1657 dnl look for a section named .rel.dyn.
1658 if readelf -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1659 libc_cv_z_combreloc=yes
1660 else
1661 libc_cv_z_combreloc=no
1662 fi
1663 else
1664 libc_cv_z_combreloc=no
1665 fi
1666 rm -f conftest*])
1667 if test "$libc_cv_z_combreloc" = yes; then
1668 AC_DEFINE(HAVE_Z_COMBRELOC)
1669 fi
1670 AC_SUBST(libc_cv_z_combreloc)
1672 AC_CACHE_CHECK(for -z execstack,
1673 libc_cv_z_execstack, [dnl
1674 cat > conftest.c <<EOF
1675 int _start (void) { return 42; }
1676 EOF
1677 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1678 -fPIC -shared -o conftest.so conftest.c
1679 -Wl,-z,execstack -nostdlib
1680 1>&AS_MESSAGE_LOG_FD])
1681 then
1682 libc_cv_z_execstack=yes
1683 else
1684 libc_cv_z_execstack=no
1685 fi
1686 rm -f conftest*])
1687 AC_SUBST(libc_cv_z_execstack)
1689 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1690 cat > conftest.c <<EOF
1691 int foo;
1692 main () { return 0;}
1693 EOF
1694 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1695 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1696 then
1697 libc_cv_fpie=yes
1698 else
1699 libc_cv_fpie=no
1700 fi
1701 rm -f conftest*])
1703 AC_SUBST(libc_cv_fpie)
1705 AC_CACHE_CHECK(for --hash-style option,
1706 libc_cv_hashstyle, [dnl
1707 cat > conftest.c <<EOF
1708 int _start (void) { return 42; }
1709 EOF
1710 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1711 -fPIC -shared -o conftest.so conftest.c
1712 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1713 then
1714 libc_cv_hashstyle=yes
1715 else
1716 libc_cv_hashstyle=no
1717 fi
1718 rm -f conftest*])
1719 AC_SUBST(libc_cv_hashstyle)
1720 fi
1722 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1723 cat > conftest.c <<EOF
1724 int foo;
1725 EOF
1726 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1727 conftest.c 1>&AS_MESSAGE_LOG_FD])
1728 then
1729 libc_cv_fno_toplevel_reorder=yes
1730 else
1731 libc_cv_fno_toplevel_reorder=no
1732 fi
1733 rm -f conftest*])
1734 if test $libc_cv_fno_toplevel_reorder = yes; then
1735 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1736 else
1737 fno_unit_at_a_time=-fno-unit-at-a-time
1738 fi
1739 AC_SUBST(fno_unit_at_a_time)
1741 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1742 cat > conftest.c <<EOF
1743 int foo;
1744 main () { return 0;}
1745 EOF
1746 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1747 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1748 then
1749 libc_cv_ssp=yes
1750 else
1751 libc_cv_ssp=no
1752 fi
1753 rm -f conftest*])
1754 AC_SUBST(libc_cv_ssp)
1756 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1757 cat > conftest.c <<EOF
1758 int foo;
1759 #ifdef __GNUC_GNU_INLINE__
1760 main () { return 0;}
1761 #else
1762 #error
1763 #endif
1764 EOF
1765 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1766 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1767 then
1768 libc_cv_gnu89_inline=yes
1769 else
1770 libc_cv_gnu89_inline=no
1771 fi
1772 rm -f conftest*])
1773 if test $libc_cv_gnu89_inline = yes; then
1774 gnu89_inline=-fgnu89-inline
1775 else
1776 gnu89_inline=
1777 fi
1778 AC_SUBST(gnu89_inline)
1780 if test $elf != yes; then
1781 AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
1782 [AC_TRY_COMPILE(, [asm (".section .init");
1783 asm (".section .fini");
1784 asm ("${libc_cv_dot_text}");],
1785 libc_cv_have_initfini=yes,
1786 libc_cv_have_initfini=no)])
1787 AC_SUBST(libc_cv_have_initfini)dnl
1788 if test $libc_cv_have_initfini = yes; then
1789 AC_DEFINE(HAVE_INITFINI)
1790 fi
1791 fi
1793 if test $elf = yes; then
1794 AC_CACHE_CHECK(whether cc puts quotes around section names,
1795 libc_cv_have_section_quotes,
1796 [cat > conftest.c <<EOF
1797 static const int foo
1798 __attribute__ ((section ("bar"))) = 1;
1799 EOF
1800 if ${CC-cc} -S conftest.c -o conftest.s; then
1801 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1802 libc_cv_have_section_quotes=yes
1803 else
1804 libc_cv_have_section_quotes=no
1805 fi
1806 else
1807 libc_cv_have_section_quotes=unknown
1808 fi
1809 rm -f conftest.[cs]
1810 ])
1811 if test $libc_cv_have_section_quotes = yes; then
1812 AC_DEFINE(HAVE_SECTION_QUOTES)
1813 fi
1814 fi
1816 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1817 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1818 [cat > conftest.$ac_ext <<EOF
1819 dnl This sometimes fails to find confdefs.h, for some reason.
1820 dnl [#]line $LINENO "[$]0"
1821 [#]line $LINENO "configure"
1822 #include "confdefs.h"
1823 void underscore_test(void) {
1824 return; }
1825 EOF
1826 if AC_TRY_EVAL(ac_compile); then
1827 if grep _underscore_test conftest* >/dev/null; then
1828 ifelse([$1], , :, [rm -f conftest*
1829 $1])
1830 else
1831 ifelse([$2], , , [rm -f conftest*
1832 $2])
1833 fi
1834 else
1835 echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
1836 cat conftest.$ac_ext >&AS_MESSAGE_LOG_FD
1837 ifelse([$2], , , [rm -f conftest*
1838 $2])
1839 fi
1840 rm -f conftest*])
1842 if test $elf = yes; then
1843 libc_cv_asm_underscores=no
1844 else
1845 if test $ac_cv_prog_cc_works = yes; then
1846 AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1847 [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1848 libc_cv_asm_underscores=yes,
1849 libc_cv_asm_underscores=no)])
1850 else
1851 AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1852 [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1853 libc_cv_asm_underscores=no)])
1854 fi
1855 fi
1856 if test $libc_cv_asm_underscores = no; then
1857 AC_DEFINE(NO_UNDERSCORES)
1858 fi
1860 if test $elf = yes; then
1861 libc_cv_weak_symbols=yes
1862 fi
1864 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1865 [dnl
1866 cat > conftest.s <<EOF
1867 ${libc_cv_dot_text}
1868 ${libc_cv_asm_global_directive} foo
1869 foo:
1870 .weak foo
1871 .weak bar; bar = foo
1872 EOF
1873 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1874 libc_cv_asm_weak_directive=yes
1875 else
1876 libc_cv_asm_weak_directive=no
1877 fi
1878 rm -f conftest*])
1880 if test $libc_cv_asm_weak_directive = no; then
1881 AC_CACHE_CHECK(for assembler .weakext directive,
1882 libc_cv_asm_weakext_directive,
1883 [dnl
1884 cat > conftest.s <<EOF
1885 ${libc_cv_dot_text}
1886 ${libc_cv_asm_global_directive} foo
1887 foo:
1888 .weakext bar foo
1889 .weakext baz
1890 ${libc_cv_asm_global_directive} baz
1891 baz:
1892 EOF
1893 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1894 libc_cv_asm_weakext_directive=yes
1895 else
1896 libc_cv_asm_weakext_directive=no
1897 fi
1898 rm -f conftest*])
1900 fi # no .weak
1902 if test $libc_cv_asm_weak_directive = yes; then
1903 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1904 elif test $libc_cv_asm_weakext_directive = yes; then
1905 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1906 fi
1908 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1909 case $machine in
1910 sparc/sparc64*) cfi_offset=2047;;
1911 *) cfi_offset=0;;
1912 esac
1913 cat > conftest.s <<EOF
1914 .text
1915 .type func,%function
1916 func:
1917 .cfi_startproc
1918 .cfi_remember_state
1919 .cfi_rel_offset 1, $cfi_offset
1920 .cfi_endproc
1921 EOF
1922 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1923 libc_cv_asm_cfi_directives=yes
1924 else
1925 libc_cv_asm_cfi_directives=no
1926 fi
1927 rm -f conftest*])
1928 if test $libc_cv_asm_cfi_directives = yes; then
1929 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1930 fi
1932 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1933 cat > conftest.c <<\EOF
1934 _start () {}
1935 int __eh_pc;
1936 __throw () {}
1937 EOF
1938 dnl No \ in command here because it ends up inside ''.
1939 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1940 -nostdlib -nostartfiles -Wl,--no-whole-archive
1941 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1942 libc_cv_ld_no_whole_archive=yes
1943 else
1944 libc_cv_ld_no_whole_archive=no
1945 fi
1946 rm -f conftest*])
1947 if test $libc_cv_ld_no_whole_archive = yes; then
1948 no_whole_archive=-Wl,--no-whole-archive
1949 fi
1950 AC_SUBST(no_whole_archive)dnl
1952 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1953 cat > conftest.c <<\EOF
1954 _start () {}
1955 int __eh_pc;
1956 __throw () {}
1957 EOF
1958 dnl No \ in command here because it ends up inside ''.
1959 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1960 -nostdlib -nostartfiles -fexceptions
1961 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1962 libc_cv_gcc_exceptions=yes
1963 else
1964 libc_cv_gcc_exceptions=no
1965 fi
1966 rm -f conftest*])
1967 if test $libc_cv_gcc_exceptions = yes; then
1968 exceptions=-fexceptions
1969 fi
1970 AC_SUBST(exceptions)dnl
1972 if test "$host_cpu" = powerpc ; then
1973 # Check for a bug present in at least versions 2.8.x of GCC
1974 # and versions 1.0.x of EGCS.
1975 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1976 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1977 libc_cv_c_asmcr0_bug='no',
1978 libc_cv_c_asmcr0_bug='yes')])
1979 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1980 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1981 fi
1982 fi
1984 dnl Check whether compiler understands __builtin_expect.
1985 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1986 [cat > conftest.c <<EOF
1987 #line $LINENO "configure"
1988 int foo (int a)
1989 {
1990 a = __builtin_expect (a, 10);
1991 return a == 10 ? 0 : 1;
1992 }
1993 EOF
1994 dnl No \ in command here because it ends up inside ''.
1995 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostdlib -nostartfiles
1996 -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1997 libc_cv_gcc_builtin_expect=yes
1998 else
1999 libc_cv_gcc_builtin_expect=no
2000 fi
2001 rm -f conftest*])
2002 if test "$libc_cv_gcc_builtin_expect" = yes; then
2003 AC_DEFINE(HAVE_BUILTIN_EXPECT)
2004 fi
2006 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
2007 cat > conftest.c <<\EOF
2008 void zero (void *x)
2009 {
2010 __builtin_memset (x, 0, 1000);
2011 }
2012 EOF
2013 dnl
2014 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
2015 then
2016 libc_cv_gcc_builtin_memset=no
2017 else
2018 libc_cv_gcc_builtin_memset=yes
2019 fi
2020 rm -f conftest* ])
2021 if test "$libc_cv_gcc_builtin_memset" = yes ; then
2022 AC_DEFINE(HAVE_BUILTIN_MEMSET)
2023 fi
2025 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
2026 cat > conftest.c <<\EOF
2027 extern char *strstr (const char *, const char *) __asm ("my_strstr");
2028 char *foo (const char *a, const char *b)
2029 {
2030 return __builtin_strstr (a, b);
2031 }
2032 EOF
2033 dnl
2034 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
2035 then
2036 libc_cv_gcc_builtin_redirection=yes
2037 else
2038 libc_cv_gcc_builtin_redirection=no
2039 fi
2040 rm -f conftest* ])
2041 if test "$libc_cv_gcc_builtin_redirection" = yes ; then
2042 AC_DEFINE(HAVE_BUILTIN_REDIRECTION)
2043 fi
2045 dnl Check whether the compiler supports the __thread keyword.
2046 if test "x$use__thread" != xno; then
2047 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
2048 [cat > conftest.c <<\EOF
2049 __thread int a = 42;
2050 EOF
2051 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
2052 libc_cv_gcc___thread=yes
2053 else
2054 libc_cv_gcc___thread=no
2055 fi
2056 rm -f conftest*])
2057 if test "$libc_cv_gcc___thread" = yes; then
2058 AC_DEFINE(HAVE___THREAD)
2059 fi
2060 else
2061 libc_cv_gcc___thread=no
2062 fi
2064 if test "$libc_cv_gcc___thread" = yes; then
2065 dnl Check whether the compiler supports the tls_model attribute.
2066 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2067 cat > conftest.c <<\EOF
2068 extern __thread int a __attribute__((tls_model ("initial-exec")));
2069 EOF
2070 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2071 libc_cv_gcc_tls_model_attr=yes
2072 else
2073 libc_cv_gcc_tls_model_attr=no
2074 fi
2075 rm -f conftest*])
2076 if test "$libc_cv_gcc_tls_model_attr" = yes; then
2077 AC_DEFINE(HAVE_TLS_MODEL_ATTRIBUTE)
2078 fi
2079 fi
2081 if test -n "$submachine"; then
2082 AC_CACHE_CHECK([for compiler option for CPU variant],
2083 libc_cv_cc_submachine, [dnl
2084 libc_cv_cc_submachine=no
2085 for opt in "-march=$submachine" "-mcpu=$submachine"; do
2086 if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2087 libc_cv_cc_submachine="$opt"
2088 break
2089 fi
2090 done])
2091 if test "x$libc_cv_cc_submachine" = xno; then
2092 AC_MSG_ERROR([${CC-cc} does not support $submachine])
2093 fi
2094 fi
2095 AC_SUBST(libc_cv_cc_submachine)
2097 dnl Check whether we have the gd library available.
2098 AC_MSG_CHECKING(for libgd)
2099 if test "$with_gd" != "no"; then
2100 old_CFLAGS="$CFLAGS"
2101 CFLAGS="$CFLAGS $libgd_include"
2102 old_LDFLAGS="$LDFLAGS"
2103 LDFLAGS="$LDFLAGS $libgd_ldflags"
2104 old_LIBS="$LIBS"
2105 LIBS="$LIBS -lgd -lpng -lz -lm"
2106 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2107 CFLAGS="$old_CFLAGS"
2108 LDFLAGS="$old_LDFLAGS"
2109 LIBS="$old_LIBS"
2110 else
2111 LIBGD=no
2112 fi
2113 AC_MSG_RESULT($LIBGD)
2114 AC_SUBST(LIBGD)
2116 # SELinux detection
2117 if test x$with_selinux = xno ; then
2118 have_selinux=no;
2119 else
2120 # See if we have the SELinux library
2121 AC_CHECK_LIB(selinux, is_selinux_enabled,
2122 have_selinux=yes, have_selinux=no)
2123 # See if we have the SELinux header with the NSCD permissions in it.
2124 if test x$have_selinux = xyes ; then
2125 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2126 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2127 [#ifdef NSCD__SHMEMHOST
2128 return 0;
2129 #else
2130 #error NSCD__SHMEMHOST not defined
2131 #endif],
2132 have_selinux=yes, have_selinux=no)
2133 AC_MSG_RESULT($have_selinux)
2134 fi
2136 if test x$with_selinux = xyes ; then
2137 if test x$have_selinux = xno ; then
2138 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2139 fi
2140 fi
2141 fi
2142 # Check if we're building with SELinux support.
2143 if test "x$have_selinux" = xyes; then
2144 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2146 # See if we have the libaudit library
2147 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2148 have_libaudit=yes, have_libaudit=no)
2149 if test "x$have_libaudit" = xyes; then
2150 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2151 fi
2152 AC_SUBST(have_libaudit)
2154 # See if we have the libcap library
2155 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2156 if test "x$have_libcap" = xyes; then
2157 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2158 fi
2159 AC_SUBST(have_libcap)
2160 fi
2161 AC_SUBST(have_selinux)
2163 dnl check for the size of 'long double'.
2164 AC_CHECK_SIZEOF(long double, 0)
2165 sizeof_long_double=$ac_cv_sizeof_long_double
2166 AC_SUBST(sizeof_long_double)
2168 ### End of automated tests.
2169 ### Now run sysdeps configure fragments.
2171 # They also can set these variables.
2172 use_ldconfig=no
2173 ldd_rewrite_script=no
2174 libc_cv_sysconfdir=$sysconfdir
2175 libc_cv_gcc_unwind_find_fde=no
2176 libc_cv_idn=no
2178 # Iterate over all the sysdep directories we will use, running their
2179 # configure fragments.
2180 for dir in $sysnames; do
2181 case $dir in
2182 /*) dest=$dir ;;
2183 *) dest=$srcdir/$dir ;;
2184 esac
2185 if test -r $dest/configure; then
2186 AC_MSG_RESULT(running configure fragment for $dir)
2187 . $dest/configure
2188 fi
2189 done
2191 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2192 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2193 fi
2194 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2196 dnl This is tested by existing code and it's simpler to avoid changing it.
2197 AC_DEFINE(USE_IN_LIBIO)
2199 # Test for old glibc 2.0.x headers so that they can be removed properly
2200 # Search only in includedir.
2201 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2202 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2203 then
2204 old_glibc_headers=yes
2205 else
2206 old_glibc_headers=no
2207 fi
2208 AC_MSG_RESULT($old_glibc_headers)
2209 if test ${old_glibc_headers} = yes; then
2210 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2211 AC_MSG_WARN(*** be removed.)
2212 fi
2213 AC_SUBST(old_glibc_headers)
2215 AC_SUBST(libc_cv_slibdir)
2216 AC_SUBST(libc_cv_localedir)
2217 AC_SUBST(libc_cv_sysconfdir)
2218 AC_SUBST(libc_cv_rootsbindir)
2219 AC_SUBST(libc_cv_forced_unwind)
2221 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2222 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2223 AC_SUBST(libc_cv_cc_sse4)
2224 AC_SUBST(libc_cv_cc_avx)
2225 AC_SUBST(libc_cv_cc_novzeroupper)
2226 AC_SUBST(libc_cv_as_i686)
2228 AC_SUBST(use_ldconfig)
2229 AC_SUBST(ldd_rewrite_script)
2231 AC_SUBST(elf) AC_SUBST(xcoff)
2232 if test $elf = yes; then
2233 AC_DEFINE(HAVE_ELF)
2234 fi
2235 if test $xcoff = yes; then
2236 AC_DEFINE(HAVE_XCOFF)
2237 fi
2239 AC_SUBST(static)
2240 AC_SUBST(shared)
2241 if test $shared = default; then
2242 shared=$elf
2243 fi
2245 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2246 [libc_cv_pic_default=yes
2247 cat > conftest.c <<EOF
2248 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2249 # error PIC is default.
2250 #endif
2251 EOF
2252 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2253 libc_cv_pic_default=no
2254 fi
2255 rm -f conftest.*])
2256 AC_SUBST(libc_cv_pic_default)
2258 AC_SUBST(profile)
2259 AC_SUBST(omitfp)
2260 AC_SUBST(bounded)
2261 AC_SUBST(static_nss)
2262 AC_SUBST(nopic_initfini)
2264 AC_SUBST(DEFINES)
2266 dnl See sysdeps/mach/configure.in for this variable.
2267 AC_SUBST(mach_interface_list)
2269 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2270 config_makefile=
2271 else
2272 config_makefile=Makefile
2273 fi
2275 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2276 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2277 AC_SUBST(VERSION)
2278 AC_SUBST(RELEASE)
2280 AC_CONFIG_FILES([config.make ${config_makefile}])
2281 AC_CONFIG_COMMANDS([default],[[
2282 case $CONFIG_FILES in *config.make*)
2283 echo "$config_vars" >> config.make;;
2284 esac
2285 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2286 AC_OUTPUT