sysdeps/ia64/fpu/s_truncf.S

   1 .file "truncf.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  39 //
  40 // History
  41 //==============================================================
  42 // 07/07/00 Created
  43 // 05/20/02 Cleaned up namespace and sf0 syntax
  44 // 01/20/03 Improved performance and reduced code size
  45 //==============================================================
  46
  47 // API
  48 //==============================================================
  49 // float truncf(float x)
  50 //==============================================================
  51
  52 // general input registers:
  53 // r14 - r18
  54
  55 rExpBias   = r14
  56 rSignexp   = r15
  57 rExp       = r16
  58 rExpMask   = r17
  59 rBigexp    = r18
  60
  61 // floating-point registers:
  62 // f8 - f10
  63
  64 fXtruncInt = f9
  65 fNormX     = f10
  66
  67 // predicate registers used:
  68 // p6, p7
  69
  70 // Overview of operation
  71 //==============================================================
  72 // float truncf(float x)
  73 // Return an integer value (represented as a float) less than or
  74 // equal to x in magnitude.
  75 // This is x rounded toward zero to an integral value.
  76 //==============================================================
  77
  78 // double_extended
  79 // if the exponent is > 1003e => 3F(true) = 63(decimal)
  80 // we have a significand of 64 bits 1.63-bits.
  81 // If we multiply by 2^63, we no longer have a fractional part
  82 // So input is an integer value already.
  83
  84 // double
  85 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  86 // 34 + 3ff = 433
  87 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  88 // If we multiply by 2^52, we no longer have a fractional part
  89 // So input is an integer value already.
  90
  91 // single
  92 // if the exponent is > 10016 => 17(true) = 23(decimal)
  93 // we have a significand of 24 bits 1.23-bits. (implicit 1)
  94 // If we multiply by 2^23, we no longer have a fractional part
  95 // So input is an integer value already.
  96
  97 .section .text
  98 GLOBAL_LIBM_ENTRY(truncf)
  99
 100 { .mfi
 101       getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
 102       fcvt.fx.trunc.s1 fXtruncInt  = f8      // Convert to int in significand
 103       addl             rBigexp = 0x10016, r0 // Set exponent at which is integer
 104 }
 105 { .mfi
 106       mov              rExpBias    = 0x0FFFF // Form exponent bias
 107       fnorm.s1         fNormX  = f8          // Normalize input
 108       mov              rExpMask    = 0x1FFFF // Form exponent mask
 109 }
 110 ;;
 111
 112 { .mfi
 113       nop.m            0
 114       fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
 115       nop.i            0
 116 }
 117 ;;
 118
 119 { .mfb
 120       nop.m            0
 121       fclass.m         p6,p0 = f8, 0x1e3     // Test x natval, nan, inf
 122 (p7)  br.cond.spnt     TRUNC_UNORM           // Branch if x unorm
 123 }
 124 ;;
 125
 126 TRUNC_COMMON:
 127 // Return here from TRUNC_UNORM
 128 { .mfb
 129       and              rExp = rSignexp, rExpMask // Get biased exponent
 130 (p6)  fma.s.s0         f8 = f8, f1, f0       // Result if x natval, nan, inf
 131 (p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf
 132 }
 133 ;;
 134
 135 { .mfi
 136       cmp.lt           p6,p0 = rExp, rExpBias // Is |x| < 1?
 137       fcvt.xf          f8 = fXtruncInt        // Result, assume 1 <= |x| < 2^23
 138       cmp.ge           p7,p0 = rExp, rBigexp  // Is |x| >= 2^23?
 139 }
 140 ;;
 141
 142 // We must correct result if |x| < 1, or |x| >= 2^23
 143 .pred.rel "mutex",p6,p7
 144 { .mfi
 145       nop.m            0
 146 (p6)  fmerge.s         f8 = fNormX, f0        // If |x| < 1, result sgn(x)*0
 147       nop.i            0
 148 }
 149 { .mfb
 150       nop.m            0
 151 (p7)  fma.s.s0         f8 = fNormX, f1, f0    // If |x| >= 2^23, result x
 152       br.ret.sptk      b0                     // Exit main path
 153 }
 154 ;;
 155
 156
 157 TRUNC_UNORM:
 158 // Here if x unorm
 159 { .mfb
 160       getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
 161       fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
 162       br.cond.sptk     TRUNC_COMMON           // Return to main path
 163 }
 164 ;;
 165
 166 GLOBAL_LIBM_END(truncf)