sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991,92,93,94,95,96,97,98,99 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16 # write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18
  19 # errno.texi contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24 # Descriptive paragraph...
  25 # @end deftypevr
  26
  27 BEGIN {
  28
  29     # Here we list the E* names that might be duplicate names for the
  30     # same integer value on some systems.  This causes the code below
  31     # to generate ``#if defined (ALIAS) && ALIAS != ORIGINAL'' in the code,
  32     # so the output does not presume that these are in fact aliases.
  33     # We list here all the known potential cases on any system,
  34     # so that the C source we produce will do the right thing based
  35     # on the actual #define'd values it's compiled with.
  36     alias["EWOULDBLOCK"]= "EAGAIN";
  37     alias["EDEADLOCK"]  = "EDEADLK";
  38     alias["ENOTSUP"]    = "EOPNOTSUPP";
  39
  40     print "/* This file is generated from errno.texi by errlist.awk.  */"
  41     print "";
  42     print "#include <errno.h>";
  43     print "#include <libintl.h>";
  44     print "";
  45     print "#ifndef SYS_ERRLIST";
  46     print "# define SYS_ERRLIST _sys_errlist";
  47     print "# define SYS_ERRLIST_ALIAS sys_errlist";
  48     print "#endif";
  49     print "#ifndef SYS_NERR";
  50     print "# define SYS_NERR _sys_nerr";
  51     print "# define SYS_NERR_ALIAS sys_nerr";
  52     print "#endif";
  53     print "#ifndef ERR_REMAP";
  54     print "# define ERR_REMAP(n) n";
  55     print "#endif";
  56     print "";
  57     print "const char *const SYS_ERRLIST[] =";
  58     print "  {";
  59     print "    [0] = N_(\"Success\"),"
  60   }
  61 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  62 errnoh == 1 && $1 == "@comment" \
  63   {
  64     ++errnoh;
  65     etext = $3;
  66     for (i = 4; i <= NF; ++i)
  67       etext = etext " " $i;
  68     next;
  69   }
  70 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  71   {
  72     e = $4; errnoh++; next;
  73   }
  74 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  75   {
  76     errno = $3 + 0;
  77     if (alias[e])
  78       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  79     else
  80       printf "#ifdef %s\n", e;
  81     errnoh = 4;
  82     desc="";
  83     next;
  84   }
  85 errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
  86   {
  87     printf "/*%s */\n", desc;
  88     printf "    [ERR_REMAP (%s)] = N_(\"%s\"),\n", e, etext;
  89     print "#endif";
  90     errnoh = 0;
  91     next;
  92   }
  93 errnoh == 4 \
  94   {
  95     # This magic tag in C comments gets them copied into libc.pot.
  96     desc = desc "\nTRANS " $0; next
  97   }
  98 { errnoh=0 }
  99 END {
 100   print "  };";
 101   print "";
 102   print "const int SYS_NERR = sizeof SYS_ERRLIST / sizeof SYS_ERRLIST [0];";
 103   print "#ifdef SYS_ERRLIST_ALIAS";
 104   print "weak_alias (_sys_errlist, SYS_ERRLIST_ALIAS)";
 105   print "#endif";
 106   print "#ifdef SYS_NERR_ALIAS";
 107   print "weak_alias (_sys_nerr, SYS_NERR_ALIAS)";
 108   print "#endif";
 109   }