configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware [default=yes],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66               shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69               profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  72               omitfp=$enableval, omitfp=no)
  73
  74 dnl Generic infrastructure for drop-in additions to libc.
  75 AC_ARG_ENABLE(add-ons, dnl
  76 [  --enable-add-ons=DIR... configure and build named extra directories],
  77               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  78               [add_ons=])
  79 AC_CONFIG_SUBDIRS($add_ons)
  80 add_ons_pfx=
  81 if test x"$add_ons" != x; then
  82   for f in $add_ons; do
  83     add_ons_pfx="$add_ons_pfx $f/"
  84   done
  85 fi
  86
  87 AC_CANONICAL_HOST
  88 # We keep the original values in `$config_*' and never modify them, so we
  89 # can write them unchanged into config.make.  Everything else uses
  90 # $machine, $vendor, and $os, and changes them whenever convenient.
  91 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  92
  93 # Some configurations imply other options.
  94 case "$host_os" in
  95 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  96   # These systems always use GNU tools.
  97   gnu_ld=yes gnu_as=yes ;;
  98 esac
  99 case "$host_os" in
 100 linux*ecoff*)
 101   ;;
 102 gnu* | linux* | sysv4* | solaris2*)
 103   # These systems (almost) always use the ELF format.
 104   elf=yes
 105   ;;
 106 esac
 107
 108 machine=$config_machine
 109 vendor=$config_vendor
 110 os=$config_os
 111
 112 dnl We need to use [ and ] for other purposes for a while now.
 113 changequote(,)dnl
 114 # Expand the configuration machine name into a subdirectory by architecture
 115 # type and particular chip.
 116 case "$machine" in
 117 a29k | am29000) base_machine=a29k machine=a29k ;;
 118 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 119 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 120 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 121 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 122 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 123 m88???)         base_machine=m88k machine=m88k/$machine ;;
 124 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 125 mips*)          base_machine=mips machine=mips/$machine ;;
 126 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 127 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 128 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 129 esac
 130 changequote([,])dnl
 131 AC_SUBST(base_machine)
 132
 133 # Compute the list of sysdep directories for this configuration.
 134 # This can take a while to compute.
 135 sysdep_dir=$srcdir/sysdeps
 136 AC_MSG_CHECKING(sysdep dirs)
 137 dnl We need to use [ and ] for other purposes for a while now.
 138 changequote(,)dnl
 139 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 140 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 141
 142 case "$os" in
 143 gnu*)
 144   base_os=mach/hurd ;;
 145 netbsd* | 386bsd* | freebsd* | bsdi*)
 146   base_os=unix/bsd/bsd4.4 ;;
 147 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 148   base_os=unix/bsd ;;
 149 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 150   base_os=unix/sysv ;;
 151 solaris[2-9]*)
 152   base_os=unix/sysv/sysv4 ;;
 153 none)
 154   base_os=standalone ;;
 155 *)
 156   base_os='' ;;
 157 esac
 158
 159 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 160 tail=$os
 161 ostry=$os
 162 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 163   ostry="$ostry /$o"
 164   tail=$o
 165 done
 166 o=`echo $tail | sed 's/[0-9]*$//'`
 167 if test $o != $tail; then
 168   ostry="$ostry /$o"
 169 fi
 170
 171 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 172 base=
 173 tail=$base_os
 174 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 175   set $b
 176   base="$base /$1"
 177   tail="$2"
 178 done
 179
 180 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 181 mach=
 182 tail=$machine
 183 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 184   set $m
 185   # Prepend the machine's FPU directory unless --without-fp.
 186   if test "$with_fp" = yes; then
 187     mach="$mach /$1/fpu"
 188   fi
 189   mach="$mach /$1"
 190   tail="$2"
 191 done
 192
 193 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 194 changequote([,])dnl
 195
 196 # Find what sysdep directories exist.
 197 sysnames=
 198 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 199 for d in $add_ons_pfx ''; do
 200   for b in $base ''; do
 201     for m0 in $mach ''; do
 202       for v in /$vendor ''; do
 203         for o in /$ostry ''; do
 204           for m in $mach ''; do
 205             if test "$m0$b$v$o$m"; then
 206               try="${d}sysdeps$m0$b$v$o$m"
 207               test -n "$enable_debug_configure" &&
 208               echo "$0 [DEBUG]: try $try" >&2
 209               case $try in
 210                 /*) dest=$try ;;
 211                 *)  dest=$srcdir/$try ;;
 212               esac
 213               if test -d $dest; then
 214                 sysnames="$sysnames $try"
 215                 { test -n "$o" || test -n "$b"; } && os_used=t
 216                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 217               fi
 218             fi
 219           done
 220         done
 221       done
 222     done
 223   done
 224 done
 225 IFS="$ac_save_ifs"
 226
 227 if test -z "$os_used" && test "$os" != none; then
 228   AC_MSG_ERROR(Operating system $os is not supported.)
 229 fi
 230 if test -z "$machine_used" && test "$machine" != none; then
 231   AC_MSG_ERROR(The $machine is not supported.)
 232 fi
 233
 234 # We have now validated the configuration.
 235
 236
 237 # If using ELF, look for an `elf' subdirectory of each machine directory.
 238 # We prepend these rather than inserting them whereever the machine appears
 239 # because things specified by the machine's ELF ABI should override
 240 # OS-specific things, and should always be the same for any OS on the
 241 # machine (otherwise what's the point of an ABI?).
 242 if test "$elf" = yes; then
 243   elf_dirs=
 244   for d in $add_ons_pfx ''; do
 245     case $d in
 246       /*) xsrcdir= ;;
 247       *)  xsrcdir=$srcdir/ ;;
 248     esac
 249     for m in $mach; do
 250       if test -d $xsrcdir${d}sysdeps$m/elf; then
 251         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 252       fi
 253     done
 254   done
 255   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 256 fi
 257
 258
 259 # Expand the list of system names into a full list of directories
 260 # from each element's parent name and Implies file (if present).
 261 set $sysnames
 262 names=
 263 while test $# -gt 0; do
 264   name=$1
 265   shift
 266
 267   case " $names " in *" $name "*)
 268     # Already in the list.
 269     continue
 270   esac
 271
 272   # Report each name as we discover it, so there is no long pause in output.
 273   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 274
 275   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 276
 277   case $name in
 278     /*) xsrcdir= ;;
 279     *)  xsrcdir=$srcdir/ ;;
 280   esac
 281   test -n "$enable_debug_configure" &&
 282   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 283
 284   if test -f $xsrcdir$name/Implies; then
 285     # Collect more names from the `Implies' file (removing comments).
 286     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 287     implied=
 288     for x in $implied_candidate; do
 289       if test -d $xsrcdir$name_base/$x; then
 290         implied="$implied $name_base/$x";
 291       else
 292         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 293       fi
 294     done
 295   else
 296     implied=
 297   fi
 298
 299   # Add NAME to the list of names.
 300   names="$names $name"
 301
 302   # Find the parent of NAME, using the empty string if it has none.
 303 changequote(,)dnl
 304   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 305 changequote([,])dnl
 306
 307   # Add the names implied by NAME, and NAME's parent (if it has one), to
 308   # the list of names to be processed (the argument list).  We prepend the
 309   # implied names to the list and append the parent.  We want implied
 310   # directories to come before further directories inferred from the
 311   # configuration components; this ensures that for sysv4, unix/common
 312   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 313   # after sysv4).
 314   sysnames="`echo $implied $* $parent`"
 315   test -n "$sysnames" && set $sysnames
 316 done
 317
 318 # Add the default directories.
 319 sysnames="$names sysdeps/generic sysdeps/stub"
 320 AC_SUBST(sysnames)
 321 # The other names were emitted during the scan.
 322 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 323
 324
 325 ### Locate tools.
 326
 327 AC_PROG_INSTALL
 328 if test "$INSTALL" = "${srcdir}/install-sh"; then
 329   # The makefiles need to use a different form to find it in $srcdir.
 330   INSTALL='$(..)./install-sh'
 331 fi
 332 AC_PROG_LN_S
 333 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 334
 335 AC_CHECK_TOOL(CC, gcc)
 336 if test $host != $build; then
 337   AC_CHECK_PROG(BUILD_CC, gcc cc)
 338 fi
 339 AC_PROG_CPP
 340 AC_CHECK_TOOL(AR, ar)
 341 AC_CHECK_TOOL(RANLIB, ranlib, :)
 342
 343 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 344 echo '#include <stddef.h>
 345 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 346 if eval "$ac_cpp conftest.c 2>/dev/null" \
 347 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 348   libc_cv_signed_size_t=no
 349 else
 350   libc_cv_signed_size_t=yes
 351 fi
 352 rm -f conftest*])
 353 if test $libc_cv_signed_size_t = yes; then
 354   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 355   cat >> confdefs.h <<\EOF
 356 #undef __SIZE_TYPE__
 357 #define __SIZE_TYPE__ unsigned
 358 EOF
 359 fi
 360
 361 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 362 AC_TRY_COMPILE(dnl
 363 [#define __need_size_t
 364 #define __need_wchar_t
 365 #include <stddef.h>
 366 #define __need_NULL
 367 #include <stddef.h>], [size_t size; wchar_t wchar;
 368 #ifdef offsetof
 369 #error stddef.h ignored __need_*
 370 #endif
 371 if (&size == NULL || &wchar == NULL) abort ();],
 372                libc_cv_friendly_stddef=yes,
 373                libc_cv_friendly_stddef=no)])
 374 if test $libc_cv_friendly_stddef = yes; then
 375   config_vars="$config_vars
 376 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 377 fi
 378
 379 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 380                libc_cv_need_minus_P, [dnl
 381 cat > conftest.S <<EOF
 382 #include "confdefs.h"
 383 /* Nothing whatsoever.  */
 384 EOF
 385 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 386   libc_cv_need_minus_P=no
 387 else
 388   libc_cv_need_minus_P=yes
 389 fi
 390 rm -f conftest*])
 391 if test $libc_cv_need_minus_P = yes; then
 392   config_vars="$config_vars
 393 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 394 fi
 395
 396 AC_CACHE_CHECK(for assembler global-symbol directive,
 397                libc_cv_asm_global_directive, [dnl
 398 libc_cv_asm_global_directive=UNKNOWN
 399 for ac_globl in .globl .global; do
 400   cat > conftest.s <<EOF
 401 .text
 402 ${ac_globl} foo
 403 foo: .long 0
 404 EOF
 405   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 406     libc_cv_asm_global_directive=${ac_globl}
 407   fi
 408   rm -f conftest*
 409   test $libc_cv_asm_global_directive != UNKNOWN && break
 410 done])
 411 if test $libc_cv_asm_global_directive = UNKNOWN; then
 412   AC_MSG_ERROR(cannot determine asm global directive)
 413 else
 414   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 415 fi
 416
 417 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 418 cat > conftest.s <<EOF
 419 .text
 420 foo: .long 0
 421 .set glibc_conftest_frobozz,foo
 422 $libc_cv_asm_global_directive glibc_conftest_frobozz
 423 EOF
 424 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 425 # (but it doesn't work), so we must do a linking check to be sure.
 426 cat > conftest1.c <<\EOF
 427 extern int glibc_conftest_frobozz;
 428 main () { printf ("%d\n", glibc_conftest_frobozz); }
 429 EOF
 430 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 431             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 432   libc_cv_asm_set_directive=yes
 433 else
 434   libc_cv_asm_set_directive=no
 435 fi
 436 rm -f conftest*])
 437 if test $libc_cv_asm_set_directive = yes; then
 438   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 439 fi
 440
 441 if test $elf != yes; then
 442   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 443                  [AC_TRY_COMPILE(, [asm (".section .init");
 444                                     asm (".section .fini");
 445                                     asm (".text");],
 446                                  libc_cv_have_initfini=yes,
 447                                  libc_cv_have_initfini=no)])
 448   AC_SUBST(libc_cv_have_initfini)dnl
 449   if test $libc_cv_have_initfini = yes; then
 450     AC_DEFINE(HAVE_INITFINI)
 451   fi
 452 fi
 453
 454 if test $elf = yes; then
 455   libc_cv_asm_underscores=no
 456 else
 457   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 458                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 459                               libc_cv_asm_underscores=yes,
 460                               libc_cv_asm_underscores=no)])
 461 fi
 462 if test $libc_cv_asm_underscores = no; then
 463   AC_DEFINE(NO_UNDERSCORES)
 464 fi
 465
 466 if test $elf = yes; then
 467   libc_cv_weak_symbols=yes
 468   libc_cv_asm_weak_directive=yes
 469   libc_cv_asm_weakext_directive=no
 470 else
 471   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 472                  [dnl
 473 cat > conftest.s <<EOF
 474 .text
 475 ${libc_cv_asm_global_directive} foo
 476 foo: .long 0
 477 .weak foo
 478 .weak bar; bar = foo
 479 EOF
 480   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 481     libc_cv_asm_weak_directive=yes
 482   else
 483     libc_cv_asm_weak_directive=no
 484   fi
 485   rm -f conftest*])
 486
 487 if test $libc_cv_asm_weak_directive = no; then
 488   AC_CACHE_CHECK(for assembler .weakext directive,
 489                  libc_cv_asm_weakext_directive,
 490                  [dnl
 491 cat > conftest.s <<EOF
 492 .text
 493 ${libc_cv_asm_global_directive} foo
 494 foo: .long 0
 495 .weakext foo
 496 .weakext foo, bar
 497 EOF
 498   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 499     libc_cv_asm_weakext_directive=yes
 500   else
 501     libc_cv_asm_weakext_directive=no
 502   fi
 503   rm -f conftest*])
 504
 505   fi # no .weak
 506 fi # not ELF
 507
 508 if test $libc_cv_asm_weak_directive = yes; then
 509   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 510 elif test $libc_cv_asm_weakext_directive = yes; then
 511   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 512 fi
 513
 514 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 515 cat > conftest.c <<\EOF
 516 _start () {}
 517 int __eh_pc;
 518 __throw () {}
 519 EOF
 520 dnl No \ in command here because it ends up inside ''.
 521 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 522                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 523                             -o conftest conftest.c]); then
 524   libc_cv_ld_no_whole_archive=yes
 525 else
 526   libc_cv_ld_no_whole_archive=no
 527 fi
 528 rm -f conftest*])
 529 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 530
 531 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 532 cat > conftest.c <<\EOF
 533 _start () {}
 534 int __eh_pc;
 535 __throw () {}
 536 EOF
 537 dnl No \ in command here because it ends up inside ''.
 538 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 539                             -nostdlib -nostartfiles -fno-exceptions
 540                             -o conftest conftest.c]); then
 541   libc_cv_gcc_no_exceptions=yes
 542 else
 543   libc_cv_gcc_no_exceptions=no
 544 fi
 545 rm -f conftest*])
 546 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 547
 548 ### End of automated tests.
 549 ### Now run sysdeps configure fragments.
 550
 551 # sysdeps configure fragments may set these with files to be linked below.
 552 libc_link_dests=
 553 libc_link_sources=
 554
 555 # Iterate over all the sysdep directories we will use, running their
 556 # configure fragments, and looking for a uname implementation.
 557 uname=
 558 for dir in $sysnames; do
 559   case $dir in
 560     /*) dest=$dir ;;
 561     *)  dest=$srcdir/$dir ;;
 562   esac
 563   if test -r $dest/configure; then
 564     AC_MSG_RESULT(running configure fragment for $dest)
 565     . $dest/configure
 566   fi
 567 [
 568   if test -z "$uname"; then
 569     if test -r $sysdep_dir/$dir/uname.c ||
 570        test -r $sysdep_dir/$dir/uname.S ||
 571        { test -r $sysdep_dir/$dir/syscalls.list &&
 572          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 573       uname=$dir
 574     fi
 575   fi
 576 ]dnl
 577 done
 578
 579 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 580
 581 # If we will use the generic uname implementation, we must figure out what
 582 # it will say by examining the system, and write the results in config-name.h.
 583 if test "$uname" = generic; then
 584
 585 changequote(,)dnl
 586   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 587 changequote([,])dnl
 588   if test $uname_sysname != $config_os; then
 589     config_release=`echo $config_os | sed s/$uname_sysname//`
 590   fi
 591 dnl
 592 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 593     if test -r /vmunix; then
 594       kernel_id=`strings /vmunix | grep UNIX`
 595     elif test -r /dynix; then
 596       kernel_id=`strings /dynix | grep DYNIX`
 597     else
 598       kernel_id=
 599     fi
 600 ])dnl
 601
 602   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 603 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 604 changequote(,)dnl
 605   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 606 changequote([,])dnl
 607   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 608          != x$config_release; then
 609     # The configuration release is a substring of the kernel release.
 610     libc_cv_uname_release=$kernel_release
 611   elif test x$config_release != x; then
 612     libc_cv_uname_release=$config_release
 613   elif test x$kernel_release != x; then
 614     libc_cv_uname_release=$kernel_release
 615   else
 616     libc_cv_uname_release=unknown
 617   fi])
 618   uname_release="$libc_cv_uname_release"
 619
 620   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 621 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 622 changequote(,)dnl
 623   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 624 changequote([,])dnl
 625   if test -n "$kernel_version"; then
 626     libc_cv_uname_version="$kernel_version"
 627   else
 628     libc_cv_uname_version=unknown
 629   fi])
 630   uname_version="$libc_cv_uname_version"
 631
 632 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 633   config_uname=config-name.h:config-name.in
 634 else
 635   # For non-generic uname, we don't need to create config-name.h at all.
 636   config_uname=
 637 fi
 638
 639 AC_MSG_CHECKING(stdio selection)
 640 AC_SUBST(stdio)
 641 case $stdio in
 642 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 643 default) stdio=stdio ;;
 644 esac
 645 AC_MSG_RESULT($stdio)
 646
 647 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 648 if test $gnu_ld = yes; then
 649   AC_DEFINE(HAVE_GNU_LD)
 650 fi
 651 if test $gnu_as = yes; then
 652   AC_DEFINE(HAVE_GNU_AS)
 653 fi
 654 if test $elf = yes; then
 655   AC_DEFINE(HAVE_ELF)
 656 fi
 657
 658 AC_SUBST(shared)
 659 if test $shared = default; then
 660   if test $gnu_ld = yes; then
 661     shared=$elf
 662   fi
 663 fi
 664 AC_SUBST(profile)
 665 AC_SUBST(omitfp)
 666
 667 AC_SUBST(DEFINES)
 668
 669 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 670   config_makefile=
 671 else
 672   config_makefile=Makefile
 673 fi
 674
 675 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 676           [echo '$config_vars' >> config.make])