configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 AC_ARG_ENABLE(static, dnl
  74 [  --enable-static         build static library [default=yes]],
  75               static=$enableval, static=yes)
  76 AC_ARG_ENABLE(shared, dnl
  77 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  78               shared=$enableval, shared=default)
  79 AC_ARG_ENABLE(profile, dnl
  80 [  --enable-profile        build profiled library [default=yes]],
  81               profile=$enableval, profile=yes)
  82 AC_ARG_ENABLE(omitfp, dnl
  83 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  84               omitfp=$enableval, omitfp=no)
  85 AC_ARG_ENABLE(bounded, dnl
  86 [  --enable-bounded        build with runtime bounds checking [default=no]],
  87               bounded=$enableval, bounded=no)
  88 AC_ARG_ENABLE(versioning, dnl
  89 [  --disable-versioning    do not include versioning information in the
  90                           library objects [default=yes if supported]],
  91              enable_versioning=$enableval, enable_versioning=yes)
  92
  93 dnl Generic infrastructure for drop-in additions to libc.
  94 AC_ARG_ENABLE(add-ons, dnl
  95 [  --enable-add-ons[=DIR1,DIR2]...
  96                           configure and build add-ons in DIR1,DIR2,...
  97                           search for add-ons if no parameter given],
  98   [case "$enableval" in
  99     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 100          test "$add_ons" = "*" && add_ons= ;;
 101     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 102    esac],
 103   [add_ons=])
 104
 105 AC_CONFIG_SUBDIRS($add_ons)
 106 add_ons_pfx=
 107 if test x"$add_ons" != x; then
 108   for f in $add_ons; do
 109     # Test whether such a subdir really exists.
 110     if test -d $srcdir/$f; then
 111       add_ons_pfx="$add_ons_pfx $f/"
 112     else
 113       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 114     fi
 115   done
 116 fi
 117
 118 dnl On some platforms we cannot use dynamic loading.  We must provide
 119 dnl static NSS modules.
 120 AC_ARG_ENABLE(static-nss, dnl
 121 [  --enable-static-nss     build static NSS modules [default=no]],
 122               static_nss=$enableval, static_nss=no)
 123 if test x"$static_nss" = xyes; then
 124   AC_DEFINE(DO_STATIC_NSS)
 125 fi
 126
 127 AC_ARG_ENABLE(force-install,
 128 [  --disable-force-install don't force installation of files from this package,
 129                           even if they are older than the installed files],
 130               force_install=$enableval, force_install=yes)
 131 AC_SUBST(force_install)
 132
 133 AC_CANONICAL_HOST
 134
 135 # The way shlib-versions is used to generate soversions.mk uses a
 136 # fairly simplistic model for name recognition that can't distinguish
 137 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 138 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 139 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 140 case "$host_os" in
 141 linux*)
 142   ;;
 143 gnu*)
 144   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 145   ;;
 146 esac
 147
 148 # We keep the original values in `$config_*' and never modify them, so we
 149 # can write them unchanged into config.make.  Everything else uses
 150 # $machine, $vendor, and $os, and changes them whenever convenient.
 151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 152
 153 # Some configurations imply other options.
 154 case "$host_os" in
 155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 156   # These systems always use GNU tools.
 157   gnu_ld=yes gnu_as=yes ;;
 158 esac
 159 case "$host_os" in
 160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 162   ;;
 163 gnu* | linux* | sysv4* | solaris2* | irix6*)
 164   # These systems (almost) always use the ELF format.
 165   elf=yes
 166   ;;
 167 esac
 168
 169 machine=$config_machine
 170 vendor=$config_vendor
 171 os=$config_os
 172
 173 ###
 174 ### I put this here to prevent those annoying emails from people who cannot
 175 ### read and try to compile glibc on unsupported platforms.  --drepper
 176 ###
 177 ### By using the undocumented --enable-hacker-mode option for configure
 178 ### one can skip this test to make the configuration not fail for unsupported
 179 ### platforms.
 180 ###
 181 if test -z "$enable_hacker_mode"; then
 182   case "$machine-$host_os" in
 183   *-linux* | *-gnu* | arm*-none*)
 184     ;;
 185   *)
 186     echo "*** The GNU C library is currently not available for this platform."
 187     echo "*** So far nobody cared to port it and if there is no volunteer it"
 188     echo "*** might never happen.  So, if you have interest to see glibc on"
 189     echo "*** this platform visit"
 190     echo "***   http://www.gnu.org/software/libc/porting.html"
 191     echo "*** and join the group of porters"
 192     exit 1
 193     ;;
 194   esac
 195 fi
 196
 197 dnl We need to use [ and ] for other purposes for a while now.
 198 changequote(,)dnl
 199 # Expand the configuration machine name into a subdirectory by architecture
 200 # type and particular chip.
 201 case "$machine" in
 202 a29k | am29000) base_machine=a29k machine=a29k ;;
 203 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 204 arm*)           base_machine=arm machine=arm/$machine ;;
 205 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 206 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 207 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 208 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 209 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 210 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 211 m88???)         base_machine=m88k machine=m88k/$machine ;;
 212 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 213 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 214 mips*)          base_machine=mips
 215                 case "`uname -m`" in
 216                 IP22) machine=mips/mips3 ;;
 217                 *)    machine=mips/$machine ,,
 218                 esac ;;
 219 sparc | sparcv[67])
 220                 base_machine=sparc machine=sparc/sparc32 ;;
 221 sparcv8 | supersparc | hypersparc)
 222                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 223 sparc64 | ultrasparc)
 224                 base_machine=sparc machine=sparc/sparc64 ;;
 225 esac
 226 changequote([,])dnl
 227 AC_SUBST(base_machine)
 228
 229 if test "$base_machine" = "i386"; then
 230   AC_DEFINE(USE_REGPARMS)
 231 fi
 232
 233 # Compute the list of sysdep directories for this configuration.
 234 # This can take a while to compute.
 235 sysdep_dir=$srcdir/sysdeps
 236 AC_MSG_CHECKING(sysdep dirs)
 237 dnl We need to use [ and ] for other purposes for a while now.
 238 changequote(,)dnl
 239 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 240 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 241
 242 case "$os" in
 243 gnu*)
 244   base_os=mach/hurd ;;
 245 netbsd* | 386bsd* | freebsd* | bsdi*)
 246   base_os=unix/bsd/bsd4.4 ;;
 247 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 248   base_os=unix/bsd ;;
 249 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 250   base_os=unix/sysv ;;
 251 irix6*)
 252   base_os=unix/sysv/irix6/$os ;;
 253 solaris[2-9]*)
 254   base_os=unix/sysv/sysv4 ;;
 255 none)
 256   base_os=standalone ;;
 257 *)
 258   base_os='' ;;
 259 esac
 260
 261 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 262 tail=$os
 263 ostry=$os
 264 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 265   ostry="$ostry /$o"
 266   tail=$o
 267 done
 268 o=`echo $tail | sed 's/[0-9]*$//'`
 269 if test $o != $tail; then
 270   ostry="$ostry /$o"
 271 fi
 272 # For linux-gnu, try linux-gnu, then linux.
 273 o=`echo $tail | sed 's/-.*$//'`
 274 if test $o != $tail; then
 275   ostry="$ostry /$o"
 276 fi
 277
 278 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 279 base=
 280 tail=$base_os
 281 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 282   set $b
 283   base="$base /$1"
 284   tail="$2"
 285 done
 286
 287 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 288 mach=
 289 tail=$machine
 290 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 291   set $m
 292   # Prepend the machine's FPU directory unless --without-fp.
 293   if test "$with_fp" = yes; then
 294     mach="$mach /$1/fpu"
 295   fi
 296   mach="$mach /$1"
 297   tail="$2"
 298 done
 299
 300 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 301 changequote([,])dnl
 302
 303 # Find what sysdep directories exist.
 304 sysnames=
 305 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 306 for d in $add_ons_pfx ''; do
 307   for b in $base ''; do
 308     for m0 in $mach ''; do
 309       for v in /$vendor ''; do
 310         test "$v" = / && continue
 311         for o in /$ostry ''; do
 312           test "$o" = / && continue
 313           for m in $mach ''; do
 314             if test "$m0$b$v$o$m"; then
 315               try="${d}sysdeps$m0$b$v$o$m"
 316               test -n "$enable_debug_configure" &&
 317               echo "$0 [DEBUG]: try $try" >&2
 318               if test -d $srcdir/$try; then
 319                 sysnames="$sysnames $try"
 320                 { test -n "$o" || test -n "$b"; } && os_used=t
 321                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 322               fi
 323             fi
 324           done
 325         done
 326       done
 327     done
 328   done
 329 done
 330 IFS="$ac_save_ifs"
 331
 332 if test -z "$os_used" && test "$os" != none; then
 333   AC_MSG_ERROR(Operating system $os is not supported.)
 334 fi
 335 if test -z "$machine_used" && test "$machine" != none; then
 336   AC_MSG_ERROR(The $machine is not supported.)
 337 fi
 338
 339 # We have now validated the configuration.
 340
 341
 342 # If using ELF, look for an `elf' subdirectory of each machine directory.
 343 # We prepend these rather than inserting them whereever the machine appears
 344 # because things specified by the machine's ELF ABI should override
 345 # OS-specific things, and should always be the same for any OS on the
 346 # machine (otherwise what's the point of an ABI?).
 347 if test "$elf" = yes; then
 348   elf_dirs=
 349   for d in $add_ons_pfx ''; do
 350     for m in $mach; do
 351       if test -d $srcdir/${d}sysdeps$m/elf; then
 352         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 353       fi
 354     done
 355   done
 356   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 357 fi
 358
 359
 360 # Expand the list of system names into a full list of directories
 361 # from each element's parent name and Implies file (if present).
 362 set $sysnames
 363 names=
 364 while test $# -gt 0; do
 365   name=$1
 366   shift
 367
 368   case " $names " in *" $name "*)
 369     # Already in the list.
 370     continue
 371   esac
 372
 373   # Report each name as we discover it, so there is no long pause in output.
 374   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 375
 376   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 377
 378   case $name in
 379     /*) xsrcdir= ;;
 380     *)  xsrcdir=$srcdir/ ;;
 381   esac
 382   test -n "$enable_debug_configure" &&
 383   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 384
 385   if test -f $xsrcdir$name/Implies; then
 386     # Collect more names from the `Implies' file (removing comments).
 387     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 388     implied=
 389     for x in $implied_candidate; do
 390       if test -d $xsrcdir$name_base/$x; then
 391         implied="$implied $name_base/$x";
 392       else
 393         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 394       fi
 395     done
 396   else
 397     implied=
 398   fi
 399
 400   # Add NAME to the list of names.
 401   names="$names $name"
 402
 403   # Find the parent of NAME, using the empty string if it has none.
 404 changequote(,)dnl
 405   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 406 changequote([,])dnl
 407
 408   # Add the names implied by NAME, and NAME's parent (if it has one), to
 409   # the list of names to be processed (the argument list).  We prepend the
 410   # implied names to the list and append the parent.  We want implied
 411   # directories to come before further directories inferred from the
 412   # configuration components; this ensures that for sysv4, unix/common
 413   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 414   # after sysv4).
 415   sysnames="`echo $implied $* $parent`"
 416   test -n "$sysnames" && set $sysnames
 417 done
 418
 419 # Add the default directories.
 420 default_sysnames=sysdeps/generic
 421 if test "$elf" = yes; then
 422   default_sysnames="sysdeps/generic/elf $default_sysnames"
 423 fi
 424 sysnames="$names $default_sysnames"
 425 AC_SUBST(sysnames)
 426 # The other names were emitted during the scan.
 427 AC_MSG_RESULT($default_sysnames)
 428
 429
 430 ### Locate tools.
 431
 432 AC_PROG_INSTALL
 433 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 434   # The makefiles need to use a different form to find it in $srcdir.
 435   INSTALL='\$(..)./install-sh -c'
 436 fi
 437 AC_PROG_LN_S
 438
 439 # These programs are version sensitive.
 440 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 441 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 442   [version \([egcygnustp-]*[0-9.]*\)],
 443   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|cygnus-2.9[1-9].*],
 444   critic_missing=t)
 445 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 446   [version \([0-9][0-9.]*\), by],
 447   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 448
 449 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 450   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 451   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 452 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 453   [GNU texinfo.* \([0-9][0-9.]*\)],
 454   [1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 455
 456 if test -n "$critic_missing"; then
 457 AC_MSG_ERROR([
 458 *** Some critical program is missing or too old.
 459 *** Check the INSTALL file for required versions.])
 460 fi
 461
 462 test -n "$aux_missing" && AC_MSG_WARN([
 463 *** An auxiliary program is missing or too old;
 464 *** some features will be disabled.
 465 *** Check the INSTALL file for required versions.])
 466
 467 AC_PROG_CC_LOCAL
 468 AC_CANONICAL_BUILD
 469 if test $host != $build; then
 470   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 471 fi
 472 AC_SUBST(cross_compiling)
 473 AC_PROG_CPP
 474 LIBC_PROG_BINUTILS
 475 AC_CHECK_TOOL(AR, ar)
 476 AC_CHECK_TOOL(RANLIB, ranlib, :)
 477 AC_CHECK_TOOL(MIG, mig)
 478
 479 # if using special system headers, find out the compiler's sekrit
 480 # header directory and add that to the list.  NOTE: Only does the right
 481 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 482 if test -n "$sysheaders"; then
 483   ccheaders=`$CC -print-file-name=include`
 484   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 485 fi
 486 AC_SUBST(SYSINCLUDES)
 487
 488 # check if ranlib is necessary
 489 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 490 cat > conftest.c <<EOF
 491 int a;
 492 char b;
 493 void c(void) {}
 494 EOF
 495 $CC $CFLAGS -c conftest.c
 496 $AR cr conftest.a conftest.c
 497 cp conftest.a conftest2.a
 498 $RANLIB conftest.a
 499 if cmp -s conftest.a conftest2.a; then
 500   libc_cv_ranlib_necessary=no
 501 else
 502   libc_cv_ranlib_necessary=yes
 503 fi
 504 rm -rf conftest*])
 505 if test "$libc_cv_ranlib_necessary" = no; then
 506  RANLIB=:
 507 fi
 508
 509 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 510 # since this would lead to problems installing/building glibc.
 511 # LD_LIBRARY_PATH contains the current directory if one of the following
 512 # is true:
 513 # - one of the terminals (":" and ";") is the first or last sign
 514 # - two terminals occur directly after each other
 515 # - the path contains an element with a dot in it
 516 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 517 changequote(,)dnl
 518 case ${LD_LIBRARY_PATH} in
 519   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 520     ld_library_path_setting="contains current directory"
 521     ;;
 522   *)
 523     ld_library_path_setting="ok"
 524     ;;
 525 esac
 526 changequote([,])dnl
 527 AC_MSG_RESULT($ld_library_path_setting)
 528 if test "$ld_library_path_setting" != "ok"; then
 529 AC_MSG_ERROR([
 530 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 531 *** building glibc. Please change the environment variable
 532 *** and run configure again.])
 533 fi
 534
 535 AC_PATH_PROG(BASH, bash, no)
 536 if test "$BASH" != no &&
 537    $BASH -c 'test "$BASH_VERSINFO" \
 538              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 539   libc_cv_have_bash2=yes
 540 else
 541   libc_cv_have_bash2=no
 542 fi
 543 AC_SUBST(libc_cv_have_bash2)
 544
 545 dnl We need a ksh compatible shell for tzselect.
 546 if test "$BASH" = no; then
 547   AC_PATH_PROG(KSH, ksh, no)
 548   if test "$KSH" = no; then
 549     libc_cv_have_ksh=no
 550   else
 551     libc_cv_have_ksh=yes
 552   fi
 553 else
 554   KSH="$BASH"
 555   AC_SUBST(KSH)
 556   libc_cv_have_ksh=yes
 557 fi
 558 AC_SUBST(libc_cv_have_ksh)
 559
 560 AC_PROG_AWK
 561 AC_PATH_PROG(PERL, perl, no)
 562 AC_SUBST(PERL)
 563 dnl This works around a bug in autoconf.
 564 install_info_path=/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin
 565 AC_PATH_PROG(INSTALL_INFO, install-info, no, $install_info_path)
 566 AC_SUBST(INSTALL_INFO)
 567 if test "$INSTALL_INFO" != "no"; then
 568 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 569  [mkdir conftest.d
 570   # There is a hard ^_ on the next line.  I am open to better ideas.
 571   (echo '\x1f'
 572   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 573   echo '* Menu:') >conftest.d/dir
 574   (echo 'INFO-DIR-SECTION i-d-s works'
 575   echo 'START-INFO-DIR-ENTRY'
 576   echo '* Prog: (prog).   Program.'
 577   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 578   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 579   then
 580     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 581     then libc_cv_old_debian_install_info=no
 582     else libc_cv_old_debian_install_info=yes
 583     fi
 584   else libc_cv_old_debian_install_info=no testfailed=t
 585   fi
 586   rm -fr conftest.d])
 587 if test -n "$testfailed"
 588 then AC_MSG_WARN([install-info errored out, check config.log])
 589 fi
 590 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 591 fi
 592 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 593
 594 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 595 echo '#include <stddef.h>
 596 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 597 if eval "$ac_cpp conftest.c 2>/dev/null" \
 598 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 599   libc_cv_signed_size_t=no
 600 else
 601   libc_cv_signed_size_t=yes
 602 fi
 603 rm -f conftest*])
 604 if test $libc_cv_signed_size_t = yes; then
 605   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 606   cat >> confdefs.h <<\EOF
 607 #undef __SIZE_TYPE__
 608 #define __SIZE_TYPE__ unsigned
 609 EOF
 610 fi
 611
 612 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 613 AC_TRY_COMPILE(dnl
 614 [#define __need_size_t
 615 #define __need_wchar_t
 616 #include <stddef.h>
 617 #define __need_NULL
 618 #include <stddef.h>], [size_t size; wchar_t wchar;
 619 #ifdef offsetof
 620 #error stddef.h ignored __need_*
 621 #endif
 622 if (&size == NULL || &wchar == NULL) abort ();],
 623                libc_cv_friendly_stddef=yes,
 624                libc_cv_friendly_stddef=no)])
 625 if test $libc_cv_friendly_stddef = yes; then
 626   config_vars="$config_vars
 627 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 628 fi
 629
 630 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 631                libc_cv_need_minus_P, [dnl
 632 cat > conftest.S <<EOF
 633 #include "confdefs.h"
 634 /* Nothing whatsoever.  */
 635 EOF
 636 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 637   libc_cv_need_minus_P=no
 638 else
 639   libc_cv_need_minus_P=yes
 640 fi
 641 rm -f conftest*])
 642 if test $libc_cv_need_minus_P = yes; then
 643   config_vars="$config_vars
 644 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 645 fi
 646
 647 AC_CACHE_CHECK(for assembler global-symbol directive,
 648                libc_cv_asm_global_directive, [dnl
 649 libc_cv_asm_global_directive=UNKNOWN
 650 for ac_globl in .globl .global; do
 651   cat > conftest.s <<EOF
 652 .text
 653 ${ac_globl} foo
 654 foo:
 655 EOF
 656   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 657     libc_cv_asm_global_directive=${ac_globl}
 658   fi
 659   rm -f conftest*
 660   test $libc_cv_asm_global_directive != UNKNOWN && break
 661 done])
 662 if test $libc_cv_asm_global_directive = UNKNOWN; then
 663   AC_MSG_ERROR(cannot determine asm global directive)
 664 else
 665   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 666 fi
 667
 668 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 669 cat > conftest.s <<EOF
 670 .text
 671 foo:
 672 .set glibc_conftest_frobozz,foo
 673 $libc_cv_asm_global_directive glibc_conftest_frobozz
 674 EOF
 675 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 676 # (but it doesn't work), so we must do a linking check to be sure.
 677 cat > conftest1.c <<\EOF
 678 extern int glibc_conftest_frobozz;
 679 main () { printf ("%d\n", glibc_conftest_frobozz); }
 680 EOF
 681 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 682             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 683   libc_cv_asm_set_directive=yes
 684 else
 685   libc_cv_asm_set_directive=no
 686 fi
 687 rm -f conftest*])
 688 if test $libc_cv_asm_set_directive = yes; then
 689   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 690 fi
 691
 692 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 693 [cat > conftest.s <<EOF
 694 .text
 695 _sym:
 696 .symver _sym,sym@VERS
 697 EOF
 698 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 699   libc_cv_asm_symver_directive=yes
 700 else
 701   libc_cv_asm_symver_directive=no
 702 fi
 703 rm -f conftest*])
 704 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 705 if test $libc_cv_asm_symver_directive = yes; then
 706   cat > conftest.s <<EOF
 707 .text
 708 _sym:
 709 .symver _sym,sym@VERS
 710 EOF
 711   cat > conftest.map <<EOF
 712 VERS_1 {
 713         global: sym;
 714 };
 715
 716 VERS_2 {
 717         global: sym;
 718 } VERS_1;
 719 EOF
 720   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 721     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 722                                         -nostartfiles -nostdlib
 723                                         -Wl,--version-script,conftest.map
 724                        1>&AC_FD_CC]);
 725     then
 726       libc_cv_ld_version_script_option=yes
 727     else
 728       libc_cv_ld_version_script_option=no
 729     fi
 730   else
 731     libc_cv_ld_version_script_option=no
 732   fi
 733 else
 734   libc_cv_ld_version_script_option=no
 735 fi
 736 rm -f conftest*])
 737 if test $libc_cv_asm_symver_directive = yes &&
 738    test $libc_cv_ld_version_script_option = yes &&
 739    test $enable_versioning = yes; then
 740   VERSIONING=yes
 741   AC_DEFINE(DO_VERSIONING)
 742 else
 743   VERSIONING=no
 744 fi
 745 AC_SUBST(VERSIONING)
 746
 747 if test $VERSIONING = no; then
 748   echo "\
 749 *** WARNING: You should not compile GNU libc without versioning. Not using
 750 *** versioning will introduce incompatibilities so that old binaries
 751 *** will not run anymore.
 752 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 753 fi
 754 if test $elf = yes; then
 755   AC_CACHE_CHECK(for .previous assembler directive,
 756                  libc_cv_asm_previous_directive, [dnl
 757   cat > conftest.s <<EOF
 758 .section foo_section
 759 .previous
 760 EOF
 761   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 762     libc_cv_asm_previous_directive=yes
 763   else
 764     libc_cv_asm_previous_directive=no
 765   fi
 766   rm -f conftest*])
 767   if test $libc_cv_asm_previous_directive = yes; then
 768     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 769   else
 770     AC_CACHE_CHECK(for .popsection assembler directive,
 771                    libc_cv_asm_popsection_directive, [dnl
 772     cat > conftest.s <<EOF
 773 .pushsection foo_section
 774 .popsection
 775 EOF
 776     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 777       libc_cv_asm_popsection_directive=yes
 778     else
 779       libc_cv_asm_popsection_directive=no
 780     fi
 781     rm -f conftest*])
 782     if test $libc_cv_asm_popsection_directive = yes; then
 783       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 784     fi
 785   fi
 786 fi
 787
 788 if test $elf != yes; then
 789   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 790                  [AC_TRY_COMPILE(, [asm (".section .init");
 791                                     asm (".section .fini");
 792                                     asm (".text");],
 793                                  libc_cv_have_initfini=yes,
 794                                  libc_cv_have_initfini=no)])
 795   AC_SUBST(libc_cv_have_initfini)dnl
 796   if test $libc_cv_have_initfini = yes; then
 797     AC_DEFINE(HAVE_INITFINI)
 798   fi
 799 fi
 800
 801 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 802 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 803 [cat > conftest.$ac_ext <<EOF
 804 dnl This sometimes fails to find confdefs.h, for some reason.
 805 dnl [#]line __oline__ "[$]0"
 806 [#]line __oline__ "configure"
 807 #include "confdefs.h"
 808 void underscore_test(void) {
 809 return; }
 810 EOF
 811 if AC_TRY_EVAL(ac_compile); then
 812   if grep _underscore_test conftest* >/dev/null; then
 813     ifelse([$1], , :, [rm -f conftest*
 814     $1])
 815   else
 816     ifelse([$2], , , [rm -f conftest*
 817     $2])
 818   fi
 819 else
 820   echo "configure: failed program was:" >&AC_FD_CC
 821   cat conftest.$ac_ext >&AC_FD_CC
 822   ifelse([$2], , , [rm -f conftest*
 823   $2])
 824 fi
 825 rm -f conftest*])
 826
 827 if test $elf = yes; then
 828   libc_cv_asm_underscores=no
 829 else
 830   if test $ac_cv_prog_cc_works = yes; then
 831     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 832                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 833                                 libc_cv_asm_underscores=yes,
 834                                 libc_cv_asm_underscores=no)])
 835   else
 836     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 837                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 838                                             libc_cv_asm_underscores=no)])
 839   fi
 840 fi
 841 if test $libc_cv_asm_underscores = no; then
 842   AC_DEFINE(NO_UNDERSCORES)
 843 fi
 844
 845 if test $elf = yes; then
 846   libc_cv_weak_symbols=yes
 847 fi
 848
 849 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 850                  [dnl
 851 cat > conftest.s <<EOF
 852 .text
 853 ${libc_cv_asm_global_directive} foo
 854 foo:
 855 .weak foo
 856 .weak bar; bar = foo
 857 EOF
 858 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 859   libc_cv_asm_weak_directive=yes
 860 else
 861   libc_cv_asm_weak_directive=no
 862 fi
 863 rm -f conftest*])
 864
 865 if test $libc_cv_asm_weak_directive = no; then
 866   AC_CACHE_CHECK(for assembler .weakext directive,
 867                  libc_cv_asm_weakext_directive,
 868                  [dnl
 869 cat > conftest.s <<EOF
 870 .text
 871 ${libc_cv_asm_global_directive} foo
 872 foo:
 873 .weakext bar foo
 874 .weakext baz
 875 ${libc_cv_asm_global_directive} baz
 876 baz:
 877 EOF
 878   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 879     libc_cv_asm_weakext_directive=yes
 880   else
 881     libc_cv_asm_weakext_directive=no
 882   fi
 883   rm -f conftest*])
 884
 885 fi # no .weak
 886
 887 if test $libc_cv_asm_weak_directive = yes; then
 888   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 889 elif test $libc_cv_asm_weakext_directive = yes; then
 890   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 891 fi
 892
 893 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 894 cat > conftest.c <<\EOF
 895 _start () {}
 896 int __eh_pc;
 897 __throw () {}
 898 EOF
 899 dnl No \ in command here because it ends up inside ''.
 900 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 901                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 902                             -o conftest conftest.c 1>&AC_FD_CC]); then
 903   libc_cv_ld_no_whole_archive=yes
 904 else
 905   libc_cv_ld_no_whole_archive=no
 906 fi
 907 rm -f conftest*])
 908 if test $libc_cv_ld_no_whole_archive = yes; then
 909   no_whole_archive=-Wl,--no-whole-archive
 910 fi
 911 AC_SUBST(no_whole_archive)dnl
 912
 913 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 914 cat > conftest.c <<\EOF
 915 _start () {}
 916 int __eh_pc;
 917 __throw () {}
 918 EOF
 919 dnl No \ in command here because it ends up inside ''.
 920 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 921                             -nostdlib -nostartfiles -fexceptions
 922                             -o conftest conftest.c 1>&AC_FD_CC]); then
 923   libc_cv_gcc_exceptions=yes
 924 else
 925   libc_cv_gcc_exceptions=no
 926 fi
 927 rm -f conftest*])
 928 if test $libc_cv_gcc_exceptions = yes; then
 929   exceptions=-fexceptions
 930 fi
 931 AC_SUBST(exceptions)dnl
 932
 933 if test "$base_machine" = alpha ; then
 934 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 935 cat > conftest.c <<\EOF
 936 foo () { }
 937 EOF
 938 dnl
 939 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 940 then
 941   libc_cv_gcc_alpha_ng_prefix=yes
 942 else
 943   libc_cv_gcc_alpha_ng_prefix=no
 944 fi
 945 rm -f conftest* ])
 946 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 947   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 948 else
 949   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 950 fi
 951 fi
 952
 953 if test "$host_cpu" = powerpc ; then
 954 # Check for a bug present in at least versions 2.8.x of GCC
 955 # and versions 1.0.x of EGCS.
 956 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 957 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 958                libc_cv_c_asmcr0_bug='no',
 959                libc_cv_c_asmcr0_bug='yes')])
 960 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 961   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 962 fi
 963 fi
 964
 965 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 966 [cat > conftest.c <<EOF
 967 #line __oline__ "configure"
 968 static char __EH_FRAME_BEGIN__[];
 969 _start ()
 970 {
 971 #ifdef CHECK__register_frame
 972   __register_frame (__EH_FRAME_BEGIN__);
 973   __deregister_frame (__EH_FRAME_BEGIN__);
 974 #endif
 975 #ifdef CHECK__register_frame_info
 976   __register_frame_info (__EH_FRAME_BEGIN__);
 977   __deregister_frame_info (__EH_FRAME_BEGIN__);
 978 #endif
 979 }
 980 int __eh_pc;
 981 __throw () {}
 982 /* FIXME: this is fragile.  */
 983 malloc () {}
 984 strcmp () {}
 985 strlen () {}
 986 memcpy () {}
 987 memset () {}
 988 free () {}
 989 abort () {}
 990 __bzero () {}
 991 EOF
 992 dnl No \ in command here because it ends up inside ''.
 993 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 994                             -nostdlib -nostartfiles
 995                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 996   libc_cv_gcc_dwarf2_unwind_info=static
 997 else
 998   libc_cv_gcc_dwarf2_unwind_info=no
 999 fi
1000 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1001   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1002                               -nostdlib -nostartfiles
1003                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1004     libc_cv_gcc_dwarf2_unwind_info=yes
1005   else
1006     libc_cv_gcc_dwarf2_unwind_info=no
1007   fi
1008 fi
1009 rm -f conftest*])
1010 case $libc_cv_gcc_dwarf2_unwind_info in
1011 yes)
1012   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1013   ;;
1014 static)
1015   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1016   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1017   ;;
1018 esac
1019
1020 dnl Check whether compiler understands __builtin_expect.
1021 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1022 [cat > conftest.c <<EOF
1023 #line __oline__ "configure"
1024 int foo (int a)
1025 {
1026   a = __builtin_expect (a, 10);
1027   return a == 10 ? 0 : 1;
1028 }
1029 EOF
1030 dnl No \ in command here because it ends up inside ''.
1031 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1032                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1033   libc_cv_gcc_builtin_expect=yes
1034 else
1035   libc_cv_gcc_builtin_expect=no
1036 fi
1037 rm -f conftest*])
1038 if test "$libc_cv_gcc_builtin_expect" = yes; then
1039   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1040 fi
1041
1042 ### End of automated tests.
1043 ### Now run sysdeps configure fragments.
1044
1045 # sysdeps configure fragments may set these with files to be linked below.
1046 libc_link_dests=
1047 libc_link_sources=
1048
1049 # They also can set these variables.
1050 ldd_rewrite_script=no
1051
1052 # Iterate over all the sysdep directories we will use, running their
1053 # configure fragments, and looking for a uname implementation.
1054 uname=
1055 for dir in $sysnames; do
1056   case $dir in
1057     /*) dest=$dir ;;
1058     *)  dest=$srcdir/$dir ;;
1059   esac
1060   if test -r $dest/configure; then
1061     AC_MSG_RESULT(running configure fragment for $dest)
1062     . $dest/configure
1063   fi
1064 [
1065   if test -z "$uname"; then
1066     if test -r $dest/uname.c ||
1067        test -r $dest/uname.S ||
1068        { test -r $dest/syscalls.list &&
1069          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1070       uname=$dir
1071     fi
1072   fi
1073 ]dnl
1074 done
1075
1076 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1077
1078 # If we will use the generic uname implementation, we must figure out what
1079 # it will say by examining the system, and write the results in config-name.h.
1080 if test "$uname" = "sysdeps/generic"; then
1081
1082 changequote(,)dnl
1083   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1084 changequote([,])dnl
1085   if test $uname_sysname != $config_os; then
1086     config_release=`echo $config_os | sed s/$uname_sysname//`
1087   fi
1088 dnl
1089 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1090     if test -r /vmunix; then
1091       kernel_id=`strings /vmunix | grep UNIX`
1092     elif test -r /dynix; then
1093       kernel_id=`strings /dynix | grep DYNIX`
1094     else
1095       kernel_id=
1096     fi
1097 ])dnl
1098
1099   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1100 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1101 changequote(,)dnl
1102   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1103 changequote([,])dnl
1104   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1105          != x$config_release; then
1106     # The configuration release is a substring of the kernel release.
1107     libc_cv_uname_release=$kernel_release
1108   elif test x$config_release != x; then
1109     libc_cv_uname_release=$config_release
1110   elif test x$kernel_release != x; then
1111     libc_cv_uname_release=$kernel_release
1112   else
1113     libc_cv_uname_release=unknown
1114   fi])
1115   uname_release="$libc_cv_uname_release"
1116
1117   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1118 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1119 changequote(,)dnl
1120   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1121 changequote([,])dnl
1122   if test -n "$kernel_version"; then
1123     libc_cv_uname_version="$kernel_version"
1124   else
1125     libc_cv_uname_version=unknown
1126   fi])
1127   uname_version="$libc_cv_uname_version"
1128
1129 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1130   config_uname=config-name.h:config-name.in
1131 else
1132   # For non-generic uname, we don't need to create config-name.h at all.
1133   config_uname=
1134 fi
1135
1136 AC_MSG_CHECKING(stdio selection)
1137 AC_SUBST(stdio)
1138 case $stdio in
1139 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1140 default) stdio=stdio ;;
1141 esac
1142 AC_MSG_RESULT($stdio)
1143
1144 # Test for old glibc 2.0.x headers so that they can be removed properly
1145 # Search only in includedir.
1146 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1147 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1148 then
1149   old_glibc_headers=yes
1150 else
1151   old_glibc_headers=no
1152 fi
1153 AC_MSG_RESULT($old_glibc_headers)
1154 if test ${old_glibc_headers} = yes; then
1155   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1156   AC_MSG_WARN(*** be removed.)
1157 fi
1158 AC_SUBST(old_glibc_headers)
1159
1160 AC_SUBST(libc_cv_slibdir)
1161 AC_SUBST(libc_cv_sysconfdir)
1162 AC_SUBST(libc_cv_rootsbindir)
1163
1164 AC_SUBST(has_ldconfig)
1165 AC_SUBST(ldd_rewrite_script)
1166
1167 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1168 if test $gnu_ld = yes; then
1169   AC_DEFINE(HAVE_GNU_LD)
1170 fi
1171 if test $gnu_as = yes; then
1172   AC_DEFINE(HAVE_GNU_AS)
1173 fi
1174 if test $elf = yes; then
1175   AC_DEFINE(HAVE_ELF)
1176 fi
1177
1178 AC_SUBST(static)
1179 AC_SUBST(shared)
1180 if test $shared = default; then
1181   if test $gnu_ld = yes; then
1182     shared=$elf
1183   else
1184     # For now we do not assume shared libs are available.  In future more
1185     # tests might become available.
1186     shared=no
1187   fi
1188 fi
1189
1190 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1191 [pic_default=yes
1192 cat > conftest.c <<EOF
1193 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1194 # error PIC is default.
1195 #endif
1196 EOF
1197 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1198   pic_default=no
1199 fi
1200 rm -f conftest.*])
1201 AC_SUBST(pic_default)
1202
1203 AC_SUBST(profile)
1204 AC_SUBST(omitfp)
1205 AC_SUBST(bounded)
1206 AC_SUBST(static_nss)
1207 AC_SUBST(nopic_initfini)
1208
1209 AC_SUBST(DEFINES)
1210
1211 case "$add_ons" in
1212   *door*) linux_doors=yes ;;
1213   *) linux_doors=no ;;
1214 esac
1215 AC_SUBST(linux_doors)
1216
1217 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1218   config_makefile=
1219 else
1220   config_makefile=Makefile
1221 fi
1222
1223 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1224 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1225 AC_SUBST(VERSION)
1226 AC_SUBST(RELEASE)
1227
1228 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1229 case $CONFIG_FILES in *config.make*)
1230 echo "$config_vars" >> config.make;;
1231 esac
1232 test -d bits || mkdir bits], [config_vars='$config_vars'])