sysdeps/unix/sh/sysdep.S

   1 /* Copyright (C) 1999, 2000, 2005 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H
  21 #include <bits/errno.h>
  22
  23 ENTRY(__syscall_error)
  24 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  25         /* We translate the system's EWOULDBLOCK error into EAGAIN.
  26            The GNU C library always defines EWOULDBLOCK==EAGAIN.
  27            EWOULDBLOCK_sys is the original number.  */
  28         mov.l   .L1, r1
  29         cmp/eq  r1, r0
  30         bf      skip
  31         nop
  32         mov.l   .L2, r0
  33 skip:
  34 #endif
  35         /* Store it in errno... */
  36 #ifndef SHARED
  37 #ifndef _LIBC_REENTRANT
  38         mov.l   .L3, r1
  39         mov.l   r0, @r1
  40 #else
  41         mov.l   .L3, r1
  42         sts.l   pr, @-r15
  43         cfi_adjust_cfa_offset (4)
  44         cfi_rel_offset (pr, 0)
  45         jsr     @r1
  46          mov.l  r0, @-r15
  47         cfi_adjust_cfa_offset (4)
  48         mov.l   @r15+, r1
  49         cfi_adjust_cfa_offset (-4)
  50         lds.l   @r15+, pr
  51         cfi_adjust_cfa_offset (-4)
  52         mov.l   r1, @r0
  53 #endif
  54 #else
  55         mov.l   r12, @-r15
  56         cfi_adjust_cfa_offset (4)
  57         cfi_rel_offset (r12, 0)
  58 #ifndef _LIBC_REENTRANT
  59         mov     r0, r2
  60         mov.l   0f, r12
  61         mova    0f, r0
  62         add     r0, r12
  63         mov.l   .L3, r0
  64         mov.l   @(r0,r12), r1
  65         mov.l   r2, @r1
  66 #else
  67         mov.l   r0, @-r15
  68         cfi_adjust_cfa_offset (4)
  69         sts.l   pr, @-r15
  70         cfi_adjust_cfa_offset (4)
  71         cfi_rel_offset (pr, 0)
  72         mov.l   0f, r12
  73         mova    0f, r0
  74         add     r0, r12
  75         mov.l   .L3, r1
  76         mova    .L3, r0
  77         add     r0, r1
  78         jsr     @r1
  79          nop
  80         lds.l   @r15+, pr
  81         mov.l   @r15+, r1
  82         mov.l   r1, @r0
  83 #endif
  84         mov.l   @r15+, r12
  85 #endif
  86         /* And just kick back a -1.  */
  87         rts
  88          mov    #-1, r0
  89
  90         .align  2
  91 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  92 .L1:    .long   EWOULDBLOCK_sys
  93 .L2:    .long   EAGAIN
  94 #endif
  95 #ifndef SHARED
  96 #ifndef _LIBC_REENTRANT
  97 .L3:    .long   C_SYMBOL_NAME(errno)
  98 #else
  99 .L3:    .long   C_SYMBOL_NAME(__errno_location)
 100 #endif
 101 #else
 102 0:
 103         .long   _GLOBAL_OFFSET_TABLE_
 104 #ifndef _LIBC_REENTRANT
 105 .L3:    .long   C_SYMBOL_NAME(errno@GOT)
 106 #else
 107 .L3:    .long   C_SYMBOL_NAME(__errno_location@PLT)
 108 #endif
 109 #endif
 110 END(__syscall_error)