configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware [default=yes],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66               shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69               profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  72               omitfp=$enableval, omitfp=no)
  73
  74 dnl Generic infrastructure for drop-in additions to libc.
  75 AC_ARG_ENABLE(add-ons, dnl
  76 [  --enable-add-ons=DIR... configure and build named extra directories],
  77               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  78               [add_ons=])
  79 AC_CONFIG_SUBDIRS($add_ons)
  80 add_ons_pfx=
  81 if test x"$add_ons" != x; then
  82   for f in $add_ons; do
  83     add_ons_pfx="$add_ons_pfx $f/"
  84   done
  85 fi
  86
  87 AC_CANONICAL_HOST
  88
  89 # The way shlib-versions is used to generate soversions.mk uses a
  90 # fairly simplistic model for name recognition that can't distinguish
  91 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
  92 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
  93 # tell.  This doesn't get used much beyond that, so it's fairly safe.
  94 case "$host_os" in
  95 linux*)
  96   ;;
  97 gnu*)
  98   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
  99   ;;
 100 esac
 101
 102 # We keep the original values in `$config_*' and never modify them, so we
 103 # can write them unchanged into config.make.  Everything else uses
 104 # $machine, $vendor, and $os, and changes them whenever convenient.
 105 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 106
 107 # Some configurations imply other options.
 108 case "$host_os" in
 109 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 110   # These systems always use GNU tools.
 111   gnu_ld=yes gnu_as=yes ;;
 112 esac
 113 case "$host_os" in
 114 linux*ecoff*)
 115   ;;
 116 gnu* | linux* | sysv4* | solaris2*)
 117   # These systems (almost) always use the ELF format.
 118   elf=yes
 119   ;;
 120 esac
 121
 122 machine=$config_machine
 123 vendor=$config_vendor
 124 os=$config_os
 125
 126 dnl We need to use [ and ] for other purposes for a while now.
 127 changequote(,)dnl
 128 # Expand the configuration machine name into a subdirectory by architecture
 129 # type and particular chip.
 130 case "$machine" in
 131 a29k | am29000) base_machine=a29k machine=a29k ;;
 132 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 133 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 134 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 135 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 136 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 137 m88???)         base_machine=m88k machine=m88k/$machine ;;
 138 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 139 mips*)          base_machine=mips machine=mips/$machine ;;
 140 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 141 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 142 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 143 esac
 144 changequote([,])dnl
 145 AC_SUBST(base_machine)
 146
 147 # Compute the list of sysdep directories for this configuration.
 148 # This can take a while to compute.
 149 sysdep_dir=$srcdir/sysdeps
 150 AC_MSG_CHECKING(sysdep dirs)
 151 dnl We need to use [ and ] for other purposes for a while now.
 152 changequote(,)dnl
 153 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 154 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 155
 156 case "$os" in
 157 gnu*)
 158   base_os=mach/hurd ;;
 159 netbsd* | 386bsd* | freebsd* | bsdi*)
 160   base_os=unix/bsd/bsd4.4 ;;
 161 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 162   base_os=unix/bsd ;;
 163 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 164   base_os=unix/sysv ;;
 165 solaris[2-9]*)
 166   base_os=unix/sysv/sysv4 ;;
 167 none)
 168   base_os=standalone ;;
 169 *)
 170   base_os='' ;;
 171 esac
 172
 173 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 174 tail=$os
 175 ostry=$os
 176 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 177   ostry="$ostry /$o"
 178   tail=$o
 179 done
 180 o=`echo $tail | sed 's/[0-9]*$//'`
 181 if test $o != $tail; then
 182   ostry="$ostry /$o"
 183 fi
 184 # For linux-gnu, try linux-gnu, then linux.
 185 o=`echo $tail | sed 's/-.*$//'`
 186 if test $o != $tail; then
 187   ostry="$ostry /$o"
 188 fi
 189
 190 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 191 base=
 192 tail=$base_os
 193 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 194   set $b
 195   base="$base /$1"
 196   tail="$2"
 197 done
 198
 199 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 200 mach=
 201 tail=$machine
 202 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 203   set $m
 204   # Prepend the machine's FPU directory unless --without-fp.
 205   if test "$with_fp" = yes; then
 206     mach="$mach /$1/fpu"
 207   fi
 208   mach="$mach /$1"
 209   tail="$2"
 210 done
 211
 212 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 213 changequote([,])dnl
 214
 215 # Find what sysdep directories exist.
 216 sysnames=
 217 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 218 for d in $add_ons_pfx ''; do
 219   for b in $base ''; do
 220     for m0 in $mach ''; do
 221       for v in /$vendor ''; do
 222         for o in /$ostry ''; do
 223           for m in $mach ''; do
 224             if test "$m0$b$v$o$m"; then
 225               try="${d}sysdeps$m0$b$v$o$m"
 226               test -n "$enable_debug_configure" &&
 227               echo "$0 [DEBUG]: try $try" >&2
 228               case $try in
 229                 /*) dest=$try ;;
 230                 *)  dest=$srcdir/$try ;;
 231               esac
 232               if test -d $dest; then
 233                 sysnames="$sysnames $try"
 234                 { test -n "$o" || test -n "$b"; } && os_used=t
 235                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 236               fi
 237             fi
 238           done
 239         done
 240       done
 241     done
 242   done
 243 done
 244 IFS="$ac_save_ifs"
 245
 246 if test -z "$os_used" && test "$os" != none; then
 247   AC_MSG_ERROR(Operating system $os is not supported.)
 248 fi
 249 if test -z "$machine_used" && test "$machine" != none; then
 250   AC_MSG_ERROR(The $machine is not supported.)
 251 fi
 252
 253 # We have now validated the configuration.
 254
 255
 256 # If using ELF, look for an `elf' subdirectory of each machine directory.
 257 # We prepend these rather than inserting them whereever the machine appears
 258 # because things specified by the machine's ELF ABI should override
 259 # OS-specific things, and should always be the same for any OS on the
 260 # machine (otherwise what's the point of an ABI?).
 261 if test "$elf" = yes; then
 262   elf_dirs=
 263   for d in $add_ons_pfx ''; do
 264     case $d in
 265       /*) xsrcdir= ;;
 266       *)  xsrcdir=$srcdir/ ;;
 267     esac
 268     for m in $mach; do
 269       if test -d $xsrcdir${d}sysdeps$m/elf; then
 270         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 271       fi
 272     done
 273   done
 274   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 275 fi
 276
 277
 278 # Expand the list of system names into a full list of directories
 279 # from each element's parent name and Implies file (if present).
 280 set $sysnames
 281 names=
 282 while test $# -gt 0; do
 283   name=$1
 284   shift
 285
 286   case " $names " in *" $name "*)
 287     # Already in the list.
 288     continue
 289   esac
 290
 291   # Report each name as we discover it, so there is no long pause in output.
 292   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 293
 294   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 295
 296   case $name in
 297     /*) xsrcdir= ;;
 298     *)  xsrcdir=$srcdir/ ;;
 299   esac
 300   test -n "$enable_debug_configure" &&
 301   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 302
 303   if test -f $xsrcdir$name/Implies; then
 304     # Collect more names from the `Implies' file (removing comments).
 305     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 306     implied=
 307     for x in $implied_candidate; do
 308       if test -d $xsrcdir$name_base/$x; then
 309         implied="$implied $name_base/$x";
 310       else
 311         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 312       fi
 313     done
 314   else
 315     implied=
 316   fi
 317
 318   # Add NAME to the list of names.
 319   names="$names $name"
 320
 321   # Find the parent of NAME, using the empty string if it has none.
 322 changequote(,)dnl
 323   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 324 changequote([,])dnl
 325
 326   # Add the names implied by NAME, and NAME's parent (if it has one), to
 327   # the list of names to be processed (the argument list).  We prepend the
 328   # implied names to the list and append the parent.  We want implied
 329   # directories to come before further directories inferred from the
 330   # configuration components; this ensures that for sysv4, unix/common
 331   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 332   # after sysv4).
 333   sysnames="`echo $implied $* $parent`"
 334   test -n "$sysnames" && set $sysnames
 335 done
 336
 337 # Add the default directories.
 338 sysnames="$names sysdeps/generic sysdeps/stub"
 339 AC_SUBST(sysnames)
 340 # The other names were emitted during the scan.
 341 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 342
 343
 344 ### Locate tools.
 345
 346 AC_PROG_INSTALL
 347 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 348   # The makefiles need to use a different form to find it in $srcdir.
 349   INSTALL='$(..)./install-sh -c'
 350 fi
 351 AC_PROG_LN_S
 352 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 353
 354 AC_CHECK_TOOL(CC, gcc)
 355 if test $host != $build; then
 356   AC_CHECK_PROG(BUILD_CC, gcc cc)
 357 fi
 358 AC_PROG_CPP
 359 AC_CHECK_TOOL(AR, ar)
 360 AC_CHECK_TOOL(RANLIB, ranlib, :)
 361
 362 AC_PATH_PROG(BASH, bash, no)
 363 if test "$BASH" != no && $BASH -c 'test "$BASH_VERSINFO" -ge 2'; then
 364   libc_cv_have_bash2=yes
 365 else
 366   libc_cv_have_bash2=no
 367 fi
 368 AC_SUBST(libc_cv_have_bash2)
 369
 370 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 371 echo '#include <stddef.h>
 372 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 373 if eval "$ac_cpp conftest.c 2>/dev/null" \
 374 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 375   libc_cv_signed_size_t=no
 376 else
 377   libc_cv_signed_size_t=yes
 378 fi
 379 rm -f conftest*])
 380 if test $libc_cv_signed_size_t = yes; then
 381   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 382   cat >> confdefs.h <<\EOF
 383 #undef __SIZE_TYPE__
 384 #define __SIZE_TYPE__ unsigned
 385 EOF
 386 fi
 387
 388 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 389 AC_TRY_COMPILE(dnl
 390 [#define __need_size_t
 391 #define __need_wchar_t
 392 #include <stddef.h>
 393 #define __need_NULL
 394 #include <stddef.h>], [size_t size; wchar_t wchar;
 395 #ifdef offsetof
 396 #error stddef.h ignored __need_*
 397 #endif
 398 if (&size == NULL || &wchar == NULL) abort ();],
 399                libc_cv_friendly_stddef=yes,
 400                libc_cv_friendly_stddef=no)])
 401 if test $libc_cv_friendly_stddef = yes; then
 402   config_vars="$config_vars
 403 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 404 fi
 405
 406 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 407                libc_cv_need_minus_P, [dnl
 408 cat > conftest.S <<EOF
 409 #include "confdefs.h"
 410 /* Nothing whatsoever.  */
 411 EOF
 412 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 413   libc_cv_need_minus_P=no
 414 else
 415   libc_cv_need_minus_P=yes
 416 fi
 417 rm -f conftest*])
 418 if test $libc_cv_need_minus_P = yes; then
 419   config_vars="$config_vars
 420 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 421 fi
 422
 423 AC_CACHE_CHECK(for assembler global-symbol directive,
 424                libc_cv_asm_global_directive, [dnl
 425 libc_cv_asm_global_directive=UNKNOWN
 426 for ac_globl in .globl .global; do
 427   cat > conftest.s <<EOF
 428 .text
 429 ${ac_globl} foo
 430 foo: .long 0
 431 EOF
 432   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 433     libc_cv_asm_global_directive=${ac_globl}
 434   fi
 435   rm -f conftest*
 436   test $libc_cv_asm_global_directive != UNKNOWN && break
 437 done])
 438 if test $libc_cv_asm_global_directive = UNKNOWN; then
 439   AC_MSG_ERROR(cannot determine asm global directive)
 440 else
 441   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 442 fi
 443
 444 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 445 cat > conftest.s <<EOF
 446 .text
 447 foo: .long 0
 448 .set glibc_conftest_frobozz,foo
 449 $libc_cv_asm_global_directive glibc_conftest_frobozz
 450 EOF
 451 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 452 # (but it doesn't work), so we must do a linking check to be sure.
 453 cat > conftest1.c <<\EOF
 454 extern int glibc_conftest_frobozz;
 455 main () { printf ("%d\n", glibc_conftest_frobozz); }
 456 EOF
 457 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 458             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 459   libc_cv_asm_set_directive=yes
 460 else
 461   libc_cv_asm_set_directive=no
 462 fi
 463 rm -f conftest*])
 464 if test $libc_cv_asm_set_directive = yes; then
 465   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 466 fi
 467
 468 if test $elf != yes; then
 469   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 470                  [AC_TRY_COMPILE(, [asm (".section .init");
 471                                     asm (".section .fini");
 472                                     asm (".text");],
 473                                  libc_cv_have_initfini=yes,
 474                                  libc_cv_have_initfini=no)])
 475   AC_SUBST(libc_cv_have_initfini)dnl
 476   if test $libc_cv_have_initfini = yes; then
 477     AC_DEFINE(HAVE_INITFINI)
 478   fi
 479 fi
 480
 481 if test $elf = yes; then
 482   libc_cv_asm_underscores=no
 483 else
 484   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 485                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 486                               libc_cv_asm_underscores=yes,
 487                               libc_cv_asm_underscores=no)])
 488 fi
 489 if test $libc_cv_asm_underscores = no; then
 490   AC_DEFINE(NO_UNDERSCORES)
 491 fi
 492
 493 if test $elf = yes; then
 494   libc_cv_weak_symbols=yes
 495   libc_cv_asm_weak_directive=yes
 496   libc_cv_asm_weakext_directive=no
 497 else
 498   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 499                  [dnl
 500 cat > conftest.s <<EOF
 501 .text
 502 ${libc_cv_asm_global_directive} foo
 503 foo: .long 0
 504 .weak foo
 505 .weak bar; bar = foo
 506 EOF
 507   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 508     libc_cv_asm_weak_directive=yes
 509   else
 510     libc_cv_asm_weak_directive=no
 511   fi
 512   rm -f conftest*])
 513
 514 if test $libc_cv_asm_weak_directive = no; then
 515   AC_CACHE_CHECK(for assembler .weakext directive,
 516                  libc_cv_asm_weakext_directive,
 517                  [dnl
 518 cat > conftest.s <<EOF
 519 .text
 520 ${libc_cv_asm_global_directive} foo
 521 foo: .long 0
 522 .weakext foo
 523 .weakext foo, bar
 524 EOF
 525   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 526     libc_cv_asm_weakext_directive=yes
 527   else
 528     libc_cv_asm_weakext_directive=no
 529   fi
 530   rm -f conftest*])
 531
 532   fi # no .weak
 533 fi # not ELF
 534
 535 if test $libc_cv_asm_weak_directive = yes; then
 536   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 537 elif test $libc_cv_asm_weakext_directive = yes; then
 538   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 539 fi
 540
 541 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 542 cat > conftest.c <<\EOF
 543 _start () {}
 544 int __eh_pc;
 545 __throw () {}
 546 EOF
 547 dnl No \ in command here because it ends up inside ''.
 548 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 549                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 550                             -o conftest conftest.c]); then
 551   libc_cv_ld_no_whole_archive=yes
 552 else
 553   libc_cv_ld_no_whole_archive=no
 554 fi
 555 rm -f conftest*])
 556 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 557
 558 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 559 cat > conftest.c <<\EOF
 560 _start () {}
 561 int __eh_pc;
 562 __throw () {}
 563 EOF
 564 dnl No \ in command here because it ends up inside ''.
 565 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 566                             -nostdlib -nostartfiles -fno-exceptions
 567                             -o conftest conftest.c]); then
 568   libc_cv_gcc_no_exceptions=yes
 569 else
 570   libc_cv_gcc_no_exceptions=no
 571 fi
 572 rm -f conftest*])
 573 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 574
 575 ### End of automated tests.
 576 ### Now run sysdeps configure fragments.
 577
 578 # sysdeps configure fragments may set these with files to be linked below.
 579 libc_link_dests=
 580 libc_link_sources=
 581
 582 # Iterate over all the sysdep directories we will use, running their
 583 # configure fragments, and looking for a uname implementation.
 584 uname=
 585 for dir in $sysnames; do
 586   case $dir in
 587     /*) dest=$dir ;;
 588     *)  dest=$srcdir/$dir ;;
 589   esac
 590   if test -r $dest/configure; then
 591     AC_MSG_RESULT(running configure fragment for $dest)
 592     . $dest/configure
 593   fi
 594 [
 595   if test -z "$uname"; then
 596     if test -r $sysdep_dir/$dir/uname.c ||
 597        test -r $sysdep_dir/$dir/uname.S ||
 598        { test -r $sysdep_dir/$dir/syscalls.list &&
 599          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 600       uname=$dir
 601     fi
 602   fi
 603 ]dnl
 604 done
 605
 606 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 607
 608 # If we will use the generic uname implementation, we must figure out what
 609 # it will say by examining the system, and write the results in config-name.h.
 610 if test "$uname" = generic; then
 611
 612 changequote(,)dnl
 613   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 614 changequote([,])dnl
 615   if test $uname_sysname != $config_os; then
 616     config_release=`echo $config_os | sed s/$uname_sysname//`
 617   fi
 618 dnl
 619 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 620     if test -r /vmunix; then
 621       kernel_id=`strings /vmunix | grep UNIX`
 622     elif test -r /dynix; then
 623       kernel_id=`strings /dynix | grep DYNIX`
 624     else
 625       kernel_id=
 626     fi
 627 ])dnl
 628
 629   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 630 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 631 changequote(,)dnl
 632   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 633 changequote([,])dnl
 634   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 635          != x$config_release; then
 636     # The configuration release is a substring of the kernel release.
 637     libc_cv_uname_release=$kernel_release
 638   elif test x$config_release != x; then
 639     libc_cv_uname_release=$config_release
 640   elif test x$kernel_release != x; then
 641     libc_cv_uname_release=$kernel_release
 642   else
 643     libc_cv_uname_release=unknown
 644   fi])
 645   uname_release="$libc_cv_uname_release"
 646
 647   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 648 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 649 changequote(,)dnl
 650   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 651 changequote([,])dnl
 652   if test -n "$kernel_version"; then
 653     libc_cv_uname_version="$kernel_version"
 654   else
 655     libc_cv_uname_version=unknown
 656   fi])
 657   uname_version="$libc_cv_uname_version"
 658
 659 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 660   config_uname=config-name.h:config-name.in
 661 else
 662   # For non-generic uname, we don't need to create config-name.h at all.
 663   config_uname=
 664 fi
 665
 666 AC_MSG_CHECKING(stdio selection)
 667 AC_SUBST(stdio)
 668 case $stdio in
 669 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 670 default) stdio=stdio ;;
 671 esac
 672 AC_MSG_RESULT($stdio)
 673
 674 AC_SUBST(libc_cv_slibdir)
 675 AC_SUBST(libc_cv_sysconfdir)
 676
 677 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 678 if test $gnu_ld = yes; then
 679   AC_DEFINE(HAVE_GNU_LD)
 680 fi
 681 if test $gnu_as = yes; then
 682   AC_DEFINE(HAVE_GNU_AS)
 683 fi
 684 if test $elf = yes; then
 685   AC_DEFINE(HAVE_ELF)
 686 fi
 687
 688 AC_SUBST(shared)
 689 if test $shared = default; then
 690   if test $gnu_ld = yes; then
 691     shared=$elf
 692   fi
 693 fi
 694 AC_SUBST(profile)
 695 AC_SUBST(omitfp)
 696
 697 AC_SUBST(DEFINES)
 698
 699 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 700   config_makefile=
 701 else
 702   config_makefile=Makefile
 703 fi
 704
 705 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 706           [echo '$config_vars' >> config.make])