sysdeps/ia64/fpu/s_significand.S

   1 .file "significand.s"
   2
   3 // Copyright (C) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23 //
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://developer.intel.com/opensource.
  39 //
  40 // History
  41 //==============================================================
  42 // 2/02/00: Initial version
  43 // 4/04/00  Unwind support added
  44 // 5/31/00: Fixed bug when x a double-extended denormal
  45 //
  46 // API
  47 //==============================================================
  48 // double significand(double x)
  49 //
  50 // Overview of operation
  51 //==============================================================
  52 // If x = sig * 2**n with 1 <= sig < 2
  53 // significand returns sig
  54 //
  55 // predicate registers used:
  56 // p6, p7
  57 //
  58 // floating-point registers used:
  59 // f8, f9, f10
  60
  61 #include "libm_support.h"
  62
  63 .align 32
  64 .global significand#
  65
  66 .section .text
  67 .proc  significand#
  68 .align 32
  69
  70 significand:
  71
  72 // qnan snan inf norm     unorm 0 -+
  73 // 1    1    1   0        0     1 11
  74
  75 // f10 gets f8(sign) with f1(exp,significand)
  76 { .mfi
  77       nop.m 999
  78 (p0)  fmerge.s       f10 = f8,f1
  79       nop.i 999
  80 }
  81 { .mfi
  82       nop.m 999
  83 (p0)  fnorm          f9  = f8
  84       nop.i 999 ;;
  85 }
  86
  87 // Test for denormal input
  88 { .mfi
  89       nop.m 999
  90 (p0)  fclass.m.unc   p7,p0 = f8, 0x0b
  91       nop.i 999 ;;
  92 }
  93
  94 // p6 = TRUE ==> x is not (nan,inf,0)
  95 //               return sign(f8) exp(f1) significand(f8)
  96 // else          x is (nan,inf,0)
  97 //               return sign(f8) exp(f8) significand(f8), normalized.
  98 { .mfi
  99       nop.m 999
 100 (p0)  fclass.m.unc   p0,p6 = f8, 0xe7
 101       nop.i 999 ;;
 102 }
 103
 104 { .mmb
 105       nop.m 999
 106       nop.m 999
 107 (p7)  br.cond.spnt L(SIGNIFICAND_DENORM) ;; // Branch if x denormal
 108 }
 109
 110 { .mfi
 111       nop.m 999
 112 (p6)  fmerge.se      f8 = f10,f8
 113       nop.i 999 ;;
 114 }
 115
 116 { .mfb
 117       nop.m 999
 118 (p0)  fnorm.d        f8 = f8
 119 (p0)  br.ret.sptk    b0 ;;
 120 }
 121
 122 L(SIGNIFICAND_DENORM):
 123 // Here if x denorm
 124 { .mfi
 125       nop.m 999
 126 (p0)  fmerge.se      f8 = f10,f9
 127       nop.i 999 ;;
 128 }
 129
 130 // Check if fnorm(x) still denormal, means x double-extended denormal
 131 { .mfi
 132       nop.m 999
 133 (p0)  fclass.m.unc   p7,p0 = f9, 0x0b
 134       nop.i 999 ;;
 135 }
 136
 137 // This will be the final result unless x double-extended denormal
 138 { .mfi
 139       nop.m 999
 140 (p0)  fnorm.d        f8 = f8
 141       nop.i 999 ;;
 142 }
 143
 144 // If x double-extended denorm, then significand ok, but must merge in
 145 //    correct signexp
 146 { .mfi
 147       nop.m 999
 148 (p7)  fmerge.se      f8 = f10,f8
 149       nop.i 999 ;;
 150 }
 151
 152 // Final normalization if x double-extended denorm
 153 { .mfb
 154       nop.m 999
 155 (p7)  fnorm.d        f8 = f8
 156 (p0)  br.ret.sptk    b0 ;;
 157 }
 158
 159 .endp significand
 160 ASM_SIZE_DIRECTIVE(significand)