sysdeps/i386/fpu/e_pow.S

   1 /* ix87 specific implementation of pow function.
   2    Copyright (C) 1996, 1997, 1998, 1999, 2001, 2004, 2005
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <machine/asm.h>
  23
  24 #ifdef __ELF__
  25         .section .rodata
  26 #else
  27         .text
  28 #endif
  29
  30         .align ALIGNARG(4)
  31         ASM_TYPE_DIRECTIVE(infinity,@object)
  32 inf_zero:
  33 infinity:
  34         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0x7f
  35         ASM_SIZE_DIRECTIVE(infinity)
  36         ASM_TYPE_DIRECTIVE(zero,@object)
  37 zero:   .double 0.0
  38         ASM_SIZE_DIRECTIVE(zero)
  39         ASM_TYPE_DIRECTIVE(minf_mzero,@object)
  40 minf_mzero:
  41 minfinity:
  42         .byte 0, 0, 0, 0, 0, 0, 0xf0, 0xff
  43 mzero:
  44         .byte 0, 0, 0, 0, 0, 0, 0, 0x80
  45         ASM_SIZE_DIRECTIVE(minf_mzero)
  46         ASM_TYPE_DIRECTIVE(one,@object)
  47 one:    .double 1.0
  48         ASM_SIZE_DIRECTIVE(one)
  49         ASM_TYPE_DIRECTIVE(limit,@object)
  50 limit:  .double 0.29
  51         ASM_SIZE_DIRECTIVE(limit)
  52         ASM_TYPE_DIRECTIVE(p63,@object)
  53 p63:    .byte 0, 0, 0, 0, 0, 0, 0xe0, 0x43
  54         ASM_SIZE_DIRECTIVE(p63)
  55
  56 #ifdef PIC
  57 #define MO(op) op##@GOTOFF(%ecx)
  58 #define MOX(op,x,f) op##@GOTOFF(%ecx,x,f)
  59 #else
  60 #define MO(op) op
  61 #define MOX(op,x,f) op(,x,f)
  62 #endif
  63
  64         .text
  65 ENTRY(__ieee754_pow)
  66         fldl    12(%esp)        // y
  67         fxam
  68
  69 #ifdef  PIC
  70         LOAD_PIC_REG (cx)
  71 #endif
  72
  73         fnstsw
  74         movb    %ah, %dl
  75         andb    $0x45, %ah
  76         cmpb    $0x40, %ah      // is y == 0 ?
  77         je      11f
  78
  79         cmpb    $0x05, %ah      // is y == ±inf ?
  80         je      12f
  81
  82         cmpb    $0x01, %ah      // is y == NaN ?
  83         je      30f
  84
  85         fldl    4(%esp)         // x : y
  86
  87         subl    $8,%esp
  88         cfi_adjust_cfa_offset (8)
  89
  90         fxam
  91         fnstsw
  92         movb    %ah, %dh
  93         andb    $0x45, %ah
  94         cmpb    $0x40, %ah
  95         je      20f             // x is ±0
  96
  97         cmpb    $0x05, %ah
  98         je      15f             // x is ±inf
  99
 100         fxch                    // y : x
 101
 102         /* fistpll raises invalid exception for |y| >= 1L<<63.  */
 103         fld     %st             // y : y : x
 104         fabs                    // |y| : y : x
 105         fcompl  MO(p63)         // y : x
 106         fnstsw
 107         sahf
 108         jnc     2f
 109
 110         /* First see whether `y' is a natural number.  In this case we
 111            can use a more precise algorithm.  */
 112         fld     %st             // y : y : x
 113         fistpll (%esp)          // y : x
 114         fildll  (%esp)          // int(y) : y : x
 115         fucomp  %st(1)          // y : x
 116         fnstsw
 117         sahf
 118         jne     2f
 119
 120         /* OK, we have an integer value for y.  */
 121         popl    %eax
 122         cfi_adjust_cfa_offset (-4)
 123         popl    %edx
 124         cfi_adjust_cfa_offset (-4)
 125         orl     $0, %edx
 126         fstp    %st(0)          // x
 127         jns     4f              // y >= 0, jump
 128         fdivrl  MO(one)         // 1/x          (now referred to as x)
 129         negl    %eax
 130         adcl    $0, %edx
 131         negl    %edx
 132 4:      fldl    MO(one)         // 1 : x
 133         fxch
 134
 135 6:      shrdl   $1, %edx, %eax
 136         jnc     5f
 137         fxch
 138         fmul    %st(1)          // x : ST*x
 139         fxch
 140 5:      fmul    %st(0), %st     // x*x : ST*x
 141         shrl    $1, %edx
 142         movl    %eax, %ecx
 143         orl     %edx, %ecx
 144         jnz     6b
 145         fstp    %st(0)          // ST*x
 146         ret
 147
 148         /* y is ±NAN */
 149 30:     fldl    4(%esp)         // x : y
 150         fldl    MO(one)         // 1.0 : x : y
 151         fucomp  %st(1)          // x : y
 152         fnstsw
 153         sahf
 154         je      31f
 155         fxch                    // y : x
 156 31:     fstp    %st(1)
 157         ret
 158
 159         cfi_adjust_cfa_offset (8)
 160         .align ALIGNARG(4)
 161 2:      /* y is a real number.  */
 162         fxch                    // x : y
 163         fldl    MO(one)         // 1.0 : x : y
 164         fld     %st(1)          // x : 1.0 : x : y
 165         fsub    %st(1)          // x-1 : 1.0 : x : y
 166         fabs                    // |x-1| : 1.0 : x : y
 167         fcompl  MO(limit)       // 1.0 : x : y
 168         fnstsw
 169         fxch                    // x : 1.0 : y
 170         sahf
 171         ja      7f
 172         fsub    %st(1)          // x-1 : 1.0 : y
 173         fyl2xp1                 // log2(x) : y
 174         jmp     8f
 175
 176 7:      fyl2x                   // log2(x) : y
 177 8:      fmul    %st(1)          // y*log2(x) : y
 178         fst     %st(1)          // y*log2(x) : y*log2(x)
 179         frndint                 // int(y*log2(x)) : y*log2(x)
 180         fsubr   %st, %st(1)     // int(y*log2(x)) : fract(y*log2(x))
 181         fxch                    // fract(y*log2(x)) : int(y*log2(x))
 182         f2xm1                   // 2^fract(y*log2(x))-1 : int(y*log2(x))
 183         faddl   MO(one)         // 2^fract(y*log2(x)) : int(y*log2(x))
 184         fscale                  // 2^fract(y*log2(x))*2^int(y*log2(x)) : int(y*log2(x))
 185         addl    $8, %esp
 186         cfi_adjust_cfa_offset (-8)
 187         fstp    %st(1)          // 2^fract(y*log2(x))*2^int(y*log2(x))
 188         ret
 189
 190
 191         // pow(x,±0) = 1
 192         .align ALIGNARG(4)
 193 11:     fstp    %st(0)          // pop y
 194         fldl    MO(one)
 195         ret
 196
 197         // y == ±inf
 198         .align ALIGNARG(4)
 199 12:     fstp    %st(0)          // pop y
 200         fldl    4(%esp)         // x
 201         fabs
 202         fcompl  MO(one)         // < 1, == 1, or > 1
 203         fnstsw
 204         andb    $0x45, %ah
 205         cmpb    $0x45, %ah
 206         je      13f             // jump if x is NaN
 207
 208         cmpb    $0x40, %ah
 209         je      14f             // jump if |x| == 1
 210
 211         shlb    $1, %ah
 212         xorb    %ah, %dl
 213         andl    $2, %edx
 214         fldl    MOX(inf_zero, %edx, 4)
 215         ret
 216
 217         .align ALIGNARG(4)
 218 14:     fldl    MO(one)
 219         ret
 220
 221         .align ALIGNARG(4)
 222 13:     fldl    4(%esp)         // load x == NaN
 223         ret
 224
 225         cfi_adjust_cfa_offset (8)
 226         .align ALIGNARG(4)
 227         // x is ±inf
 228 15:     fstp    %st(0)          // y
 229         testb   $2, %dh
 230         jz      16f             // jump if x == +inf
 231
 232         // We must find out whether y is an odd integer.
 233         fld     %st             // y : y
 234         fistpll (%esp)          // y
 235         fildll  (%esp)          // int(y) : y
 236         fucompp                 // <empty>
 237         fnstsw
 238         sahf
 239         jne     17f
 240
 241         // OK, the value is an integer, but is the number of bits small
 242         // enough so that all are coming from the mantissa?
 243         popl    %eax
 244         cfi_adjust_cfa_offset (-4)
 245         popl    %edx
 246         cfi_adjust_cfa_offset (-4)
 247         andb    $1, %al
 248         jz      18f             // jump if not odd
 249         movl    %edx, %eax
 250         orl     %edx, %edx
 251         jns     155f
 252         negl    %eax
 253 155:    cmpl    $0x00200000, %eax
 254         ja      18f             // does not fit in mantissa bits
 255         // It's an odd integer.
 256         shrl    $31, %edx
 257         fldl    MOX(minf_mzero, %edx, 8)
 258         ret
 259
 260         cfi_adjust_cfa_offset (8)
 261         .align ALIGNARG(4)
 262 16:     fcompl  MO(zero)
 263         addl    $8, %esp
 264         cfi_adjust_cfa_offset (-8)
 265         fnstsw
 266         shrl    $5, %eax
 267         andl    $8, %eax
 268         fldl    MOX(inf_zero, %eax, 1)
 269         ret
 270
 271         cfi_adjust_cfa_offset (8)
 272         .align ALIGNARG(4)
 273 17:     shll    $30, %edx       // sign bit for y in right position
 274         addl    $8, %esp
 275         cfi_adjust_cfa_offset (-8)
 276 18:     shrl    $31, %edx
 277         fldl    MOX(inf_zero, %edx, 8)
 278         ret
 279
 280         cfi_adjust_cfa_offset (8)
 281         .align ALIGNARG(4)
 282         // x is ±0
 283 20:     fstp    %st(0)          // y
 284         testb   $2, %dl
 285         jz      21f             // y > 0
 286
 287         // x is ±0 and y is < 0.  We must find out whether y is an odd integer.
 288         testb   $2, %dh
 289         jz      25f
 290
 291         fld     %st             // y : y
 292         fistpll (%esp)          // y
 293         fildll  (%esp)          // int(y) : y
 294         fucompp                 // <empty>
 295         fnstsw
 296         sahf
 297         jne     26f
 298
 299         // OK, the value is an integer, but is the number of bits small
 300         // enough so that all are coming from the mantissa?
 301         popl    %eax
 302         cfi_adjust_cfa_offset (-4)
 303         popl    %edx
 304         cfi_adjust_cfa_offset (-4)
 305         andb    $1, %al
 306         jz      27f             // jump if not odd
 307         cmpl    $0xffe00000, %edx
 308         jbe     27f             // does not fit in mantissa bits
 309         // It's an odd integer.
 310         // Raise divide-by-zero exception and get minus infinity value.
 311         fldl    MO(one)
 312         fdivl   MO(zero)
 313         fchs
 314         ret
 315
 316         cfi_adjust_cfa_offset (8)
 317 25:     fstp    %st(0)
 318 26:     addl    $8, %esp
 319         cfi_adjust_cfa_offset (-8)
 320 27:     // Raise divide-by-zero exception and get infinity value.
 321         fldl    MO(one)
 322         fdivl   MO(zero)
 323         ret
 324
 325         cfi_adjust_cfa_offset (8)
 326         .align ALIGNARG(4)
 327         // x is ±0 and y is > 0.  We must find out whether y is an odd integer.
 328 21:     testb   $2, %dh
 329         jz      22f
 330
 331         fld     %st             // y : y
 332         fistpll (%esp)          // y
 333         fildll  (%esp)          // int(y) : y
 334         fucompp                 // <empty>
 335         fnstsw
 336         sahf
 337         jne     23f
 338
 339         // OK, the value is an integer, but is the number of bits small
 340         // enough so that all are coming from the mantissa?
 341         popl    %eax
 342         cfi_adjust_cfa_offset (-4)
 343         popl    %edx
 344         cfi_adjust_cfa_offset (-4)
 345         andb    $1, %al
 346         jz      24f             // jump if not odd
 347         cmpl    $0xffe00000, %edx
 348         jae     24f             // does not fit in mantissa bits
 349         // It's an odd integer.
 350         fldl    MO(mzero)
 351         ret
 352
 353         cfi_adjust_cfa_offset (8)
 354 22:     fstp    %st(0)
 355 23:     addl    $8, %esp        // Don't use 2 x pop
 356         cfi_adjust_cfa_offset (-8)
 357 24:     fldl    MO(zero)
 358         ret
 359
 360 END(__ieee754_pow)