configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 dnl I've disabled this for now since we cannot build glibc without static
  74 dnl libraries built in the moment.
  75 dnl AC_ARG_ENABLE(static, dnl
  76 dnl [  --enable-static         build static library [default=yes]],
  77 dnl           static=$enableval, static=yes)
  78 static=yes
  79 AC_ARG_ENABLE(shared, dnl
  80 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  81               shared=$enableval, shared=default)
  82 AC_ARG_ENABLE(profile, dnl
  83 [  --enable-profile        build profiled library [default=yes]],
  84               profile=$enableval, profile=yes)
  85 AC_ARG_ENABLE(omitfp, dnl
  86 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  87               omitfp=$enableval, omitfp=no)
  88 AC_ARG_ENABLE(bounded, dnl
  89 [  --enable-bounded        build with runtime bounds checking [default=no]],
  90               bounded=$enableval, bounded=no)
  91 AC_ARG_ENABLE(versioning, dnl
  92 [  --disable-versioning    do not include versioning information in the
  93                           library objects [default=yes if supported]],
  94              enable_versioning=$enableval, enable_versioning=yes)
  95
  96 dnl Generic infrastructure for drop-in additions to libc.
  97 AC_ARG_ENABLE(add-ons, dnl
  98 [  --enable-add-ons[=DIR1,DIR2]...
  99                           configure and build add-ons in DIR1,DIR2,...
 100                           search for add-ons if no parameter given],
 101   [case "$enableval" in
 102     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 103          test "$add_ons" = "*" && add_ons= ;;
 104     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 105    esac],
 106   [add_ons=])
 107
 108 AC_CONFIG_SUBDIRS($add_ons)
 109 add_ons_pfx=
 110 if test x"$add_ons" != x; then
 111   for f in $add_ons; do
 112     # Test whether such a subdir really exists.
 113     if test -d $srcdir/$f; then
 114       add_ons_pfx="$add_ons_pfx $f/"
 115     else
 116       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 117     fi
 118   done
 119 fi
 120
 121 dnl On some platforms we cannot use dynamic loading.  We must provide
 122 dnl static NSS modules.
 123 AC_ARG_ENABLE(static-nss, dnl
 124 [  --enable-static-nss     build static NSS modules [default=no]],
 125               static_nss=$enableval, static_nss=no)
 126 if test x"$static_nss" = xyes; then
 127   AC_DEFINE(DO_STATIC_NSS)
 128 fi
 129
 130 AC_ARG_ENABLE(force-install,
 131 [  --disable-force-install don't force installation of files from this package,
 132                           even if they are older than the installed files],
 133               force_install=$enableval, force_install=yes)
 134 AC_SUBST(force_install)
 135
 136 AC_CANONICAL_HOST
 137
 138 # The way shlib-versions is used to generate soversions.mk uses a
 139 # fairly simplistic model for name recognition that can't distinguish
 140 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 141 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 142 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 143 case "$host_os" in
 144 linux*)
 145   ;;
 146 gnu*)
 147   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 148   ;;
 149 esac
 150
 151 # We keep the original values in `$config_*' and never modify them, so we
 152 # can write them unchanged into config.make.  Everything else uses
 153 # $machine, $vendor, and $os, and changes them whenever convenient.
 154 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 155
 156 # Some configurations imply other options.
 157 case "$host_os" in
 158 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 159   # These systems always use GNU tools.
 160   gnu_ld=yes gnu_as=yes ;;
 161 esac
 162 case "$host_os" in
 163 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 164 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 165   ;;
 166 gnu* | linux* | sysv4* | solaris2* | irix6*)
 167   # These systems (almost) always use the ELF format.
 168   elf=yes
 169   ;;
 170 esac
 171
 172 machine=$config_machine
 173 vendor=$config_vendor
 174 os=$config_os
 175
 176 ###
 177 ### I put this here to prevent those annoying emails from people who cannot
 178 ### read and try to compile glibc on unsupported platforms.  --drepper
 179 ###
 180 ### By using the undocumented --enable-hacker-mode option for configure
 181 ### one can skip this test to make the configuration not fail for unsupported
 182 ### platforms.
 183 ###
 184 if test -z "$enable_hacker_mode"; then
 185   case "$machine-$host_os" in
 186   *-linux* | *-gnu* | arm*-none*)
 187     ;;
 188   *)
 189     echo "*** The GNU C library is currently not available for this platform."
 190     echo "*** So far nobody cared to port it and if there is no volunteer it"
 191     echo "*** might never happen.  So, if you have interest to see glibc on"
 192     echo "*** this platform visit"
 193     echo "***   http://www.gnu.org/software/libc/porting.html"
 194     echo "*** and join the group of porters"
 195     exit 1
 196     ;;
 197   esac
 198 fi
 199
 200 dnl We need to use [ and ] for other purposes for a while now.
 201 changequote(,)dnl
 202 # Expand the configuration machine name into a subdirectory by architecture
 203 # type and particular chip.
 204 case "$machine" in
 205 a29k | am29000) base_machine=a29k machine=a29k ;;
 206 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 207 arm*)           base_machine=arm machine=arm/$machine ;;
 208 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 209 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 210 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 211 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 212 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 213 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 214 m88???)         base_machine=m88k machine=m88k/$machine ;;
 215 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 216 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 217 mips*)          base_machine=mips
 218                 case "`uname -m`" in
 219                 IP22) machine=mips/mips3 ;;
 220                 *)    machine=mips/$machine ;;
 221                 esac ;;
 222 sparc | sparcv[67])
 223                 base_machine=sparc machine=sparc/sparc32 ;;
 224 sparcv8 | supersparc | hypersparc)
 225                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 226 sparc64 | ultrasparc)
 227                 base_machine=sparc machine=sparc/sparc64 ;;
 228 esac
 229 changequote([,])dnl
 230 AC_SUBST(base_machine)
 231
 232 if test "$base_machine" = "i386"; then
 233   AC_DEFINE(USE_REGPARMS)
 234 fi
 235
 236 # Compute the list of sysdep directories for this configuration.
 237 # This can take a while to compute.
 238 sysdep_dir=$srcdir/sysdeps
 239 AC_MSG_CHECKING(sysdep dirs)
 240 dnl We need to use [ and ] for other purposes for a while now.
 241 changequote(,)dnl
 242 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 243 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 244
 245 case "$os" in
 246 gnu*)
 247   base_os=mach/hurd ;;
 248 netbsd* | 386bsd* | freebsd* | bsdi*)
 249   base_os=unix/bsd/bsd4.4 ;;
 250 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 251   base_os=unix/bsd ;;
 252 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 253   base_os=unix/sysv ;;
 254 irix6*)
 255   base_os=unix/sysv/irix6/$os ;;
 256 solaris[2-9]*)
 257   base_os=unix/sysv/sysv4 ;;
 258 none)
 259   base_os=standalone ;;
 260 *)
 261   base_os='' ;;
 262 esac
 263
 264 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 265 tail=$os
 266 ostry=$os
 267 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 268   ostry="$ostry /$o"
 269   tail=$o
 270 done
 271 o=`echo $tail | sed 's/[0-9]*$//'`
 272 if test $o != $tail; then
 273   ostry="$ostry /$o"
 274 fi
 275 # For linux-gnu, try linux-gnu, then linux.
 276 o=`echo $tail | sed 's/-.*$//'`
 277 if test $o != $tail; then
 278   ostry="$ostry /$o"
 279 fi
 280
 281 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 282 base=
 283 tail=$base_os
 284 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 285   set $b
 286   base="$base /$1"
 287   tail="$2"
 288 done
 289
 290 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 291 mach=
 292 tail=$machine
 293 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 294   set $m
 295   # Prepend the machine's FPU directory unless --without-fp.
 296   if test "$with_fp" = yes; then
 297     mach="$mach /$1/fpu"
 298   fi
 299   mach="$mach /$1"
 300   tail="$2"
 301 done
 302
 303 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 304 changequote([,])dnl
 305
 306 # Find what sysdep directories exist.
 307 sysnames=
 308 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 309 for d in $add_ons_pfx ''; do
 310   for b in $base ''; do
 311     for m0 in $mach ''; do
 312       for v in /$vendor ''; do
 313         test "$v" = / && continue
 314         for o in /$ostry ''; do
 315           test "$o" = / && continue
 316           for m in $mach ''; do
 317             if test "$m0$b$v$o$m"; then
 318               try="${d}sysdeps$m0$b$v$o$m"
 319               test -n "$enable_debug_configure" &&
 320               echo "$0 [DEBUG]: try $try" >&2
 321               if test -d $srcdir/$try; then
 322                 sysnames="$sysnames $try"
 323                 { test -n "$o" || test -n "$b"; } && os_used=t
 324                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 325               fi
 326             fi
 327           done
 328         done
 329       done
 330     done
 331   done
 332 done
 333 IFS="$ac_save_ifs"
 334
 335 if test -z "$os_used" && test "$os" != none; then
 336   AC_MSG_ERROR(Operating system $os is not supported.)
 337 fi
 338 if test -z "$machine_used" && test "$machine" != none; then
 339   AC_MSG_ERROR(The $machine is not supported.)
 340 fi
 341
 342 # We have now validated the configuration.
 343
 344
 345 # If using ELF, look for an `elf' subdirectory of each machine directory.
 346 # We prepend these rather than inserting them whereever the machine appears
 347 # because things specified by the machine's ELF ABI should override
 348 # OS-specific things, and should always be the same for any OS on the
 349 # machine (otherwise what's the point of an ABI?).
 350 if test "$elf" = yes; then
 351   elf_dirs=
 352   for d in $add_ons_pfx ''; do
 353     for m in $mach; do
 354       if test -d $srcdir/${d}sysdeps$m/elf; then
 355         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 356       fi
 357     done
 358   done
 359   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 360 fi
 361
 362
 363 # Expand the list of system names into a full list of directories
 364 # from each element's parent name and Implies file (if present).
 365 set $sysnames
 366 names=
 367 while test $# -gt 0; do
 368   name=$1
 369   shift
 370
 371   case " $names " in *" $name "*)
 372     # Already in the list.
 373     continue
 374   esac
 375
 376   # Report each name as we discover it, so there is no long pause in output.
 377   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 378
 379   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 380
 381   case $name in
 382     /*) xsrcdir= ;;
 383     *)  xsrcdir=$srcdir/ ;;
 384   esac
 385   test -n "$enable_debug_configure" &&
 386   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 387
 388   if test -f $xsrcdir$name/Implies; then
 389     # Collect more names from the `Implies' file (removing comments).
 390     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 391     implied=
 392     for x in $implied_candidate; do
 393       if test -d $xsrcdir$name_base/$x; then
 394         implied="$implied $name_base/$x";
 395       else
 396         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 397       fi
 398     done
 399   else
 400     implied=
 401   fi
 402
 403   # Add NAME to the list of names.
 404   names="$names $name"
 405
 406   # Find the parent of NAME, using the empty string if it has none.
 407 changequote(,)dnl
 408   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 409 changequote([,])dnl
 410
 411   # Add the names implied by NAME, and NAME's parent (if it has one), to
 412   # the list of names to be processed (the argument list).  We prepend the
 413   # implied names to the list and append the parent.  We want implied
 414   # directories to come before further directories inferred from the
 415   # configuration components; this ensures that for sysv4, unix/common
 416   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 417   # after sysv4).
 418   sysnames="`echo $implied $* $parent`"
 419   test -n "$sysnames" && set $sysnames
 420 done
 421
 422 # Add the default directories.
 423 default_sysnames=sysdeps/generic
 424 if test "$elf" = yes; then
 425   default_sysnames="sysdeps/generic/elf $default_sysnames"
 426 fi
 427 sysnames="$names $default_sysnames"
 428 AC_SUBST(sysnames)
 429 # The other names were emitted during the scan.
 430 AC_MSG_RESULT($default_sysnames)
 431
 432
 433 ### Locate tools.
 434
 435 AC_PROG_INSTALL
 436 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 437   # The makefiles need to use a different form to find it in $srcdir.
 438   INSTALL='\$(..)./install-sh -c'
 439 fi
 440 AC_PROG_LN_S
 441
 442 # These programs are version sensitive.
 443 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 444 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 445   [version \([egcygnustp-]*[0-9.]*\)],
 446   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|cygnus-2.9[1-9].*],
 447   critic_missing=t)
 448 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 449   [version \([0-9][0-9.]*\), by],
 450   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 451
 452 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 453   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 454   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 455 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 456   [GNU texinfo.* \([0-9][0-9.]*\)],
 457   [3.1[1-9] | 3.[2-9][0-9] | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 458
 459 if test -n "$critic_missing"; then
 460 AC_MSG_ERROR([
 461 *** Some critical program is missing or too old.
 462 *** Check the INSTALL file for required versions.])
 463 fi
 464
 465 test -n "$aux_missing" && AC_MSG_WARN([
 466 *** An auxiliary program is missing or too old;
 467 *** some features will be disabled.
 468 *** Check the INSTALL file for required versions.])
 469
 470 AC_PROG_CC_LOCAL
 471 AC_CANONICAL_BUILD
 472 if test $host != $build; then
 473   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 474 fi
 475 AC_SUBST(cross_compiling)
 476 AC_PROG_CPP
 477 LIBC_PROG_BINUTILS
 478 AC_CHECK_TOOL(MIG, mig)
 479
 480 # if using special system headers, find out the compiler's sekrit
 481 # header directory and add that to the list.  NOTE: Only does the right
 482 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 483 if test -n "$sysheaders"; then
 484   ccheaders=`$CC -print-file-name=include`
 485   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 486 fi
 487 AC_SUBST(SYSINCLUDES)
 488
 489 # check if ranlib is necessary
 490 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 491 cat > conftest.c <<EOF
 492 int a;
 493 char b;
 494 void c(void) {}
 495 EOF
 496 $CC $CFLAGS -c conftest.c
 497 $AR cr conftest.a conftest.c
 498 cp conftest.a conftest2.a
 499 $RANLIB conftest.a
 500 if cmp -s conftest.a conftest2.a; then
 501   libc_cv_ranlib_necessary=no
 502 else
 503   libc_cv_ranlib_necessary=yes
 504 fi
 505 rm -rf conftest*])
 506 if test "$libc_cv_ranlib_necessary" = no; then
 507  RANLIB=:
 508 fi
 509
 510 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 511 # since this would lead to problems installing/building glibc.
 512 # LD_LIBRARY_PATH contains the current directory if one of the following
 513 # is true:
 514 # - one of the terminals (":" and ";") is the first or last sign
 515 # - two terminals occur directly after each other
 516 # - the path contains an element with a dot in it
 517 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 518 changequote(,)dnl
 519 case ${LD_LIBRARY_PATH} in
 520   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 521     ld_library_path_setting="contains current directory"
 522     ;;
 523   *)
 524     ld_library_path_setting="ok"
 525     ;;
 526 esac
 527 changequote([,])dnl
 528 AC_MSG_RESULT($ld_library_path_setting)
 529 if test "$ld_library_path_setting" != "ok"; then
 530 AC_MSG_ERROR([
 531 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 532 *** building glibc. Please change the environment variable
 533 *** and run configure again.])
 534 fi
 535
 536 AC_PATH_PROG(BASH, bash, no)
 537 if test "$BASH" != no &&
 538    $BASH -c 'test "$BASH_VERSINFO" \
 539              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 540   libc_cv_have_bash2=yes
 541 else
 542   libc_cv_have_bash2=no
 543 fi
 544 AC_SUBST(libc_cv_have_bash2)
 545
 546 dnl We need a ksh compatible shell for tzselect.
 547 if test "$BASH" = no; then
 548   AC_PATH_PROG(KSH, ksh, no)
 549   if test "$KSH" = no; then
 550     libc_cv_have_ksh=no
 551   else
 552     libc_cv_have_ksh=yes
 553   fi
 554 else
 555   KSH="$BASH"
 556   AC_SUBST(KSH)
 557   libc_cv_have_ksh=yes
 558 fi
 559 AC_SUBST(libc_cv_have_ksh)
 560
 561 AC_PROG_AWK
 562 AC_PATH_PROG(PERL, perl, no)
 563 AC_SUBST(PERL)
 564 dnl This works around a bug in autoconf.
 565 install_info_path=/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin
 566 AC_PATH_PROG(INSTALL_INFO, install-info, no, $install_info_path)
 567 AC_SUBST(INSTALL_INFO)
 568 if test "$INSTALL_INFO" != "no"; then
 569 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 570  [mkdir conftest.d
 571   # There is a hard ^_ on the next line.  I am open to better ideas.
 572   (echo '\x1f'
 573   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 574   echo '* Menu:') >conftest.d/dir
 575   (echo 'INFO-DIR-SECTION i-d-s works'
 576   echo 'START-INFO-DIR-ENTRY'
 577   echo '* Prog: (prog).   Program.'
 578   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 579   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 580   then
 581     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 582     then libc_cv_old_debian_install_info=no
 583     else libc_cv_old_debian_install_info=yes
 584     fi
 585   else libc_cv_old_debian_install_info=no testfailed=t
 586   fi
 587   rm -fr conftest.d])
 588 if test -n "$testfailed"
 589 then AC_MSG_WARN([install-info errored out, check config.log])
 590 fi
 591 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 592 fi
 593 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 594
 595 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 596 echo '#include <stddef.h>
 597 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 598 if eval "$ac_cpp conftest.c 2>/dev/null" \
 599 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 600   libc_cv_signed_size_t=no
 601 else
 602   libc_cv_signed_size_t=yes
 603 fi
 604 rm -f conftest*])
 605 if test $libc_cv_signed_size_t = yes; then
 606   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 607   cat >> confdefs.h <<\EOF
 608 #undef __SIZE_TYPE__
 609 #define __SIZE_TYPE__ unsigned
 610 EOF
 611 fi
 612
 613 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 614 AC_TRY_COMPILE(dnl
 615 [#define __need_size_t
 616 #define __need_wchar_t
 617 #include <stddef.h>
 618 #define __need_NULL
 619 #include <stddef.h>], [size_t size; wchar_t wchar;
 620 #ifdef offsetof
 621 #error stddef.h ignored __need_*
 622 #endif
 623 if (&size == NULL || &wchar == NULL) abort ();],
 624                libc_cv_friendly_stddef=yes,
 625                libc_cv_friendly_stddef=no)])
 626 if test $libc_cv_friendly_stddef = yes; then
 627   config_vars="$config_vars
 628 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 629 fi
 630
 631 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 632                libc_cv_need_minus_P, [dnl
 633 cat > conftest.S <<EOF
 634 #include "confdefs.h"
 635 /* Nothing whatsoever.  */
 636 EOF
 637 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 638   libc_cv_need_minus_P=no
 639 else
 640   libc_cv_need_minus_P=yes
 641 fi
 642 rm -f conftest*])
 643 if test $libc_cv_need_minus_P = yes; then
 644   config_vars="$config_vars
 645 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 646 fi
 647
 648 AC_CACHE_CHECK(for assembler global-symbol directive,
 649                libc_cv_asm_global_directive, [dnl
 650 libc_cv_asm_global_directive=UNKNOWN
 651 for ac_globl in .globl .global; do
 652   cat > conftest.s <<EOF
 653 .text
 654 ${ac_globl} foo
 655 foo:
 656 EOF
 657   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 658     libc_cv_asm_global_directive=${ac_globl}
 659   fi
 660   rm -f conftest*
 661   test $libc_cv_asm_global_directive != UNKNOWN && break
 662 done])
 663 if test $libc_cv_asm_global_directive = UNKNOWN; then
 664   AC_MSG_ERROR(cannot determine asm global directive)
 665 else
 666   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 667 fi
 668
 669 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 670 cat > conftest.s <<EOF
 671 .text
 672 foo:
 673 .set glibc_conftest_frobozz,foo
 674 $libc_cv_asm_global_directive glibc_conftest_frobozz
 675 EOF
 676 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 677 # (but it doesn't work), so we must do a linking check to be sure.
 678 cat > conftest1.c <<\EOF
 679 extern int glibc_conftest_frobozz;
 680 main () { printf ("%d\n", glibc_conftest_frobozz); }
 681 EOF
 682 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 683             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 684   libc_cv_asm_set_directive=yes
 685 else
 686   libc_cv_asm_set_directive=no
 687 fi
 688 rm -f conftest*])
 689 if test $libc_cv_asm_set_directive = yes; then
 690   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 691 fi
 692
 693 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 694 [cat > conftest.s <<EOF
 695 .text
 696 _sym:
 697 .symver _sym,sym@VERS
 698 EOF
 699 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 700   libc_cv_asm_symver_directive=yes
 701 else
 702   libc_cv_asm_symver_directive=no
 703 fi
 704 rm -f conftest*])
 705 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 706 if test $libc_cv_asm_symver_directive = yes; then
 707   cat > conftest.s <<EOF
 708 .text
 709 _sym:
 710 .symver _sym,sym@VERS
 711 EOF
 712   cat > conftest.map <<EOF
 713 VERS_1 {
 714         global: sym;
 715 };
 716
 717 VERS_2 {
 718         global: sym;
 719 } VERS_1;
 720 EOF
 721   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 722     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 723                                         -nostartfiles -nostdlib
 724                                         -Wl,--version-script,conftest.map
 725                        1>&AC_FD_CC]);
 726     then
 727       libc_cv_ld_version_script_option=yes
 728     else
 729       libc_cv_ld_version_script_option=no
 730     fi
 731   else
 732     libc_cv_ld_version_script_option=no
 733   fi
 734 else
 735   libc_cv_ld_version_script_option=no
 736 fi
 737 rm -f conftest*])
 738 if test $libc_cv_asm_symver_directive = yes &&
 739    test $libc_cv_ld_version_script_option = yes &&
 740    test $enable_versioning = yes; then
 741   VERSIONING=yes
 742   AC_DEFINE(DO_VERSIONING)
 743 else
 744   VERSIONING=no
 745 fi
 746 AC_SUBST(VERSIONING)
 747
 748 if test $VERSIONING = no; then
 749   echo "\
 750 *** WARNING: You should not compile GNU libc without versioning. Not using
 751 *** versioning will introduce incompatibilities so that old binaries
 752 *** will not run anymore.
 753 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 754 fi
 755 if test $elf = yes; then
 756   AC_CACHE_CHECK(for .previous assembler directive,
 757                  libc_cv_asm_previous_directive, [dnl
 758   cat > conftest.s <<EOF
 759 .section foo_section
 760 .previous
 761 EOF
 762   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 763     libc_cv_asm_previous_directive=yes
 764   else
 765     libc_cv_asm_previous_directive=no
 766   fi
 767   rm -f conftest*])
 768   if test $libc_cv_asm_previous_directive = yes; then
 769     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 770   else
 771     AC_CACHE_CHECK(for .popsection assembler directive,
 772                    libc_cv_asm_popsection_directive, [dnl
 773     cat > conftest.s <<EOF
 774 .pushsection foo_section
 775 .popsection
 776 EOF
 777     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 778       libc_cv_asm_popsection_directive=yes
 779     else
 780       libc_cv_asm_popsection_directive=no
 781     fi
 782     rm -f conftest*])
 783     if test $libc_cv_asm_popsection_directive = yes; then
 784       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 785     fi
 786   fi
 787 fi
 788
 789 if test $elf != yes; then
 790   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 791                  [AC_TRY_COMPILE(, [asm (".section .init");
 792                                     asm (".section .fini");
 793                                     asm (".text");],
 794                                  libc_cv_have_initfini=yes,
 795                                  libc_cv_have_initfini=no)])
 796   AC_SUBST(libc_cv_have_initfini)dnl
 797   if test $libc_cv_have_initfini = yes; then
 798     AC_DEFINE(HAVE_INITFINI)
 799   fi
 800 fi
 801
 802 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 803 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 804 [cat > conftest.$ac_ext <<EOF
 805 dnl This sometimes fails to find confdefs.h, for some reason.
 806 dnl [#]line __oline__ "[$]0"
 807 [#]line __oline__ "configure"
 808 #include "confdefs.h"
 809 void underscore_test(void) {
 810 return; }
 811 EOF
 812 if AC_TRY_EVAL(ac_compile); then
 813   if grep _underscore_test conftest* >/dev/null; then
 814     ifelse([$1], , :, [rm -f conftest*
 815     $1])
 816   else
 817     ifelse([$2], , , [rm -f conftest*
 818     $2])
 819   fi
 820 else
 821   echo "configure: failed program was:" >&AC_FD_CC
 822   cat conftest.$ac_ext >&AC_FD_CC
 823   ifelse([$2], , , [rm -f conftest*
 824   $2])
 825 fi
 826 rm -f conftest*])
 827
 828 if test $elf = yes; then
 829   libc_cv_asm_underscores=no
 830 else
 831   if test $ac_cv_prog_cc_works = yes; then
 832     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 833                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 834                                 libc_cv_asm_underscores=yes,
 835                                 libc_cv_asm_underscores=no)])
 836   else
 837     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 838                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 839                                             libc_cv_asm_underscores=no)])
 840   fi
 841 fi
 842 if test $libc_cv_asm_underscores = no; then
 843   AC_DEFINE(NO_UNDERSCORES)
 844 fi
 845
 846 if test $elf = yes; then
 847   libc_cv_weak_symbols=yes
 848 fi
 849
 850 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 851                  [dnl
 852 cat > conftest.s <<EOF
 853 .text
 854 ${libc_cv_asm_global_directive} foo
 855 foo:
 856 .weak foo
 857 .weak bar; bar = foo
 858 EOF
 859 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 860   libc_cv_asm_weak_directive=yes
 861 else
 862   libc_cv_asm_weak_directive=no
 863 fi
 864 rm -f conftest*])
 865
 866 if test $libc_cv_asm_weak_directive = no; then
 867   AC_CACHE_CHECK(for assembler .weakext directive,
 868                  libc_cv_asm_weakext_directive,
 869                  [dnl
 870 cat > conftest.s <<EOF
 871 .text
 872 ${libc_cv_asm_global_directive} foo
 873 foo:
 874 .weakext bar foo
 875 .weakext baz
 876 ${libc_cv_asm_global_directive} baz
 877 baz:
 878 EOF
 879   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 880     libc_cv_asm_weakext_directive=yes
 881   else
 882     libc_cv_asm_weakext_directive=no
 883   fi
 884   rm -f conftest*])
 885
 886 fi # no .weak
 887
 888 if test $libc_cv_asm_weak_directive = yes; then
 889   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 890 elif test $libc_cv_asm_weakext_directive = yes; then
 891   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 892 fi
 893
 894 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 895 cat > conftest.c <<\EOF
 896 _start () {}
 897 int __eh_pc;
 898 __throw () {}
 899 EOF
 900 dnl No \ in command here because it ends up inside ''.
 901 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 902                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 903                             -o conftest conftest.c 1>&AC_FD_CC]); then
 904   libc_cv_ld_no_whole_archive=yes
 905 else
 906   libc_cv_ld_no_whole_archive=no
 907 fi
 908 rm -f conftest*])
 909 if test $libc_cv_ld_no_whole_archive = yes; then
 910   no_whole_archive=-Wl,--no-whole-archive
 911 fi
 912 AC_SUBST(no_whole_archive)dnl
 913
 914 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 915 cat > conftest.c <<\EOF
 916 _start () {}
 917 int __eh_pc;
 918 __throw () {}
 919 EOF
 920 dnl No \ in command here because it ends up inside ''.
 921 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 922                             -nostdlib -nostartfiles -fexceptions
 923                             -o conftest conftest.c 1>&AC_FD_CC]); then
 924   libc_cv_gcc_exceptions=yes
 925 else
 926   libc_cv_gcc_exceptions=no
 927 fi
 928 rm -f conftest*])
 929 if test $libc_cv_gcc_exceptions = yes; then
 930   exceptions=-fexceptions
 931 fi
 932 AC_SUBST(exceptions)dnl
 933
 934 if test "$base_machine" = alpha ; then
 935 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 936 cat > conftest.c <<\EOF
 937 foo () { }
 938 EOF
 939 dnl
 940 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 941 then
 942   libc_cv_gcc_alpha_ng_prefix=yes
 943 else
 944   libc_cv_gcc_alpha_ng_prefix=no
 945 fi
 946 rm -f conftest* ])
 947 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 948   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 949 else
 950   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 951 fi
 952 fi
 953
 954 if test "$host_cpu" = powerpc ; then
 955 # Check for a bug present in at least versions 2.8.x of GCC
 956 # and versions 1.0.x of EGCS.
 957 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 958 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 959                libc_cv_c_asmcr0_bug='no',
 960                libc_cv_c_asmcr0_bug='yes')])
 961 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 962   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 963 fi
 964 fi
 965
 966 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 967 [cat > conftest.c <<EOF
 968 #line __oline__ "configure"
 969 static char __EH_FRAME_BEGIN__[];
 970 _start ()
 971 {
 972 #ifdef CHECK__register_frame
 973   __register_frame (__EH_FRAME_BEGIN__);
 974   __deregister_frame (__EH_FRAME_BEGIN__);
 975 #endif
 976 #ifdef CHECK__register_frame_info
 977   __register_frame_info (__EH_FRAME_BEGIN__);
 978   __deregister_frame_info (__EH_FRAME_BEGIN__);
 979 #endif
 980 }
 981 int __eh_pc;
 982 __throw () {}
 983 /* FIXME: this is fragile.  */
 984 malloc () {}
 985 strcmp () {}
 986 strlen () {}
 987 memcpy () {}
 988 memset () {}
 989 free () {}
 990 abort () {}
 991 __bzero () {}
 992 EOF
 993 dnl No \ in command here because it ends up inside ''.
 994 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 995                             -nostdlib -nostartfiles
 996                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 997   libc_cv_gcc_dwarf2_unwind_info=static
 998 else
 999   libc_cv_gcc_dwarf2_unwind_info=no
1000 fi
1001 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1002   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1003                               -nostdlib -nostartfiles
1004                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1005     libc_cv_gcc_dwarf2_unwind_info=yes
1006   else
1007     libc_cv_gcc_dwarf2_unwind_info=no
1008   fi
1009 fi
1010 rm -f conftest*])
1011 case $libc_cv_gcc_dwarf2_unwind_info in
1012 yes)
1013   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1014   ;;
1015 static)
1016   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1017   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1018   ;;
1019 esac
1020
1021 dnl Check whether compiler understands __builtin_expect.
1022 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1023 [cat > conftest.c <<EOF
1024 #line __oline__ "configure"
1025 int foo (int a)
1026 {
1027   a = __builtin_expect (a, 10);
1028   return a == 10 ? 0 : 1;
1029 }
1030 EOF
1031 dnl No \ in command here because it ends up inside ''.
1032 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1033                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1034   libc_cv_gcc_builtin_expect=yes
1035 else
1036   libc_cv_gcc_builtin_expect=no
1037 fi
1038 rm -f conftest*])
1039 if test "$libc_cv_gcc_builtin_expect" = yes; then
1040   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1041 fi
1042
1043 ### End of automated tests.
1044 ### Now run sysdeps configure fragments.
1045
1046 # sysdeps configure fragments may set these with files to be linked below.
1047 libc_link_dests=
1048 libc_link_sources=
1049
1050 # They also can set these variables.
1051 ldd_rewrite_script=no
1052
1053 # Iterate over all the sysdep directories we will use, running their
1054 # configure fragments, and looking for a uname implementation.
1055 uname=
1056 for dir in $sysnames; do
1057   case $dir in
1058     /*) dest=$dir ;;
1059     *)  dest=$srcdir/$dir ;;
1060   esac
1061   if test -r $dest/configure; then
1062     AC_MSG_RESULT(running configure fragment for $dest)
1063     . $dest/configure
1064   fi
1065 [
1066   if test -z "$uname"; then
1067     if test -r $dest/uname.c ||
1068        test -r $dest/uname.S ||
1069        { test -r $dest/syscalls.list &&
1070          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1071       uname=$dir
1072     fi
1073   fi
1074 ]dnl
1075 done
1076
1077 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1078
1079 # If we will use the generic uname implementation, we must figure out what
1080 # it will say by examining the system, and write the results in config-name.h.
1081 if test "$uname" = "sysdeps/generic"; then
1082
1083 changequote(,)dnl
1084   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1085 changequote([,])dnl
1086   if test $uname_sysname != $config_os; then
1087     config_release=`echo $config_os | sed s/$uname_sysname//`
1088   fi
1089 dnl
1090 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1091     if test -r /vmunix; then
1092       kernel_id=`strings /vmunix | grep UNIX`
1093     elif test -r /dynix; then
1094       kernel_id=`strings /dynix | grep DYNIX`
1095     else
1096       kernel_id=
1097     fi
1098 ])dnl
1099
1100   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1101 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1102 changequote(,)dnl
1103   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1104 changequote([,])dnl
1105   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1106          != x$config_release; then
1107     # The configuration release is a substring of the kernel release.
1108     libc_cv_uname_release=$kernel_release
1109   elif test x$config_release != x; then
1110     libc_cv_uname_release=$config_release
1111   elif test x$kernel_release != x; then
1112     libc_cv_uname_release=$kernel_release
1113   else
1114     libc_cv_uname_release=unknown
1115   fi])
1116   uname_release="$libc_cv_uname_release"
1117
1118   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1119 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1120 changequote(,)dnl
1121   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1122 changequote([,])dnl
1123   if test -n "$kernel_version"; then
1124     libc_cv_uname_version="$kernel_version"
1125   else
1126     libc_cv_uname_version=unknown
1127   fi])
1128   uname_version="$libc_cv_uname_version"
1129
1130 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1131   config_uname=config-name.h:config-name.in
1132 else
1133   # For non-generic uname, we don't need to create config-name.h at all.
1134   config_uname=
1135 fi
1136
1137 AC_MSG_CHECKING(stdio selection)
1138 AC_SUBST(stdio)
1139 case $stdio in
1140 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1141 default) stdio=stdio ;;
1142 esac
1143 AC_MSG_RESULT($stdio)
1144
1145 # Test for old glibc 2.0.x headers so that they can be removed properly
1146 # Search only in includedir.
1147 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1148 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1149 then
1150   old_glibc_headers=yes
1151 else
1152   old_glibc_headers=no
1153 fi
1154 AC_MSG_RESULT($old_glibc_headers)
1155 if test ${old_glibc_headers} = yes; then
1156   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1157   AC_MSG_WARN(*** be removed.)
1158 fi
1159 AC_SUBST(old_glibc_headers)
1160
1161 AC_SUBST(libc_cv_slibdir)
1162 AC_SUBST(libc_cv_sysconfdir)
1163 AC_SUBST(libc_cv_rootsbindir)
1164
1165 AC_SUBST(has_ldconfig)
1166 AC_SUBST(ldd_rewrite_script)
1167
1168 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1169 if test $gnu_ld = yes; then
1170   AC_DEFINE(HAVE_GNU_LD)
1171 fi
1172 if test $gnu_as = yes; then
1173   AC_DEFINE(HAVE_GNU_AS)
1174 fi
1175 if test $elf = yes; then
1176   AC_DEFINE(HAVE_ELF)
1177 fi
1178
1179 AC_SUBST(static)
1180 AC_SUBST(shared)
1181 if test $shared = default; then
1182   if test $gnu_ld = yes; then
1183     shared=$elf
1184   else
1185     # For now we do not assume shared libs are available.  In future more
1186     # tests might become available.
1187     shared=no
1188   fi
1189 fi
1190
1191 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1192 [pic_default=yes
1193 cat > conftest.c <<EOF
1194 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1195 # error PIC is default.
1196 #endif
1197 EOF
1198 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1199   pic_default=no
1200 fi
1201 rm -f conftest.*])
1202 AC_SUBST(pic_default)
1203
1204 AC_SUBST(profile)
1205 AC_SUBST(omitfp)
1206 AC_SUBST(bounded)
1207 AC_SUBST(static_nss)
1208 AC_SUBST(nopic_initfini)
1209
1210 AC_SUBST(DEFINES)
1211
1212 case "$add_ons" in
1213   *door*) linux_doors=yes ;;
1214   *) linux_doors=no ;;
1215 esac
1216 AC_SUBST(linux_doors)
1217
1218 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1219   config_makefile=
1220 else
1221   config_makefile=Makefile
1222 fi
1223
1224 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1225 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1226 AC_SUBST(VERSION)
1227 AC_SUBST(RELEASE)
1228
1229 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1230 case $CONFIG_FILES in *config.make*)
1231 echo "$config_vars" >> config.make;;
1232 esac
1233 test -d bits || mkdir bits], [config_vars='$config_vars'])