sysdeps/i386/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/i386.
   3
   4 # We no longer support i386 since it lacks the atomic instructions
   5 # required to implement NPTL threading.
   6 if test "$config_machine" = i386; then
   7   AC_MSG_ERROR([
   8 *** ERROR: Support for i386 is deprecated.
   9 *** Please use host i786, i686, i585 or i486.
  10 *** For example: /src/glibc/configure --host=i686-pc-linux-gnu ..."])
  11 fi
  12
  13 # The GNU C Library can't be built for i386.  There are several reasons for
  14 # this restriction.  The primary reason is that i386 lacks the atomic
  15 # operations required to support the current NPTL implementation.  While it is
  16 # possible that such atomic operations could be emulated in the kernel to date
  17 # no such work has been done to enable this.  Even with NPTL disabled you still
  18 # have no atomic.h implementation.  Given the declining use of i386 we disable
  19 # support for building with `-march=i386' or `-mcpu=i386.' We don't explicitly
  20 # check for i386, instead we make sure the compiler has support for inlining
  21 # the builtin __sync_val_compare_and_swap. If it does then we should have no
  22 # problem building for i386.
  23 LIBC_COMPILER_BUILTIN_INLINED(
  24   [__sync_val_compare_and_swap],
  25   [int a, b, c; __sync_val_compare_and_swap (&a, b, c);],
  26   [-O0],
  27   [libc_cv_unsupported_i386=no],
  28   [AC_MSG_ERROR([
  29 *** Building with -march=i386/-mcpu=i386 is not supported.
  30 *** Please use host i786, i686, i586, or i486.
  31 *** For example: /source/glibc/configure CFLAGS='-O2 -march=i686' ...])])
  32
  33 dnl Check if linker can convert "movl main@GOT(%ebx), %eax" to
  34 dnl "leal main@GOTOFF(%ebx), %eax" for static PIE.
  35 if test "$static_pie" = yes; then
  36   AC_CACHE_CHECK(for linker static PIE support, libc_cv_ld_static_pie, [dnl
  37 cat > conftest.s <<\EOF
  38         .text
  39         .global _start
  40 _start:
  41         movl    _start@GOT(%ebx), %eax
  42 EOF
  43   libc_cv_pie_option="-Wl,-pie"
  44   libc_cv_ld_static_pie=no
  45   if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp $libc_cv_pie_option -o conftest conftest.s 1>&AS_MESSAGE_LOG_FD); then
  46     if $READELF -r conftest | grep 'There are no relocations in this file.' > /dev/null; then
  47       libc_cv_ld_static_pie=yes
  48     fi
  49   fi
  50 rm -f conftest*])
  51   if test "$libc_cv_ld_static_pie" != yes; then
  52     AC_MSG_ERROR([linker support for static PIE needed])
  53   fi
  54 fi
  55
  56 dnl Check whether asm supports Intel MPX
  57 AC_CACHE_CHECK(for Intel MPX support, libc_cv_asm_mpx, [dnl
  58 cat > conftest.s <<\EOF
  59         bndmov %bnd0,(%esp)
  60 EOF
  61 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
  62   libc_cv_asm_mpx=yes
  63 else
  64   libc_cv_asm_mpx=no
  65 fi
  66 rm -f conftest*])
  67 if test $libc_cv_asm_mpx = yes; then
  68   AC_DEFINE(HAVE_MPX_SUPPORT)
  69 fi
  70
  71 dnl It is always possible to access static and hidden symbols in an
  72 dnl position independent way.
  73 AC_DEFINE(PI_STATIC_AND_HIDDEN)
  74
  75 dnl When multi-arch is enabled, all external functions must be called
  76 dnl via PIC PLT in PIE, which requires setting up EBX register.
  77 if test x"$multi_arch" != xno; then
  78   AC_DEFINE(NO_HIDDEN_EXTERN_FUNC_IN_PIE)
  79 fi