sysdeps/s390/multiarch/strlen-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of strlen.
   2    Copyright (C) 2015-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* size_t strlen (const char *s)
  27    Returns length of string s.
  28
  29    Register usage:
  30    -r1=bytes to 4k-byte boundary
  31    -r2=s
  32    -r3=tmp
  33    -r4=tmp
  34    -r5=current_len and return_value
  35    -v16=part of s
  36 */
  37 ENTRY(__strlen_vx)
  38         .machine "z13"
  39         .machinemode "zarch_nohighgprs"
  40
  41         vlbb    %v16,0(%r2),6   /* Load s until next 4k-byte boundary.  */
  42         lcbb    %r1,0(%r2),6    /* Get bytes to 4k-byte boundary or 16.  */
  43
  44         vfenezb %v16,%v16,%v16  /* Find element not equal with zero search.  */
  45         vlgvb   %r4,%v16,7      /* Load zero index or 16 if not found.  */
  46         clr     %r4,%r1         /* If found zero within loaded bytes?  */
  47         locgrl  %r2,%r4         /* Then copy return value.  */
  48         blr     %r14            /* And return.  */
  49
  50         /* Align s to 16 byte.  */
  51         risbgn  %r3,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  52         lghi    %r5,16          /* current_len = 16.  */
  53         slr     %r5,%r3         /* Compute bytes to 16bytes boundary.  */
  54
  55         /* Find zero in 16 byte aligned loop.  */
  56 .Lloop:
  57         vl      %v16,0(%r5,%r2) /* Load s.  */
  58         vfenezbs %v16,%v16,%v16 /* Find element not equal with zero search.  */
  59         je      .Lfound         /* Jump away if zero was found.  */
  60         vl      %v16,16(%r5,%r2)
  61         vfenezbs %v16,%v16,%v16
  62         je      .Lfound16
  63         vl      %v16,32(%r5,%r2)
  64         vfenezbs %v16,%v16,%v16
  65         je      .Lfound32
  66         vl      %v16,48(%r5,%r2)
  67         vfenezbs %v16,%v16,%v16
  68         je      .Lfound48
  69
  70         aghi    %r5,64
  71         j       .Lloop          /* No zero found -> loop.  */
  72
  73 .Lfound48:
  74         aghi    %r5,16
  75 .Lfound32:
  76         aghi    %r5,16
  77 .Lfound16:
  78         aghi    %r5,16
  79 .Lfound:
  80         vlgvb   %r2,%v16,7      /* Load byte index of zero.  */
  81         algr    %r2,%r5
  82         br      %r14
  83 END(__strlen_vx)
  84 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */