scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (combine_fullname)
   6     combine = 1;
   7   if (combine)
   8     parse_names = 1;
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9.]+:[  ]+.file format .*$/ {
  13   emit(0);
  14
  15   seen_opd = 0;
  16
  17   sofullname = $1;
  18   sub(/:$/, "", sofullname);
  19   soname = sofullname;
  20   sub(/^.*\//, "", soname);
  21   sub(/\.so\.[0-9.]+$/, "", soname);
  22
  23   suppress = ((filename_regexp != "" && sofullname !~ filename_regexp) \
  24               || (libname_regexp != "" && soname !~ libname_regexp));
  25
  26   next
  27 }
  28
  29 suppress { next }
  30
  31 # Normalize columns.
  32 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  33
  34 # Skip undefineds.
  35 $4 == "*UND*" { next }
  36
  37 # Skip locals.
  38 $2 == "l" { next }
  39
  40 # If the target uses ST_OTHER, it will be output before the symbol name.
  41 $2 == "g" || $2 == "w" && (NF == 7 || NF == 8) {
  42   weak = $2;
  43   type = $3;
  44   size = $5;
  45   sub(/^0*/, "", size);
  46   size = " 0x" size;
  47   version = $6;
  48   symbol = $NF;
  49   gsub(/[()]/, "", version);
  50
  51   # binutils versions up through at least 2.23 have some bugs that
  52   # caused STV_HIDDEN symbols to appear in .dynsym, though that is useless.
  53   if (NF > 7 && $7 == ".hidden") next;
  54
  55   if (version == "GLIBC_PRIVATE") next;
  56
  57   desc = "";
  58   if (type == "D" && $4 == ".tbss") {
  59     type = "T";
  60   }
  61   else if (type == "D" && $4 == ".opd") {
  62     type = "F";
  63     size = "";
  64     if (seen_opd < 0)
  65       type = "O";
  66     seen_opd = 1;
  67   }
  68   else if (type == "D" && NF == 8 && $7 == "0x80") {
  69     # Alpha functions avoiding plt entry in users
  70     type = "F";
  71     size = "";
  72     seen_opd = -1;
  73   }
  74   else if ($4 == "*ABS*") {
  75     type = "A";
  76     size = "";
  77   }
  78   else if (type == "DO") {
  79     type = "D";
  80   }
  81   else if (type == "DF") {
  82     if (symbol ~ /^\./ && seen_opd >= 0)
  83       next;
  84     seen_opd = -1;
  85     type = "F";
  86     size = "";
  87   }
  88   else if (type == "iD" && ($4 == ".text" || $4 == ".opd")) {
  89     # Indirect functions.
  90     type = "F";
  91     size = "";
  92   }
  93   else {
  94     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  95   }
  96   if (size == " 0x") {
  97     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  98   }
  99
 100   # Disabled -- weakness should not matter to shared library ABIs any more.
 101   #if (weak == "w") type = tolower(type);
 102   if (desc == "")
 103     desc = symbol " " type size;
 104
 105   if (combine)
 106     version = soname " " version (combine_fullname ? " " sofullname : "");
 107
 108   # Append to the string which collects the results.
 109   descs = descs version " " desc "\n";
 110   next;
 111 }
 112
 113 # Header crapola.
 114 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
 115
 116 {
 117   print "Don't grok this line:", $0
 118 }
 119
 120 function emit(end) {
 121   if (!end && (combine || ! parse_names || soname == ""))
 122     return;
 123   tofile = parse_names && !combine;
 124
 125   if (tofile) {
 126     out = prefix soname ".symlist";
 127     if (soname in outfiles)
 128       out = out "." ++outfiles[soname];
 129     else
 130       outfiles[soname] = 1;
 131     outpipe = "LC_ALL=C sort -u > " out;
 132   } else {
 133     outpipe = "LC_ALL=C sort -u";
 134   }
 135
 136   printf "%s", descs | outpipe;
 137
 138   descs = "";
 139
 140   if (tofile)
 141     print "wrote", out, "for", sofullname;
 142 }
 143
 144 END {
 145   emit(1);
 146 }