sysdeps/i386/bsd-setjmp.S

   1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
   2    Copyright (C) 1994-1997,2000,2001,2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <jmpbuf-offsets.h>
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27
  28 #define PARMS  LINKAGE          /* no space for saved regs */
  29 #define JMPBUF PARMS
  30 #define SIGMSK JMPBUF+PTR_SIZE
  31
  32 ENTRY (BP_SYM (setjmp))
  33         /* Note that we have to use a non-exported symbol in the next
  34            jump since otherwise gas will emit it as a jump through the
  35            PLT which is what we cannot use here.  */
  36         ENTER
  37
  38         movl JMPBUF(%esp), %eax
  39         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
  40
  41         /* Save registers.  */
  42         movl %ebx, (JB_BX*4)(%eax)
  43         movl %esi, (JB_SI*4)(%eax)
  44         movl %edi, (JB_DI*4)(%eax)
  45         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  46 #ifdef PTR_MANGLE
  47         PTR_MANGLE (%ecx)
  48 #endif
  49         movl %ecx, (JB_SP*4)(%eax)
  50         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  51 #ifdef PTR_MANGLE
  52         PTR_MANGLE (%ecx)
  53 #endif
  54         movl %ecx, (JB_PC*4)(%eax)
  55         LEAVE /* pop frame pointer to prepare for tail-call.  */
  56         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  57
  58         /* Call __sigjmp_save.  */
  59         pushl $1
  60         cfi_adjust_cfa_offset (4)
  61         pushl 8(%esp)
  62         cfi_adjust_cfa_offset (4)
  63         call BP_SYM (__sigjmp_save)
  64         popl %ecx
  65         cfi_adjust_cfa_offset (-4)
  66         popl %edx
  67         cfi_adjust_cfa_offset (-4)
  68         ret
  69 END (BP_SYM (setjmp))