configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 228 # Unify this here.
 229 if test "$machine" = rs6000; then
 230   machine="powerpc"
 231 fi
 232
 233 ###
 234 ### I put this here to prevent those annoying emails from people who cannot
 235 ### read and try to compile glibc on unsupported platforms.  --drepper
 236 ###
 237 ### By using the undocumented --enable-hacker-mode option for configure
 238 ### one can skip this test to make the configuration not fail for unsupported
 239 ### platforms.
 240 ###
 241 if test -z "$enable_hacker_mode"; then
 242   case "$machine-$host_os" in
 243   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 244     ;;
 245   *)
 246     echo "*** The GNU C library is currently not available for this platform."
 247     echo "*** So far nobody cared to port it and if there is no volunteer it"
 248     echo "*** might never happen.  So, if you have interest to see glibc on"
 249     echo "*** this platform visit"
 250     echo "***   http://www.gnu.org/software/libc/porting.html"
 251     echo "*** and join the group of porters"
 252     exit 1
 253     ;;
 254   esac
 255 fi
 256
 257 dnl We need to use [ and ] for other purposes for a while now.
 258 changequote(,)dnl
 259 # Expand the configuration machine name into a subdirectory by architecture
 260 # type and particular chip.
 261 case "$machine" in
 262 a29k | am29000) base_machine=a29k machine=a29k ;;
 263 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 264 arm*)           base_machine=arm machine=arm/$machine ;;
 265 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 266 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 267 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 268 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 269 ia64)           base_machine=ia64 machine=ia64 ;;
 270 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 271 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 272 m88???)         base_machine=m88k machine=m88k/$machine ;;
 273 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 274 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 275 mips*)          base_machine=mips
 276                 case "`uname -m`" in
 277                 IP22) machine=mips/mips3 ;;
 278                 *)    machine=mips/$machine ;;
 279                 esac ;;
 280 sparc | sparcv[67])
 281                 base_machine=sparc machine=sparc/sparc32 ;;
 282 sparcv8 | supersparc | hypersparc)
 283                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 284 sparcv8plus | sparcv8plusa | sparcv9)
 285                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 286 sparc64 | ultrasparc)
 287                 base_machine=sparc machine=sparc/sparc64 ;;
 288 esac
 289 changequote([,])dnl
 290 AC_SUBST(base_machine)
 291
 292 if test "$base_machine" = "i386"; then
 293   AC_DEFINE(USE_REGPARMS)
 294 fi
 295
 296 # Compute the list of sysdep directories for this configuration.
 297 # This can take a while to compute.
 298 sysdep_dir=$srcdir/sysdeps
 299 AC_MSG_CHECKING(sysdep dirs)
 300 dnl We need to use [ and ] for other purposes for a while now.
 301 changequote(,)dnl
 302 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 303 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 304
 305 case "$os" in
 306 gnu*)
 307   base_os=mach/hurd ;;
 308 netbsd* | 386bsd* | freebsd* | bsdi*)
 309   base_os=unix/bsd/bsd4.4 ;;
 310 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 311   base_os=unix/bsd ;;
 312 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 313   base_os=unix/sysv ;;
 314 irix6*)
 315   base_os=unix/sysv/irix6/$os ;;
 316 solaris[2-9]*)
 317   base_os=unix/sysv/sysv4 ;;
 318 hpux*)
 319   base_os=unix/sysv/hpux/$os ;;
 320 aix4.3*)
 321   base_os=unix/sysv/aix/aix4.3 ;;
 322 none)
 323   base_os=standalone ;;
 324 *)
 325   base_os='' ;;
 326 esac
 327
 328 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 329 tail=$os
 330 ostry=$os
 331 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 332   ostry="$ostry /$o"
 333   tail=$o
 334 done
 335 o=`echo $tail | sed 's/[0-9]*$//'`
 336 if test $o != $tail; then
 337   ostry="$ostry /$o"
 338 fi
 339 # For linux-gnu, try linux-gnu, then linux.
 340 o=`echo $tail | sed 's/-.*$//'`
 341 if test $o != $tail; then
 342   ostry="$ostry /$o"
 343 fi
 344
 345 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 346 base=
 347 tail=$base_os
 348 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 349   set $b
 350   base="$base /$1"
 351   tail="$2"
 352 done
 353
 354 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 355 mach=
 356 tail=$machine
 357 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 358   set $m
 359   # Prepend the machine's FPU directory unless --without-fp.
 360   if test "$with_fp" = yes; then
 361     mach="$mach /$1/fpu"
 362   fi
 363   mach="$mach /$1"
 364   tail="$2"
 365 done
 366
 367 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 368 changequote([,])dnl
 369
 370 # Find what sysdep directories exist.
 371 sysnames=
 372 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 373 for d in $add_ons_pfx ''; do
 374   for b in $base ''; do
 375     for m0 in $mach ''; do
 376       for v in /$vendor ''; do
 377         test "$v" = / && continue
 378         for o in /$ostry ''; do
 379           test "$o" = / && continue
 380           for m in $mach ''; do
 381             if test "$m0$b$v$o$m"; then
 382               try="${d}sysdeps$m0$b$v$o$m"
 383               test -n "$enable_debug_configure" &&
 384               echo "$0 [DEBUG]: try $try" >&2
 385               if test -d $srcdir/$try; then
 386                 sysnames="$sysnames $try"
 387                 { test -n "$o" || test -n "$b"; } && os_used=t
 388                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 389               fi
 390             fi
 391           done
 392         done
 393       done
 394     done
 395   done
 396 done
 397 IFS="$ac_save_ifs"
 398
 399 if test -z "$os_used" && test "$os" != none; then
 400   AC_MSG_ERROR(Operating system $os is not supported.)
 401 fi
 402 if test -z "$machine_used" && test "$machine" != none; then
 403   AC_MSG_ERROR(The $machine is not supported.)
 404 fi
 405
 406 # We have now validated the configuration.
 407
 408
 409 # If using ELF, look for an `elf' subdirectory of each machine directory.
 410 # We prepend these rather than inserting them whereever the machine appears
 411 # because things specified by the machine's ELF ABI should override
 412 # OS-specific things, and should always be the same for any OS on the
 413 # machine (otherwise what's the point of an ABI?).
 414 if test "$elf" = yes; then
 415   elf_dirs=
 416   for d in $add_ons_pfx ''; do
 417     for m in $mach; do
 418       if test -d $srcdir/${d}sysdeps$m/elf; then
 419         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 420       fi
 421     done
 422   done
 423   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 424 fi
 425
 426
 427 # Expand the list of system names into a full list of directories
 428 # from each element's parent name and Implies file (if present).
 429 set $sysnames
 430 names=
 431 while test $# -gt 0; do
 432   name=$1
 433   shift
 434
 435   case " $names " in *" $name "*)
 436     # Already in the list.
 437     continue
 438   esac
 439
 440   # Report each name as we discover it, so there is no long pause in output.
 441   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 442
 443   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 444
 445   case $name in
 446     /*) xsrcdir= ;;
 447     *)  xsrcdir=$srcdir/ ;;
 448   esac
 449   test -n "$enable_debug_configure" &&
 450   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 451
 452   if test -f $xsrcdir$name/Implies; then
 453     # Collect more names from the `Implies' file (removing comments).
 454     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 455     implied=
 456     for x in $implied_candidate; do
 457       if test -d $xsrcdir$name_base/$x; then
 458         implied="$implied $name_base/$x";
 459       else
 460         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 461       fi
 462     done
 463   else
 464     implied=
 465   fi
 466
 467   # Add NAME to the list of names.
 468   names="$names $name"
 469
 470   # Find the parent of NAME, using the empty string if it has none.
 471 changequote(,)dnl
 472   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 473 changequote([,])dnl
 474
 475   # Add the names implied by NAME, and NAME's parent (if it has one), to
 476   # the list of names to be processed (the argument list).  We prepend the
 477   # implied names to the list and append the parent.  We want implied
 478   # directories to come before further directories inferred from the
 479   # configuration components; this ensures that for sysv4, unix/common
 480   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 481   # after sysv4).
 482   sysnames="`echo $implied $* $parent`"
 483   test -n "$sysnames" && set $sysnames
 484 done
 485
 486 # Add the default directories.
 487 default_sysnames=sysdeps/generic
 488 if test "$elf" = yes; then
 489   default_sysnames="sysdeps/generic/elf $default_sysnames"
 490 fi
 491 sysnames="$names $default_sysnames"
 492 AC_SUBST(sysnames)
 493 # The other names were emitted during the scan.
 494 AC_MSG_RESULT($default_sysnames)
 495
 496
 497 ### Locate tools.
 498
 499 AC_PROG_INSTALL
 500 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 501   # The makefiles need to use a different form to find it in $srcdir.
 502   INSTALL='\$(..)./scripts/install-sh -c'
 503 fi
 504 AC_PROG_LN_S
 505
 506 # These programs are version sensitive.
 507 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 508 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 509   [version \([egcygnustpi-]*[0-9.]*\)],
 510   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 511   critic_missing=t)
 512 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 513   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 514   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 515
 516 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 517   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 518   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 519 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 520   [GNU texinfo.* \([0-9][0-9.]*\)],
 521   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 522 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 523   [GNU sed version \([0-9]*\.[0-9.]*\)],
 524   [3.0[2-9]|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 525
 526 if test -n "$critic_missing"; then
 527 AC_MSG_ERROR([
 528 *** Some critical program is missing or too old.
 529 *** Check the INSTALL file for required versions.])
 530 fi
 531
 532 test -n "$aux_missing" && AC_MSG_WARN([
 533 *** An auxiliary program is missing or too old;
 534 *** some features will be disabled.
 535 *** Check the INSTALL file for required versions.])
 536
 537 # glibcbug.in wants to know the compiler version.
 538 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 539 AC_SUBST(CCVERSION)
 540
 541 AC_PROG_CC_LOCAL
 542 AC_CANONICAL_BUILD
 543 if test $host != $build; then
 544   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 545 fi
 546 AC_SUBST(cross_compiling)
 547 AC_PROG_CPP
 548 LIBC_PROG_BINUTILS
 549 AC_CHECK_TOOL(MIG, mig)
 550
 551 # if using special system headers, find out the compiler's sekrit
 552 # header directory and add that to the list.  NOTE: Only does the right
 553 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 554 if test -n "$sysheaders"; then
 555   ccheaders=`$CC -print-file-name=include`
 556   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 557 fi
 558 AC_SUBST(SYSINCLUDES)
 559
 560 # check if ranlib is necessary
 561 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 562 cat > conftest.c <<EOF
 563 int a;
 564 char b;
 565 void c(void) {}
 566 EOF
 567 $CC $CFLAGS -c conftest.c
 568 $AR cr conftest.a conftest.c
 569 cp conftest.a conftest2.a
 570 $RANLIB conftest.a
 571 if cmp -s conftest.a conftest2.a; then
 572   libc_cv_ranlib_necessary=no
 573 else
 574   libc_cv_ranlib_necessary=yes
 575 fi
 576 rm -rf conftest*])
 577 if test "$libc_cv_ranlib_necessary" = no; then
 578  RANLIB=:
 579 fi
 580
 581 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 582 # since this would lead to problems installing/building glibc.
 583 # LD_LIBRARY_PATH contains the current directory if one of the following
 584 # is true:
 585 # - one of the terminals (":" and ";") is the first or last sign
 586 # - two terminals occur directly after each other
 587 # - the path contains an element with a dot in it
 588 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 589 changequote(,)dnl
 590 case ${LD_LIBRARY_PATH} in
 591   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 592     ld_library_path_setting="contains current directory"
 593     ;;
 594   *)
 595     ld_library_path_setting="ok"
 596     ;;
 597 esac
 598 changequote([,])dnl
 599 AC_MSG_RESULT($ld_library_path_setting)
 600 if test "$ld_library_path_setting" != "ok"; then
 601 AC_MSG_ERROR([
 602 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 603 *** building glibc. Please change the environment variable
 604 *** and run configure again.])
 605 fi
 606
 607 AC_PATH_PROG(BASH, bash, no)
 608 if test "$BASH" != no &&
 609    $BASH -c 'test "$BASH_VERSINFO" \
 610              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 611   libc_cv_have_bash2=yes
 612 else
 613   libc_cv_have_bash2=no
 614 fi
 615 AC_SUBST(libc_cv_have_bash2)
 616
 617 dnl We need a ksh compatible shell for tzselect.
 618 if test "$BASH" = no; then
 619   AC_PATH_PROG(KSH, ksh, no)
 620   if test "$KSH" = no; then
 621     libc_cv_have_ksh=no
 622   else
 623     libc_cv_have_ksh=yes
 624   fi
 625 else
 626   KSH="$BASH"
 627   AC_SUBST(KSH)
 628   libc_cv_have_ksh=yes
 629 fi
 630 AC_SUBST(libc_cv_have_ksh)
 631
 632 AC_PROG_AWK
 633 AC_PATH_PROG(PERL, perl, no)
 634 if test "$PERL" != no &&
 635    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 636   PERL=no
 637 fi
 638 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 639              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 640 if test "$INSTALL_INFO" != "no"; then
 641 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 642  [mkdir conftest.d
 643   # There is a hard ^_ on the next line.  I am open to better ideas.
 644   (echo '\x1f'
 645   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 646   echo '* Menu:') >conftest.d/dir
 647   (echo 'INFO-DIR-SECTION i-d-s works'
 648   echo 'START-INFO-DIR-ENTRY'
 649   echo '* Prog: (prog).   Program.'
 650   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 651   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 652   then
 653     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 654     then libc_cv_old_debian_install_info=no
 655     else libc_cv_old_debian_install_info=yes
 656     fi
 657   else libc_cv_old_debian_install_info=no testfailed=t
 658   fi
 659   rm -fr conftest.d])
 660 if test -n "$testfailed"
 661 then AC_MSG_WARN([install-info errored out, check config.log])
 662 fi
 663 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 664 fi
 665 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 666
 667 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 668 echo '#include <stddef.h>
 669 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 670 if eval "$ac_cpp conftest.c 2>/dev/null" \
 671 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 672   libc_cv_signed_size_t=no
 673 else
 674   libc_cv_signed_size_t=yes
 675 fi
 676 rm -f conftest*])
 677 if test $libc_cv_signed_size_t = yes; then
 678   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 679   cat >> confdefs.h <<\EOF
 680 #undef __SIZE_TYPE__
 681 #define __SIZE_TYPE__ unsigned
 682 EOF
 683 fi
 684
 685 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 686 AC_TRY_COMPILE(dnl
 687 [#define __need_size_t
 688 #define __need_wchar_t
 689 #include <stddef.h>
 690 #define __need_NULL
 691 #include <stddef.h>], [size_t size; wchar_t wchar;
 692 #ifdef offsetof
 693 #error stddef.h ignored __need_*
 694 #endif
 695 if (&size == NULL || &wchar == NULL) abort ();],
 696                libc_cv_friendly_stddef=yes,
 697                libc_cv_friendly_stddef=no)])
 698 if test $libc_cv_friendly_stddef = yes; then
 699   config_vars="$config_vars
 700 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 701 fi
 702
 703 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 704                libc_cv_need_minus_P, [dnl
 705 cat > conftest.S <<EOF
 706 #include "confdefs.h"
 707 /* Nothing whatsoever.  */
 708 EOF
 709 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 710   libc_cv_need_minus_P=no
 711 else
 712   libc_cv_need_minus_P=yes
 713 fi
 714 rm -f conftest*])
 715 if test $libc_cv_need_minus_P = yes; then
 716   config_vars="$config_vars
 717 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 718 fi
 719
 720 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 721 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 722 cat > conftest.s <<EOF
 723 .text
 724 EOF
 725 libc_cv_dot_text=
 726 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 727   libc_cv_dot_text=.text
 728 fi
 729 rm -f conftest*])
 730 if test -z "$libc_cv_dot_text"; then
 731   AC_MSG_RESULT(no)
 732 else
 733   AC_MSG_RESULT(yes)
 734 fi
 735
 736 AC_CACHE_CHECK(for assembler global-symbol directive,
 737                libc_cv_asm_global_directive, [dnl
 738 libc_cv_asm_global_directive=UNKNOWN
 739 for ac_globl in .globl .global .EXPORT; do
 740   cat > conftest.s <<EOF
 741         ${libc_cv_dot_text}
 742         ${ac_globl} foo
 743 foo:
 744 EOF
 745   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 746     libc_cv_asm_global_directive=${ac_globl}
 747   fi
 748   rm -f conftest*
 749   test $libc_cv_asm_global_directive != UNKNOWN && break
 750 done])
 751 if test $libc_cv_asm_global_directive = UNKNOWN; then
 752   AC_MSG_ERROR(cannot determine asm global directive)
 753 else
 754   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 755 fi
 756
 757 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 758 cat > conftest.s <<EOF
 759 ${libc_cv_dot_text}
 760 foo:
 761 .set glibc_conftest_frobozz,foo
 762 $libc_cv_asm_global_directive glibc_conftest_frobozz
 763 EOF
 764 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 765 # (but it doesn't work), so we must do a linking check to be sure.
 766 cat > conftest1.c <<\EOF
 767 extern int glibc_conftest_frobozz;
 768 main () { printf ("%d\n", glibc_conftest_frobozz); }
 769 EOF
 770 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 771             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 772   libc_cv_asm_set_directive=yes
 773 else
 774   libc_cv_asm_set_directive=no
 775 fi
 776 rm -f conftest*])
 777 if test $libc_cv_asm_set_directive = yes; then
 778   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 779 fi
 780
 781 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 782 [cat > conftest.s <<EOF
 783 ${libc_cv_dot_text}
 784 _sym:
 785 .symver _sym,sym@VERS
 786 EOF
 787 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 788   libc_cv_asm_symver_directive=yes
 789 else
 790   libc_cv_asm_symver_directive=no
 791 fi
 792 rm -f conftest*])
 793 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 794 if test $libc_cv_asm_symver_directive = yes; then
 795   cat > conftest.s <<EOF
 796 ${libc_cv_dot_text}
 797 _sym:
 798 .symver _sym,sym@VERS
 799 EOF
 800   cat > conftest.map <<EOF
 801 VERS_1 {
 802         global: sym;
 803 };
 804
 805 VERS_2 {
 806         global: sym;
 807 } VERS_1;
 808 EOF
 809   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 810     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 811                                         -nostartfiles -nostdlib
 812                                         -Wl,--version-script,conftest.map
 813                        1>&AC_FD_CC]);
 814     then
 815       libc_cv_ld_version_script_option=yes
 816     else
 817       libc_cv_ld_version_script_option=no
 818     fi
 819   else
 820     libc_cv_ld_version_script_option=no
 821   fi
 822 else
 823   libc_cv_ld_version_script_option=no
 824 fi
 825 rm -f conftest*])
 826 if test $shared != no &&
 827    test $libc_cv_asm_symver_directive = yes &&
 828    test $libc_cv_ld_version_script_option = yes &&
 829    test $enable_versioning = yes; then
 830   VERSIONING=yes
 831   AC_DEFINE(DO_VERSIONING)
 832 else
 833   VERSIONING=no
 834 fi
 835 AC_SUBST(VERSIONING)
 836
 837 if test $shared != no && test $VERSIONING = no; then
 838   echo "\
 839 *** WARNING: You should not compile GNU libc without versioning. Not using
 840 *** versioning will introduce incompatibilities so that old binaries
 841 *** will not run anymore.
 842 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 843 fi
 844 if test $elf = yes; then
 845   AC_CACHE_CHECK(for .previous assembler directive,
 846                  libc_cv_asm_previous_directive, [dnl
 847   cat > conftest.s <<EOF
 848 .section foo_section
 849 .previous
 850 EOF
 851   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 852     libc_cv_asm_previous_directive=yes
 853   else
 854     libc_cv_asm_previous_directive=no
 855   fi
 856   rm -f conftest*])
 857   if test $libc_cv_asm_previous_directive = yes; then
 858     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 859   else
 860     AC_CACHE_CHECK(for .popsection assembler directive,
 861                    libc_cv_asm_popsection_directive, [dnl
 862     cat > conftest.s <<EOF
 863 .pushsection foo_section
 864 .popsection
 865 EOF
 866     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 867       libc_cv_asm_popsection_directive=yes
 868     else
 869       libc_cv_asm_popsection_directive=no
 870     fi
 871     rm -f conftest*])
 872     if test $libc_cv_asm_popsection_directive = yes; then
 873       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 874     fi
 875   fi
 876   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 877                  libc_cv_asm_protected_directive, [dnl
 878   cat > conftest.s <<EOF
 879 .protected foo
 880 foo:
 881 .hidden bar
 882 bar:
 883 EOF
 884   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 885     libc_cv_asm_protected_directive=yes
 886   else
 887     libc_cv_asm_protected_directive=no
 888   fi
 889   rm -f conftest*])
 890   AC_SUBST(libc_cv_asm_protected_directive)
 891 fi
 892
 893 if test $elf != yes; then
 894   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 895                  [AC_TRY_COMPILE(, [asm (".section .init");
 896                                     asm (".section .fini");
 897                                     asm ("${libc_cv_dot_text}");],
 898                                  libc_cv_have_initfini=yes,
 899                                  libc_cv_have_initfini=no)])
 900   AC_SUBST(libc_cv_have_initfini)dnl
 901   if test $libc_cv_have_initfini = yes; then
 902     AC_DEFINE(HAVE_INITFINI)
 903   fi
 904 fi
 905
 906 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 907 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 908 [cat > conftest.$ac_ext <<EOF
 909 dnl This sometimes fails to find confdefs.h, for some reason.
 910 dnl [#]line __oline__ "[$]0"
 911 [#]line __oline__ "configure"
 912 #include "confdefs.h"
 913 void underscore_test(void) {
 914 return; }
 915 EOF
 916 if AC_TRY_EVAL(ac_compile); then
 917   if grep _underscore_test conftest* >/dev/null; then
 918     ifelse([$1], , :, [rm -f conftest*
 919     $1])
 920   else
 921     ifelse([$2], , , [rm -f conftest*
 922     $2])
 923   fi
 924 else
 925   echo "configure: failed program was:" >&AC_FD_CC
 926   cat conftest.$ac_ext >&AC_FD_CC
 927   ifelse([$2], , , [rm -f conftest*
 928   $2])
 929 fi
 930 rm -f conftest*])
 931
 932 if test $elf = yes; then
 933   libc_cv_asm_underscores=no
 934 else
 935   if test $ac_cv_prog_cc_works = yes; then
 936     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 937                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 938                                 libc_cv_asm_underscores=yes,
 939                                 libc_cv_asm_underscores=no)])
 940   else
 941     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 942                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 943                                             libc_cv_asm_underscores=no)])
 944   fi
 945 fi
 946 if test $libc_cv_asm_underscores = no; then
 947   AC_DEFINE(NO_UNDERSCORES)
 948 fi
 949
 950 if test $elf = yes; then
 951   libc_cv_weak_symbols=yes
 952 fi
 953
 954 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 955                [dnl
 956 cat > conftest.s <<EOF
 957 ${libc_cv_dot_text}
 958 ${libc_cv_asm_global_directive} foo
 959 foo:
 960 .weak foo
 961 .weak bar; bar = foo
 962 EOF
 963 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 964   libc_cv_asm_weak_directive=yes
 965 else
 966   libc_cv_asm_weak_directive=no
 967 fi
 968 rm -f conftest*])
 969
 970 if test $libc_cv_asm_weak_directive = no; then
 971   AC_CACHE_CHECK(for assembler .weakext directive,
 972                  libc_cv_asm_weakext_directive,
 973                  [dnl
 974 cat > conftest.s <<EOF
 975 ${libc_cv_dot_text}
 976 ${libc_cv_asm_global_directive} foo
 977 foo:
 978 .weakext bar foo
 979 .weakext baz
 980 ${libc_cv_asm_global_directive} baz
 981 baz:
 982 EOF
 983   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 984     libc_cv_asm_weakext_directive=yes
 985   else
 986     libc_cv_asm_weakext_directive=no
 987   fi
 988   rm -f conftest*])
 989
 990 fi # no .weak
 991
 992 if test $libc_cv_asm_weak_directive = yes; then
 993   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 994 elif test $libc_cv_asm_weakext_directive = yes; then
 995   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 996 fi
 997
 998 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 999 cat > conftest.c <<\EOF
1000 _start () {}
1001 int __eh_pc;
1002 __throw () {}
1003 EOF
1004 dnl No \ in command here because it ends up inside ''.
1005 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1006                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1007                             -o conftest conftest.c 1>&AC_FD_CC]); then
1008   libc_cv_ld_no_whole_archive=yes
1009 else
1010   libc_cv_ld_no_whole_archive=no
1011 fi
1012 rm -f conftest*])
1013 if test $libc_cv_ld_no_whole_archive = yes; then
1014   no_whole_archive=-Wl,--no-whole-archive
1015 fi
1016 AC_SUBST(no_whole_archive)dnl
1017
1018 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1019 cat > conftest.c <<\EOF
1020 _start () {}
1021 int __eh_pc;
1022 __throw () {}
1023 EOF
1024 dnl No \ in command here because it ends up inside ''.
1025 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1026                             -nostdlib -nostartfiles -fexceptions
1027                             -o conftest conftest.c 1>&AC_FD_CC]); then
1028   libc_cv_gcc_exceptions=yes
1029 else
1030   libc_cv_gcc_exceptions=no
1031 fi
1032 rm -f conftest*])
1033 if test $libc_cv_gcc_exceptions = yes; then
1034   exceptions=-fexceptions
1035 fi
1036 AC_SUBST(exceptions)dnl
1037
1038 if test "$base_machine" = alpha ; then
1039 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1040 cat > conftest.c <<\EOF
1041 foo () { }
1042 EOF
1043 dnl
1044 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1045 then
1046   libc_cv_gcc_alpha_ng_prefix=yes
1047 else
1048   libc_cv_gcc_alpha_ng_prefix=no
1049 fi
1050 rm -f conftest* ])
1051 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1052   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1053 else
1054   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1055 fi
1056 fi
1057
1058 if test "$host_cpu" = powerpc ; then
1059 # Check for a bug present in at least versions 2.8.x of GCC
1060 # and versions 1.0.x of EGCS.
1061 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1062 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1063                libc_cv_c_asmcr0_bug='no',
1064                libc_cv_c_asmcr0_bug='yes')])
1065 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1066   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1067 fi
1068 fi
1069
1070 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1071 [cat > conftest.c <<EOF
1072 #line __oline__ "configure"
1073 static char __EH_FRAME_BEGIN__[];
1074 _start ()
1075 {
1076 #ifdef CHECK__register_frame
1077   __register_frame (__EH_FRAME_BEGIN__);
1078   __deregister_frame (__EH_FRAME_BEGIN__);
1079 #endif
1080 #ifdef CHECK__register_frame_info
1081   __register_frame_info (__EH_FRAME_BEGIN__);
1082   __deregister_frame_info (__EH_FRAME_BEGIN__);
1083 #endif
1084 }
1085 int __eh_pc;
1086 __throw () {}
1087 /* FIXME: this is fragile.  */
1088 malloc () {}
1089 strcmp () {}
1090 strlen () {}
1091 memcpy () {}
1092 memset () {}
1093 free () {}
1094 abort () {}
1095 __bzero () {}
1096 EOF
1097 dnl No \ in command here because it ends up inside ''.
1098 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1099                             -nostdlib -nostartfiles
1100                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1101   libc_cv_gcc_dwarf2_unwind_info=static
1102 else
1103   libc_cv_gcc_dwarf2_unwind_info=no
1104 fi
1105 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1106   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1107                               -nostdlib -nostartfiles
1108                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1109     libc_cv_gcc_dwarf2_unwind_info=yes
1110   else
1111     libc_cv_gcc_dwarf2_unwind_info=no
1112   fi
1113 fi
1114 rm -f conftest*])
1115 case $libc_cv_gcc_dwarf2_unwind_info in
1116 yes)
1117   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1118   ;;
1119 static)
1120   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1121   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1122   ;;
1123 esac
1124
1125 dnl Check whether compiler understands __builtin_expect.
1126 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1127 [cat > conftest.c <<EOF
1128 #line __oline__ "configure"
1129 int foo (int a)
1130 {
1131   a = __builtin_expect (a, 10);
1132   return a == 10 ? 0 : 1;
1133 }
1134 EOF
1135 dnl No \ in command here because it ends up inside ''.
1136 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1137                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1138   libc_cv_gcc_builtin_expect=yes
1139 else
1140   libc_cv_gcc_builtin_expect=no
1141 fi
1142 rm -f conftest*])
1143 if test "$libc_cv_gcc_builtin_expect" = yes; then
1144   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1145 fi
1146
1147 dnl Check whether the compiler supports subtraction of local labels.
1148 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1149 [cat > conftest.c <<EOF
1150 changequote(,)dnl
1151 #line __oline__ "configure"
1152 int foo (int a)
1153 {
1154   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1155   void *p = &&l1 + ar[a];
1156   goto *p;
1157  l1:
1158   return 1;
1159  l2:
1160   return 2;
1161 }
1162 changequote([,])dnl
1163 EOF
1164 dnl No \ in command here because it ends up inside ''.
1165 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1166                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1167   libc_cv_gcc_subtract_local_labels=yes
1168 else
1169   libc_cv_gcc_subtract_local_labels=no
1170 fi
1171 rm -f conftest*])
1172 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1173   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1174 fi
1175
1176 dnl Check whether we have the gd library available.
1177 AC_MSG_CHECKING(for libgd)
1178 old_CFLAGS="$CFLAGS"
1179 CFLAGS="$CFLAGS $libgd_include"
1180 old_LDFLAGS="$LDFLAGS"
1181 LDFLAGS="$LDFLAGS $libgd_ldflags"
1182 old_LIBS="$LIBS"
1183 LIBS="$LIBS -lgd -lpng -lz"
1184 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1185 CFLAGS="$old_CFLAGS"
1186 LDFLAGS="$old_LDFLAGS"
1187 LIBS="$old_LIBS"
1188 AC_MSG_RESULT($LIBGD)
1189 AC_SUBST(LIBGD)
1190
1191 dnl check for the size of 'long double'.
1192 AC_CHECK_SIZEOF(long double, 0)
1193 sizeof_long_double=$ac_cv_sizeof_long_double
1194 AC_SUBST(sizeof_long_double)
1195
1196 ### End of automated tests.
1197 ### Now run sysdeps configure fragments.
1198
1199 # sysdeps configure fragments may set these with files to be linked below.
1200 libc_link_dests=
1201 libc_link_sources=
1202
1203 # They also can set these variables.
1204 use_ldconfig=no
1205 ldd_rewrite_script=no
1206
1207 # Iterate over all the sysdep directories we will use, running their
1208 # configure fragments, and looking for a uname implementation.
1209 uname=
1210 for dir in $sysnames; do
1211   case $dir in
1212     /*) dest=$dir ;;
1213     *)  dest=$srcdir/$dir ;;
1214   esac
1215   if test -r $dest/configure; then
1216     AC_MSG_RESULT(running configure fragment for $dest)
1217     . $dest/configure
1218   fi
1219 [
1220   if test -z "$uname"; then
1221     if test -r $dest/uname.c ||
1222        test -r $dest/uname.S ||
1223        { test -r $dest/syscalls.list &&
1224          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1225       uname=$dir
1226     fi
1227   fi
1228 ]dnl
1229 done
1230
1231 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1232
1233 # If we will use the generic uname implementation, we must figure out what
1234 # it will say by examining the system, and write the results in config-name.h.
1235 if test "$uname" = "sysdeps/generic"; then
1236
1237 changequote(,)dnl
1238   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1239 changequote([,])dnl
1240   if test $uname_sysname != $config_os; then
1241     config_release=`echo $config_os | sed s/$uname_sysname//`
1242   fi
1243 dnl
1244 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1245     if test -r /vmunix; then
1246       kernel_id=`strings /vmunix | grep UNIX`
1247     elif test -r /dynix; then
1248       kernel_id=`strings /dynix | grep DYNIX`
1249     else
1250       kernel_id=
1251     fi
1252 ])dnl
1253
1254   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1255 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1256 changequote(,)dnl
1257   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1258 changequote([,])dnl
1259   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1260          != x$config_release; then
1261     # The configuration release is a substring of the kernel release.
1262     libc_cv_uname_release=$kernel_release
1263   elif test x$config_release != x; then
1264     libc_cv_uname_release=$config_release
1265   elif test x$kernel_release != x; then
1266     libc_cv_uname_release=$kernel_release
1267   else
1268     libc_cv_uname_release=unknown
1269   fi])
1270   uname_release="$libc_cv_uname_release"
1271
1272   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1273 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1274 changequote(,)dnl
1275   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1276 changequote([,])dnl
1277   if test -n "$kernel_version"; then
1278     libc_cv_uname_version="$kernel_version"
1279   else
1280     libc_cv_uname_version=unknown
1281   fi])
1282   uname_version="$libc_cv_uname_version"
1283
1284 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1285   config_uname=config-name.h:config-name.in
1286 else
1287   # For non-generic uname, we don't need to create config-name.h at all.
1288   config_uname=
1289 fi
1290
1291 AC_MSG_CHECKING(stdio selection)
1292 AC_SUBST(stdio)
1293 case $stdio in
1294 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1295 default) stdio=stdio ;;
1296 esac
1297 AC_MSG_RESULT($stdio)
1298
1299 # Test for old glibc 2.0.x headers so that they can be removed properly
1300 # Search only in includedir.
1301 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1302 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1303 then
1304   old_glibc_headers=yes
1305 else
1306   old_glibc_headers=no
1307 fi
1308 AC_MSG_RESULT($old_glibc_headers)
1309 if test ${old_glibc_headers} = yes; then
1310   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1311   AC_MSG_WARN(*** be removed.)
1312 fi
1313 AC_SUBST(old_glibc_headers)
1314
1315 AC_SUBST(libc_cv_slibdir)
1316 AC_SUBST(libc_cv_localedir)
1317 AC_SUBST(libc_cv_sysconfdir)
1318 AC_SUBST(libc_cv_rootsbindir)
1319
1320 AC_SUBST(use_ldconfig)
1321 AC_SUBST(ldd_rewrite_script)
1322
1323 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1324 if test $gnu_ld = yes; then
1325   AC_DEFINE(HAVE_GNU_LD)
1326 fi
1327 if test $gnu_as = yes; then
1328   AC_DEFINE(HAVE_GNU_AS)
1329 fi
1330 if test $elf = yes; then
1331   AC_DEFINE(HAVE_ELF)
1332 fi
1333
1334 AC_SUBST(static)
1335 AC_SUBST(shared)
1336 if test $shared = default; then
1337   if test $gnu_ld = yes; then
1338     shared=$elf
1339   else
1340     # For now we do not assume shared libs are available.  In future more
1341     # tests might become available.
1342     shared=no
1343   fi
1344 fi
1345
1346 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1347 [pic_default=yes
1348 cat > conftest.c <<EOF
1349 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1350 # error PIC is default.
1351 #endif
1352 EOF
1353 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1354   pic_default=no
1355 fi
1356 rm -f conftest.*])
1357 AC_SUBST(pic_default)
1358
1359 AC_SUBST(profile)
1360 AC_SUBST(omitfp)
1361 AC_SUBST(bounded)
1362 AC_SUBST(static_nss)
1363 AC_SUBST(nopic_initfini)
1364
1365 AC_SUBST(DEFINES)
1366
1367 case "$add_ons" in
1368   *door*) linux_doors=yes ;;
1369   *) linux_doors=no ;;
1370 esac
1371 AC_SUBST(linux_doors)
1372
1373 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1374   config_makefile=
1375 else
1376   config_makefile=Makefile
1377 fi
1378
1379 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1380 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1381 AC_SUBST(VERSION)
1382 AC_SUBST(RELEASE)
1383
1384 echo '*** Do NOT install this release on any production system!'
1385 echo '*** It is known to be broken and will be so for quite some time.'
1386 echo '*** Use the latest released version instead.'
1387
1388 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1389 case $CONFIG_FILES in *config.make*)
1390 echo "$config_vars" >> config.make;;
1391 esac
1392 test -d bits || mkdir bits], [config_vars='$config_vars'])