configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_ARG_WITH(binutils, dnl
  63   --with-binutils=PATH    specify location of binutils (as and ld),
  64             path_binutils=$withval, path_binutils='')
  65 AC_ARG_WITH(elf, dnl
  66   --with-elf              if using the ELF object format,
  67             elf=$withval, elf=no)
  68 AC_ARG_WITH(cvs, dnl
  69 [  --without-cvs          if CVS should not be used],
  70             with_cvs=$withval, with_cvs=yes)
  71 AC_SUBST(with_cvs)
  72
  73 AC_ARG_WITH(headers, dnl
  74 [  --with-headers=PATH     location of system headers to use
  75                           [e.g. /usr/src/linux/include]
  76                           [default=compiler default]],
  77             sysheaders=$withval, sysheaders='')
  78
  79 AC_ARG_ENABLE(libio, dnl
  80 [  --enable-libio          build in GNU libio instead of GNU stdio],
  81               [if test $enableval = yes; then
  82                  stdio=libio
  83                else
  84                  stdio=stdio
  85                fi],
  86               stdio=default)
  87
  88 AC_ARG_ENABLE(sanity-checks, dnl
  89 [  --disable-sanity-checks really do not use threads (should not be used
  90                           except in special situations) [default=yes]],
  91               enable_sanity=$enableval, enable_sanity=yes)
  92
  93 dnl Arguments to enable or disable building the static, shared, profiled,
  94 dnl and -fomit-frame-pointer libraries.
  95 dnl I've disabled this for now since we cannot build glibc without static
  96 dnl libraries built in the moment.
  97 dnl AC_ARG_ENABLE(static, dnl
  98 dnl [  --enable-static         build static library [default=yes]],
  99 dnl           static=$enableval, static=yes)
 100 static=yes
 101 AC_ARG_ENABLE(shared, dnl
 102 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 103               shared=$enableval, shared=default)
 104 AC_ARG_ENABLE(profile, dnl
 105 [  --enable-profile        build profiled library [default=yes]],
 106               profile=$enableval, profile=yes)
 107 AC_ARG_ENABLE(omitfp, dnl
 108 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 109               omitfp=$enableval, omitfp=no)
 110 AC_ARG_ENABLE(bounded, dnl
 111 [  --enable-bounded        build with runtime bounds checking [default=no]],
 112               bounded=$enableval, bounded=no)
 113 AC_ARG_ENABLE(versioning, dnl
 114 [  --disable-versioning    do not include versioning information in the
 115                           library objects [default=yes if supported]],
 116              enable_versioning=$enableval, enable_versioning=yes)
 117
 118 dnl Generic infrastructure for drop-in additions to libc.
 119 AC_ARG_ENABLE(add-ons, dnl
 120 [  --enable-add-ons[=DIR1,DIR2]...
 121                           configure and build add-ons in DIR1,DIR2,...
 122                           search for add-ons if no parameter given],
 123   [case "$enableval" in
 124     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 125          test "$add_ons" = "*" && add_ons= ;;
 126     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 127    esac],
 128   [add_ons=])
 129
 130 AC_CONFIG_SUBDIRS($add_ons)
 131 add_ons_pfx=
 132 if test x"$add_ons" != x; then
 133   for f in $add_ons; do
 134     # Test whether such a subdir really exists.
 135     if test -d $srcdir/$f; then
 136       add_ons_pfx="$add_ons_pfx $f/"
 137     else
 138       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 139     fi
 140   done
 141 fi
 142
 143 dnl On some platforms we cannot use dynamic loading.  We must provide
 144 dnl static NSS modules.
 145 AC_ARG_ENABLE(static-nss, dnl
 146 [  --enable-static-nss     build static NSS modules [default=no]],
 147               static_nss=$enableval, static_nss=no)
 148 if test x"$static_nss" = xyes; then
 149   AC_DEFINE(DO_STATIC_NSS)
 150 fi
 151
 152 AC_ARG_ENABLE(force-install,
 153 [  --disable-force-install don't force installation of files from this package,
 154                           even if they are older than the installed files],
 155               force_install=$enableval, force_install=yes)
 156 AC_SUBST(force_install)
 157
 158 dnl On some platforms we allow dropping compatibility with all kernel
 159 dnl versions.
 160 AC_ARG_ENABLE(kernel,
 161 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 162                            than VERSION],
 163               minimum_kernel=$enableval)
 164 dnl Prevent unreasonable values.
 165 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 166   # Better nothing than this.
 167   minimum_kernel=""
 168 else
 169   if test "$minimum_kernel" = current; then
 170     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 171   fi
 172 fi
 173
 174 AC_CANONICAL_HOST
 175
 176 # The way shlib-versions is used to generate soversions.mk uses a
 177 # fairly simplistic model for name recognition that can't distinguish
 178 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 179 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 180 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 181 case "$host_os" in
 182 linux*)
 183   ;;
 184 gnu*)
 185   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 186   ;;
 187 esac
 188
 189 # We keep the original values in `$config_*' and never modify them, so we
 190 # can write them unchanged into config.make.  Everything else uses
 191 # $machine, $vendor, and $os, and changes them whenever convenient.
 192 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 193
 194 # Don't allow vendor == "unknown"
 195 test "$config_vendor" = unknown && config_vendor=
 196 config_os="`echo $config_os | sed 's/^unknown-//'`"
 197
 198 # Some configurations imply other options.
 199 case "$host_os" in
 200 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 201   # These systems always use GNU tools.
 202   gnu_ld=yes gnu_as=yes ;;
 203 esac
 204 case "$host_os" in
 205 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 206 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 207   ;;
 208 gnu* | linux* | sysv4* | solaris2* | irix6*)
 209   # These systems (almost) always use the ELF format.
 210   elf=yes
 211   ;;
 212 esac
 213
 214 machine=$config_machine
 215 vendor=$config_vendor
 216 os=$config_os
 217
 218 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 219 # Unify this here.
 220 if test "$machine" = rs6000; then
 221   machine="powerpc"
 222 fi
 223
 224 ###
 225 ### I put this here to prevent those annoying emails from people who cannot
 226 ### read and try to compile glibc on unsupported platforms.  --drepper
 227 ###
 228 ### By using the undocumented --enable-hacker-mode option for configure
 229 ### one can skip this test to make the configuration not fail for unsupported
 230 ### platforms.
 231 ###
 232 if test -z "$enable_hacker_mode"; then
 233   case "$machine-$host_os" in
 234   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 235     ;;
 236   *)
 237     echo "*** The GNU C library is currently not available for this platform."
 238     echo "*** So far nobody cared to port it and if there is no volunteer it"
 239     echo "*** might never happen.  So, if you have interest to see glibc on"
 240     echo "*** this platform visit"
 241     echo "***   http://www.gnu.org/software/libc/porting.html"
 242     echo "*** and join the group of porters"
 243     exit 1
 244     ;;
 245   esac
 246 fi
 247
 248 dnl We need to use [ and ] for other purposes for a while now.
 249 changequote(,)dnl
 250 # Expand the configuration machine name into a subdirectory by architecture
 251 # type and particular chip.
 252 case "$machine" in
 253 a29k | am29000) base_machine=a29k machine=a29k ;;
 254 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 255 arm*)           base_machine=arm machine=arm/$machine ;;
 256 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 257 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 258 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 259 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 260 ia64)           base_machine=ia64 machine=ia64 ;;
 261 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 262 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 263 m88???)         base_machine=m88k machine=m88k/$machine ;;
 264 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 265 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 266 mips*)          base_machine=mips
 267                 case "`uname -m`" in
 268                 IP22) machine=mips/mips3 ;;
 269                 *)    machine=mips/$machine ;;
 270                 esac ;;
 271 sh3*)           base_machine=sh machine=sh/sh3 ;;
 272 sh4*)           base_machine=sh machine=sh/sh4 ;;
 273 sparc | sparcv[67])
 274                 base_machine=sparc machine=sparc/sparc32 ;;
 275 sparcv8 | supersparc | hypersparc)
 276                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 277 sparcv8plus | sparcv8plusa | sparcv9)
 278                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 279 sparc64 | ultrasparc)
 280                 base_machine=sparc machine=sparc/sparc64 ;;
 281 esac
 282 changequote([,])dnl
 283 AC_SUBST(base_machine)
 284
 285 if test "$base_machine" = "i386"; then
 286   AC_DEFINE(USE_REGPARMS)
 287 fi
 288
 289 # Compute the list of sysdep directories for this configuration.
 290 # This can take a while to compute.
 291 sysdep_dir=$srcdir/sysdeps
 292 AC_MSG_CHECKING(sysdep dirs)
 293 dnl We need to use [ and ] for other purposes for a while now.
 294 changequote(,)dnl
 295 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 296 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 297
 298 case "$os" in
 299 gnu*)
 300   base_os=mach/hurd ;;
 301 netbsd* | 386bsd* | freebsd* | bsdi*)
 302   base_os=unix/bsd/bsd4.4 ;;
 303 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 304   base_os=unix/bsd ;;
 305 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 306   base_os=unix/sysv ;;
 307 irix6*)
 308   base_os=unix/sysv/irix6/$os ;;
 309 solaris[2-9]*)
 310   base_os=unix/sysv/sysv4 ;;
 311 hpux*)
 312   base_os=unix/sysv/hpux/$os ;;
 313 aix4.3*)
 314   base_os=unix/sysv/aix/aix4.3 ;;
 315 none)
 316   base_os=standalone ;;
 317 *)
 318   base_os='' ;;
 319 esac
 320
 321 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 322 tail=$os
 323 ostry=$os
 324 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 325   ostry="$ostry /$o"
 326   tail=$o
 327 done
 328 o=`echo $tail | sed 's/[0-9]*$//'`
 329 if test $o != $tail; then
 330   ostry="$ostry /$o"
 331 fi
 332 # For linux-gnu, try linux-gnu, then linux.
 333 o=`echo $tail | sed 's/-.*$//'`
 334 if test $o != $tail; then
 335   ostry="$ostry /$o"
 336 fi
 337
 338 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 339 base=
 340 tail=$base_os
 341 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 342   set $b
 343   base="$base /$1"
 344   tail="$2"
 345 done
 346
 347 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 348 mach=
 349 tail=$machine
 350 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 351   set $m
 352   # Prepend the machine's FPU directory unless --without-fp.
 353   if test "$with_fp" = yes; then
 354     mach="$mach /$1/fpu"
 355   fi
 356   mach="$mach /$1"
 357   tail="$2"
 358 done
 359
 360 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 361 changequote([,])dnl
 362
 363 # Find what sysdep directories exist.
 364 sysnames=
 365 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 366 for d in $add_ons_pfx ''; do
 367   for b in $base ''; do
 368     for m0 in $mach ''; do
 369       for v in /$vendor ''; do
 370         test "$v" = / && continue
 371         for o in /$ostry ''; do
 372           test "$o" = / && continue
 373           for m in $mach ''; do
 374             if test "$m0$b$v$o$m"; then
 375               try="${d}sysdeps$m0$b$v$o$m"
 376               test -n "$enable_debug_configure" &&
 377               echo "$0 [DEBUG]: try $try" >&2
 378               if test -d $srcdir/$try; then
 379                 sysnames="$sysnames $try"
 380                 { test -n "$o" || test -n "$b"; } && os_used=t
 381                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 382               fi
 383             fi
 384           done
 385         done
 386       done
 387     done
 388   done
 389 done
 390 IFS="$ac_save_ifs"
 391
 392 if test -z "$os_used" && test "$os" != none; then
 393   AC_MSG_ERROR(Operating system $os is not supported.)
 394 fi
 395 if test -z "$machine_used" && test "$machine" != none; then
 396   AC_MSG_ERROR(The $machine is not supported.)
 397 fi
 398
 399 # We have now validated the configuration.
 400
 401
 402 # If using ELF, look for an `elf' subdirectory of each machine directory.
 403 # We prepend these rather than inserting them whereever the machine appears
 404 # because things specified by the machine's ELF ABI should override
 405 # OS-specific things, and should always be the same for any OS on the
 406 # machine (otherwise what's the point of an ABI?).
 407 if test "$elf" = yes; then
 408   elf_dirs=
 409   for d in $add_ons_pfx ''; do
 410     for m in $mach; do
 411       if test -d $srcdir/${d}sysdeps$m/elf; then
 412         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 413       fi
 414     done
 415   done
 416   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 417 fi
 418
 419
 420 # Expand the list of system names into a full list of directories
 421 # from each element's parent name and Implies file (if present).
 422 set $sysnames
 423 names=
 424 while test $# -gt 0; do
 425   name=$1
 426   shift
 427
 428   case " $names " in *" $name "*)
 429     # Already in the list.
 430     continue
 431   esac
 432
 433   # Report each name as we discover it, so there is no long pause in output.
 434   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 435
 436   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 437
 438   case $name in
 439     /*) xsrcdir= ;;
 440     *)  xsrcdir=$srcdir/ ;;
 441   esac
 442   test -n "$enable_debug_configure" &&
 443   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 444
 445   if test -f $xsrcdir$name/Implies; then
 446     # Collect more names from the `Implies' file (removing comments).
 447     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 448     implied=
 449     for x in $implied_candidate; do
 450       if test -d $xsrcdir$name_base/$x; then
 451         implied="$implied $name_base/$x";
 452       else
 453         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 454       fi
 455     done
 456   else
 457     implied=
 458   fi
 459
 460   # Add NAME to the list of names.
 461   names="$names $name"
 462
 463   # Find the parent of NAME, using the empty string if it has none.
 464 changequote(,)dnl
 465   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 466 changequote([,])dnl
 467
 468   # Add the names implied by NAME, and NAME's parent (if it has one), to
 469   # the list of names to be processed (the argument list).  We prepend the
 470   # implied names to the list and append the parent.  We want implied
 471   # directories to come before further directories inferred from the
 472   # configuration components; this ensures that for sysv4, unix/common
 473   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 474   # after sysv4).
 475   sysnames="`echo $implied $* $parent`"
 476   test -n "$sysnames" && set $sysnames
 477 done
 478
 479 # Add the default directories.
 480 default_sysnames=sysdeps/generic
 481 if test "$elf" = yes; then
 482   default_sysnames="sysdeps/generic/elf $default_sysnames"
 483 fi
 484 sysnames="$names $default_sysnames"
 485 AC_SUBST(sysnames)
 486 # The other names were emitted during the scan.
 487 AC_MSG_RESULT($default_sysnames)
 488
 489
 490 ### Locate tools.
 491
 492 AC_PROG_INSTALL
 493 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 494   # The makefiles need to use a different form to find it in $srcdir.
 495   INSTALL='\$(..)./scripts/install-sh -c'
 496 fi
 497 AC_PROG_LN_S
 498
 499 # We need the physical current working directory.  We cannot use the
 500 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 501 # find a pwd binary.  Note that assigning to the PWD environment
 502 # variable might have some interesting side effects, so we don't do
 503 # that.
 504 AC_PATH_PROG(PWD_P, pwd, no)
 505 if test "$PWD_P" = no; then
 506   AC_MSG_ERROR(*** A pwd binary could not be found.)
 507 fi
 508
 509 # These programs are version sensitive.
 510 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 511 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 512   [version \([egcygnustpi-]*[0-9.]*\)],
 513   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 514   critic_missing=t)
 515 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 516   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 517   [3.79* | 3.[89]*], critic_missing=t)
 518
 519 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 520   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 521   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 522 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 523   [GNU texinfo.* \([0-9][0-9.]*\)],
 524   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 525 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 526   [GNU sed version \([0-9]*\.[0-9.]*\)],
 527   [3.0[2-9]*|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 528
 529 if test -n "$critic_missing"; then
 530 AC_MSG_ERROR([
 531 *** Some critical program is missing or too old.
 532 *** Check the INSTALL file for required versions.])
 533 fi
 534
 535 test -n "$aux_missing" && AC_MSG_WARN([
 536 *** An auxiliary program is missing or too old;
 537 *** some features will be disabled.
 538 *** Check the INSTALL file for required versions.])
 539
 540 # glibcbug.in wants to know the compiler version.
 541 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 542 AC_SUBST(CCVERSION)
 543
 544 AC_PROG_CC_LOCAL
 545 AC_CANONICAL_BUILD
 546 if test $host != $build; then
 547   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 548 fi
 549 AC_SUBST(cross_compiling)
 550 AC_PROG_CPP
 551 LIBC_PROG_BINUTILS
 552 AC_CHECK_TOOL(MIG, mig)
 553
 554 # if using special system headers, find out the compiler's sekrit
 555 # header directory and add that to the list.  NOTE: Only does the right
 556 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 557 if test -n "$sysheaders"; then
 558   ccheaders=`$CC -print-file-name=include`
 559   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 560 fi
 561 AC_SUBST(SYSINCLUDES)
 562
 563 # check if ranlib is necessary
 564 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 565 cat > conftest.c <<EOF
 566 int a;
 567 char b;
 568 void c(void) {}
 569 EOF
 570 $CC $CFLAGS -c conftest.c
 571 $AR cr conftest.a conftest.c
 572 cp conftest.a conftest2.a
 573 $RANLIB conftest.a
 574 if cmp -s conftest.a conftest2.a; then
 575   libc_cv_ranlib_necessary=no
 576 else
 577   libc_cv_ranlib_necessary=yes
 578 fi
 579 rm -rf conftest*])
 580 if test "$libc_cv_ranlib_necessary" = no; then
 581  RANLIB=:
 582 fi
 583
 584 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 585 # since this would lead to problems installing/building glibc.
 586 # LD_LIBRARY_PATH contains the current directory if one of the following
 587 # is true:
 588 # - one of the terminals (":" and ";") is the first or last sign
 589 # - two terminals occur directly after each other
 590 # - the path contains an element with a dot in it
 591 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 592 changequote(,)dnl
 593 case ${LD_LIBRARY_PATH} in
 594   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 595     ld_library_path_setting="contains current directory"
 596     ;;
 597   *)
 598     ld_library_path_setting="ok"
 599     ;;
 600 esac
 601 changequote([,])dnl
 602 AC_MSG_RESULT($ld_library_path_setting)
 603 if test "$ld_library_path_setting" != "ok"; then
 604 AC_MSG_ERROR([
 605 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 606 *** building glibc. Please change the environment variable
 607 *** and run configure again.])
 608 fi
 609
 610 AC_PATH_PROG(BASH, bash, no)
 611 if test "$BASH" != no &&
 612    $BASH -c 'test "$BASH_VERSINFO" \
 613              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 614   libc_cv_have_bash2=yes
 615 else
 616   libc_cv_have_bash2=no
 617 fi
 618 AC_SUBST(libc_cv_have_bash2)
 619
 620 dnl We need a ksh compatible shell for tzselect.
 621 if test "$BASH" = no; then
 622   AC_PATH_PROG(KSH, ksh, no)
 623   if test "$KSH" = no; then
 624     libc_cv_have_ksh=no
 625   else
 626     libc_cv_have_ksh=yes
 627   fi
 628 else
 629   KSH="$BASH"
 630   AC_SUBST(KSH)
 631   libc_cv_have_ksh=yes
 632 fi
 633 AC_SUBST(libc_cv_have_ksh)
 634
 635 AC_PROG_AWK
 636 AC_PATH_PROG(PERL, perl, no)
 637 if test "$PERL" != no &&
 638    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 639   PERL=no
 640 fi
 641 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 642              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 643 if test "$INSTALL_INFO" != "no"; then
 644 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 645  [mkdir conftest.d
 646   # There is a hard ^_ on the next line.  I am open to better ideas.
 647   (echo '\x1f'
 648   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 649   echo '* Menu:') >conftest.d/dir
 650   (echo 'INFO-DIR-SECTION i-d-s works'
 651   echo 'START-INFO-DIR-ENTRY'
 652   echo '* Prog: (prog).   Program.'
 653   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 654   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 655   then
 656     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 657     then libc_cv_old_debian_install_info=no
 658     else libc_cv_old_debian_install_info=yes
 659     fi
 660   else libc_cv_old_debian_install_info=no testfailed=t
 661   fi
 662   rm -fr conftest.d])
 663 if test -n "$testfailed"
 664 then AC_MSG_WARN([install-info errored out, check config.log])
 665 fi
 666 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 667 fi
 668 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 669
 670 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 671 echo '#include <stddef.h>
 672 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 673 if eval "$ac_cpp conftest.c 2>/dev/null" \
 674 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 675   libc_cv_signed_size_t=no
 676 else
 677   libc_cv_signed_size_t=yes
 678 fi
 679 rm -f conftest*])
 680 if test $libc_cv_signed_size_t = yes; then
 681   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 682   cat >> confdefs.h <<\EOF
 683 #undef __SIZE_TYPE__
 684 #define __SIZE_TYPE__ unsigned
 685 EOF
 686 fi
 687
 688 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 689 AC_TRY_COMPILE(dnl
 690 [#define __need_size_t
 691 #define __need_wchar_t
 692 #include <stddef.h>
 693 #define __need_NULL
 694 #include <stddef.h>], [size_t size; wchar_t wchar;
 695 #ifdef offsetof
 696 #error stddef.h ignored __need_*
 697 #endif
 698 if (&size == NULL || &wchar == NULL) abort ();],
 699                libc_cv_friendly_stddef=yes,
 700                libc_cv_friendly_stddef=no)])
 701 if test $libc_cv_friendly_stddef = yes; then
 702   config_vars="$config_vars
 703 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 704 fi
 705
 706 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 707                libc_cv_need_minus_P, [dnl
 708 cat > conftest.S <<EOF
 709 #include "confdefs.h"
 710 /* Nothing whatsoever.  */
 711 EOF
 712 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 713   libc_cv_need_minus_P=no
 714 else
 715   libc_cv_need_minus_P=yes
 716 fi
 717 rm -f conftest*])
 718 if test $libc_cv_need_minus_P = yes; then
 719   config_vars="$config_vars
 720 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 721 fi
 722
 723 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 724 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 725 cat > conftest.s <<EOF
 726 .text
 727 EOF
 728 libc_cv_dot_text=
 729 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 730   libc_cv_dot_text=.text
 731 fi
 732 rm -f conftest*])
 733 if test -z "$libc_cv_dot_text"; then
 734   AC_MSG_RESULT(no)
 735 else
 736   AC_MSG_RESULT(yes)
 737 fi
 738
 739 AC_CACHE_CHECK(for assembler global-symbol directive,
 740                libc_cv_asm_global_directive, [dnl
 741 libc_cv_asm_global_directive=UNKNOWN
 742 for ac_globl in .globl .global .EXPORT; do
 743   cat > conftest.s <<EOF
 744         ${libc_cv_dot_text}
 745         ${ac_globl} foo
 746 foo:
 747 EOF
 748   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 749     libc_cv_asm_global_directive=${ac_globl}
 750   fi
 751   rm -f conftest*
 752   test $libc_cv_asm_global_directive != UNKNOWN && break
 753 done])
 754 if test $libc_cv_asm_global_directive = UNKNOWN; then
 755   AC_MSG_ERROR(cannot determine asm global directive)
 756 else
 757   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 758 fi
 759
 760 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 761 cat > conftest.s <<EOF
 762 ${libc_cv_dot_text}
 763 foo:
 764 .set glibc_conftest_frobozz,foo
 765 $libc_cv_asm_global_directive glibc_conftest_frobozz
 766 EOF
 767 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 768 # (but it doesn't work), so we must do a linking check to be sure.
 769 cat > conftest1.c <<\EOF
 770 extern int glibc_conftest_frobozz;
 771 main () { printf ("%d\n", glibc_conftest_frobozz); }
 772 EOF
 773 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 774             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 775   libc_cv_asm_set_directive=yes
 776 else
 777   libc_cv_asm_set_directive=no
 778 fi
 779 rm -f conftest*])
 780 if test $libc_cv_asm_set_directive = yes; then
 781   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 782 fi
 783
 784 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 785 [cat > conftest.s <<EOF
 786 ${libc_cv_dot_text}
 787 _sym:
 788 .symver _sym,sym@VERS
 789 EOF
 790 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 791   libc_cv_asm_symver_directive=yes
 792 else
 793   libc_cv_asm_symver_directive=no
 794 fi
 795 rm -f conftest*])
 796 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 797 if test $libc_cv_asm_symver_directive = yes; then
 798   cat > conftest.s <<EOF
 799 ${libc_cv_dot_text}
 800 _sym:
 801 .symver _sym,sym@VERS
 802 EOF
 803   cat > conftest.map <<EOF
 804 VERS_1 {
 805         global: sym;
 806 };
 807
 808 VERS_2 {
 809         global: sym;
 810 } VERS_1;
 811 EOF
 812   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 813     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 814                                         -nostartfiles -nostdlib
 815                                         -Wl,--version-script,conftest.map
 816                        1>&AC_FD_CC]);
 817     then
 818       libc_cv_ld_version_script_option=yes
 819     else
 820       libc_cv_ld_version_script_option=no
 821     fi
 822   else
 823     libc_cv_ld_version_script_option=no
 824   fi
 825 else
 826   libc_cv_ld_version_script_option=no
 827 fi
 828 rm -f conftest*])
 829 if test $shared != no &&
 830    test $libc_cv_asm_symver_directive = yes &&
 831    test $libc_cv_ld_version_script_option = yes &&
 832    test $enable_versioning = yes; then
 833   VERSIONING=yes
 834   AC_DEFINE(DO_VERSIONING)
 835 else
 836   VERSIONING=no
 837 fi
 838 AC_SUBST(VERSIONING)
 839
 840 if test $shared != no && test $VERSIONING = no; then
 841   echo "\
 842 *** WARNING: You should not compile GNU libc without versioning. Not using
 843 *** versioning will introduce incompatibilities so that old binaries
 844 *** will not run anymore.
 845 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 846 fi
 847 if test $elf = yes; then
 848   AC_CACHE_CHECK(for .previous assembler directive,
 849                  libc_cv_asm_previous_directive, [dnl
 850   cat > conftest.s <<EOF
 851 .section foo_section
 852 .previous
 853 EOF
 854   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 855     libc_cv_asm_previous_directive=yes
 856   else
 857     libc_cv_asm_previous_directive=no
 858   fi
 859   rm -f conftest*])
 860   if test $libc_cv_asm_previous_directive = yes; then
 861     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 862   else
 863     AC_CACHE_CHECK(for .popsection assembler directive,
 864                    libc_cv_asm_popsection_directive, [dnl
 865     cat > conftest.s <<EOF
 866 .pushsection foo_section
 867 .popsection
 868 EOF
 869     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 870       libc_cv_asm_popsection_directive=yes
 871     else
 872       libc_cv_asm_popsection_directive=no
 873     fi
 874     rm -f conftest*])
 875     if test $libc_cv_asm_popsection_directive = yes; then
 876       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 877     fi
 878   fi
 879   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 880                  libc_cv_asm_protected_directive, [dnl
 881   cat > conftest.s <<EOF
 882 .protected foo
 883 foo:
 884 .hidden bar
 885 bar:
 886 EOF
 887   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 888     libc_cv_asm_protected_directive=yes
 889   else
 890     libc_cv_asm_protected_directive=no
 891   fi
 892   rm -f conftest*])
 893   AC_SUBST(libc_cv_asm_protected_directive)
 894
 895   AC_CACHE_CHECK(for -z nodelete option,
 896                  libc_cv_z_nodelete, [dnl
 897   cat > conftest.c <<EOF
 898 int _start (void) { return 42; }
 899 EOF
 900   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
 901   then
 902     libc_cv_z_nodelete=yes
 903   else
 904     libc_cv_z_nodelete=no
 905   fi
 906   rm -f conftest*])
 907   AC_SUBST(libc_cv_z_nodelete)
 908
 909   AC_CACHE_CHECK(for -z nodlopen option,
 910                  libc_cv_z_nodlopen, [dnl
 911   cat > conftest.c <<EOF
 912 int _start (void) { return 42; }
 913 EOF
 914   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
 915   then
 916     libc_cv_z_nodlopen=yes
 917   else
 918     libc_cv_z_nodlopen=no
 919   fi
 920   rm -f conftest*])
 921   AC_SUBST(libc_cv_z_nodlopen)
 922 fi
 923
 924 if test $elf != yes; then
 925   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 926                  [AC_TRY_COMPILE(, [asm (".section .init");
 927                                     asm (".section .fini");
 928                                     asm ("${libc_cv_dot_text}");],
 929                                  libc_cv_have_initfini=yes,
 930                                  libc_cv_have_initfini=no)])
 931   AC_SUBST(libc_cv_have_initfini)dnl
 932   if test $libc_cv_have_initfini = yes; then
 933     AC_DEFINE(HAVE_INITFINI)
 934   fi
 935 fi
 936
 937 if test $elf = yes -a $gnu_ld = yes; then
 938   AC_CACHE_CHECK(whether cc puts quotes around section names,
 939                  libc_cv_have_section_quotes,
 940                  [cat > conftest.c <<EOF
 941                   static const int foo
 942                   __attribute__ ((section ("bar"))) = 1;
 943 EOF
 944                   if ${CC-cc} -S conftest.c -o conftest.s; then
 945                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
 946                       libc_cv_have_section_quotes=yes
 947                     else
 948                       libc_cv_have_section_quotes=no
 949                     fi
 950                   else
 951                     libc_cv_have_section_quotes=unknown
 952                   fi
 953                   rm -f conftest.[cs]
 954                  ])
 955   if test $libc_cv_have_section_quotes = yes; then
 956     AC_DEFINE(HAVE_SECTION_QUOTES)
 957   fi
 958 fi
 959
 960 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 961 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 962 [cat > conftest.$ac_ext <<EOF
 963 dnl This sometimes fails to find confdefs.h, for some reason.
 964 dnl [#]line __oline__ "[$]0"
 965 [#]line __oline__ "configure"
 966 #include "confdefs.h"
 967 void underscore_test(void) {
 968 return; }
 969 EOF
 970 if AC_TRY_EVAL(ac_compile); then
 971   if grep _underscore_test conftest* >/dev/null; then
 972     ifelse([$1], , :, [rm -f conftest*
 973     $1])
 974   else
 975     ifelse([$2], , , [rm -f conftest*
 976     $2])
 977   fi
 978 else
 979   echo "configure: failed program was:" >&AC_FD_CC
 980   cat conftest.$ac_ext >&AC_FD_CC
 981   ifelse([$2], , , [rm -f conftest*
 982   $2])
 983 fi
 984 rm -f conftest*])
 985
 986 if test $elf = yes; then
 987   libc_cv_asm_underscores=no
 988 else
 989   if test $ac_cv_prog_cc_works = yes; then
 990     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 991                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 992                                 libc_cv_asm_underscores=yes,
 993                                 libc_cv_asm_underscores=no)])
 994   else
 995     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 996                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 997                                             libc_cv_asm_underscores=no)])
 998   fi
 999 fi
1000 if test $libc_cv_asm_underscores = no; then
1001   AC_DEFINE(NO_UNDERSCORES)
1002 fi
1003
1004 if test $elf = yes; then
1005   libc_cv_weak_symbols=yes
1006 fi
1007
1008 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1009                [dnl
1010 cat > conftest.s <<EOF
1011 ${libc_cv_dot_text}
1012 ${libc_cv_asm_global_directive} foo
1013 foo:
1014 .weak foo
1015 .weak bar; bar = foo
1016 EOF
1017 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1018   libc_cv_asm_weak_directive=yes
1019 else
1020   libc_cv_asm_weak_directive=no
1021 fi
1022 rm -f conftest*])
1023
1024 if test $libc_cv_asm_weak_directive = no; then
1025   AC_CACHE_CHECK(for assembler .weakext directive,
1026                  libc_cv_asm_weakext_directive,
1027                  [dnl
1028 cat > conftest.s <<EOF
1029 ${libc_cv_dot_text}
1030 ${libc_cv_asm_global_directive} foo
1031 foo:
1032 .weakext bar foo
1033 .weakext baz
1034 ${libc_cv_asm_global_directive} baz
1035 baz:
1036 EOF
1037   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1038     libc_cv_asm_weakext_directive=yes
1039   else
1040     libc_cv_asm_weakext_directive=no
1041   fi
1042   rm -f conftest*])
1043
1044 fi # no .weak
1045
1046 if test $libc_cv_asm_weak_directive = yes; then
1047   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1048 elif test $libc_cv_asm_weakext_directive = yes; then
1049   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1050 fi
1051
1052 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1053 cat > conftest.c <<\EOF
1054 _start () {}
1055 int __eh_pc;
1056 __throw () {}
1057 EOF
1058 dnl No \ in command here because it ends up inside ''.
1059 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1060                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1061                             -o conftest conftest.c 1>&AC_FD_CC]); then
1062   libc_cv_ld_no_whole_archive=yes
1063 else
1064   libc_cv_ld_no_whole_archive=no
1065 fi
1066 rm -f conftest*])
1067 if test $libc_cv_ld_no_whole_archive = yes; then
1068   no_whole_archive=-Wl,--no-whole-archive
1069 fi
1070 AC_SUBST(no_whole_archive)dnl
1071
1072 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1073 cat > conftest.c <<\EOF
1074 _start () {}
1075 int __eh_pc;
1076 __throw () {}
1077 EOF
1078 dnl No \ in command here because it ends up inside ''.
1079 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1080                             -nostdlib -nostartfiles -fexceptions
1081                             -o conftest conftest.c 1>&AC_FD_CC]); then
1082   libc_cv_gcc_exceptions=yes
1083 else
1084   libc_cv_gcc_exceptions=no
1085 fi
1086 rm -f conftest*])
1087 if test $libc_cv_gcc_exceptions = yes; then
1088   exceptions=-fexceptions
1089 fi
1090 AC_SUBST(exceptions)dnl
1091
1092 if test "$base_machine" = alpha ; then
1093 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1094 cat > conftest.c <<\EOF
1095 foo () { }
1096 EOF
1097 dnl
1098 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1099 then
1100   libc_cv_gcc_alpha_ng_prefix=yes
1101 else
1102   libc_cv_gcc_alpha_ng_prefix=no
1103 fi
1104 rm -f conftest* ])
1105 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1106   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1107 else
1108   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1109 fi
1110 fi
1111
1112 if test "$host_cpu" = powerpc ; then
1113 # Check for a bug present in at least versions 2.8.x of GCC
1114 # and versions 1.0.x of EGCS.
1115 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1116 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1117                libc_cv_c_asmcr0_bug='no',
1118                libc_cv_c_asmcr0_bug='yes')])
1119 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1120   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1121 fi
1122 fi
1123
1124 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1125 [cat > conftest.c <<EOF
1126 #line __oline__ "configure"
1127 static char __EH_FRAME_BEGIN__[];
1128 _start ()
1129 {
1130 #ifdef CHECK__register_frame
1131   __register_frame (__EH_FRAME_BEGIN__);
1132   __deregister_frame (__EH_FRAME_BEGIN__);
1133 #endif
1134 #ifdef CHECK__register_frame_info
1135   __register_frame_info (__EH_FRAME_BEGIN__);
1136   __deregister_frame_info (__EH_FRAME_BEGIN__);
1137 #endif
1138 }
1139 int __eh_pc;
1140 __throw () {}
1141 /* FIXME: this is fragile.  */
1142 malloc () {}
1143 strcmp () {}
1144 strlen () {}
1145 memcpy () {}
1146 memset () {}
1147 free () {}
1148 abort () {}
1149 __bzero () {}
1150 EOF
1151 dnl No \ in command here because it ends up inside ''.
1152 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1153                             -nostdlib -nostartfiles
1154                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1155   libc_cv_gcc_dwarf2_unwind_info=static
1156 else
1157   libc_cv_gcc_dwarf2_unwind_info=no
1158 fi
1159 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1160   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1161                               -nostdlib -nostartfiles
1162                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1163     libc_cv_gcc_dwarf2_unwind_info=yes
1164   else
1165     libc_cv_gcc_dwarf2_unwind_info=no
1166   fi
1167 fi
1168 rm -f conftest*])
1169 case $libc_cv_gcc_dwarf2_unwind_info in
1170 yes)
1171   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1172   ;;
1173 static)
1174   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1175   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1176   ;;
1177 esac
1178
1179 dnl Check whether compiler understands __builtin_expect.
1180 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1181 [cat > conftest.c <<EOF
1182 #line __oline__ "configure"
1183 int foo (int a)
1184 {
1185   a = __builtin_expect (a, 10);
1186   return a == 10 ? 0 : 1;
1187 }
1188 EOF
1189 dnl No \ in command here because it ends up inside ''.
1190 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1191                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1192   libc_cv_gcc_builtin_expect=yes
1193 else
1194   libc_cv_gcc_builtin_expect=no
1195 fi
1196 rm -f conftest*])
1197 if test "$libc_cv_gcc_builtin_expect" = yes; then
1198   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1199 fi
1200
1201 dnl Check whether the compiler supports subtraction of local labels.
1202 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1203 [cat > conftest.c <<EOF
1204 changequote(,)dnl
1205 #line __oline__ "configure"
1206 int foo (int a)
1207 {
1208   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1209   void *p = &&l1 + ar[a];
1210   goto *p;
1211  l1:
1212   return 1;
1213  l2:
1214   return 2;
1215 }
1216 changequote([,])dnl
1217 EOF
1218 dnl No \ in command here because it ends up inside ''.
1219 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1220                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1221   libc_cv_gcc_subtract_local_labels=yes
1222 else
1223   libc_cv_gcc_subtract_local_labels=no
1224 fi
1225 rm -f conftest*])
1226 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1227   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1228 fi
1229
1230 dnl Check whether we have the gd library available.
1231 AC_MSG_CHECKING(for libgd)
1232 old_CFLAGS="$CFLAGS"
1233 CFLAGS="$CFLAGS $libgd_include"
1234 old_LDFLAGS="$LDFLAGS"
1235 LDFLAGS="$LDFLAGS $libgd_ldflags"
1236 old_LIBS="$LIBS"
1237 LIBS="$LIBS -lgd -lpng -lz -lm"
1238 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1239 CFLAGS="$old_CFLAGS"
1240 LDFLAGS="$old_LDFLAGS"
1241 LIBS="$old_LIBS"
1242 AC_MSG_RESULT($LIBGD)
1243 AC_SUBST(LIBGD)
1244
1245 dnl check for the size of 'long double'.
1246 AC_CHECK_SIZEOF(long double, 0)
1247 sizeof_long_double=$ac_cv_sizeof_long_double
1248 AC_SUBST(sizeof_long_double)
1249
1250 ### End of automated tests.
1251 ### Now run sysdeps configure fragments.
1252
1253 # sysdeps configure fragments may set these with files to be linked below.
1254 libc_link_dests=
1255 libc_link_sources=
1256
1257 # They also can set these variables.
1258 use_ldconfig=no
1259 ldd_rewrite_script=no
1260
1261 # Iterate over all the sysdep directories we will use, running their
1262 # configure fragments, and looking for a uname implementation.
1263 uname=
1264 for dir in $sysnames; do
1265   case $dir in
1266     /*) dest=$dir ;;
1267     *)  dest=$srcdir/$dir ;;
1268   esac
1269   if test -r $dest/configure; then
1270     AC_MSG_RESULT(running configure fragment for $dest)
1271     . $dest/configure
1272   fi
1273 [
1274   if test -z "$uname"; then
1275     if test -r $dest/uname.c ||
1276        test -r $dest/uname.S ||
1277        { test -r $dest/syscalls.list &&
1278          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1279       uname=$dir
1280     fi
1281   fi
1282 ]dnl
1283 done
1284
1285 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1286
1287 # If we will use the generic uname implementation, we must figure out what
1288 # it will say by examining the system, and write the results in config-name.h.
1289 if test "$uname" = "sysdeps/generic"; then
1290
1291 changequote(,)dnl
1292   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1293 changequote([,])dnl
1294   if test $uname_sysname != $config_os; then
1295     config_release=`echo $config_os | sed s/$uname_sysname//`
1296   fi
1297 dnl
1298 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1299     if test -r /vmunix; then
1300       kernel_id=`strings /vmunix | grep UNIX`
1301     elif test -r /dynix; then
1302       kernel_id=`strings /dynix | grep DYNIX`
1303     else
1304       kernel_id=
1305     fi
1306 ])dnl
1307
1308   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1309 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1310 changequote(,)dnl
1311   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1312 changequote([,])dnl
1313   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1314          != x$config_release; then
1315     # The configuration release is a substring of the kernel release.
1316     libc_cv_uname_release=$kernel_release
1317   elif test x$config_release != x; then
1318     libc_cv_uname_release=$config_release
1319   elif test x$kernel_release != x; then
1320     libc_cv_uname_release=$kernel_release
1321   else
1322     libc_cv_uname_release=unknown
1323   fi])
1324   uname_release="$libc_cv_uname_release"
1325
1326   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1327 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1328 changequote(,)dnl
1329   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1330 changequote([,])dnl
1331   if test -n "$kernel_version"; then
1332     libc_cv_uname_version="$kernel_version"
1333   else
1334     libc_cv_uname_version=unknown
1335   fi])
1336   uname_version="$libc_cv_uname_version"
1337
1338 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1339   config_uname=config-name.h:config-name.in
1340 else
1341   # For non-generic uname, we don't need to create config-name.h at all.
1342   config_uname=
1343 fi
1344
1345 AC_MSG_CHECKING(stdio selection)
1346 AC_SUBST(stdio)
1347 case $stdio in
1348 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1349 default) stdio=stdio ;;
1350 esac
1351 AC_MSG_RESULT($stdio)
1352
1353 # Test for old glibc 2.0.x headers so that they can be removed properly
1354 # Search only in includedir.
1355 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1356 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1357 then
1358   old_glibc_headers=yes
1359 else
1360   old_glibc_headers=no
1361 fi
1362 AC_MSG_RESULT($old_glibc_headers)
1363 if test ${old_glibc_headers} = yes; then
1364   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1365   AC_MSG_WARN(*** be removed.)
1366 fi
1367 AC_SUBST(old_glibc_headers)
1368
1369 AC_SUBST(libc_cv_slibdir)
1370 AC_SUBST(libc_cv_localedir)
1371 AC_SUBST(libc_cv_sysconfdir)
1372 AC_SUBST(libc_cv_rootsbindir)
1373
1374 AC_SUBST(use_ldconfig)
1375 AC_SUBST(ldd_rewrite_script)
1376
1377 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1378 if test $gnu_ld = yes; then
1379   AC_DEFINE(HAVE_GNU_LD)
1380 fi
1381 if test $gnu_as = yes; then
1382   AC_DEFINE(HAVE_GNU_AS)
1383 fi
1384 if test $elf = yes; then
1385   AC_DEFINE(HAVE_ELF)
1386 fi
1387
1388 AC_SUBST(static)
1389 AC_SUBST(shared)
1390 if test $shared = default; then
1391   if test $gnu_ld = yes; then
1392     shared=$elf
1393   else
1394     # For now we do not assume shared libs are available.  In future more
1395     # tests might become available.
1396     shared=no
1397   fi
1398 fi
1399
1400 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1401 [pic_default=yes
1402 cat > conftest.c <<EOF
1403 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1404 # error PIC is default.
1405 #endif
1406 EOF
1407 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1408   pic_default=no
1409 fi
1410 rm -f conftest.*])
1411 AC_SUBST(pic_default)
1412
1413 AC_SUBST(profile)
1414 AC_SUBST(omitfp)
1415 AC_SUBST(bounded)
1416 AC_SUBST(static_nss)
1417 AC_SUBST(nopic_initfini)
1418
1419 AC_SUBST(DEFINES)
1420
1421 case "$add_ons" in
1422   *door*) linux_doors=yes ;;
1423   *) linux_doors=no ;;
1424 esac
1425 AC_SUBST(linux_doors)
1426
1427 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1428   config_makefile=
1429 else
1430   config_makefile=Makefile
1431 fi
1432
1433 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1434 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1435 AC_SUBST(VERSION)
1436 AC_SUBST(RELEASE)
1437
1438 echo '*** Do NOT install this release on any production system!'
1439 echo '*** We are in early testing stages.'
1440
1441 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1442 case $CONFIG_FILES in *config.make*)
1443 echo "$config_vars" >> config.make;;
1444 esac
1445 test -d bits || mkdir bits], [config_vars='$config_vars'])