sysdeps/hppa/lshift.s

   1 ; HP-PA  __mpn_lshift --
   2
   3 ; Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   4
   5 ; This file is part of the GNU MP Library.
   6
   7 ; The GNU MP Library is free software; you can redistribute it and/or modify
   8 ; it under the terms of the GNU Library General Public License as published by
   9 ; the Free Software Foundation; either version 2 of the License, or (at your
  10 ; option) any later version.
  11
  12 ; The GNU MP Library is distributed in the hope that it will be useful, but
  13 ; WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ; or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 ; License for more details.
  16
  17 ; You should have received a copy of the GNU Library General Public License
  18 ; along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ; MA 02111-1307, USA.
  21
  22
  23 ; INPUT PARAMETERS
  24 ; res_ptr       gr26
  25 ; s_ptr         gr25
  26 ; size          gr24
  27 ; cnt           gr23
  28
  29         .code
  30         .export         __mpn_lshift
  31 __mpn_lshift
  32         .proc
  33         .callinfo       frame=64,no_calls
  34         .entry
  35
  36         sh2add          %r24,%r25,%r25
  37         sh2add          %r24,%r26,%r26
  38         ldws,mb         -4(0,%r25),%r22
  39         subi            32,%r23,%r1
  40         mtsar           %r1
  41         addib,=         -1,%r24,L$0004
  42         vshd            %r0,%r22,%r28           ; compute carry out limb
  43         ldws,mb         -4(0,%r25),%r29
  44         addib,=         -1,%r24,L$0002
  45         vshd            %r22,%r29,%r20
  46
  47 L$loop  ldws,mb         -4(0,%r25),%r22
  48         stws,mb         %r20,-4(0,%r26)
  49         addib,=         -1,%r24,L$0003
  50         vshd            %r29,%r22,%r20
  51         ldws,mb         -4(0,%r25),%r29
  52         stws,mb         %r20,-4(0,%r26)
  53         addib,<>        -1,%r24,L$loop
  54         vshd            %r22,%r29,%r20
  55
  56 L$0002  stws,mb         %r20,-4(0,%r26)
  57         vshd            %r29,%r0,%r20
  58         bv              0(%r2)
  59         stw             %r20,-4(0,%r26)
  60 L$0003  stws,mb         %r20,-4(0,%r26)
  61 L$0004  vshd            %r22,%r0,%r20
  62         bv              0(%r2)
  63         stw             %r20,-4(0,%r26)
  64
  65         .exit
  66         .procend