configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 AC_ARG_ENABLE(static, dnl
  74 [  --enable-static         build static library [default=yes]],
  75               static=$enableval, static=yes)
  76 AC_ARG_ENABLE(shared, dnl
  77 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  78               shared=$enableval, shared=default)
  79 AC_ARG_ENABLE(profile, dnl
  80 [  --enable-profile        build profiled library [default=yes]],
  81               profile=$enableval, profile=yes)
  82 AC_ARG_ENABLE(omitfp, dnl
  83 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  84               omitfp=$enableval, omitfp=no)
  85 AC_ARG_ENABLE(bounded, dnl
  86 [  --enable-bounded        build with runtime bounds checking [default=no]],
  87               bounded=$enableval, bounded=no)
  88 AC_ARG_ENABLE(versioning, dnl
  89 [  --disable-versioning    do not include versioning information in the
  90                           library objects [default=yes if supported]],
  91              enable_versioning=$enableval, enable_versioning=yes)
  92
  93 dnl Generic infrastructure for drop-in additions to libc.
  94 AC_ARG_ENABLE(add-ons, dnl
  95 [  --enable-add-ons[=DIR1,DIR2]...
  96                           configure and build add-ons in DIR1,DIR2,...
  97                           search for add-ons if no parameter given],
  98   [case "$enableval" in
  99     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 100          test "$add_ons" = "*" && add_ons= ;;
 101     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 102    esac],
 103   [add_ons=])
 104
 105 AC_CONFIG_SUBDIRS($add_ons)
 106 add_ons_pfx=
 107 if test x"$add_ons" != x; then
 108   for f in $add_ons; do
 109     # Test whether such a subdir really exists.
 110     if test -d $srcdir/$f; then
 111       add_ons_pfx="$add_ons_pfx $f/"
 112     else
 113       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 114     fi
 115   done
 116 fi
 117
 118 dnl On some platforms we cannot use dynamic loading.  We must provide
 119 dnl static NSS modules.
 120 AC_ARG_ENABLE(static-nss, dnl
 121 [  --enable-static-nss     build static NSS modules [default=no]],
 122               static_nss=$enableval, static_nss=no)
 123 if test x"$static_nss" = xyes; then
 124   AC_DEFINE(DO_STATIC_NSS)
 125 fi
 126
 127 AC_ARG_ENABLE(force-install,
 128 [  --disable-force-install don't force installation of files from this package,
 129                           even if they are older than the installed files],
 130               force_install=$enableval, force_install=yes)
 131 AC_SUBST(force_install)
 132
 133 AC_CANONICAL_HOST
 134
 135 # The way shlib-versions is used to generate soversions.mk uses a
 136 # fairly simplistic model for name recognition that can't distinguish
 137 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 138 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 139 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 140 case "$host_os" in
 141 linux*)
 142   ;;
 143 gnu*)
 144   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 145   ;;
 146 esac
 147
 148 # We keep the original values in `$config_*' and never modify them, so we
 149 # can write them unchanged into config.make.  Everything else uses
 150 # $machine, $vendor, and $os, and changes them whenever convenient.
 151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 152
 153 # Some configurations imply other options.
 154 case "$host_os" in
 155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 156   # These systems always use GNU tools.
 157   gnu_ld=yes gnu_as=yes ;;
 158 esac
 159 case "$host_os" in
 160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 162   ;;
 163 gnu* | linux* | sysv4* | solaris2* | irix6*)
 164   # These systems (almost) always use the ELF format.
 165   elf=yes
 166   ;;
 167 esac
 168
 169 machine=$config_machine
 170 vendor=$config_vendor
 171 os=$config_os
 172
 173 ###
 174 ### I put this here to prevent those annoying emails from people who cannot
 175 ### read and try to compile glibc on unsupported platforms.  --drepper
 176 ###
 177 ### By using the undocumented --enable-hacker-mode option for configure
 178 ### one can skip this test to make the configuration not fail for unsupported
 179 ### platforms.
 180 ###
 181 if test -z "$enable_hacker_mode"; then
 182   case "$machine-$host_os" in
 183   *-linux* | *-gnu* | arm*-none*)
 184     ;;
 185   *)
 186     echo "*** The GNU C library is currently not available for this platform."
 187     echo "*** So far nobody cared to port it and if there is no volunteer it"
 188     echo "*** might never happen.  So, if you have interest to see glibc on"
 189     echo "*** this platform visit"
 190     echo "***   http://www.gnu.org/software/libc/porting.html"
 191     echo "*** and join the group of porters"
 192     exit 1
 193     ;;
 194   esac
 195 fi
 196
 197 dnl We need to use [ and ] for other purposes for a while now.
 198 changequote(,)dnl
 199 # Expand the configuration machine name into a subdirectory by architecture
 200 # type and particular chip.
 201 case "$machine" in
 202 a29k | am29000) base_machine=a29k machine=a29k ;;
 203 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 204 arm*)           base_machine=arm machine=arm/$machine ;;
 205 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 206 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 207 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 208 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 209 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 210 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 211 m88???)         base_machine=m88k machine=m88k/$machine ;;
 212 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 213 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 214 mips*)          base_machine=mips
 215                 case "`uname -m`" in
 216                 IP22) machine=mips/mips3 ;;
 217                 *)    machine=mips/$machine ,,
 218                 esac ;;
 219 sparc | sparcv[67])
 220                 base_machine=sparc machine=sparc/sparc32 ;;
 221 sparcv8 | supersparc | hypersparc)
 222                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 223 sparc64 | ultrasparc)
 224                 base_machine=sparc machine=sparc/sparc64 ;;
 225 esac
 226 changequote([,])dnl
 227 AC_SUBST(base_machine)
 228
 229 if test "$base_machine" = "i386"; then
 230   AC_DEFINE(USE_REGPARMS)
 231 fi
 232
 233 # Compute the list of sysdep directories for this configuration.
 234 # This can take a while to compute.
 235 sysdep_dir=$srcdir/sysdeps
 236 AC_MSG_CHECKING(sysdep dirs)
 237 dnl We need to use [ and ] for other purposes for a while now.
 238 changequote(,)dnl
 239 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 240 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 241
 242 case "$os" in
 243 gnu*)
 244   base_os=mach/hurd ;;
 245 netbsd* | 386bsd* | freebsd* | bsdi*)
 246   base_os=unix/bsd/bsd4.4 ;;
 247 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 248   base_os=unix/bsd ;;
 249 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 250   base_os=unix/sysv ;;
 251 irix6*)
 252   base_os=unix/sysv/irix6/$os ;;
 253 solaris[2-9]*)
 254   base_os=unix/sysv/sysv4 ;;
 255 none)
 256   base_os=standalone ;;
 257 *)
 258   base_os='' ;;
 259 esac
 260
 261 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 262 tail=$os
 263 ostry=$os
 264 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 265   ostry="$ostry /$o"
 266   tail=$o
 267 done
 268 o=`echo $tail | sed 's/[0-9]*$//'`
 269 if test $o != $tail; then
 270   ostry="$ostry /$o"
 271 fi
 272 # For linux-gnu, try linux-gnu, then linux.
 273 o=`echo $tail | sed 's/-.*$//'`
 274 if test $o != $tail; then
 275   ostry="$ostry /$o"
 276 fi
 277
 278 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 279 base=
 280 tail=$base_os
 281 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 282   set $b
 283   base="$base /$1"
 284   tail="$2"
 285 done
 286
 287 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 288 mach=
 289 tail=$machine
 290 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 291   set $m
 292   # Prepend the machine's FPU directory unless --without-fp.
 293   if test "$with_fp" = yes; then
 294     mach="$mach /$1/fpu"
 295   fi
 296   mach="$mach /$1"
 297   tail="$2"
 298 done
 299
 300 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 301 changequote([,])dnl
 302
 303 # Find what sysdep directories exist.
 304 sysnames=
 305 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 306 for d in $add_ons_pfx ''; do
 307   for b in $base ''; do
 308     for m0 in $mach ''; do
 309       for v in /$vendor ''; do
 310         test "$v" = / && continue
 311         for o in /$ostry ''; do
 312           test "$o" = / && continue
 313           for m in $mach ''; do
 314             if test "$m0$b$v$o$m"; then
 315               try="${d}sysdeps$m0$b$v$o$m"
 316               test -n "$enable_debug_configure" &&
 317               echo "$0 [DEBUG]: try $try" >&2
 318               if test -d $srcdir/$try; then
 319                 sysnames="$sysnames $try"
 320                 { test -n "$o" || test -n "$b"; } && os_used=t
 321                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 322               fi
 323             fi
 324           done
 325         done
 326       done
 327     done
 328   done
 329 done
 330 IFS="$ac_save_ifs"
 331
 332 if test -z "$os_used" && test "$os" != none; then
 333   AC_MSG_ERROR(Operating system $os is not supported.)
 334 fi
 335 if test -z "$machine_used" && test "$machine" != none; then
 336   AC_MSG_ERROR(The $machine is not supported.)
 337 fi
 338
 339 # We have now validated the configuration.
 340
 341
 342 # If using ELF, look for an `elf' subdirectory of each machine directory.
 343 # We prepend these rather than inserting them whereever the machine appears
 344 # because things specified by the machine's ELF ABI should override
 345 # OS-specific things, and should always be the same for any OS on the
 346 # machine (otherwise what's the point of an ABI?).
 347 if test "$elf" = yes; then
 348   elf_dirs=
 349   for d in $add_ons_pfx ''; do
 350     for m in $mach; do
 351       if test -d $srcdir/${d}sysdeps$m/elf; then
 352         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 353       fi
 354     done
 355   done
 356   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 357 fi
 358
 359
 360 # Expand the list of system names into a full list of directories
 361 # from each element's parent name and Implies file (if present).
 362 set $sysnames
 363 names=
 364 while test $# -gt 0; do
 365   name=$1
 366   shift
 367
 368   case " $names " in *" $name "*)
 369     # Already in the list.
 370     continue
 371   esac
 372
 373   # Report each name as we discover it, so there is no long pause in output.
 374   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 375
 376   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 377
 378   case $name in
 379     /*) xsrcdir= ;;
 380     *)  xsrcdir=$srcdir/ ;;
 381   esac
 382   test -n "$enable_debug_configure" &&
 383   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 384
 385   if test -f $xsrcdir$name/Implies; then
 386     # Collect more names from the `Implies' file (removing comments).
 387     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 388     implied=
 389     for x in $implied_candidate; do
 390       if test -d $xsrcdir$name_base/$x; then
 391         implied="$implied $name_base/$x";
 392       else
 393         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 394       fi
 395     done
 396   else
 397     implied=
 398   fi
 399
 400   # Add NAME to the list of names.
 401   names="$names $name"
 402
 403   # Find the parent of NAME, using the empty string if it has none.
 404 changequote(,)dnl
 405   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 406 changequote([,])dnl
 407
 408   # Add the names implied by NAME, and NAME's parent (if it has one), to
 409   # the list of names to be processed (the argument list).  We prepend the
 410   # implied names to the list and append the parent.  We want implied
 411   # directories to come before further directories inferred from the
 412   # configuration components; this ensures that for sysv4, unix/common
 413   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 414   # after sysv4).
 415   sysnames="`echo $implied $* $parent`"
 416   test -n "$sysnames" && set $sysnames
 417 done
 418
 419 # Add the default directories.
 420 default_sysnames=sysdeps/generic
 421 if test "$elf" = yes; then
 422   default_sysnames="sysdeps/generic/elf $default_sysnames"
 423 fi
 424 sysnames="$names $default_sysnames"
 425 AC_SUBST(sysnames)
 426 # The other names were emitted during the scan.
 427 AC_MSG_RESULT($default_sysnames)
 428
 429
 430 ### Locate tools.
 431
 432 AC_PROG_INSTALL
 433 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 434   # The makefiles need to use a different form to find it in $srcdir.
 435   INSTALL='\$(..)./install-sh -c'
 436 fi
 437 AC_PROG_LN_S
 438
 439 # These programs are version sensitive.
 440 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 441 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 442   [version \([egcstp-]*[0-9.]*\)],
 443   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*],
 444   critic_missing=t)
 445 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 446   [version \([0-9][0-9.]*\), by],
 447   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 448
 449 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 450   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 451   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 452 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 453   [GNU texinfo \([0-9][0-9.]*\)],
 454   [3.1[1-9] | 3.[2-9][0-9]], MAKEINFO=: aux_missing=t)
 455
 456 if test -n "$critic_missing"; then
 457 AC_MSG_ERROR([
 458 *** Some critical program is missing or too old.
 459 *** Check the INSTALL file for required versions.])
 460 fi
 461
 462 test -n "$aux_missing" && AC_MSG_WARN([
 463 *** An auxiliary program is missing or too old;
 464 *** some features will be disabled.
 465 *** Check the INSTALL file for required versions.])
 466
 467 AC_PROG_CC_LOCAL
 468 AC_CANONICAL_BUILD
 469 if test $host != $build; then
 470   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 471 fi
 472 AC_SUBST(cross_compiling)
 473 AC_PROG_CPP
 474 LIBC_PROG_BINUTILS
 475 AC_CHECK_TOOL(AR, ar)
 476 AC_CHECK_TOOL(RANLIB, ranlib, :)
 477 AC_CHECK_TOOL(MIG, mig)
 478
 479 # if using special system headers, find out the compiler's sekrit
 480 # header directory and add that to the list.  NOTE: Only does the right
 481 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 482 if test -n "$sysheaders"; then
 483   ccheaders=`$CC -print-file-name=include`
 484   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 485 fi
 486 AC_SUBST(SYSINCLUDES)
 487
 488 # check if ranlib is necessary
 489 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 490 cat > conftest.c <<EOF
 491 int a;
 492 char b;
 493 void c(void) {}
 494 EOF
 495 $CC $CFLAGS -c conftest.c
 496 $AR cr conftest.a conftest.c
 497 cp conftest.a conftest2.a
 498 $RANLIB conftest.a
 499 if cmp -s conftest.a conftest2.a; then
 500   libc_cv_ranlib_necessary=no
 501 else
 502   libc_cv_ranlib_necessary=yes
 503 fi
 504 rm -rf conftest*])
 505 if test "$libc_cv_ranlib_necessary" = no; then
 506  RANLIB=:
 507 fi
 508
 509 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 510 # since this would lead to problems installing/building glibc.
 511 # LD_LIBRARY_PATH contains the current directory if one of the following
 512 # is true:
 513 # - one of the terminals (":" and ";") is the first or last sign
 514 # - two terminals occur directly after each other
 515 # - the path contains an element with a dot in it
 516 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 517 changequote(,)dnl
 518 case ${LD_LIBRARY_PATH} in
 519   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 520     ld_library_path_setting="contains current directory"
 521     ;;
 522   *)
 523     ld_library_path_setting="ok"
 524     ;;
 525 esac
 526 changequote([,])dnl
 527 AC_MSG_RESULT($ld_library_path_setting)
 528 if test "$ld_library_path_setting" != "ok"; then
 529 AC_MSG_ERROR([
 530 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 531 *** building glibc. Please change the environment variable
 532 *** and run configure again.])
 533 fi
 534
 535 AC_PATH_PROG(BASH, bash, no)
 536 if test "$BASH" != no &&
 537    $BASH -c 'test "$BASH_VERSINFO" \
 538              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 539   libc_cv_have_bash2=yes
 540 else
 541   libc_cv_have_bash2=no
 542 fi
 543 AC_SUBST(libc_cv_have_bash2)
 544
 545 dnl We need a ksh compatible shell for tzselect.
 546 if test "$BASH" = no; then
 547   AC_PATH_PROG(KSH, ksh, no)
 548   if test "$KSH" = no; then
 549     libc_cv_have_ksh=no
 550   else
 551     libc_cv_have_ksh=yes
 552   fi
 553 else
 554   KSH="$BASH"
 555   AC_SUBST(KSH)
 556   libc_cv_have_ksh=yes
 557 fi
 558 AC_SUBST(libc_cv_have_ksh)
 559
 560 AC_PROG_AWK
 561 AC_PATH_PROGS(PERL, perl, no)
 562 AC_SUBST(PERL)
 563
 564 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 565 echo '#include <stddef.h>
 566 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 567 if eval "$ac_cpp conftest.c 2>/dev/null" \
 568 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 569   libc_cv_signed_size_t=no
 570 else
 571   libc_cv_signed_size_t=yes
 572 fi
 573 rm -f conftest*])
 574 if test $libc_cv_signed_size_t = yes; then
 575   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 576   cat >> confdefs.h <<\EOF
 577 #undef __SIZE_TYPE__
 578 #define __SIZE_TYPE__ unsigned
 579 EOF
 580 fi
 581
 582 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 583 AC_TRY_COMPILE(dnl
 584 [#define __need_size_t
 585 #define __need_wchar_t
 586 #include <stddef.h>
 587 #define __need_NULL
 588 #include <stddef.h>], [size_t size; wchar_t wchar;
 589 #ifdef offsetof
 590 #error stddef.h ignored __need_*
 591 #endif
 592 if (&size == NULL || &wchar == NULL) abort ();],
 593                libc_cv_friendly_stddef=yes,
 594                libc_cv_friendly_stddef=no)])
 595 if test $libc_cv_friendly_stddef = yes; then
 596   config_vars="$config_vars
 597 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 598 fi
 599
 600 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 601                libc_cv_need_minus_P, [dnl
 602 cat > conftest.S <<EOF
 603 #include "confdefs.h"
 604 /* Nothing whatsoever.  */
 605 EOF
 606 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 607   libc_cv_need_minus_P=no
 608 else
 609   libc_cv_need_minus_P=yes
 610 fi
 611 rm -f conftest*])
 612 if test $libc_cv_need_minus_P = yes; then
 613   config_vars="$config_vars
 614 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 615 fi
 616
 617 AC_CACHE_CHECK(for assembler global-symbol directive,
 618                libc_cv_asm_global_directive, [dnl
 619 libc_cv_asm_global_directive=UNKNOWN
 620 for ac_globl in .globl .global; do
 621   cat > conftest.s <<EOF
 622 .text
 623 ${ac_globl} foo
 624 foo:
 625 EOF
 626   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 627     libc_cv_asm_global_directive=${ac_globl}
 628   fi
 629   rm -f conftest*
 630   test $libc_cv_asm_global_directive != UNKNOWN && break
 631 done])
 632 if test $libc_cv_asm_global_directive = UNKNOWN; then
 633   AC_MSG_ERROR(cannot determine asm global directive)
 634 else
 635   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 636 fi
 637
 638 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 639 cat > conftest.s <<EOF
 640 .text
 641 foo:
 642 .set glibc_conftest_frobozz,foo
 643 $libc_cv_asm_global_directive glibc_conftest_frobozz
 644 EOF
 645 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 646 # (but it doesn't work), so we must do a linking check to be sure.
 647 cat > conftest1.c <<\EOF
 648 extern int glibc_conftest_frobozz;
 649 main () { printf ("%d\n", glibc_conftest_frobozz); }
 650 EOF
 651 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 652             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 653   libc_cv_asm_set_directive=yes
 654 else
 655   libc_cv_asm_set_directive=no
 656 fi
 657 rm -f conftest*])
 658 if test $libc_cv_asm_set_directive = yes; then
 659   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 660 fi
 661
 662 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 663 [cat > conftest.s <<EOF
 664 .text
 665 _sym:
 666 .symver _sym,sym@VERS
 667 EOF
 668 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 669   libc_cv_asm_symver_directive=yes
 670 else
 671   libc_cv_asm_symver_directive=no
 672 fi
 673 rm -f conftest*])
 674 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 675 if test $libc_cv_asm_symver_directive = yes; then
 676   cat > conftest.s <<EOF
 677 .text
 678 _sym:
 679 .symver _sym,sym@VERS
 680 EOF
 681   cat > conftest.map <<EOF
 682 VERS_1 {
 683         global: sym;
 684 };
 685
 686 VERS_2 {
 687         global: sym;
 688 } VERS_1;
 689 EOF
 690   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 691     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 692                                         -nostartfiles -nostdlib
 693                                         -Wl,--version-script,conftest.map
 694                        1>&AC_FD_CC]);
 695     then
 696       libc_cv_ld_version_script_option=yes
 697     else
 698       libc_cv_ld_version_script_option=no
 699     fi
 700   else
 701     libc_cv_ld_version_script_option=no
 702   fi
 703 else
 704   libc_cv_ld_version_script_option=no
 705 fi
 706 rm -f conftest*])
 707 if test $libc_cv_asm_symver_directive = yes &&
 708    test $libc_cv_ld_version_script_option = yes &&
 709    test $enable_versioning = yes; then
 710   VERSIONING=yes
 711   AC_DEFINE(DO_VERSIONING)
 712 else
 713   VERSIONING=no
 714 fi
 715 AC_SUBST(VERSIONING)
 716
 717 if test $VERSIONING = no; then
 718   echo "\
 719 *** WARNING: You should not compile GNU libc without versioning. Not using
 720 *** versioning will introduce incompatibilities so that old binaries
 721 *** will not run anymore.
 722 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 723 fi
 724 if test $elf = yes; then
 725   AC_CACHE_CHECK(for .previous assembler directive,
 726                  libc_cv_asm_previous_directive, [dnl
 727   cat > conftest.s <<EOF
 728 .section foo_section
 729 .previous
 730 EOF
 731   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 732     libc_cv_asm_previous_directive=yes
 733   else
 734     libc_cv_asm_previous_directive=no
 735   fi
 736   rm -f conftest*])
 737   if test $libc_cv_asm_previous_directive = yes; then
 738     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 739   else
 740     AC_CACHE_CHECK(for .popsection assembler directive,
 741                    libc_cv_asm_popsection_directive, [dnl
 742     cat > conftest.s <<EOF
 743 .pushsection foo_section
 744 .popsection
 745 EOF
 746     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 747       libc_cv_asm_popsection_directive=yes
 748     else
 749       libc_cv_asm_popsection_directive=no
 750     fi
 751     rm -f conftest*])
 752     if test $libc_cv_asm_popsection_directive = yes; then
 753       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 754     fi
 755   fi
 756 fi
 757
 758 if test $elf != yes; then
 759   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 760                  [AC_TRY_COMPILE(, [asm (".section .init");
 761                                     asm (".section .fini");
 762                                     asm (".text");],
 763                                  libc_cv_have_initfini=yes,
 764                                  libc_cv_have_initfini=no)])
 765   AC_SUBST(libc_cv_have_initfini)dnl
 766   if test $libc_cv_have_initfini = yes; then
 767     AC_DEFINE(HAVE_INITFINI)
 768   fi
 769 fi
 770
 771 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 772 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 773 [cat > conftest.$ac_ext <<EOF
 774 dnl This sometimes fails to find confdefs.h, for some reason.
 775 dnl [#]line __oline__ "[$]0"
 776 [#]line __oline__ "configure"
 777 #include "confdefs.h"
 778 void underscore_test(void) {
 779 return; }
 780 EOF
 781 if AC_TRY_EVAL(ac_compile); then
 782   if grep _underscore_test conftest* >/dev/null; then
 783     ifelse([$1], , :, [rm -f conftest*
 784     $1])
 785   else
 786     ifelse([$2], , , [rm -f conftest*
 787     $2])
 788   fi
 789 else
 790   echo "configure: failed program was:" >&AC_FD_CC
 791   cat conftest.$ac_ext >&AC_FD_CC
 792   ifelse([$2], , , [rm -f conftest*
 793   $2])
 794 fi
 795 rm -f conftest*])
 796
 797 if test $elf = yes; then
 798   libc_cv_asm_underscores=no
 799 else
 800   if test $ac_cv_prog_cc_works = yes; then
 801     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 802                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 803                                 libc_cv_asm_underscores=yes,
 804                                 libc_cv_asm_underscores=no)])
 805   else
 806     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 807                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 808                                             libc_cv_asm_underscores=no)])
 809   fi
 810 fi
 811 if test $libc_cv_asm_underscores = no; then
 812   AC_DEFINE(NO_UNDERSCORES)
 813 fi
 814
 815 if test $elf = yes; then
 816   libc_cv_weak_symbols=yes
 817 fi
 818
 819 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 820                  [dnl
 821 cat > conftest.s <<EOF
 822 .text
 823 ${libc_cv_asm_global_directive} foo
 824 foo:
 825 .weak foo
 826 .weak bar; bar = foo
 827 EOF
 828 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 829   libc_cv_asm_weak_directive=yes
 830 else
 831   libc_cv_asm_weak_directive=no
 832 fi
 833 rm -f conftest*])
 834
 835 if test $libc_cv_asm_weak_directive = no; then
 836   AC_CACHE_CHECK(for assembler .weakext directive,
 837                  libc_cv_asm_weakext_directive,
 838                  [dnl
 839 cat > conftest.s <<EOF
 840 .text
 841 ${libc_cv_asm_global_directive} foo
 842 foo:
 843 .weakext bar foo
 844 .weakext baz
 845 ${libc_cv_asm_global_directive} baz
 846 baz:
 847 EOF
 848   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 849     libc_cv_asm_weakext_directive=yes
 850   else
 851     libc_cv_asm_weakext_directive=no
 852   fi
 853   rm -f conftest*])
 854
 855 fi # no .weak
 856
 857 if test $libc_cv_asm_weak_directive = yes; then
 858   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 859 elif test $libc_cv_asm_weakext_directive = yes; then
 860   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 861 fi
 862
 863 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 864 cat > conftest.c <<\EOF
 865 _start () {}
 866 int __eh_pc;
 867 __throw () {}
 868 EOF
 869 dnl No \ in command here because it ends up inside ''.
 870 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 871                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 872                             -o conftest conftest.c 1>&AC_FD_CC]); then
 873   libc_cv_ld_no_whole_archive=yes
 874 else
 875   libc_cv_ld_no_whole_archive=no
 876 fi
 877 rm -f conftest*])
 878 if test $libc_cv_ld_no_whole_archive = yes; then
 879   no_whole_archive=-Wl,--no-whole-archive
 880 fi
 881 AC_SUBST(no_whole_archive)dnl
 882
 883 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 884 cat > conftest.c <<\EOF
 885 _start () {}
 886 int __eh_pc;
 887 __throw () {}
 888 EOF
 889 dnl No \ in command here because it ends up inside ''.
 890 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 891                             -nostdlib -nostartfiles -fexceptions
 892                             -o conftest conftest.c 1>&AC_FD_CC]); then
 893   libc_cv_gcc_exceptions=yes
 894 else
 895   libc_cv_gcc_exceptions=no
 896 fi
 897 rm -f conftest*])
 898 if test $libc_cv_gcc_exceptions = yes; then
 899   exceptions=-fexceptions
 900 fi
 901 AC_SUBST(exceptions)dnl
 902
 903 if test "$base_machine" = alpha ; then
 904 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 905 cat > conftest.c <<\EOF
 906 foo () { }
 907 EOF
 908 dnl
 909 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 910 then
 911   libc_cv_gcc_alpha_ng_prefix=yes
 912 else
 913   libc_cv_gcc_alpha_ng_prefix=no
 914 fi
 915 rm -f conftest* ])
 916 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 917   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 918 else
 919   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 920 fi
 921 fi
 922
 923 if test "$host_cpu" = powerpc ; then
 924 # Check for a bug present in at least versions 2.8.x of GCC
 925 # and versions 1.0.x of EGCS.
 926 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 927 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 928                libc_cv_c_asmcr0_bug='no',
 929                libc_cv_c_asmcr0_bug='yes')])
 930 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 931   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 932 fi
 933 fi
 934
 935 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 936 [cat > conftest.c <<EOF
 937 #line __oline__ "configure"
 938 static char __EH_FRAME_BEGIN__[];
 939 _start ()
 940 {
 941 #ifdef CHECK__register_frame
 942   __register_frame (__EH_FRAME_BEGIN__);
 943   __deregister_frame (__EH_FRAME_BEGIN__);
 944 #endif
 945 #ifdef CHECK__register_frame_info
 946   __register_frame_info (__EH_FRAME_BEGIN__);
 947   __deregister_frame_info (__EH_FRAME_BEGIN__);
 948 #endif
 949 }
 950 int __eh_pc;
 951 __throw () {}
 952 /* FIXME: this is fragile.  */
 953 malloc () {}
 954 strcmp () {}
 955 strlen () {}
 956 memcpy () {}
 957 memset () {}
 958 free () {}
 959 abort () {}
 960 __bzero () {}
 961 EOF
 962 dnl No \ in command here because it ends up inside ''.
 963 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 964                             -nostdlib -nostartfiles
 965                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 966   libc_cv_gcc_dwarf2_unwind_info=static
 967 else
 968   libc_cv_gcc_dwarf2_unwind_info=no
 969 fi
 970 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 971   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 972                               -nostdlib -nostartfiles
 973                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 974     libc_cv_gcc_dwarf2_unwind_info=yes
 975   else
 976     libc_cv_gcc_dwarf2_unwind_info=no
 977   fi
 978 fi
 979 rm -f conftest*])
 980 case $libc_cv_gcc_dwarf2_unwind_info in
 981 yes)
 982   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 983   ;;
 984 static)
 985   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 986   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 987   ;;
 988 esac
 989
 990 ### End of automated tests.
 991 ### Now run sysdeps configure fragments.
 992
 993 # sysdeps configure fragments may set these with files to be linked below.
 994 libc_link_dests=
 995 libc_link_sources=
 996
 997 # They also can set these variables.
 998 ldd_rewrite_script=no
 999
1000 # Iterate over all the sysdep directories we will use, running their
1001 # configure fragments, and looking for a uname implementation.
1002 uname=
1003 for dir in $sysnames; do
1004   case $dir in
1005     /*) dest=$dir ;;
1006     *)  dest=$srcdir/$dir ;;
1007   esac
1008   if test -r $dest/configure; then
1009     AC_MSG_RESULT(running configure fragment for $dest)
1010     . $dest/configure
1011   fi
1012 [
1013   if test -z "$uname"; then
1014     if test -r $dest/uname.c ||
1015        test -r $dest/uname.S ||
1016        { test -r $dest/syscalls.list &&
1017          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1018       uname=$dir
1019     fi
1020   fi
1021 ]dnl
1022 done
1023
1024 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1025
1026 # If we will use the generic uname implementation, we must figure out what
1027 # it will say by examining the system, and write the results in config-name.h.
1028 if test "$uname" = "sysdeps/generic"; then
1029
1030 changequote(,)dnl
1031   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1032 changequote([,])dnl
1033   if test $uname_sysname != $config_os; then
1034     config_release=`echo $config_os | sed s/$uname_sysname//`
1035   fi
1036 dnl
1037 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1038     if test -r /vmunix; then
1039       kernel_id=`strings /vmunix | grep UNIX`
1040     elif test -r /dynix; then
1041       kernel_id=`strings /dynix | grep DYNIX`
1042     else
1043       kernel_id=
1044     fi
1045 ])dnl
1046
1047   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1048 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1049 changequote(,)dnl
1050   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1051 changequote([,])dnl
1052   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1053          != x$config_release; then
1054     # The configuration release is a substring of the kernel release.
1055     libc_cv_uname_release=$kernel_release
1056   elif test x$config_release != x; then
1057     libc_cv_uname_release=$config_release
1058   elif test x$kernel_release != x; then
1059     libc_cv_uname_release=$kernel_release
1060   else
1061     libc_cv_uname_release=unknown
1062   fi])
1063   uname_release="$libc_cv_uname_release"
1064
1065   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1066 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1067 changequote(,)dnl
1068   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1069 changequote([,])dnl
1070   if test -n "$kernel_version"; then
1071     libc_cv_uname_version="$kernel_version"
1072   else
1073     libc_cv_uname_version=unknown
1074   fi])
1075   uname_version="$libc_cv_uname_version"
1076
1077 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1078   config_uname=config-name.h:config-name.in
1079 else
1080   # For non-generic uname, we don't need to create config-name.h at all.
1081   config_uname=
1082 fi
1083
1084 AC_MSG_CHECKING(stdio selection)
1085 AC_SUBST(stdio)
1086 case $stdio in
1087 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1088 default) stdio=stdio ;;
1089 esac
1090 AC_MSG_RESULT($stdio)
1091
1092 # Test for old glibc 2.0.x headers so that they can be removed properly
1093 # Search only in includedir.
1094 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1095 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1096 then
1097   old_glibc_headers=yes
1098 else
1099   old_glibc_headers=no
1100 fi
1101 AC_MSG_RESULT($old_glibc_headers)
1102 if test ${old_glibc_headers} = yes; then
1103   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1104   AC_MSG_WARN(*** be removed.)
1105 fi
1106 AC_SUBST(old_glibc_headers)
1107
1108 AC_SUBST(libc_cv_slibdir)
1109 AC_SUBST(libc_cv_sysconfdir)
1110 AC_SUBST(libc_cv_rootsbindir)
1111
1112 AC_SUBST(has_ldconfig)
1113 AC_SUBST(ldd_rewrite_script)
1114
1115 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1116 if test $gnu_ld = yes; then
1117   AC_DEFINE(HAVE_GNU_LD)
1118 fi
1119 if test $gnu_as = yes; then
1120   AC_DEFINE(HAVE_GNU_AS)
1121 fi
1122 if test $elf = yes; then
1123   AC_DEFINE(HAVE_ELF)
1124 fi
1125
1126 AC_SUBST(static)
1127 AC_SUBST(shared)
1128 if test $shared = default; then
1129   if test $gnu_ld = yes; then
1130     shared=$elf
1131   else
1132     # For now we do not assume shared libs are available.  In future more
1133     # tests might become available.
1134     shared=no
1135   fi
1136 fi
1137
1138 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1139 [pic_default=yes
1140 cat > conftest.c <<EOF
1141 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1142 # error PIC is default.
1143 #endif
1144 EOF
1145 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1146   pic_default=no
1147 fi
1148 rm -f conftest.*])
1149 AC_SUBST(pic_default)
1150
1151 AC_SUBST(profile)
1152 AC_SUBST(omitfp)
1153 AC_SUBST(bounded)
1154 AC_SUBST(static_nss)
1155 AC_SUBST(nopic_initfini)
1156
1157 AC_SUBST(DEFINES)
1158
1159 case "$add_ons" in
1160   *door*) linux_doors=yes ;;
1161   *) linux_doors=no ;;
1162 esac
1163 AC_SUBST(linux_doors)
1164
1165 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1166   config_makefile=
1167 else
1168   config_makefile=Makefile
1169 fi
1170
1171 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1172 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1173 AC_SUBST(VERSION)
1174 AC_SUBST(RELEASE)
1175
1176 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1177 case $CONFIG_FILES in *config.make*)
1178 echo "$config_vars" >> config.make;;
1179 esac
1180 test -d bits || mkdir bits], [config_vars='$config_vars'])