| blob | 64be29d87777bbede92507f25e8b484cafb0ae1b |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
4 [glibc], [https://www.gnu.org/software/glibc/])
5 AC_CONFIG_SRCDIR([include/features.h])
6 AC_CONFIG_HEADERS([config.h])
7 AC_CONFIG_AUX_DIR([scripts])
9 ACX_PKGVERSION([GNU libc])
10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
12 [Package description])
13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
14 [Bug reporting address])
16 # Glibc should not depend on any header files
17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
18 [m4_divert_text([DEFAULTS],
19 [ac_includes_default='/* none */'])])
21 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
22 # here to work around the Autoconf issue discussed in
23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
24 AC_DEFUN([AC_PROG_CPP],
25 [AC_REQUIRE([AC_PROG_CC])dnl
26 AC_ARG_VAR([CPP], [C preprocessor])dnl
27 _AC_ARG_VAR_CPPFLAGS()dnl
28 # On Suns, sometimes $CPP names a directory.
29 if test -n "$CPP" && test -d "$CPP"; then
30 CPP=
31 fi
32 if test -z "$CPP"; then
33 CPP="$CC -E"
34 fi
35 AC_SUBST(CPP)dnl
36 ])# AC_PROG_CPP
38 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
39 # issue discussed in
40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
43 dnl This is here so we can set $subdirs directly based on configure fragments.
44 AC_CONFIG_SUBDIRS()
46 AC_CANONICAL_HOST
48 AC_PROG_CC
49 if test $host != $build; then
50 AC_CHECK_PROGS(BUILD_CC, gcc cc)
51 fi
52 AC_SUBST(cross_compiling)
53 AC_PROG_CPP
54 AC_CHECK_TOOL(READELF, readelf, false)
56 # We need the C++ compiler only for testing.
57 AC_PROG_CXX
58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
60 AC_LANG_PUSH([C++])
61 # Default, dynamic case.
62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
63 [libc_cv_cxx_link_ok=yes],
64 [libc_cv_cxx_link_ok=no])
65 # Static case.
66 old_LDFLAGS="$LDFLAGS"
67 LDFLAGS="$LDFLAGS -static"
68 AC_LINK_IFELSE([AC_LANG_SOURCE([
69 #include <iostream>
71 int
72 main()
73 {
74 std::cout << "Hello, world!";
75 return 0;
76 }
77 ])],
78 [],
79 [libc_cv_cxx_link_ok=no])
80 LDFLAGS="$old_LDFLAGS"
81 AC_LANG_POP([C++])])
82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
85 AC_MSG_ERROR([you must configure in a separate build directory])
86 fi
88 # This will get text that should go into config.make.
89 config_vars=
91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
92 AC_ARG_WITH([gd],
93 AS_HELP_STRING([--with-gd=DIR],
94 [find libgd include dir and library with prefix DIR]),
95 [dnl
96 case "$with_gd" in
97 yes|''|no) ;;
98 *) libgd_include="-I$withval/include"
99 libgd_ldflags="-L$withval/lib" ;;
100 esac
101 ])
102 AC_ARG_WITH([gd-include],
103 AS_HELP_STRING([--with-gd-include=DIR],
104 [find libgd include files in DIR]),
105 [dnl
106 case "$with_gd_include" in
107 ''|no) ;;
108 *) libgd_include="-I$withval" ;;
109 esac
110 ])
111 AC_ARG_WITH([gd-lib],
112 AS_HELP_STRING([--with-gd-lib=DIR],
113 [find libgd library files in DIR]),
114 [dnl
115 case "$with_gd_lib" in
116 ''|no) ;;
117 *) libgd_ldflags="-L$withval" ;;
118 esac
119 ])
121 if test -n "$libgd_include"; then
122 config_vars="$config_vars
123 CFLAGS-memusagestat.c = $libgd_include"
124 fi
125 if test -n "$libgd_ldflags"; then
126 config_vars="$config_vars
127 libgd-LDFLAGS = $libgd_ldflags"
128 fi
130 dnl Arguments to specify presence of other packages/features.
131 AC_ARG_WITH([binutils],
132 AS_HELP_STRING([--with-binutils=PATH],
133 [specify location of binutils (as and ld)]),
134 [path_binutils=$withval],
135 [path_binutils=''])
136 AC_ARG_WITH([selinux],
137 AS_HELP_STRING([--with-selinux],
138 [if building with SELinux support]),
139 [with_selinux=$withval],
140 [with_selinux=auto])
142 AC_ARG_WITH([headers],
143 AS_HELP_STRING([--with-headers=PATH],
144 [location of system headers to use
145 (for example /usr/src/linux/include)
146 @<:@default=compiler default@:>@]),
147 [sysheaders=$withval],
148 [sysheaders=''])
149 AC_SUBST(sysheaders)
151 AC_SUBST(use_default_link)
152 AC_ARG_WITH([default-link],
153 AS_HELP_STRING([--with-default-link],
154 [do not use explicit linker scripts]),
155 [use_default_link=$withval],
156 [use_default_link=default])
158 dnl Additional build flags injection.
159 AC_ARG_WITH([nonshared-cflags],
160 AS_HELP_STRING([--with-nonshared-cflags=CFLAGS],
161 [build nonshared libraries with additional CFLAGS]),
162 [extra_nonshared_cflags=$withval],
163 [extra_nonshared_cflags=])
164 AC_SUBST(extra_nonshared_cflags)
166 AC_ARG_ENABLE([sanity-checks],
167 AS_HELP_STRING([--disable-sanity-checks],
168 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
169 [enable_sanity=$enableval],
170 [enable_sanity=yes])
172 AC_ARG_ENABLE([shared],
173 AS_HELP_STRING([--enable-shared],
174 [build shared library @<:@default=yes if GNU ld@:>@]),
175 [shared=$enableval],
176 [shared=yes])
177 AC_ARG_ENABLE([profile],
178 AS_HELP_STRING([--enable-profile],
179 [build profiled library @<:@default=no@:>@]),
180 [profile=$enableval],
181 [profile=no])
182 AC_ARG_ENABLE([static-pie],
183 AS_HELP_STRING([--enable-static-pie],
184 [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
185 [static_pie=$enableval],
186 [static_pie=no])
187 AC_ARG_ENABLE([timezone-tools],
188 AS_HELP_STRING([--disable-timezone-tools],
189 [do not install timezone tools @<:@default=install@:>@]),
190 [enable_timezone_tools=$enableval],
191 [enable_timezone_tools=yes])
192 AC_SUBST(enable_timezone_tools)
194 AC_ARG_ENABLE([hardcoded-path-in-tests],
195 AS_HELP_STRING([--enable-hardcoded-path-in-tests],
196 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
197 [hardcoded_path_in_tests=$enableval],
198 [hardcoded_path_in_tests=no])
199 AC_SUBST(hardcoded_path_in_tests)
201 AC_ARG_ENABLE([stackguard-randomization],
202 AS_HELP_STRING([--enable-stackguard-randomization],
203 [initialize __stack_chk_guard canary with a random number at program start]),
204 [enable_stackguard_randomize=$enableval],
205 [enable_stackguard_randomize=no])
206 if test "$enable_stackguard_randomize" = yes; then
207 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
208 fi
210 AC_ARG_ENABLE([hidden-plt],
211 AS_HELP_STRING([--disable-hidden-plt],
212 [do not hide internal function calls to avoid PLT]),
213 [hidden=$enableval],
214 [hidden=yes])
215 if test "x$hidden" = xno; then
216 AC_DEFINE(NO_HIDDEN)
217 fi
219 AC_ARG_ENABLE([bind-now],
220 AS_HELP_STRING([--enable-bind-now],
221 [disable lazy relocations in DSOs]),
222 [bindnow=$enableval],
223 [bindnow=no])
224 AC_SUBST(bindnow)
225 if test "x$bindnow" = xyes; then
226 AC_DEFINE(BIND_NOW)
227 fi
229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
230 dnl -fstack-protector-strong.
231 AC_ARG_ENABLE([stack-protector],
232 AS_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
233 [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
234 [enable_stack_protector=$enableval],
235 [enable_stack_protector=no])
236 case "$enable_stack_protector" in
237 all|yes|no|strong) ;;
238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
239 esac
241 dnl On some platforms we cannot use dynamic loading. We must provide
242 dnl static NSS modules.
243 AC_ARG_ENABLE([static-nss],
244 AS_HELP_STRING([--enable-static-nss],
245 [build static NSS modules @<:@default=no@:>@]),
246 [static_nss=$enableval],
247 [static_nss=no])
248 dnl Enable static NSS also if we build no shared objects.
249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
250 static_nss=yes
251 AC_DEFINE(DO_STATIC_NSS)
252 fi
254 AC_ARG_ENABLE([force-install],
255 AS_HELP_STRING([--disable-force-install],
256 [don't force installation of files from this package, even if they are older than the installed files]),
257 [force_install=$enableval],
258 [force_install=yes])
259 AC_SUBST(force_install)
261 AC_ARG_ENABLE([maintainer-mode],
262 AS_HELP_STRING([--enable-maintainer-mode],
263 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
264 [maintainer=$enableval],
265 [maintainer=no])
267 dnl On some platforms we allow dropping compatibility with all kernel
268 dnl versions.
269 AC_ARG_ENABLE([kernel],
270 AS_HELP_STRING([--enable-kernel=VERSION],
271 [compile for compatibility with kernel not older than VERSION]),
272 [minimum_kernel=$enableval],
273 [])
274 dnl Prevent unreasonable values.
275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
276 # Better nothing than this.
277 minimum_kernel=""
278 else
279 if test "$minimum_kernel" = current; then
280 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
281 fi
282 fi
284 dnl For the development we sometimes want gcc to issue even more warnings.
285 dnl This is not the default since many of the extra warnings are not
286 dnl appropriate.
287 AC_ARG_ENABLE([all-warnings],
288 AS_HELP_STRING([--enable-all-warnings],
289 [enable all useful warnings gcc can issue]),
290 [all_warnings=$enableval],
291 [])
292 AC_SUBST(all_warnings)
294 AC_ARG_ENABLE([werror],
295 AS_HELP_STRING([--disable-werror],
296 [do not build with -Werror]),
297 [enable_werror=$enableval],
298 [enable_werror=yes])
299 AC_SUBST(enable_werror)
301 AC_ARG_ENABLE([multi-arch],
302 AS_HELP_STRING([--enable-multi-arch],
303 [enable single DSO with optimizations for multiple architectures]),
304 [multi_arch=$enableval],
305 [multi_arch=default])
307 AC_ARG_ENABLE([experimental-malloc],
308 AS_HELP_STRING([--disable-experimental-malloc],
309 [disable experimental malloc features]),
310 [experimental_malloc=$enableval],
311 [experimental_malloc=yes])
312 AC_SUBST(experimental_malloc)
314 AC_ARG_ENABLE([memory-tagging],
315 AS_HELP_STRING([--enable-memory-tagging],
316 [enable memory tagging if supported by the architecture @<:@default=no@:>@]),
317 [memory_tagging=$enableval],
318 [memory_tagging=no])
319 if test "$memory_tagging" = yes; then
320 # Only enable this on architectures that support it.
321 case $host_cpu in
322 aarch64)
323 AC_DEFINE(USE_MTAG)
324 ;;
325 esac
326 fi
327 AC_SUBST(memory_tagging)
329 AC_ARG_ENABLE([crypt],
330 AS_HELP_STRING([--disable-crypt],
331 [do not build nor install the passphrase hashing library, libcrypt]),
332 [build_crypt=$enableval],
333 [build_crypt=yes])
334 AC_SUBST(build_crypt)
336 AC_ARG_ENABLE([nss-crypt],
337 AS_HELP_STRING([--enable-nss-crypt],
338 [enable libcrypt to use nss]),
339 [nss_crypt=$enableval],
340 [nss_crypt=no])
341 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
342 AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
343 nss_crypt=no
344 fi
345 if test x$nss_crypt = xyes; then
346 nss_includes=-I$(nss-config --includedir 2>/dev/null)
347 if test $? -ne 0; then
348 AC_MSG_ERROR([cannot find include directory with nss-config])
349 fi
350 nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
351 if test $? -ne 0; then
352 AC_MSG_ERROR([cannot find include directory with nspr-config])
353 fi
354 old_CFLAGS="$CFLAGS"
355 CFLAGS="$CFLAGS $nss_includes $nspr_includes"
356 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
357 #include <hasht.h>
358 #include <nsslowhash.h>
359 void f (void) { NSSLOW_Init (); }])],
360 libc_cv_nss_crypt=yes,
361 AC_MSG_ERROR([
362 cannot find NSS headers with lowlevel hash function interfaces]))
363 old_LIBS="$LIBS"
364 old_LDFLAGS="$LDFLAGS"
365 LIBS="$LIBS -lfreebl3"
366 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
367 #include <hasht.h>
368 #include <nsslowhash.h>],
369 [NSSLOW_Init();])],
370 libc_cv_nss_crypt=yes,
371 AC_MSG_ERROR([
372 cannot link program using lowlevel NSS hash functions]))
373 # Check to see if there is a static NSS cryptographic library.
374 # If there isn't then we can't link anything with libcrypt.a,
375 # and that might mean disabling some static tests.
376 LDFLAGS="$LDFLAGS -static"
377 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
378 #include <hasht.h>
379 #include <nsslowhash.h>],
380 [NSSLOW_Init();])],
381 libc_cv_static_nss_crypt=yes,
382 libc_cv_static_nss_crypt=no)
383 LDFLAGS="$old_LDFLAGS"
384 CFLAGS="$old_CFLAGS"
385 LIBS="$old_LIBS"
386 else
387 libc_cv_nss_crypt=no
388 libc_cv_static_nss_crypt=no
389 fi
390 AC_SUBST(libc_cv_nss_crypt)
391 AC_SUBST(libc_cv_static_nss_crypt)
394 AC_ARG_ENABLE([systemtap],
395 [AS_HELP_STRING([--enable-systemtap],
396 [enable systemtap static probe points @<:@default=no@:>@])],
397 [systemtap=$enableval],
398 [systemtap=no])
399 if test "x$systemtap" != xno; then
400 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
401 old_CFLAGS="$CFLAGS"
402 CFLAGS="-std=gnu11 $CFLAGS"
403 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
404 void foo (int i, void *p)
405 {
406 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
407 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
408 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
409 CFLAGS="$old_CFLAGS"])
410 if test $libc_cv_sdt = yes; then
411 AC_DEFINE([USE_STAP_PROBE])
412 elif test "x$systemtap" != xauto; then
413 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
414 fi
415 fi
417 AC_ARG_ENABLE([build-nscd],
418 [AS_HELP_STRING([--disable-build-nscd],
419 [disable building and installing the nscd daemon])],
420 [build_nscd=$enableval],
421 [build_nscd=default])
422 AC_SUBST(build_nscd)
424 # Note the use of $use_nscd is near the bottom of the file.
425 AC_ARG_ENABLE([nscd],
426 [AS_HELP_STRING([--disable-nscd],
427 [library functions will not contact the nscd daemon])],
428 [use_nscd=$enableval],
429 [use_nscd=yes])
431 AC_ARG_ENABLE([pt_chown],
432 [AS_HELP_STRING([--enable-pt_chown],
433 [Enable building and installing pt_chown])],
434 [build_pt_chown=$enableval],
435 [build_pt_chown=no])
436 AC_SUBST(build_pt_chown)
437 if test "$build_pt_chown" = yes; then
438 AC_DEFINE(HAVE_PT_CHOWN)
439 fi
441 AC_ARG_ENABLE([tunables],
442 [AS_HELP_STRING([--enable-tunables],
443 [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
444 [have_tunables=$enableval],
445 [have_tunables=yes])
446 AC_SUBST(have_tunables)
447 if test "$have_tunables" = yes; then
448 AC_DEFINE(HAVE_TUNABLES)
449 fi
451 # The abi-tags file uses a fairly simplistic model for name recognition that
452 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
453 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
454 # This doesn't get used much beyond that, so it's fairly safe.
455 case "$host_os" in
456 linux*)
457 ;;
458 gnu*)
459 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
460 ;;
461 esac
463 AC_ARG_ENABLE([mathvec],
464 [AS_HELP_STRING([--enable-mathvec],
465 [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
466 [build_mathvec=$enableval],
467 [build_mathvec=notset])
469 AC_TRY_COMPILE([], [
470 #ifndef __CET__
471 # error no CET compiler support
472 #endif],
473 [libc_cv_compiler_default_cet=yes],
474 [libc_cv_compiler_default_cet=no])
476 AC_ARG_ENABLE([cet],
477 AS_HELP_STRING([--enable-cet],
478 [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
479 [enable_cet=$enableval],
480 [enable_cet=$libc_cv_compiler_default_cet])
482 # We keep the original values in `$config_*' and never modify them, so we
483 # can write them unchanged into config.make. Everything else uses
484 # $machine, $vendor, and $os, and changes them whenever convenient.
485 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
487 # Don't allow vendor == "unknown"
488 test "$config_vendor" = unknown && config_vendor=
489 config_os="`echo $config_os | sed 's/^unknown-//'`"
491 # Some configurations imply other options.
492 elf=yes
494 # The configure fragment of a port can modify these to supplement
495 # or override the table in the case statement below. No fragment should
496 # ever change the config_* variables, however.
497 machine=$config_machine
498 vendor=$config_vendor
499 os=$config_os
500 base_os=''
502 submachine=
503 AC_ARG_WITH([cpu],
504 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
505 [dnl
506 case "$withval" in
507 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
508 no) ;;
509 *) submachine="$withval" ;;
510 esac
511 ])
513 # An preconfigure script can set this when it wants to disable the sanity
514 # check below.
515 libc_config_ok=no
517 # A preconfigure script for a system that may or may not use fpu
518 # sysdeps directories sets this to a preprocessor conditional for
519 # whether to use such directories.
520 with_fp_cond=1
522 dnl Let sysdeps/*/preconfigure act here.
523 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
526 ###
527 ### By using the undocumented --enable-hacker-mode option for configure
528 ### one can skip this test to make the configuration not fail for unsupported
529 ### platforms.
530 ###
531 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
532 case "$machine-$host_os" in
533 *-linux* | *-gnu*)
534 ;;
535 *)
536 AC_MSG_ERROR([
537 *** The GNU C library is currently unavailable for this platform.
538 *** If you are interested in seeing glibc on this platform visit
539 *** the "How to submit a new port" in the wiki:
540 *** https://sourceware.org/glibc/wiki/#Development
541 *** and join the community!])
542 ;;
543 esac
544 fi
546 # Set base_machine if not set by a preconfigure fragment.
547 test -n "$base_machine" || base_machine=$machine
548 AC_SUBST(base_machine)
550 # Determine whether to use fpu or nofpu sysdeps directories.
551 AC_CACHE_CHECK([for use of fpu sysdeps directories],
552 libc_cv_with_fp, [dnl
553 cat > conftest.c <<EOF
554 #if $with_fp_cond
555 int dummy;
556 #else
557 # error "no hardware floating point"
558 #endif
559 EOF
560 libc_cv_with_fp=no
561 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
562 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
563 libc_cv_with_fp=yes
564 fi
565 rm -f conftest*])
566 AC_SUBST(libc_cv_with_fp)
568 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
569 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
570 [libc_cv_ssp=yes],
571 [libc_cv_ssp=no])
572 ])
574 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
575 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
576 [libc_cv_ssp_strong=yes],
577 [libc_cv_ssp_strong=no])
578 ])
580 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
581 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
582 [libc_cv_ssp_all=yes],
583 [libc_cv_ssp_all=no])
584 ])
586 stack_protector=
587 no_stack_protector=
588 if test "$libc_cv_ssp" = yes; then
589 no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
590 AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
591 fi
593 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
594 stack_protector="-fstack-protector"
595 AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
596 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
597 stack_protector="-fstack-protector-all"
598 AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
599 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
600 stack_protector="-fstack-protector-strong"
601 AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
602 else
603 stack_protector="-fno-stack-protector"
604 AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
605 fi
606 AC_SUBST(libc_cv_ssp)
607 AC_SUBST(stack_protector)
608 AC_SUBST(no_stack_protector)
610 if test -n "$stack_protector"; then
611 dnl Don't run configure tests with stack-protection on, to avoid problems with
612 dnl bootstrapping.
613 no_ssp=-fno-stack-protector
614 else
615 no_ssp=
617 if test "$enable_stack_protector" != no; then
618 AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
619 fi
620 fi
622 # For the multi-arch option we need support in the assembler & linker.
623 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
624 libc_cv_ld_gnu_indirect_function, [dnl
625 cat > conftest.S <<EOF
626 .type foo,%gnu_indirect_function
627 foo:
628 .globl _start
629 _start:
630 .globl __start
631 __start:
632 .data
633 #ifdef _LP64
634 .quad foo
635 #else
636 .long foo
637 #endif
638 EOF
639 libc_cv_ld_gnu_indirect_function=no
640 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
641 -nostartfiles -nostdlib $no_ssp \
642 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
643 # Do a link to see if the backend supports IFUNC relocs.
644 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
645 LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
646 libc_cv_ld_gnu_indirect_function=yes
647 }
648 fi
649 rm -f conftest*])
651 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
652 AC_CACHE_CHECK([for gcc attribute ifunc support],
653 libc_cv_gcc_indirect_function, [dnl
654 cat > conftest.c <<EOF
655 extern int func (int);
656 int used_func (int a)
657 {
658 return a;
659 }
660 static void *resolver ()
661 {
662 return &used_func;
663 }
664 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
665 EOF
666 libc_cv_gcc_indirect_function=no
667 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
668 2>&AS_MESSAGE_LOG_FD ; then
669 if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
670 libc_cv_gcc_indirect_function=yes
671 fi
672 fi
673 rm -f conftest*])
675 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
676 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
677 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
678 libc_cv_textrel_ifunc, [dnl
679 cat > conftest.S <<EOF
680 .type foo,%gnu_indirect_function
681 foo:
682 .globl _start
683 _start:
684 .globl __start
685 __start:
686 .data
687 #ifdef _LP64
688 .quad foo
689 #else
690 .long foo
691 #endif
692 .text
693 .globl address
694 address:
695 #ifdef _LP64
696 .quad address
697 #else
698 .long address
699 #endif
700 EOF
701 libc_cv_textrel_ifunc=no
702 if test $libc_cv_ld_gnu_indirect_function = yes; then
703 if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
704 libc_cv_textrel_ifunc=yes
705 fi
706 fi
707 rm -f conftest*])
708 AC_SUBST(libc_cv_textrel_ifunc)
710 # Check if CC supports attribute retain as it is used in attribute_used_retain macro.
711 AC_CACHE_CHECK([for GNU attribute retain support],
712 libc_cv_gnu_retain, [dnl
713 cat > conftest.c <<EOF
714 static int var __attribute__ ((used, retain, section ("__libc_atexit")));
715 EOF
716 libc_cv_gnu_retain=no
717 if ${CC-cc} -Werror -c conftest.c -o /dev/null 1>&AS_MESSAGE_LOG_FD \
718 2>&AS_MESSAGE_LOG_FD ; then
719 libc_cv_gnu_retain=yes
720 fi
721 rm -f conftest*])
722 if test $libc_cv_gnu_retain = yes; then
723 AC_DEFINE(HAVE_GNU_RETAIN)
724 fi
725 LIBC_CONFIG_VAR([have-gnu-retain], [$libc_cv_gnu_retain])
727 # Check if gcc warns about alias for function with incompatible types.
728 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
729 libc_cv_gcc_incompatible_alias, [dnl
730 cat > conftest.c <<EOF
731 int __redirect_foo (const void *s, int c);
733 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
734 __typeof (__redirect_foo) *foo_impl (void)
735 {
736 return 0;
737 }
739 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
740 EOF
741 libc_cv_gcc_incompatible_alias=yes
742 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
743 libc_cv_gcc_incompatible_alias=no
744 fi
745 rm -f conftest*])
747 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
748 if test x"$multi_arch" = xyes; then
749 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
750 else
751 multi_arch=no
752 fi
753 fi
754 if test x"$libc_cv_gcc_indirect_function" != xyes; then
755 # GCC 8+ emits a warning for alias with incompatible types and it might
756 # fail to build ifunc resolvers aliases to either weak or internal
757 # symbols. Disables multiarch build in this case.
758 if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
759 AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
760 if test x"$multi_arch" = xyes; then
761 AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
762 fi
763 AC_MSG_WARN([Multi-arch is disabled.])
764 multi_arch=no
765 elif test x"$multi_arch" = xyes; then
766 AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
767 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
768 fi
769 fi
770 multi_arch_d=
771 if test x"$multi_arch" != xno; then
772 multi_arch_d=/multiarch
773 fi
775 # Compute the list of sysdep directories for this configuration.
776 # This can take a while to compute.
777 sysdep_dir=$srcdir/sysdeps
778 AC_MSG_CHECKING(sysdep dirs)
779 dnl We need to use [ and ] for other purposes for a while now.
780 changequote(,)dnl
781 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
782 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
784 test "x$base_os" != x || case "$os" in
785 gnu*)
786 base_os=mach/hurd ;;
787 linux*)
788 base_os=unix/sysv ;;
789 esac
791 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
792 tail=$os
793 ostry=$os
794 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
795 ostry="$ostry /$o"
796 tail=$o
797 done
798 o=`echo $tail | sed 's/[0-9]*$//'`
799 if test $o != $tail; then
800 ostry="$ostry /$o"
801 fi
802 # For linux-gnu, try linux-gnu, then linux.
803 o=`echo $tail | sed 's/-.*$//'`
804 if test $o != $tail; then
805 ostry="$ostry /$o"
806 fi
808 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
809 base=
810 tail=$base_os
811 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
812 set $b
813 base="$base /$1"
814 tail="$2"
815 done
817 # For sparc/sparc32, try sparc/sparc32 and then sparc.
818 mach=
819 tail=$machine${submachine:+/$submachine}
820 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
821 set $m
822 # Prepend the machine's FPU directory unless the architecture specific
823 # preconfigure disables it.
824 if test "$libc_cv_with_fp" = yes; then
825 maybe_fpu=/fpu
826 else
827 maybe_fpu=/nofpu
828 fi
829 # For each machine term, try it with and then without /multiarch.
830 for try_fpu in $maybe_fpu ''; do
831 for try_multi in $multi_arch_d ''; do
832 mach="$mach /$1$try_fpu$try_multi"
833 done
834 done
835 tail="$2"
836 done
838 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
839 changequote([,])dnl
841 # Find what sysdep directories exist.
842 sysnames=
843 for b in $base ''; do
844 for m0 in $mach ''; do
845 for v in /$vendor ''; do
846 test "$v" = / && continue
847 for o in /$ostry ''; do
848 test "$o" = / && continue
849 for m in $mach ''; do
850 try_suffix="$m0$b$v$o$m"
851 if test -n "$try_suffix"; then
852 try_srcdir="${srcdir}/"
853 try="sysdeps$try_suffix"
854 test -n "$enable_debug_configure" &&
855 echo "$0 [DEBUG]: try $try" >&2
856 if test -d "$try_srcdir$try"; then
857 sysnames="$sysnames $try"
858 { test -n "$o" || test -n "$b"; } && os_used=t
859 { test -n "$m" || test -n "$m0"; } && machine_used=t
860 case x${m0:-$m} in
861 x*/$submachine) submachine_used=t ;;
862 esac
863 fi
864 fi
865 done
866 done
867 done
868 done
869 done
871 # If the assembler supports gnu_indirect_function symbol type and the
872 # architecture supports multi-arch, we enable multi-arch by default.
873 case $sysnames in
874 *"$multi_arch_d"*)
875 ;;
876 *)
877 test x"$multi_arch" = xdefault && multi_arch=no
878 ;;
879 esac
880 if test x"$multi_arch" != xno; then
881 AC_DEFINE(USE_MULTIARCH)
882 fi
883 AC_SUBST(multi_arch)
885 if test -z "$os_used" && test "$os" != none; then
886 AC_MSG_ERROR(Operating system $os is not supported.)
887 fi
888 if test -z "$machine_used" && test "$machine" != none; then
889 AC_MSG_ERROR(The $machine is not supported.)
890 fi
891 if test -z "$submachine_used" && test -n "$submachine"; then
892 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
893 fi
894 AC_SUBST(submachine)
896 # We have now validated the configuration.
898 # Expand the list of system names into a full list of directories
899 # from each element's parent name and Implies file (if present).
900 set $sysnames
901 names=
902 while test $# -gt 0; do
903 name=$1
904 shift
906 case " $names " in *" $name "*)
907 # Already in the list.
908 continue
909 esac
911 # Report each name as we discover it, so there is no long pause in output.
912 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
914 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
916 case $name in
917 /*) xsrcdir= ;;
918 *) xsrcdir=$srcdir/ ;;
919 esac
920 test -n "$enable_debug_configure" &&
921 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
923 for implies_file in Implies Implies-before Implies-after; do
924 implies_type=`echo $implies_file | sed s/-/_/`
925 eval ${implies_type}=
926 if test -f $xsrcdir$name/$implies_file; then
927 # Collect more names from the `Implies' file (removing comments).
928 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
929 for x in $implied_candidate; do
930 found=no
931 if test -d $xsrcdir$name_base/$x; then
932 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
933 found=yes
934 fi
935 try="sysdeps/$x"
936 try_srcdir=$srcdir/
937 test -n "$enable_debug_configure" &&
938 echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
939 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
940 then
941 eval "${implies_type}=\"\$${implies_type} \$try\""
942 found=yes
943 fi
944 if test $found = no; then
945 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
946 fi
947 done
948 fi
949 done
951 # Add NAME to the list of names.
952 names="$names $name"
954 # Find the parent of NAME, using the empty string if it has none.
955 changequote(,)dnl
956 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
957 changequote([,])dnl
959 test -n "$enable_debug_configure" &&
960 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
961 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
963 # Add the names implied by NAME, and NAME's parent (if it has one), to
964 # the list of names to be processed (the argument list). We prepend the
965 # implied names to the list and append the parent. We want implied
966 # directories to come before further directories inferred from the
967 # configuration components; this ensures that for sysv4, unix/common
968 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
969 # after sysv4).
970 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
971 test -n "$sysnames" && set $sysnames
972 done
974 # Add the default directories.
975 default_sysnames="sysdeps/generic"
976 sysnames="$names $default_sysnames"
977 AC_SUBST(sysnames)
978 # The other names were emitted during the scan.
979 AC_MSG_RESULT($default_sysnames)
982 ### Locate tools.
984 AC_PROG_INSTALL
985 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
986 # The makefiles need to use a different form to find it in $srcdir.
987 INSTALL='\$(..)./scripts/install-sh -c'
988 fi
989 AC_PROG_LN_S
991 LIBC_PROG_BINUTILS
993 # Accept binutils 2.25 or newer.
994 AC_CHECK_PROG_VER(AS, $AS, --version,
995 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
996 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
997 AS=: critic_missing="$critic_missing as")
999 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
1000 # Accept gold 1.14 or higher
1001 AC_CHECK_PROG_VER(LD, $LD, --version,
1002 [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
1003 [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
1004 LD=: critic_missing="$critic_missing GNU gold")
1005 else
1006 AC_CHECK_PROG_VER(LD, $LD, --version,
1007 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1008 [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1009 LD=: critic_missing="$critic_missing GNU ld")
1010 fi
1012 # These programs are version sensitive.
1013 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1014 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1015 [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1017 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1018 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1019 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1020 MSGFMT=: aux_missing="$aux_missing msgfmt")
1021 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1022 [GNU texinfo.* \([0-9][0-9.]*\)],
1023 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1024 MAKEINFO=: aux_missing="$aux_missing makeinfo")
1025 AC_CHECK_PROG_VER(SED, sed, --version,
1026 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1027 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1028 SED=: aux_missing="$aux_missing sed")
1029 AC_CHECK_PROG_VER(AWK, gawk, --version,
1030 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1031 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1032 AC_CHECK_PROG_VER(BISON, bison, --version,
1033 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1034 [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1036 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1037 AC_TRY_COMPILE([], [
1038 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1039 #error insufficient compiler
1040 #endif],
1041 [libc_cv_compiler_ok=yes],
1042 [libc_cv_compiler_ok=no])])
1043 AS_IF([test $libc_cv_compiler_ok != yes],
1044 [critic_missing="$critic_missing compiler"])
1046 AC_CHECK_TOOL(NM, nm, false)
1048 if test "x$maintainer" = "xyes"; then
1049 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1050 case "x$AUTOCONF" in
1051 xno|x|x:) AUTOCONF=no ;;
1052 *)
1053 AC_CACHE_CHECK(dnl
1054 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1055 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1056 libc_cv_autoconf_works=yes
1057 else
1058 libc_cv_autoconf_works=no
1059 fi])
1060 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1061 ;;
1062 esac
1063 if test "x$AUTOCONF" = xno; then
1064 aux_missing="$aux_missing autoconf"
1065 fi
1066 else
1067 AUTOCONF=no
1068 fi
1070 # Check for python3 if available, or else python.
1071 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1072 [Python \([0-9][0-9.]*\)],
1073 [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1074 critic_missing="$critic_missing python")
1075 PYTHON="$PYTHON_PROG -B"
1076 AC_SUBST(PYTHON)
1078 test -n "$critic_missing" && AC_MSG_ERROR([
1079 *** These critical programs are missing or too old:$critic_missing
1080 *** Check the INSTALL file for required versions.])
1082 test -n "$aux_missing" && AC_MSG_WARN([
1083 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1084 *** some features or tests will be disabled.
1085 *** Check the INSTALL file for required versions.])
1087 # if using special system headers, find out the compiler's sekrit
1088 # header directory and add that to the list. NOTE: Only does the right
1089 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1090 if test -n "$sysheaders"; then
1091 SYSINCLUDES=-nostdinc
1092 for d in include include-fixed; do
1093 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1094 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1095 done
1096 SYSINCLUDES="$SYSINCLUDES \
1097 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1098 if test -n "$CXX"; then
1099 CXX_SYSINCLUDES=
1100 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1101 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1102 test "x$cxxheaders" != x &&
1103 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1104 done
1105 fi
1106 fi
1107 AC_SUBST(SYSINCLUDES)
1108 AC_SUBST(CXX_SYSINCLUDES)
1110 # Obtain some C++ header file paths. This is used to make a local
1111 # copy of those headers in Makerules.
1112 if test -n "$CXX"; then
1113 find_cxx_header () {
1114 echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1115 | sed -n "\,$1:,{s/:\$//;p}"
1116 }
1117 CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1118 CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1119 CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1120 fi
1121 AC_SUBST(CXX_CSTDLIB_HEADER)
1122 AC_SUBST(CXX_CMATH_HEADER)
1123 AC_SUBST(CXX_BITS_STD_ABS_H)
1125 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1126 # since this would lead to problems installing/building glibc.
1127 # LD_LIBRARY_PATH contains the current directory if one of the following
1128 # is true:
1129 # - one of the terminals (":" and ";") is the first or last sign
1130 # - two terminals occur directly after each other
1131 # - the path contains an element with a dot in it
1132 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1133 changequote(,)dnl
1134 case ${LD_LIBRARY_PATH} in
1135 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1136 ld_library_path_setting="contains current directory"
1137 ;;
1138 *)
1139 ld_library_path_setting="ok"
1140 ;;
1141 esac
1142 changequote([,])dnl
1143 AC_MSG_RESULT($ld_library_path_setting)
1144 if test "$ld_library_path_setting" != "ok"; then
1145 AC_MSG_ERROR([
1146 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1147 *** building glibc. Please change the environment variable
1148 *** and run configure again.])
1149 fi
1151 AC_PATH_PROG(BASH_SHELL, bash, no)
1153 AC_PATH_PROG(PERL, perl, no)
1154 if test "$PERL" != no &&
1155 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1156 PERL=no
1157 fi
1158 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1159 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1161 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1162 cat > conftest.s <<EOF
1163 .text
1164 foo:
1165 .set glibc_conftest_frobozz,foo
1166 .globl glibc_conftest_frobozz
1167 EOF
1168 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1169 # (but it doesn't work), so we must do a linking check to be sure.
1170 cat > conftest1.c <<\EOF
1171 extern int glibc_conftest_frobozz;
1172 void _start() { glibc_conftest_frobozz = 1; }
1173 EOF
1174 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1175 -nostartfiles -nostdlib $no_ssp \
1176 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1177 libc_cv_asm_set_directive=yes
1178 else
1179 libc_cv_asm_set_directive=no
1180 fi
1181 rm -f conftest*])
1182 if test $libc_cv_asm_set_directive = yes; then
1183 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1184 fi
1186 AC_CACHE_CHECK(linker support for protected data symbol,
1187 libc_cv_protected_data,
1188 [cat > conftest.c <<EOF
1189 int bar __attribute__ ((visibility ("protected"))) = 1;
1190 EOF
1191 libc_cv_protected_data=no
1192 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1193 cat > conftest.c <<EOF
1194 extern int bar;
1195 int main (void) { return bar; }
1196 EOF
1197 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1198 libc_cv_protected_data=yes
1199 fi
1200 fi
1201 rm -f conftest.*
1202 ])
1203 AC_SUBST(libc_cv_protected_data)
1205 AC_CACHE_CHECK(linker support for INSERT in linker script,
1206 libc_cv_insert,
1207 [cat > conftest.c <<EOF
1208 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1209 int test (void) { return bar; }
1210 EOF
1211 cat > conftest.t <<EOF
1212 SECTIONS
1213 {
1214 .bar : { *(.bar) }
1215 }
1216 INSERT AFTER .rela.dyn;
1217 EOF
1218 libc_cv_insert=no
1219 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1220 libc_cv_insert=yes
1221 fi
1222 rm -f conftest.*
1223 ])
1224 AC_SUBST(libc_cv_insert)
1226 AC_CACHE_CHECK(for broken __attribute__((alias())),
1227 libc_cv_broken_alias_attribute,
1228 [cat > conftest.c <<EOF
1229 extern int foo (int x) __asm ("xyzzy");
1230 int bar (int x) { return x; }
1231 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1232 extern int dfoo;
1233 extern __typeof (dfoo) dfoo __asm ("abccb");
1234 int dfoo = 1;
1235 EOF
1236 libc_cv_broken_alias_attribute=yes
1237 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1238 if grep 'xyzzy' conftest.s >/dev/null &&
1239 grep 'abccb' conftest.s >/dev/null; then
1240 libc_cv_broken_alias_attribute=no
1241 fi
1242 fi
1243 rm -f conftest.c conftest.s
1244 ])
1245 if test $libc_cv_broken_alias_attribute = yes; then
1246 AC_MSG_ERROR(working alias attribute support required)
1247 fi
1249 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1250 libc_cv_have_sdata_section,
1251 [echo "int i;" > conftest.c
1252 libc_cv_have_sdata_section=no
1253 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1254 | grep '\.sdata' >/dev/null; then
1255 libc_cv_have_sdata_section=yes
1256 fi
1257 rm -f conftest.c conftest.so
1258 ])
1259 if test $libc_cv_have_sdata_section = yes; then
1260 AC_DEFINE(HAVE_SDATA_SECTION)
1261 fi
1263 AC_CACHE_CHECK(for libunwind-support in compiler,
1264 libc_cv_cc_with_libunwind, [
1265 cat > conftest.c <<EOF
1266 int main (void) { return 0; }
1267 EOF
1268 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1269 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1270 libc_cv_cc_with_libunwind=yes
1271 else
1272 libc_cv_cc_with_libunwind=no
1273 fi
1274 rm -f conftest*])
1275 AC_SUBST(libc_cv_cc_with_libunwind)
1276 if test $libc_cv_cc_with_libunwind = yes; then
1277 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1278 fi
1280 ASFLAGS_config=
1281 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1282 libc_cv_as_noexecstack, [dnl
1283 cat > conftest.c <<EOF
1284 void foo (void) { }
1285 EOF
1286 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1287 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1288 && grep .note.GNU-stack conftest.s >/dev/null \
1289 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1290 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1291 then
1292 libc_cv_as_noexecstack=yes
1293 else
1294 libc_cv_as_noexecstack=no
1295 fi
1296 rm -f conftest*])
1297 if test $libc_cv_as_noexecstack = yes; then
1298 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1299 fi
1300 AC_SUBST(ASFLAGS_config)
1302 AC_CACHE_CHECK(for -z combreloc,
1303 libc_cv_z_combreloc, [dnl
1304 cat > conftest.c <<EOF
1305 extern int bar (int);
1306 extern int mumble;
1307 int foo (void) { return bar (mumble); }
1308 EOF
1309 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1310 -fPIC -shared $no_ssp -o conftest.so conftest.c
1311 -nostdlib -nostartfiles
1312 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1313 then
1314 dnl The following test is a bit weak. We must use a tool which can test
1315 dnl cross-platform since the gcc used can be a cross compiler. Without
1316 dnl introducing new options this is not easily doable. Instead use a tool
1317 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1318 dnl look for a section named .rel.dyn or .rela.dyn.
1319 if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1320 libc_cv_z_combreloc=yes
1321 else
1322 libc_cv_z_combreloc=no
1323 fi
1324 else
1325 libc_cv_z_combreloc=no
1326 fi
1327 rm -f conftest*])
1328 if test "$libc_cv_z_combreloc" = yes; then
1329 AC_DEFINE(HAVE_Z_COMBRELOC)
1330 fi
1331 AC_SUBST(libc_cv_z_combreloc)
1333 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1334 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1335 AC_SUBST(libc_cv_z_execstack)
1337 LIBC_LINKER_FEATURE([-z start-stop-gc], [-Wl,-z,start-stop-gc],
1338 [libc_cv_z_start_stop_gc=yes], [libc_cv_z_start_stop_gc=no])
1339 LIBC_CONFIG_VAR([have-z-start-stop-gc], [$libc_cv_z_start_stop_gc])
1341 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1342 [-Wl,--no-dynamic-linker],
1343 [libc_cv_no_dynamic_linker=yes],
1344 [libc_cv_no_dynamic_linker=no])
1345 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1347 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1348 LIBC_TRY_CC_OPTION([-static-pie],
1349 [libc_cv_static_pie=yes],
1350 [libc_cv_static_pie=no])
1351 ])
1352 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1354 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1355 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1356 ])
1358 AC_SUBST(libc_cv_fpie)
1360 AC_CACHE_CHECK(for --hash-style option,
1361 libc_cv_hashstyle, [dnl
1362 cat > conftest.c <<EOF
1363 int _start (void) { return 42; }
1364 EOF
1365 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1366 -fPIC -shared -o conftest.so conftest.c
1367 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1368 then
1369 libc_cv_hashstyle=yes
1370 else
1371 libc_cv_hashstyle=no
1372 fi
1373 rm -f conftest*])
1374 AC_SUBST(libc_cv_hashstyle)
1376 # The linker's default -shared behavior is good enough if it
1377 # does these things that our custom linker scripts ensure that
1378 # all allocated NOTE sections come first.
1379 if test "$use_default_link" = default; then
1380 AC_CACHE_CHECK([for sufficient default -shared layout],
1381 libc_cv_use_default_link, [dnl
1382 libc_cv_use_default_link=no
1383 cat > conftest.s <<\EOF
1384 .section .note.a,"a",%note
1385 .balign 4
1386 .long 4,4,9
1387 .string "GNU"
1388 .string "foo"
1389 .section .note.b,"a",%note
1390 .balign 4
1391 .long 4,4,9
1392 .string "GNU"
1393 .string "bar"
1394 EOF
1395 if AC_TRY_COMMAND([dnl
1396 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1397 ac_try=`$READELF -S conftest.so | sed -n \
1398 ['${x;p;}
1399 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1400 t a
1401 b
1402 : a
1403 H']`
1404 then
1405 libc_seen_a=no libc_seen_b=no
1406 set -- $ac_try
1407 while test $# -ge 2 -a "$1" = NOTE; do
1408 case "$2" in
1409 .note.a) libc_seen_a=yes ;;
1410 .note.b) libc_seen_b=yes ;;
1411 esac
1412 shift 2
1413 done
1414 case "$libc_seen_a$libc_seen_b" in
1415 yesyes)
1416 libc_cv_use_default_link=yes
1417 ;;
1418 *)
1419 echo >&AS_MESSAGE_LOG_FD "\
1420 $libc_seen_a$libc_seen_b from:
1421 $ac_try"
1422 ;;
1423 esac
1424 fi
1425 rm -f conftest*])
1426 use_default_link=$libc_cv_use_default_link
1427 fi
1429 AC_CACHE_CHECK(for GLOB_DAT reloc,
1430 libc_cv_has_glob_dat, [dnl
1431 cat > conftest.c <<EOF
1432 extern int mumble;
1433 int foo (void) { return mumble; }
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1436 -fPIC -shared -o conftest.so conftest.c
1437 -nostdlib -nostartfiles $no_ssp
1438 1>&AS_MESSAGE_LOG_FD])
1439 then
1440 dnl look for GLOB_DAT relocation.
1441 if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1442 libc_cv_has_glob_dat=yes
1443 else
1444 libc_cv_has_glob_dat=no
1445 fi
1446 else
1447 libc_cv_has_glob_dat=no
1448 fi
1449 rm -f conftest*])
1450 AC_SUBST(libc_cv_has_glob_dat)
1452 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1453 cat > conftest.c <<EOF
1454 int foo;
1455 EOF
1456 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1457 conftest.c 1>&AS_MESSAGE_LOG_FD])
1458 then
1459 libc_cv_fno_toplevel_reorder=yes
1460 else
1461 libc_cv_fno_toplevel_reorder=no
1462 fi
1463 rm -f conftest*])
1464 if test $libc_cv_fno_toplevel_reorder = yes; then
1465 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1466 else
1467 fno_unit_at_a_time=-fno-unit-at-a-time
1468 fi
1469 AC_SUBST(fno_unit_at_a_time)
1471 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1472 [dnl
1473 cat > conftest.c <<EOF
1474 __thread int i;
1475 void foo (void)
1476 {
1477 i = 10;
1478 }
1479 EOF
1480 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1481 conftest.c 1>&AS_MESSAGE_LOG_FD])
1482 then
1483 libc_cv_mtls_dialect_gnu2=yes
1484 else
1485 libc_cv_mtls_dialect_gnu2=no
1486 fi
1487 rm -f conftest*])
1488 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1489 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1491 AC_CACHE_CHECK(whether cc puts quotes around section names,
1492 libc_cv_have_section_quotes,
1493 [cat > conftest.c <<EOF
1494 static const int foo
1495 __attribute__ ((section ("bar"))) = 1;
1496 EOF
1497 if ${CC-cc} -S conftest.c -o conftest.s; then
1498 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1499 libc_cv_have_section_quotes=yes
1500 else
1501 libc_cv_have_section_quotes=no
1502 fi
1503 else
1504 libc_cv_have_section_quotes=unknown
1505 fi
1506 rm -f conftest.{c,s}
1507 ])
1508 if test $libc_cv_have_section_quotes = yes; then
1509 AC_DEFINE(HAVE_SECTION_QUOTES)
1510 fi
1512 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1513 cat > conftest.c <<\EOF
1514 void zero (void *x)
1515 {
1516 __builtin_memset (x, 0, 1000);
1517 }
1518 EOF
1519 dnl
1520 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1521 then
1522 libc_cv_gcc_builtin_memset=no
1523 else
1524 libc_cv_gcc_builtin_memset=yes
1525 fi
1526 rm -f conftest* ])
1527 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1528 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1529 fi
1531 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1532 cat > conftest.c <<\EOF
1533 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1534 char *foo (const char *a, const char *b)
1535 {
1536 return __builtin_strstr (a, b);
1537 }
1538 EOF
1539 dnl
1540 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1541 then
1542 libc_cv_gcc_builtin_redirection=yes
1543 else
1544 libc_cv_gcc_builtin_redirection=no
1545 fi
1546 rm -f conftest* ])
1547 if test "$libc_cv_gcc_builtin_redirection" = no; then
1548 AC_MSG_ERROR([support for the symbol redirection needed])
1549 fi
1551 dnl Determine how to disable generation of FMA instructions.
1552 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1553 libc_cv_cc_nofma, [dnl
1554 libc_cv_cc_nofma=
1555 for opt in -ffp-contract=off -mno-fused-madd; do
1556 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1557 done])
1558 AC_SUBST(libc_cv_cc_nofma)
1560 if test -n "$submachine"; then
1561 AC_CACHE_CHECK([for compiler option for CPU variant],
1562 libc_cv_cc_submachine, [dnl
1563 libc_cv_cc_submachine=no
1564 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1565 LIBC_TRY_CC_OPTION([$opt], [
1566 libc_cv_cc_submachine="$opt"
1567 break], [])
1568 done])
1569 if test "x$libc_cv_cc_submachine" = xno; then
1570 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1571 fi
1572 fi
1573 AC_SUBST(libc_cv_cc_submachine)
1575 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1576 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1577 cat > conftest.c <<EOF
1578 void
1579 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1580 foo (void) {}
1581 EOF
1582 libc_cv_cc_loop_to_function=no
1583 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1584 then
1585 libc_cv_cc_loop_to_function=yes
1586 fi
1587 rm -f conftest*])
1588 if test $libc_cv_cc_loop_to_function = yes; then
1589 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1590 fi
1591 AC_SUBST(libc_cv_cc_loop_to_function)
1593 dnl Check whether we have the gd library available.
1594 AC_MSG_CHECKING(for libgd)
1595 if test "$with_gd" != "no"; then
1596 old_CFLAGS="$CFLAGS"
1597 CFLAGS="$CFLAGS $libgd_include"
1598 old_LDFLAGS="$LDFLAGS"
1599 LDFLAGS="$LDFLAGS $libgd_ldflags"
1600 old_LIBS="$LIBS"
1601 LIBS="$LIBS -lgd -lpng -lz -lm"
1602 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gd.h>]], [[gdImagePng (0, 0)]])],
1603 [LIBGD=yes], [LIBGD=no])
1604 CFLAGS="$old_CFLAGS"
1605 LDFLAGS="$old_LDFLAGS"
1606 LIBS="$old_LIBS"
1607 else
1608 LIBGD=no
1609 fi
1610 AC_MSG_RESULT($LIBGD)
1611 AC_SUBST(LIBGD)
1613 # SELinux detection
1614 if test x$with_selinux = xno ; then
1615 have_selinux=no;
1616 else
1617 # See if we have the SELinux library
1618 AC_CHECK_LIB(selinux, is_selinux_enabled,
1619 have_selinux=yes, have_selinux=no)
1620 if test x$with_selinux = xyes ; then
1621 if test x$have_selinux = xno ; then
1622 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1623 fi
1624 fi
1625 fi
1626 # Check if we're building with SELinux support.
1627 if test "x$have_selinux" = xyes; then
1628 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1630 # See if we have the libaudit library
1631 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1632 have_libaudit=yes, have_libaudit=no)
1633 if test "x$have_libaudit" = xyes; then
1634 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1635 fi
1636 AC_SUBST(have_libaudit)
1638 # See if we have the libcap library
1639 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1640 if test "x$have_libcap" = xyes; then
1641 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1642 fi
1643 AC_SUBST(have_libcap)
1644 fi
1645 AC_SUBST(have_selinux)
1647 CPPUNDEFS=
1648 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1649 dnl Since we are building the implementations of the fortified functions here,
1650 dnl having the macro defined interacts very badly.
1651 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1652 [AC_TRY_COMPILE([], [
1653 #ifdef _FORTIFY_SOURCE
1654 # error bogon
1655 #endif],
1656 [libc_cv_predef_fortify_source=no],
1657 [libc_cv_predef_fortify_source=yes])])
1658 if test $libc_cv_predef_fortify_source = yes; then
1659 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1660 fi
1661 AC_SUBST(CPPUNDEFS)
1663 # Some linkers on some architectures support __ehdr_start but with
1664 # bugs. Make sure usage of it does not create relocations in the
1665 # output (as the linker should resolve them all for us).
1666 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1667 libc_cv_ehdr_start, [
1668 old_CFLAGS="$CFLAGS"
1669 old_LDFLAGS="$LDFLAGS"
1670 old_LIBS="$LIBS"
1671 CFLAGS="$CFLAGS -fPIC"
1672 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1673 LIBS=
1674 AC_LINK_IFELSE([AC_LANG_SOURCE([
1675 typedef struct {
1676 char foo;
1677 long val;
1678 } Ehdr;
1679 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1680 long ehdr (void) { return __ehdr_start.val; }
1681 ])],
1682 [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1683 libc_cv_ehdr_start=broken
1684 else
1685 libc_cv_ehdr_start=yes
1686 fi], [libc_cv_ehdr_start=no])
1687 CFLAGS="$old_CFLAGS"
1688 LDFLAGS="$old_LDFLAGS"
1689 LIBS="$old_LIBS"
1690 ])
1691 if test "$libc_cv_ehdr_start" = yes; then
1692 AC_DEFINE([HAVE_EHDR_START])
1693 elif test "$libc_cv_ehdr_start" = broken; then
1694 AC_MSG_WARN([linker is broken -- you should upgrade])
1695 fi
1697 dnl Starting with binutils 2.35, GAS can attach multiple symbol versions
1698 dnl to one symbol (PR 23840).
1699 AC_CACHE_CHECK(whether the assembler requires one version per symbol,
1700 libc_cv_symver_needs_alias, [dnl
1701 cat > conftest.s <<EOF
1702 .text
1703 testfunc:
1704 .globl testfunc
1705 .symver testfunc, testfunc1@VERSION1
1706 .symver testfunc, testfunc1@VERSION2
1707 EOF
1708 libc_cv_symver_needs_alias=no
1709 if ${CC-cc} $ASFLAGS -c conftest.s 2>&AS_MESSAGE_LOG_FD; then
1710 libc_cv_symver_needs_alias=no
1711 else
1712 libc_cv_symver_needs_alias=yes
1713 fi
1714 rm conftest.*
1715 ])
1716 if test "$libc_cv_symver_needs_alias" = yes; then
1717 AC_DEFINE(SYMVER_NEEDS_ALIAS)
1718 fi
1720 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1721 libc_cv_builtin_trap, [dnl
1722 libc_cv_builtin_trap=no
1723 AC_TRY_COMPILE([], [__builtin_trap ()], [
1724 libc_undefs=`$NM -u conftest.o |
1725 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1726 2>&AS_MESSAGE_LOG_FD` || {
1727 AC_MSG_ERROR([confusing output from $NM -u])
1728 }
1729 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1730 if test -z "$libc_undefs"; then
1731 libc_cv_builtin_trap=yes
1732 fi])])
1733 if test $libc_cv_builtin_trap = yes; then
1734 AC_DEFINE([HAVE_BUILTIN_TRAP])
1735 fi
1737 dnl C++ feature tests.
1738 AC_LANG_PUSH([C++])
1740 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1741 libc_cv_cxx_thread_local, [
1742 old_CXXFLAGS="$CXXFLAGS"
1743 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1744 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1745 #include <thread>
1747 // Compiler support.
1748 struct S
1749 {
1750 S ();
1751 ~S ();
1752 };
1753 thread_local S s;
1754 S * get () { return &s; }
1756 // libstdc++ support.
1757 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1758 #error __cxa_thread_atexit_impl not supported
1759 #endif
1760 ])],
1761 [libc_cv_cxx_thread_local=yes],
1762 [libc_cv_cxx_thread_local=no])
1763 CXXFLAGS="$old_CXXFLAGS"
1764 ])
1765 AC_SUBST(libc_cv_cxx_thread_local)
1767 AC_LANG_POP([C++])
1768 dnl End of C++ feature tests.
1770 ### End of automated tests.
1771 ### Now run sysdeps configure fragments.
1773 # They also can set these variables.
1774 use_ldconfig=no
1775 ldd_rewrite_script=no
1776 libc_cv_sysconfdir=$sysconfdir
1777 libc_cv_localstatedir=$localstatedir
1778 libc_cv_gcc_unwind_find_fde=no
1779 libc_cv_idn=no
1780 pthread_in_libc=yes
1782 # Iterate over all the sysdep directories we will use, running their
1783 # configure fragments.
1784 for dir in $sysnames; do
1785 case $dir in
1786 /*) dest=$dir ;;
1787 *) dest=$srcdir/$dir ;;
1788 esac
1789 if test -r $dest/configure; then
1790 AC_MSG_RESULT(running configure fragment for $dir)
1791 . $dest/configure
1792 fi
1793 done
1795 if test x"$build_mathvec" = xnotset; then
1796 build_mathvec=no
1797 fi
1798 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1800 AC_SUBST(libc_extra_cflags)
1801 AC_SUBST(libc_extra_cppflags)
1803 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1804 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1805 fi
1806 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1808 # A sysdeps configure fragment can reset this if IFUNC is not actually
1809 # usable even though the assembler knows how to generate the symbol type.
1810 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1811 AC_DEFINE(HAVE_IFUNC)
1812 fi
1813 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1815 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1816 AC_DEFINE(HAVE_GCC_IFUNC)
1817 fi
1818 LIBC_CONFIG_VAR([have-gcc-ifunc], [$libc_cv_gcc_indirect_function])
1820 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1821 # configure fragment can override the value to prevent this AC_DEFINE.
1822 AC_SUBST(use_nscd)
1823 if test "x$use_nscd" != xno; then
1824 AC_DEFINE([USE_NSCD])
1825 fi
1826 if test "x$build_nscd" = xdefault; then
1827 build_nscd=$use_nscd
1828 fi
1830 AC_SUBST(libc_cv_slibdir)
1831 AC_SUBST(libc_cv_rtlddir)
1832 AC_SUBST(libc_cv_complocaledir)
1833 AC_SUBST(libc_cv_sysconfdir)
1834 AC_SUBST(libc_cv_localstatedir)
1835 AC_SUBST(libc_cv_rootsbindir)
1837 if test x$use_ldconfig = xyes; then
1838 AC_DEFINE(USE_LDCONFIG)
1839 fi
1840 AC_SUBST(use_ldconfig)
1841 AC_SUBST(ldd_rewrite_script)
1843 AC_SUBST(static)
1844 AC_SUBST(shared)
1846 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1847 [libc_cv_pic_default=yes
1848 cat > conftest.c <<EOF
1849 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1850 # error PIC is default.
1851 #endif
1852 EOF
1853 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1854 libc_cv_pic_default=no
1855 fi
1856 rm -f conftest.*])
1857 AC_SUBST(libc_cv_pic_default)
1859 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1860 [libc_cv_cc_pie_default=yes
1861 cat > conftest.c <<EOF
1862 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1863 # error PIE is default.
1864 #endif
1865 EOF
1866 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1867 libc_cv_cc_pie_default=no
1868 fi
1869 rm -f conftest.*])
1870 libc_cv_pie_default=$libc_cv_cc_pie_default
1871 AC_SUBST(libc_cv_cc_pie_default)
1872 AC_SUBST(libc_cv_pie_default)
1874 # Set the `multidir' variable by grabbing the variable from the compiler.
1875 # We do it once and save the result in a generated makefile.
1876 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1877 AC_SUBST(libc_cv_multidir)
1879 if test "$static_pie" = yes; then
1880 # Check target support for static PIE
1881 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef SUPPORT_STATIC_PIE
1882 # error static PIE is not supported
1883 #endif]])], , AC_MSG_ERROR([the architecture does not support static PIE]))
1884 # The linker must support --no-dynamic-linker.
1885 if test "$libc_cv_no_dynamic_linker" != yes; then
1886 AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1887 fi
1888 # Default to PIE.
1889 libc_cv_pie_default=yes
1890 AC_DEFINE(ENABLE_STATIC_PIE)
1891 fi
1892 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1894 AC_SUBST(profile)
1895 AC_SUBST(static_nss)
1897 AC_SUBST(DEFINES)
1899 dnl See sysdeps/mach/configure.ac for this variable.
1900 AC_SUBST(mach_interface_list)
1902 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1903 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1904 AC_SUBST(VERSION)
1905 AC_SUBST(RELEASE)
1907 if test "$pthread_in_libc" = yes; then
1908 AC_DEFINE(PTHREAD_IN_LIBC)
1909 fi
1910 AC_SUBST(pthread_in_libc)
1912 AC_CONFIG_FILES([config.make Makefile])
1913 AC_CONFIG_COMMANDS([default],[[
1914 case $CONFIG_FILES in *config.make*)
1915 echo "$config_vars" >> config.make;;
1916 esac
1917 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1918 AC_OUTPUT