sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <kernel-features.h>
  23 #include <tcb-offsets.h>
  24
  25
  26 /* Clone the calling process, but without copying the whole address space.
  27    The calling process is suspended until the new process exits or is
  28    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  29    and the process ID of the new process to the old process.  */
  30
  31 ENTRY (__vfork)
  32
  33         /* Pop the return PC value into ECX.  */
  34         popl    %ecx
  35         cfi_adjust_cfa_offset (-4)
  36         cfi_register (%eip, %ecx)
  37
  38         /* Save the TCB-cached PID away in %edx, and then negate the TCB
  39            field.  But if it's zero, set it to 0x80000000 instead.  See
  40            raise.c for the logic that relies on this value.  */
  41         movl    %gs:PID, %edx
  42         movl    %edx, %eax
  43         negl    %eax
  44         jne     1f
  45         movl    $0x80000000, %eax
  46 1:      movl    %eax, %gs:PID
  47
  48
  49         /* Stuff the syscall number in EAX and enter into the kernel.  */
  50         movl    $SYS_ify (vfork), %eax
  51         int     $0x80
  52
  53         /* Jump to the return PC.  Don't jump directly since this
  54            disturbs the branch target cache.  Instead push the return
  55            address back on the stack.  */
  56         pushl   %ecx
  57         cfi_adjust_cfa_offset (4)
  58
  59         /* Restore the original value of the TCB cache of the PID, if we're
  60            the parent.  But in the child (syscall return value equals zero),
  61            leave things as they are.  */
  62         testl   %eax, %eax
  63         je      1f
  64         movl    %edx, %gs:PID
  65 1:
  66
  67         cmpl    $-4095, %eax
  68         /* Branch forward if it failed.  */
  69         jae     SYSCALL_ERROR_LABEL
  70
  71         ret
  72
  73 PSEUDO_END (__vfork)
  74 libc_hidden_def (__vfork)
  75
  76 weak_alias (__vfork, vfork)
  77 strong_alias (__vfork, __libc_vfork)