sysdeps/i386/i686/fpu/s_fmaxl.S

   1 /* Compute maximum of two numbers, regarding NaN as missing argument.
   2    Copyright (C) 1997-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         .text
  23 ENTRY(__fmaxl)
  24         fldt    4(%esp)         // x
  25         fldt    16(%esp)        // x : y
  26
  27         fucomi  %st(1), %st
  28         jp      2f
  29         fcmovb  %st(1), %st
  30
  31         fstp    %st(1)
  32
  33         ret
  34
  35 2:      // Unordered.
  36         fucomi  %st(0), %st
  37         jp      3f
  38         // st(1) is a NaN; st(0) is not.  Test if st(1) is signaling.
  39         testb   $0x40, 11(%esp)
  40         jz      4f
  41         fstp    %st(1)
  42         ret
  43
  44 3:      // st(0) is a NaN; st(1) may or may not be.
  45         fxch
  46         fucomi  %st(0), %st
  47         jp      4f
  48         // st(1) is a NaN; st(0) is not.  Test if st(1) is signaling.
  49         testb   $0x40, 23(%esp)
  50         jz      4f
  51         fstp    %st(1)
  52         ret
  53
  54 4:      // Both arguments are NaNs, or one is a signaling NaN.
  55         faddp
  56         ret
  57 END(__fmaxl)
  58 weak_alias (__fmaxl, fmaxl)