sysdeps/unix/sysv/linux/hppa/pt-vfork.S

   1 /* Copyright (C) 2005-2017 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21 #include <tcb-offsets.h>
  22
  23 /* Clone the calling process, but without copying the whole address space.
  24    The calling process is suspended until the new process exits or is
  25    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  26    and the process ID of the new process to the old process.  */
  27
  28 .Lthread_start:                                         ASM_LINE_SEP
  29
  30         /* r26, r25, r24, r23 are free since vfork has no arguments */
  31 ENTRY(__vfork)
  32         /* We must not create a frame. When the child unwinds to call
  33            exec it will clobber the same frame that the parent
  34            needs to unwind.  */
  35
  36         /* Save the PIC register. */
  37 #ifdef PIC
  38         copy    %r19, %r25      /* parent */
  39 #endif
  40
  41         /* Syscall saves and restores all register states */
  42         ble     0x100(%sr2,%r0)
  43         ldi     __NR_vfork,%r20
  44
  45         /* Check for error */
  46         ldi     -4096,%r1
  47         comclr,>>= %r1,%ret0,%r0        /* Note: unsigned compare. */
  48         b,n     .Lerror
  49
  50         /* Return, and DO NOT restore rp. The child may have called
  51            functions that updated the frame's rp. This works because
  52            the kernel ensures rp is preserved across the vfork
  53            syscall.  */
  54         bv,n    %r0(%rp)
  55
  56 .Lerror:
  57         /* Now we need a stack to call a function. We are assured
  58            that there is no child now, so it's safe to create
  59            a frame.  */
  60         stw     %rp, -20(%sp)
  61         stwm    %r3, 64(%sp)
  62         stw     %sp, -4(%sp)
  63
  64         sub     %r0,%ret0,%r3
  65         SYSCALL_ERROR_HANDLER
  66         /* Restore the PIC register (in delay slot) on error */
  67 #ifdef PIC
  68         copy    %r25, %r19    /* parent */
  69 #else
  70         nop
  71 #endif
  72         /* Write syscall return into errno location */
  73         stw     %r3, 0(%ret0)
  74         ldw     -84(%sp), %rp
  75         bv      %r0(%rp)
  76         ldwm    -64(%sp), %r3
  77 PSEUDO_END (__vfork)
  78 libc_hidden_def (__vfork)
  79 weak_alias (__vfork, vfork)