| blob | 2eed49a2eed81413f4c25800e1e121bcbcc93bd6 |
1 /* Optimized version of the standard memcmp() function.
2 This file is part of the GNU C Library.
3 Copyright (C) 2000, 2001, 2004 Free Software Foundation, Inc.
4 Contributed by Dan Pop <Dan.Pop@cern.ch>.
6 The GNU C Library is free software; you can redistribute it and/or
7 modify it under the terms of the GNU Lesser General Public
8 License as published by the Free Software Foundation; either
9 version 2.1 of the License, or (at your option) any later version.
11 The GNU C Library is distributed in the hope that it will be useful,
12 but WITHOUT ANY WARRANTY; without even the implied warranty of
13 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
14 Lesser General Public License for more details.
16 You should have received a copy of the GNU Lesser General Public
17 License along with the GNU C Library; if not, write to the Free
18 Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
19 02111-1307 USA. */
21 /* Return: the result of the comparison
23 Inputs:
24 in0: dest (aka s1)
25 in1: src (aka s2)
26 in2: byte count
28 In this form, it assumes little endian mode. For big endian mode, the
29 the two shifts in .l2 must be inverted:
31 shl tmp1[0] = r[1 + MEMLAT], sh1 // tmp1 = w0 << sh1
32 shr.u tmp2[0] = r[0 + MEMLAT], sh2 // tmp2 = w1 >> sh2
34 and all the mux1 instructions should be replaced by plain mov's. */
36 #include <sysdep.h>
37 #undef ret
39 #define OP_T_THRES 16
40 #define OPSIZ 8
41 #define MEMLAT 2
43 #define start r15
44 #define saved_pr r17
45 #define saved_lc r18
46 #define dest r19
47 #define src r20
48 #define len r21
49 #define asrc r22
50 #define tmp r23
51 #define value1 r24
52 #define value2 r25
53 #define sh2 r28
54 #define sh1 r29
55 #define loopcnt r30
57 ENTRY(memcmp)
58 .prologue
59 alloc r2 = ar.pfs, 3, 37, 0, 40
61 .rotr r[MEMLAT + 2], q[MEMLAT + 5], tmp1[4], tmp2[4], val[2]
62 .rotp p[MEMLAT + 4 + 1]
64 mov ret0 = r0 // by default return value = 0
65 .save pr, saved_pr
66 mov saved_pr = pr // save the predicate registers
67 .save ar.lc, saved_lc
68 mov saved_lc = ar.lc // save the loop counter
69 .body
70 mov dest = in0 // dest
71 mov src = in1 // src
72 mov len = in2 // len
73 sub tmp = r0, in0 // tmp = -dest
74 ;;
75 and loopcnt = 7, tmp // loopcnt = -dest % 8
76 cmp.ge p6, p0 = OP_T_THRES, len // is len <= OP_T_THRES
77 (p6) br.cond.spnt .cmpfew // compare byte by byte
78 ;;
79 cmp.eq p6, p0 = loopcnt, r0
80 (p6) br.cond.sptk .dest_aligned
81 sub len = len, loopcnt // len -= -dest % 8
82 adds loopcnt = -1, loopcnt // --loopcnt
83 ;;
84 mov ar.lc = loopcnt
85 .l1: // copy -dest % 8 bytes
86 ld1 value1 = [src], 1 // value = *src++
87 ld1 value2 = [dest], 1
88 ;;
89 cmp.ne p6, p0 = value1, value2
90 (p6) br.cond.spnt .done
91 br.cloop.dptk .l1
92 .dest_aligned:
93 and sh1 = 7, src // sh1 = src % 8
94 and tmp = -8, len // tmp = len & -OPSIZ
95 and asrc = -8, src // asrc = src & -OPSIZ -- align src
96 shr.u loopcnt = len, 3 // loopcnt = len / 8
97 and len = 7, len ;; // len = len % 8
98 shl sh1 = sh1, 3 // sh1 = 8 * (src % 8)
99 adds loopcnt = -1, loopcnt // --loopcnt
100 mov pr.rot = 1 << 16 ;; // set rotating predicates
101 sub sh2 = 64, sh1 // sh2 = 64 - sh1
102 mov ar.lc = loopcnt // set LC
103 cmp.eq p6, p0 = sh1, r0 // is the src aligned?
104 (p6) br.cond.sptk .src_aligned
105 add src = src, tmp // src += len & -OPSIZ
106 mov ar.ec = MEMLAT + 4 + 1 // four more passes needed
107 ld8 r[1] = [asrc], 8 ;; // r[1] = w0
108 .align 32
110 // We enter this loop with p6 cleared by the above comparison
112 .l2:
113 (p[0]) ld8 r[0] = [asrc], 8 // r[0] = w1
114 (p[0]) ld8 q[0] = [dest], 8
115 (p[MEMLAT]) shr.u tmp1[0] = r[1 + MEMLAT], sh1 // tmp1 = w0 >> sh1
116 (p[MEMLAT]) shl tmp2[0] = r[0 + MEMLAT], sh2 // tmp2 = w1 << sh2
117 (p[MEMLAT+4]) cmp.ne p6, p0 = q[MEMLAT + 4], val[1]
118 (p[MEMLAT+3]) or val[0] = tmp1[3], tmp2[3] // val = tmp1 | tmp2
119 (p6) br.cond.spnt .l2exit
120 br.ctop.sptk .l2
121 br.cond.sptk .cmpfew
122 .l3exit:
123 mux1 value1 = r[MEMLAT], @rev
124 mux1 value2 = q[MEMLAT], @rev
125 cmp.ne p6, p0 = r0, r0 ;; // clear p6
126 .l2exit:
127 (p6) mux1 value1 = val[1], @rev
128 (p6) mux1 value2 = q[MEMLAT + 4], @rev ;;
129 cmp.ltu p6, p7 = value2, value1 ;;
130 (p6) mov ret0 = -1
131 (p7) mov ret0 = 1
132 mov pr = saved_pr, -1 // restore the predicate registers
133 mov ar.lc = saved_lc // restore the loop counter
134 br.ret.sptk.many b0
135 .src_aligned:
136 cmp.ne p6, p0 = r0, r0 // clear p6
137 mov ar.ec = MEMLAT + 1 ;; // set EC
138 .l3:
139 (p[0]) ld8 r[0] = [src], 8
140 (p[0]) ld8 q[0] = [dest], 8
141 (p[MEMLAT]) cmp.ne p6, p0 = r[MEMLAT], q[MEMLAT]
142 (p6) br.cond.spnt .l3exit
143 br.ctop.dptk .l3 ;;
144 .cmpfew:
145 cmp.eq p6, p0 = len, r0 // is len == 0 ?
146 adds len = -1, len // --len;
147 (p6) br.cond.spnt .restore_and_exit ;;
148 mov ar.lc = len
149 .l4:
150 ld1 value1 = [src], 1
151 ld1 value2 = [dest], 1
152 ;;
153 cmp.ne p6, p0 = value1, value2
154 (p6) br.cond.spnt .done
155 br.cloop.dptk .l4 ;;
156 .done:
157 (p6) sub ret0 = value2, value1 // don't execute it if falling thru
158 .restore_and_exit:
159 mov pr = saved_pr, -1 // restore the predicate registers
160 mov ar.lc = saved_lc // restore the loop counter
161 br.ret.sptk.many b0
162 END(memcmp)
164 weak_alias (memcmp, bcmp)
165 libc_hidden_builtin_def (memcmp)