sysdeps/aarch64/setjmp.S

   1 /* Copyright (C) 1997-2017 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public License as
   7    published by the Free Software Foundation; either version 2.1 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <stap-probe.h>
  22
  23         /* Keep traditional entry points in with sigsetjmp(). */
  24 ENTRY (setjmp)
  25         mov     x1, #1
  26         b       1f
  27 END (setjmp)
  28
  29 ENTRY (_setjmp)
  30         mov     x1, #0
  31         b       1f
  32 END (_setjmp)
  33 libc_hidden_def (_setjmp)
  34
  35 ENTRY (__sigsetjmp)
  36         DELOUSE (0)
  37
  38 1:
  39         stp     x19, x20, [x0, #JB_X19<<3]
  40         stp     x21, x22, [x0, #JB_X21<<3]
  41         stp     x23, x24, [x0, #JB_X23<<3]
  42         stp     x25, x26, [x0, #JB_X25<<3]
  43         stp     x27, x28, [x0, #JB_X27<<3]
  44
  45 #ifdef PTR_MANGLE
  46         PTR_MANGLE (4, 30, 3, 2)
  47         stp     x29,  x4, [x0, #JB_X29<<3]
  48 #else
  49         stp     x29, x30, [x0, #JB_X29<<3]
  50 #endif
  51         /* setjmp probe takes 3 arguments, address of jump buffer
  52            first argument (8@x0), return value second argument (-4@x1),
  53            and target address (8@x30), respectively.  */
  54         LIBC_PROBE (setjmp, 3, 8@x0, -4@x1, 8@x30)
  55         stp      d8,  d9, [x0, #JB_D8<<3]
  56         stp     d10, d11, [x0, #JB_D10<<3]
  57         stp     d12, d13, [x0, #JB_D12<<3]
  58         stp     d14, d15, [x0, #JB_D14<<3]
  59 #ifdef PTR_MANGLE
  60         mov     x4, sp
  61         PTR_MANGLE (5, 4, 3, 2)
  62         str     x5, [x0, #JB_SP<<3]
  63 #else
  64         mov     x2,  sp
  65         str     x2,  [x0, #JB_SP<<3]
  66 #endif
  67 #if IS_IN (rtld)
  68         /* In ld.so we never save the signal mask */
  69         mov     w0, #0
  70         RET
  71 #else
  72         b       C_SYMBOL_NAME(__sigjmp_save)
  73 #endif
  74 END (__sigsetjmp)
  75 hidden_def (__sigsetjmp)