| blob | a64aeb9979a53cd7f69c20f6f38db75c7a1bdf49 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP], [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29 CPP=
30 fi
31 if test -z "$CPP"; then
32 CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
37 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
45 AC_CANONICAL_HOST
47 AC_PROG_CC
48 if test $host != $build; then
49 AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 AC_CHECK_TOOL(READELF, readelf, false)
55 # We need the C++ compiler only for testing.
56 AC_PROG_CXX
57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
59 AC_LANG_PUSH([C++])
60 # Default, dynamic case.
61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
62 [libc_cv_cxx_link_ok=yes],
63 [libc_cv_cxx_link_ok=no])
64 # Static case.
65 old_LDFLAGS="$LDFLAGS"
66 LDFLAGS="$LDFLAGS -static"
67 AC_LINK_IFELSE([AC_LANG_SOURCE([
68 #include <iostream>
70 int
71 main()
72 {
73 std::cout << "Hello, world!";
74 return 0;
75 }
76 ])],
77 [],
78 [libc_cv_cxx_link_ok=no])
79 LDFLAGS="$old_LDFLAGS"
80 AC_LANG_POP([C++])])
81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
84 AC_MSG_ERROR([you must configure in a separate build directory])
85 fi
87 # This will get text that should go into config.make.
88 config_vars=
90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
91 AC_ARG_WITH([gd],
92 AC_HELP_STRING([--with-gd=DIR],
93 [find libgd include dir and library with prefix DIR]),
94 [dnl
95 case "$with_gd" in
96 yes|''|no) ;;
97 *) libgd_include="-I$withval/include"
98 libgd_ldflags="-L$withval/lib" ;;
99 esac
100 ])
101 AC_ARG_WITH([gd-include],
102 AC_HELP_STRING([--with-gd-include=DIR],
103 [find libgd include files in DIR]),
104 [dnl
105 case "$with_gd_include" in
106 ''|no) ;;
107 *) libgd_include="-I$withval" ;;
108 esac
109 ])
110 AC_ARG_WITH([gd-lib],
111 AC_HELP_STRING([--with-gd-lib=DIR],
112 [find libgd library files in DIR]),
113 [dnl
114 case "$with_gd_lib" in
115 ''|no) ;;
116 *) libgd_ldflags="-L$withval" ;;
117 esac
118 ])
120 if test -n "$libgd_include"; then
121 config_vars="$config_vars
122 CFLAGS-memusagestat.c = $libgd_include"
123 fi
124 if test -n "$libgd_ldflags"; then
125 config_vars="$config_vars
126 libgd-LDFLAGS = $libgd_ldflags"
127 fi
129 dnl Arguments to specify presence of other packages/features.
130 AC_ARG_WITH([fp],
131 AC_HELP_STRING([--with-fp],
132 [if using floating-point hardware @<:@default=yes@:>@]),
133 [with_fp=$withval],
134 [with_fp=yes])
135 AC_SUBST(with_fp)
136 AC_ARG_WITH([binutils],
137 AC_HELP_STRING([--with-binutils=PATH],
138 [specify location of binutils (as and ld)]),
139 [path_binutils=$withval],
140 [path_binutils=''])
141 AC_ARG_WITH([selinux],
142 AC_HELP_STRING([--with-selinux],
143 [if building with SELinux support]),
144 [with_selinux=$withval],
145 [with_selinux=auto])
147 AC_ARG_WITH([headers],
148 AC_HELP_STRING([--with-headers=PATH],
149 [location of system headers to use
150 (for example /usr/src/linux/include)
151 @<:@default=compiler default@:>@]),
152 [sysheaders=$withval],
153 [sysheaders=''])
154 AC_SUBST(sysheaders)
156 AC_SUBST(use_default_link)
157 AC_ARG_WITH([default-link],
158 AC_HELP_STRING([--with-default-link],
159 [do not use explicit linker scripts]),
160 [use_default_link=$withval],
161 [use_default_link=default])
163 AC_ARG_ENABLE([sanity-checks],
164 AC_HELP_STRING([--disable-sanity-checks],
165 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
166 [enable_sanity=$enableval],
167 [enable_sanity=yes])
169 AC_ARG_ENABLE([shared],
170 AC_HELP_STRING([--enable-shared],
171 [build shared library @<:@default=yes if GNU ld@:>@]),
172 [shared=$enableval],
173 [shared=yes])
174 AC_ARG_ENABLE([profile],
175 AC_HELP_STRING([--enable-profile],
176 [build profiled library @<:@default=no@:>@]),
177 [profile=$enableval],
178 [profile=no])
179 AC_ARG_ENABLE([timezone-tools],
180 AC_HELP_STRING([--disable-timezone-tools],
181 [do not install timezone tools @<:@default=install@:>@]),
182 [enable_timezone_tools=$enableval],
183 [enable_timezone_tools=yes])
184 AC_SUBST(enable_timezone_tools)
186 AC_ARG_ENABLE([hardcoded-path-in-tests],
187 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
188 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
189 [hardcoded_path_in_tests=$enableval],
190 [hardcoded_path_in_tests=no])
191 AC_SUBST(hardcoded_path_in_tests)
193 AC_ARG_ENABLE([stackguard-randomization],
194 AC_HELP_STRING([--enable-stackguard-randomization],
195 [initialize __stack_chk_guard canary with a random number at program start]),
196 [enable_stackguard_randomize=$enableval],
197 [enable_stackguard_randomize=no])
198 if test "$enable_stackguard_randomize" = yes; then
199 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
200 fi
202 AC_ARG_ENABLE([lock-elision],
203 AC_HELP_STRING([--enable-lock-elision[=yes/no]],
204 [Enable lock elision for pthread mutexes by default]),
205 [enable_lock_elision=$enableval],
206 [enable_lock_elision=no])
207 AC_SUBST(enable_lock_elision)
208 if test "$enable_lock_elision" = yes ; then
209 AC_DEFINE(ENABLE_LOCK_ELISION)
210 fi
212 dnl Generic infrastructure for drop-in additions to libc.
213 AC_ARG_ENABLE([add-ons],
214 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
215 [configure and build add-ons in DIR1,DIR2,...
216 search for add-ons if no parameter given]),
217 , [enable_add_ons=yes])
219 AC_ARG_ENABLE([hidden-plt],
220 AC_HELP_STRING([--disable-hidden-plt],
221 [do not hide internal function calls to avoid PLT]),
222 [hidden=$enableval],
223 [hidden=yes])
224 if test "x$hidden" = xno; then
225 AC_DEFINE(NO_HIDDEN)
226 fi
228 AC_ARG_ENABLE([bind-now],
229 AC_HELP_STRING([--enable-bind-now],
230 [disable lazy relocations in DSOs]),
231 [bindnow=$enableval],
232 [bindnow=no])
233 AC_SUBST(bindnow)
234 if test "x$bindnow" = xyes; then
235 AC_DEFINE(BIND_NOW)
236 fi
238 dnl On some platforms we cannot use dynamic loading. We must provide
239 dnl static NSS modules.
240 AC_ARG_ENABLE([static-nss],
241 AC_HELP_STRING([--enable-static-nss],
242 [build static NSS modules @<:@default=no@:>@]),
243 [static_nss=$enableval],
244 [static_nss=no])
245 dnl Enable static NSS also if we build no shared objects.
246 if test x"$static_nss" = xyes || test x"$shared" = xno; then
247 static_nss=yes
248 AC_DEFINE(DO_STATIC_NSS)
249 fi
251 AC_ARG_ENABLE([force-install],
252 AC_HELP_STRING([--disable-force-install],
253 [don't force installation of files from this package, even if they are older than the installed files]),
254 [force_install=$enableval],
255 [force_install=yes])
256 AC_SUBST(force_install)
258 AC_ARG_ENABLE([maintainer-mode],
259 AC_HELP_STRING([--enable-maintainer-mode],
260 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
261 [maintainer=$enableval],
262 [maintainer=no])
264 dnl On some platforms we allow dropping compatibility with all kernel
265 dnl versions.
266 AC_ARG_ENABLE([kernel],
267 AC_HELP_STRING([--enable-kernel=VERSION],
268 [compile for compatibility with kernel not older than VERSION]),
269 [minimum_kernel=$enableval],
270 [])
271 dnl Prevent unreasonable values.
272 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
273 # Better nothing than this.
274 minimum_kernel=""
275 else
276 if test "$minimum_kernel" = current; then
277 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
278 fi
279 fi
281 dnl For the development we sometimes want gcc to issue even more warnings.
282 dnl This is not the default since many of the extra warnings are not
283 dnl appropriate.
284 AC_ARG_ENABLE([all-warnings],
285 AC_HELP_STRING([--enable-all-warnings],
286 [enable all useful warnings gcc can issue]),
287 [all_warnings=$enableval],
288 [])
289 AC_SUBST(all_warnings)
291 AC_ARG_ENABLE([werror],
292 AC_HELP_STRING([--disable-werror],
293 [do not build with -Werror]),
294 [enable_werror=$enableval],
295 [enable_werror=yes])
296 AC_SUBST(enable_werror)
298 AC_ARG_ENABLE([multi-arch],
299 AC_HELP_STRING([--enable-multi-arch],
300 [enable single DSO with optimizations for multiple architectures]),
301 [multi_arch=$enableval],
302 [multi_arch=default])
304 AC_ARG_ENABLE([nss-crypt],
305 AC_HELP_STRING([--enable-nss-crypt],
306 [enable libcrypt to use nss]),
307 [nss_crypt=$enableval],
308 [nss_crypt=no])
309 if test x$nss_crypt = xyes; then
310 nss_includes=-I$(nss-config --includedir 2>/dev/null)
311 if test $? -ne 0; then
312 AC_MSG_ERROR([cannot find include directory with nss-config])
313 fi
314 old_CFLAGS="$CFLAGS"
315 CFLAGS="$CFLAGS $nss_includes"
316 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
317 #include <hasht.h>
318 #include <nsslowhash.h>
319 void f (void) { NSSLOW_Init (); }])],
320 libc_cv_nss_crypt=yes,
321 AC_MSG_ERROR([
322 cannot find NSS headers with lowlevel hash function interfaces]))
323 old_LIBS="$LIBS"
324 LIBS="$LIBS -lfreebl3"
325 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
326 #include <hasht.h>
327 #include <nsslowhash.h>],
328 [NSSLOW_Init();])],
329 libc_cv_nss_crypt=yes,
330 AC_MSG_ERROR([
331 cannot link program using lowlevel NSS hash functions]))
332 CFLAGS="$old_CFLAGS"
333 LIBS="$old_LIBS"
334 else
335 libc_cv_nss_crypt=no
336 fi
337 AC_SUBST(libc_cv_nss_crypt)
340 AC_ARG_ENABLE([obsolete-rpc],
341 AC_HELP_STRING([--enable-obsolete-rpc],
342 [build and install the obsolete RPC code for link-time usage]),
343 [link_obsolete_rpc=$enableval],
344 [link_obsolete_rpc=no])
345 AC_SUBST(link_obsolete_rpc)
347 if test "$link_obsolete_rpc" = yes; then
348 AC_DEFINE(LINK_OBSOLETE_RPC)
349 fi
351 AC_ARG_ENABLE([systemtap],
352 [AS_HELP_STRING([--enable-systemtap],
353 [enable systemtap static probe points @<:@default=no@:>@])],
354 [systemtap=$enableval],
355 [systemtap=no])
356 if test "x$systemtap" != xno; then
357 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
358 old_CFLAGS="$CFLAGS"
359 CFLAGS="-std=gnu11 $CFLAGS"
360 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
361 void foo (int i, void *p)
362 {
363 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
364 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
365 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
366 CFLAGS="$old_CFLAGS"])
367 if test $libc_cv_sdt = yes; then
368 AC_DEFINE([USE_STAP_PROBE])
369 elif test "x$systemtap" != xauto; then
370 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
371 fi
372 fi
374 AC_ARG_ENABLE([build-nscd],
375 [AS_HELP_STRING([--disable-build-nscd],
376 [disable building and installing the nscd daemon])],
377 [build_nscd=$enableval],
378 [build_nscd=default])
379 AC_SUBST(build_nscd)
381 # Note the use of $use_nscd is near the bottom of the file.
382 AC_ARG_ENABLE([nscd],
383 [AS_HELP_STRING([--disable-nscd],
384 [library functions will not contact the nscd daemon])],
385 [use_nscd=$enableval],
386 [use_nscd=yes])
388 AC_ARG_ENABLE([pt_chown],
389 [AS_HELP_STRING([--enable-pt_chown],
390 [Enable building and installing pt_chown])],
391 [build_pt_chown=$enableval],
392 [build_pt_chown=no])
393 AC_SUBST(build_pt_chown)
394 if test "$build_pt_chown" = yes; then
395 AC_DEFINE(HAVE_PT_CHOWN)
396 fi
398 # The abi-tags file uses a fairly simplistic model for name recognition that
399 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
400 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
401 # This doesn't get used much beyond that, so it's fairly safe.
402 case "$host_os" in
403 linux*)
404 ;;
405 gnu*)
406 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
407 ;;
408 esac
410 AC_ARG_ENABLE([mathvec],
411 [AS_HELP_STRING([--enable-mathvec],
412 [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
413 [build_mathvec=$enableval],
414 [build_mathvec=notset])
416 # We keep the original values in `$config_*' and never modify them, so we
417 # can write them unchanged into config.make. Everything else uses
418 # $machine, $vendor, and $os, and changes them whenever convenient.
419 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
421 # Don't allow vendor == "unknown"
422 test "$config_vendor" = unknown && config_vendor=
423 config_os="`echo $config_os | sed 's/^unknown-//'`"
425 # Some configurations imply other options.
426 elf=yes
428 # The configure fragment of an add-on port can modify these to supplement
429 # or override the table in the case statement below. No fragment should
430 # ever change the config_* variables, however.
431 machine=$config_machine
432 vendor=$config_vendor
433 os=$config_os
434 base_os=''
436 submachine=
437 AC_ARG_WITH([cpu],
438 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
439 [dnl
440 case "$withval" in
441 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
442 no) ;;
443 *) submachine="$withval" ;;
444 esac
445 ])
447 # An preconfigure script can set this when it wants to disable the sanity
448 # check below.
449 libc_config_ok=no
451 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
452 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
454 dnl Having this here, though empty, makes sure that if add-ons' fragments
455 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
456 dnl our AC_OUTPUT will actually use it.
457 AC_CONFIG_SUBDIRS()
459 case "$enable_add_ons" in
460 ''|no) add_ons= ;;
461 yes|'*')
462 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
463 sed 's@/[[^/]]*$@@' | sort | uniq`
464 add_ons_automatic=yes
465 ;;
466 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
467 add_ons_automatic=no ;;
468 esac
470 configured_add_ons=
471 add_ons_sfx=
472 add_ons_pfx=
473 if test x"$add_ons" != x; then
474 for f in $add_ons; do
475 # Some sanity checks
476 case "$f" in
477 crypt)
478 AC_MSG_ERROR([
479 *** It seems that you're using an old \`crypt' add-on. crypt is now
480 *** part of glibc and using the old add-on will not work with this
481 *** release. Start again with fresh sources and without the old
482 *** \`crypt' add-on.])
483 ;;
484 localedata)
485 AC_MSG_ERROR([
486 *** It seems that you're using an old \`localedata' add-on. localedata
487 *** is now part of glibc and using the old add-on will not work with
488 *** this release. Start again with fresh sources and without the old
489 *** \`localedata' add-on.])
490 ;;
491 esac
492 done
494 # Now source each add-on's configure fragment.
495 # The fragments can use $srcdir/$libc_add_on to find themselves,
496 # and test $add_ons_automatic to see if they were explicitly requested.
497 # A fragment can clear (or even change) $libc_add_on to affect
498 # whether it goes into the list to be actually used in the build.
499 use_add_ons=
500 for libc_add_on in $add_ons; do
501 # Test whether such a directory really exists.
502 # It can be absolute, or relative to $srcdir, or relative to the build dir.
503 case "$libc_add_on" in
504 /*)
505 libc_add_on_srcdir=$libc_add_on
506 ;;
507 *)
508 test -d "$srcdir/$libc_add_on" || {
509 if test -d "$libc_add_on"; then
510 libc_add_on="`pwd`/$libc_add_on"
511 else
512 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
513 fi
514 }
515 libc_add_on_srcdir=$srcdir/$libc_add_on
516 ;;
517 esac
519 libc_add_on_frag=$libc_add_on_srcdir/configure
520 libc_add_on_canonical=
521 libc_add_on_config_subdirs=
522 if test -r "$libc_add_on_frag"; then
523 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
524 libc_add_on_canonical=unknown
525 libc_add_on_subdirs=
526 . "$libc_add_on_frag"
527 test -z "$libc_add_on" || {
528 configured_add_ons="$configured_add_ons $libc_add_on"
529 if test "x$libc_add_on_canonical" = xunknown; then
530 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
531 fi
532 for d in $libc_add_on_subdirs; do
533 case "$libc_add_on" in
534 /*) subdir_srcdir="$libc_add_on" ;;
535 *) subdir_srcdir="\$(..)$libc_add_on" ;;
536 esac
537 case "$d" in
538 .)
539 d="${libc_add_on_canonical:-$libc_add_on}"
540 ;;
541 /*)
542 subdir_srcdir="$d"
543 ;;
544 *)
545 subdir_srcdir="$subdir_srcdir/$d"
546 ;;
547 esac
548 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
549 add_on_subdirs="$add_on_subdirs $d"
550 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
551 $d-srcdir = $subdir_srcdir"
552 done
553 for d in $libc_add_on_config_subdirs; do
554 case "$d" in
555 /*) AC_MSG_ERROR(dnl
556 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
557 esac
558 if test ! -d "$libc_add_on_srcdir/$d"; then
559 AC_MSG_ERROR(fragment wants to configure missing directory $d)
560 fi
561 case "$libc_add_on" in
562 /*) AC_MSG_ERROR(dnl
563 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
564 esac
565 subdirs="$subdirs $libc_add_on/$d"
566 done
567 }
568 fi
569 if test -n "$libc_add_on"; then
570 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
571 use_add_ons="$use_add_ons $libc_add_on"
572 add_ons_pfx="$add_ons_pfx $libc_add_on/"
573 test -z "$libc_add_on_canonical" ||
574 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
575 fi
576 done
577 # Use echo to strip excess whitespace.
578 add_ons="`echo $use_add_ons`"
579 fi
580 AC_SUBST(add_ons)
581 AC_SUBST(add_on_subdirs)
584 ###
585 ### By using the undocumented --enable-hacker-mode option for configure
586 ### one can skip this test to make the configuration not fail for unsupported
587 ### platforms.
588 ###
589 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
590 case "$machine-$host_os" in
591 *-linux* | *-gnu*)
592 ;;
593 *)
594 AC_MSG_ERROR([
595 *** The GNU C library is currently unavailable for this platform.
596 *** If you are interested in seeing glibc on this platform visit
597 *** the "How to submit a new port" in the wiki:
598 *** https://sourceware.org/glibc/wiki/#Development
599 *** and join the community!])
600 ;;
601 esac
602 fi
604 # Set base_machine if not set by a preconfigure fragment.
605 test -n "$base_machine" || base_machine=$machine
606 AC_SUBST(base_machine)
608 # For the multi-arch option we need support in the assembler & linker.
609 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
610 libc_cv_ld_gnu_indirect_function, [dnl
611 cat > conftest.S <<EOF
612 .type foo,%gnu_indirect_function
613 foo:
614 .globl _start
615 _start:
616 .globl __start
617 __start:
618 .data
619 #ifdef _LP64
620 .quad foo
621 #else
622 .long foo
623 #endif
624 EOF
625 libc_cv_ld_gnu_indirect_function=no
626 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
627 -nostartfiles -nostdlib \
628 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
629 # Do a link to see if the backend supports IFUNC relocs.
630 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
631 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
632 libc_cv_ld_gnu_indirect_function=yes
633 }
634 fi
635 rm -f conftest*])
637 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
638 AC_CACHE_CHECK([for gcc attribute ifunc support],
639 libc_cv_gcc_indirect_function, [dnl
640 cat > conftest.c <<EOF
641 extern int func (int);
642 int used_func (int a)
643 {
644 return a;
645 }
646 static void *resolver ()
647 {
648 return &used_func;
649 }
650 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
651 EOF
652 libc_cv_gcc_indirect_function=no
653 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
654 2>&AS_MESSAGE_LOG_FD ; then
655 if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
656 libc_cv_gcc_indirect_function=yes
657 fi
658 fi
659 rm -f conftest*])
661 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
662 if test x"$multi_arch" = xyes; then
663 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
664 else
665 multi_arch=no
666 fi
667 fi
668 if test x"$libc_cv_gcc_indirect_function" != xyes &&
669 test x"$multi_arch" = xyes; then
670 AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
671 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
672 fi
673 multi_arch_d=
674 if test x"$multi_arch" != xno; then
675 multi_arch_d=/multiarch
676 fi
678 # Compute the list of sysdep directories for this configuration.
679 # This can take a while to compute.
680 sysdep_dir=$srcdir/sysdeps
681 AC_MSG_CHECKING(sysdep dirs)
682 dnl We need to use [ and ] for other purposes for a while now.
683 changequote(,)dnl
684 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
685 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
687 test "x$base_os" != x || case "$os" in
688 gnu*)
689 base_os=mach/hurd ;;
690 linux*)
691 base_os=unix/sysv ;;
692 esac
694 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
695 tail=$os
696 ostry=$os
697 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
698 ostry="$ostry /$o"
699 tail=$o
700 done
701 o=`echo $tail | sed 's/[0-9]*$//'`
702 if test $o != $tail; then
703 ostry="$ostry /$o"
704 fi
705 # For linux-gnu, try linux-gnu, then linux.
706 o=`echo $tail | sed 's/-.*$//'`
707 if test $o != $tail; then
708 ostry="$ostry /$o"
709 fi
711 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
712 base=
713 tail=$base_os
714 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
715 set $b
716 base="$base /$1"
717 tail="$2"
718 done
720 # For sparc/sparc32, try sparc/sparc32 and then sparc.
721 mach=
722 tail=$machine${submachine:+/$submachine}
723 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
724 set $m
725 # Prepend the machine's FPU directory unless --without-fp.
726 if test "$with_fp" = yes; then
727 maybe_fpu=/fpu
728 else
729 maybe_fpu=/nofpu
730 fi
731 # For each machine term, try it with and then without /multiarch.
732 for try_fpu in $maybe_fpu ''; do
733 for try_multi in $multi_arch_d ''; do
734 mach="$mach /$1$try_fpu$try_multi"
735 done
736 done
737 tail="$2"
738 done
740 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
741 changequote([,])dnl
743 # Find what sysdep directories exist.
744 sysnames_add_ons=
745 sysnames=
746 for b in $base ''; do
747 for m0 in $mach ''; do
748 for v in /$vendor ''; do
749 test "$v" = / && continue
750 for o in /$ostry ''; do
751 test "$o" = / && continue
752 for m in $mach ''; do
753 for d in $add_ons_pfx ''; do
754 for a in $add_ons_sfx ''; do
755 try_suffix="$m0$b$v$o$m"
756 if test -n "$try_suffix"; then
757 try_srcdir="${srcdir}/"
758 case "$d" in
759 /*) try_srcdir= ;;
760 esac
761 try="${d}sysdeps$try_suffix$a"
762 test -n "$enable_debug_configure" &&
763 echo "$0 [DEBUG]: try $try" >&2
764 if test -d "$try_srcdir$try"; then
765 sysnames="$sysnames $try"
766 { test -n "$o" || test -n "$b"; } && os_used=t
767 { test -n "$m" || test -n "$m0"; } && machine_used=t
768 case x${m0:-$m} in
769 x*/$submachine) submachine_used=t ;;
770 esac
771 if test -n "$d"; then
772 case "$sysnames_add_ons" in
773 *" $d "*) ;;
774 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
775 esac
776 fi
777 fi
778 fi
779 done
780 done
781 done
782 done
783 done
784 done
785 done
787 # If the assembler supports gnu_indirect_function symbol type and the
788 # architecture supports multi-arch, we enable multi-arch by default.
789 case $sysnames_add_ons$sysnames in
790 *"$multi_arch_d"*)
791 ;;
792 *)
793 test x"$multi_arch" = xdefault && multi_arch=no
794 ;;
795 esac
796 if test x"$multi_arch" != xno; then
797 AC_DEFINE(USE_MULTIARCH)
798 fi
799 AC_SUBST(multi_arch)
801 if test -z "$os_used" && test "$os" != none; then
802 AC_MSG_ERROR(Operating system $os is not supported.)
803 fi
804 if test -z "$machine_used" && test "$machine" != none; then
805 AC_MSG_ERROR(The $machine is not supported.)
806 fi
807 if test -z "$submachine_used" && test -n "$submachine"; then
808 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
809 fi
810 AC_SUBST(submachine)
812 # We have now validated the configuration.
814 # Expand the list of system names into a full list of directories
815 # from each element's parent name and Implies file (if present).
816 set $sysnames
817 names=
818 while test $# -gt 0; do
819 name=$1
820 shift
822 case " $names " in *" $name "*)
823 # Already in the list.
824 continue
825 esac
827 # Report each name as we discover it, so there is no long pause in output.
828 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
830 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
832 case $name in
833 /*) xsrcdir= ;;
834 *) xsrcdir=$srcdir/ ;;
835 esac
836 test -n "$enable_debug_configure" &&
837 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
839 for implies_file in Implies Implies-before Implies-after; do
840 implies_type=`echo $implies_file | sed s/-/_/`
841 eval ${implies_type}=
842 if test -f $xsrcdir$name/$implies_file; then
843 # Collect more names from the `Implies' file (removing comments).
844 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
845 for x in $implied_candidate; do
846 found=no
847 if test -d $xsrcdir$name_base/$x; then
848 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
849 found=yes
850 fi
851 for d in $add_ons_pfx ''; do
852 try="${d}sysdeps/$x"
853 case $d in
854 /*) try_srcdir= ;;
855 *) try_srcdir=$srcdir/ ;;
856 esac
857 test -n "$enable_debug_configure" &&
858 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
859 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
860 then
861 eval "${implies_type}=\"\$${implies_type} \$try\""
862 found=yes
863 case "$sysnames_add_ons" in
864 *" $d "*) ;;
865 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
866 esac
867 fi
868 done
869 if test $found = no; then
870 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
871 fi
872 done
873 fi
874 done
876 # Add NAME to the list of names.
877 names="$names $name"
879 # Find the parent of NAME, using the empty string if it has none.
880 changequote(,)dnl
881 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
882 changequote([,])dnl
884 test -n "$enable_debug_configure" &&
885 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
886 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
888 # Add the names implied by NAME, and NAME's parent (if it has one), to
889 # the list of names to be processed (the argument list). We prepend the
890 # implied names to the list and append the parent. We want implied
891 # directories to come before further directories inferred from the
892 # configuration components; this ensures that for sysv4, unix/common
893 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
894 # after sysv4).
895 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
896 test -n "$sysnames" && set $sysnames
897 done
899 # Add the default directories.
900 default_sysnames="sysdeps/generic"
901 sysnames="$names $default_sysnames"
902 AC_SUBST(sysnames)
903 # The other names were emitted during the scan.
904 AC_MSG_RESULT($default_sysnames)
906 # Collect the list of add-ons that supply partial sysdeps trees.
907 sysdeps_add_ons=
908 for add_on in $add_ons; do
909 case "$add_on" in
910 /*) xsrcdir= ;;
911 *) xsrcdir="$srcdir/" ;;
912 esac
914 test -d "$xsrcdir$add_on/sysdeps" || {
915 case "$configured_add_ons " in
916 *" $add_on "*) ;;
917 *|'')
918 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
919 ;;
920 esac
921 continue
922 }
924 sysdeps_add_ons="$sysdeps_add_ons $add_on"
925 case "$sysnames_add_ons" in
926 *" $add_on/ "*) ;;
927 *|'')
928 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
929 continue ;;
930 esac
932 found=no
933 for d in $sysnames; do
934 case "$d" in
935 $add_on/sysdeps/*) ;;
936 *) continue ;;
937 esac
938 (cd "$xsrcdir$d" && for f in *[[!~]]; do
939 case "$f" in
940 sys|bits)
941 for ff in $f/*.h; do
942 test -d "$ff" || { test -e "$ff" && exit 88; }
943 done
944 ;;
945 *)
946 test -d "$f" || { test -e "$f" && exit 88; }
947 ;;
948 esac
949 done)
950 if test $? -eq 88; then
951 found=yes
952 break
953 fi
954 done
955 if test $found = no; then
956 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
957 fi
958 done
959 AC_SUBST(sysdeps_add_ons)
962 ### Locate tools.
964 AC_PROG_INSTALL
965 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
966 # The makefiles need to use a different form to find it in $srcdir.
967 INSTALL='\$(..)./scripts/install-sh -c'
968 fi
969 AC_PROG_LN_S
971 LIBC_PROG_BINUTILS
973 # Accept binutils 2.22 or newer.
974 AC_CHECK_PROG_VER(AS, $AS, --version,
975 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
976 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
977 AS=: critic_missing="$critic_missing as")
978 AC_CHECK_PROG_VER(LD, $LD, --version,
979 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
980 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
981 LD=: critic_missing="$critic_missing ld")
983 # These programs are version sensitive.
984 AC_CHECK_TOOL_PREFIX
985 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
986 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
987 [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
989 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
990 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
991 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
992 MSGFMT=: aux_missing="$aux_missing msgfmt")
993 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
994 [GNU texinfo.* \([0-9][0-9.]*\)],
995 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
996 MAKEINFO=: aux_missing="$aux_missing makeinfo")
997 AC_CHECK_PROG_VER(SED, sed, --version,
998 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
999 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1000 SED=: aux_missing="$aux_missing sed")
1001 AC_CHECK_PROG_VER(AWK, gawk, --version,
1002 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1003 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1005 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1006 AC_TRY_COMPILE([], [
1007 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
1008 #error insufficient compiler
1009 #endif],
1010 [libc_cv_compiler_ok=yes],
1011 [libc_cv_compiler_ok=no])])
1012 AS_IF([test $libc_cv_compiler_ok != yes],
1013 [critic_missing="$critic_missing compiler"])
1015 AC_CHECK_TOOL(NM, nm, false)
1017 if test "x$maintainer" = "xyes"; then
1018 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1019 case "x$AUTOCONF" in
1020 xno|x|x:) AUTOCONF=no ;;
1021 *)
1022 AC_CACHE_CHECK(dnl
1023 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1024 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1025 libc_cv_autoconf_works=yes
1026 else
1027 libc_cv_autoconf_works=no
1028 fi])
1029 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1030 ;;
1031 esac
1032 if test "x$AUTOCONF" = xno; then
1033 aux_missing="$aux_missing autoconf"
1034 fi
1035 else
1036 AUTOCONF=no
1037 fi
1039 test -n "$critic_missing" && AC_MSG_ERROR([
1040 *** These critical programs are missing or too old:$critic_missing
1041 *** Check the INSTALL file for required versions.])
1043 test -n "$aux_missing" && AC_MSG_WARN([
1044 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1045 *** some features will be disabled.
1046 *** Check the INSTALL file for required versions.])
1048 # if using special system headers, find out the compiler's sekrit
1049 # header directory and add that to the list. NOTE: Only does the right
1050 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1051 if test -n "$sysheaders"; then
1052 SYSINCLUDES=-nostdinc
1053 for d in include include-fixed; do
1054 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1055 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1056 done
1057 SYSINCLUDES="$SYSINCLUDES \
1058 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1059 if test -n "$CXX"; then
1060 CXX_SYSINCLUDES=
1061 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1062 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1063 test "x$cxxheaders" != x &&
1064 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1065 done
1066 fi
1067 fi
1068 AC_SUBST(SYSINCLUDES)
1069 AC_SUBST(CXX_SYSINCLUDES)
1071 # Obtain some C++ header file paths. This is used to make a local
1072 # copy of those headers in Makerules.
1073 if test -n "$CXX"; then
1074 find_cxx_header () {
1075 echo "#include <$1>" | $CXX -M -MP -x c++ - | sed -n "/$1:/{s/:\$//;p}"
1076 }
1077 CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1078 CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1079 fi
1080 AC_SUBST(CXX_CSTDLIB_HEADER)
1081 AC_SUBST(CXX_CMATH_HEADER)
1083 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1084 # since this would lead to problems installing/building glibc.
1085 # LD_LIBRARY_PATH contains the current directory if one of the following
1086 # is true:
1087 # - one of the terminals (":" and ";") is the first or last sign
1088 # - two terminals occur directly after each other
1089 # - the path contains an element with a dot in it
1090 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1091 changequote(,)dnl
1092 case ${LD_LIBRARY_PATH} in
1093 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1094 ld_library_path_setting="contains current directory"
1095 ;;
1096 *)
1097 ld_library_path_setting="ok"
1098 ;;
1099 esac
1100 changequote([,])dnl
1101 AC_MSG_RESULT($ld_library_path_setting)
1102 if test "$ld_library_path_setting" != "ok"; then
1103 AC_MSG_ERROR([
1104 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1105 *** building glibc. Please change the environment variable
1106 *** and run configure again.])
1107 fi
1109 AC_PATH_PROG(BASH_SHELL, bash, no)
1111 AC_PATH_PROG(PERL, perl, no)
1112 if test "$PERL" != no &&
1113 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1114 PERL=no
1115 fi
1116 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1117 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1118 AC_CHECK_PROG_VER(BISON, bison, --version,
1119 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1120 [2.7*|[3-9].*|[1-9][0-9]*],
1121 BISON=no)
1123 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1124 cat > conftest.s <<EOF
1125 .text
1126 foo:
1127 .set glibc_conftest_frobozz,foo
1128 .globl glibc_conftest_frobozz
1129 EOF
1130 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1131 # (but it doesn't work), so we must do a linking check to be sure.
1132 cat > conftest1.c <<\EOF
1133 extern int glibc_conftest_frobozz;
1134 void _start() { glibc_conftest_frobozz = 1; }
1135 EOF
1136 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1137 -nostartfiles -nostdlib \
1138 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1139 libc_cv_asm_set_directive=yes
1140 else
1141 libc_cv_asm_set_directive=no
1142 fi
1143 rm -f conftest*])
1144 if test $libc_cv_asm_set_directive = yes; then
1145 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1146 fi
1148 AC_CACHE_CHECK(linker support for protected data symbol,
1149 libc_cv_protected_data,
1150 [cat > conftest.c <<EOF
1151 int bar __attribute__ ((visibility ("protected"))) = 1;
1152 EOF
1153 libc_cv_protected_data=no
1154 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1155 cat > conftest.c <<EOF
1156 extern int bar;
1157 int main (void) { return bar; }
1158 EOF
1159 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1160 libc_cv_protected_data=yes
1161 fi
1162 fi
1163 rm -f conftest.*
1164 ])
1165 AC_SUBST(libc_cv_protected_data)
1167 AC_CACHE_CHECK(for broken __attribute__((alias())),
1168 libc_cv_broken_alias_attribute,
1169 [cat > conftest.c <<EOF
1170 extern int foo (int x) __asm ("xyzzy");
1171 int bar (int x) { return x; }
1172 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1173 extern int dfoo;
1174 extern __typeof (dfoo) dfoo __asm ("abccb");
1175 int dfoo = 1;
1176 EOF
1177 libc_cv_broken_alias_attribute=yes
1178 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1179 if grep 'xyzzy' conftest.s >/dev/null &&
1180 grep 'abccb' conftest.s >/dev/null; then
1181 libc_cv_broken_alias_attribute=no
1182 fi
1183 fi
1184 rm -f conftest.c conftest.s
1185 ])
1186 if test $libc_cv_broken_alias_attribute = yes; then
1187 AC_MSG_ERROR(working alias attribute support required)
1188 fi
1190 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1191 libc_cv_have_sdata_section,
1192 [echo "int i;" > conftest.c
1193 libc_cv_have_sdata_section=no
1194 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1195 | grep '\.sdata' >/dev/null; then
1196 libc_cv_have_sdata_section=yes
1197 fi
1198 rm -f conftest.c conftest.so
1199 ])
1200 if test $libc_cv_have_sdata_section = yes; then
1201 AC_DEFINE(HAVE_SDATA_SECTION)
1202 fi
1204 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1205 libc_cv_ctors_header, [dnl
1206 libc_cv_ctors_header=yes
1207 LIBC_TRY_LINK_STATIC([
1208 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1209 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1210 ],
1211 [dnl
1212 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1213 { gsub(/\@<:@ */, "@<:@") }
1214 $2 == ".ctors" || $2 == ".dtors" {
1215 size = strtonum("0x" $6)
1216 align = strtonum("0x" $NF)
1217 seen@<:@$2@:>@ = 1
1218 stub@<:@$2@:>@ = size == align * 2
1219 }
1220 END {
1221 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1222 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1223 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1224 }
1225 '], [libc_cv_ctors_header=no])
1226 ], [dnl
1227 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1228 ])
1229 ])
1230 if test $libc_cv_ctors_header = no; then
1231 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1232 fi
1234 AC_CACHE_CHECK(for libunwind-support in compiler,
1235 libc_cv_cc_with_libunwind, [
1236 cat > conftest.c <<EOF
1237 int main (void) { return 0; }
1238 EOF
1239 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1240 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1241 libc_cv_cc_with_libunwind=yes
1242 else
1243 libc_cv_cc_with_libunwind=no
1244 fi
1245 rm -f conftest*])
1246 AC_SUBST(libc_cv_cc_with_libunwind)
1247 if test $libc_cv_cc_with_libunwind = yes; then
1248 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1249 fi
1251 ASFLAGS_config=
1252 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1253 libc_cv_as_noexecstack, [dnl
1254 cat > conftest.c <<EOF
1255 void foo (void) { }
1256 EOF
1257 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1258 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1259 && grep .note.GNU-stack conftest.s >/dev/null \
1260 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1261 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1262 then
1263 libc_cv_as_noexecstack=yes
1264 else
1265 libc_cv_as_noexecstack=no
1266 fi
1267 rm -f conftest*])
1268 if test $libc_cv_as_noexecstack = yes; then
1269 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1270 fi
1271 AC_SUBST(ASFLAGS_config)
1273 AC_CACHE_CHECK(for -z combreloc,
1274 libc_cv_z_combreloc, [dnl
1275 cat > conftest.c <<EOF
1276 extern int bar (int);
1277 extern int mumble;
1278 int foo (void) { return bar (mumble); }
1279 EOF
1280 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1281 -fPIC -shared -o conftest.so conftest.c
1282 -nostdlib -nostartfiles
1283 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1284 then
1285 dnl The following test is a bit weak. We must use a tool which can test
1286 dnl cross-platform since the gcc used can be a cross compiler. Without
1287 dnl introducing new options this is not easily doable. Instead use a tool
1288 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1289 dnl look for a section named .rel.dyn.
1290 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1291 libc_cv_z_combreloc=yes
1292 else
1293 libc_cv_z_combreloc=no
1294 fi
1295 else
1296 libc_cv_z_combreloc=no
1297 fi
1298 rm -f conftest*])
1299 if test "$libc_cv_z_combreloc" = yes; then
1300 AC_DEFINE(HAVE_Z_COMBRELOC)
1301 fi
1302 AC_SUBST(libc_cv_z_combreloc)
1304 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1305 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1306 AC_SUBST(libc_cv_z_execstack)
1308 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1309 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1310 ])
1312 AC_SUBST(libc_cv_fpie)
1314 AC_CACHE_CHECK(for --hash-style option,
1315 libc_cv_hashstyle, [dnl
1316 cat > conftest.c <<EOF
1317 int _start (void) { return 42; }
1318 EOF
1319 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1320 -fPIC -shared -o conftest.so conftest.c
1321 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1322 then
1323 libc_cv_hashstyle=yes
1324 else
1325 libc_cv_hashstyle=no
1326 fi
1327 rm -f conftest*])
1328 AC_SUBST(libc_cv_hashstyle)
1330 # The linker's default -shared behavior is good enough if it
1331 # does these things that our custom linker scripts ensure that
1332 # all allocated NOTE sections come first.
1333 if test "$use_default_link" = default; then
1334 AC_CACHE_CHECK([for sufficient default -shared layout],
1335 libc_cv_use_default_link, [dnl
1336 libc_cv_use_default_link=no
1337 cat > conftest.s <<\EOF
1338 .section .note.a,"a",%note
1339 .balign 4
1340 .long 4,4,9
1341 .string "GNU"
1342 .string "foo"
1343 .section .note.b,"a",%note
1344 .balign 4
1345 .long 4,4,9
1346 .string "GNU"
1347 .string "bar"
1348 EOF
1349 if AC_TRY_COMMAND([dnl
1350 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1351 ac_try=`$READELF -S conftest.so | sed -n \
1352 ['${x;p;}
1353 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1354 t a
1355 b
1356 : a
1357 H']`
1358 then
1359 libc_seen_a=no libc_seen_b=no
1360 set -- $ac_try
1361 while test $# -ge 2 -a "$1" = NOTE; do
1362 case "$2" in
1363 .note.a) libc_seen_a=yes ;;
1364 .note.b) libc_seen_b=yes ;;
1365 esac
1366 shift 2
1367 done
1368 case "$libc_seen_a$libc_seen_b" in
1369 yesyes)
1370 libc_cv_use_default_link=yes
1371 ;;
1372 *)
1373 echo >&AS_MESSAGE_LOG_FD "\
1374 $libc_seen_a$libc_seen_b from:
1375 $ac_try"
1376 ;;
1377 esac
1378 fi
1379 rm -f conftest*])
1380 use_default_link=$libc_cv_use_default_link
1381 fi
1383 AC_CACHE_CHECK(for GLOB_DAT reloc,
1384 libc_cv_has_glob_dat, [dnl
1385 cat > conftest.c <<EOF
1386 extern int mumble;
1387 int foo (void) { return mumble; }
1388 EOF
1389 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1390 -fPIC -shared -o conftest.so conftest.c
1391 -nostdlib -nostartfiles
1392 1>&AS_MESSAGE_LOG_FD])
1393 then
1394 dnl look for GLOB_DAT relocation.
1395 if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1396 libc_cv_has_glob_dat=yes
1397 else
1398 libc_cv_has_glob_dat=no
1399 fi
1400 else
1401 libc_cv_has_glob_dat=no
1402 fi
1403 rm -f conftest*])
1404 AC_SUBST(libc_cv_has_glob_dat)
1406 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1407 if libc_cv_output_format=`
1408 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1409 then
1410 :
1411 else
1412 libc_cv_output_format=
1413 fi
1414 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1415 AC_SUBST(libc_cv_output_format)
1417 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1418 cat > conftest.c <<EOF
1419 int foo;
1420 EOF
1421 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1422 conftest.c 1>&AS_MESSAGE_LOG_FD])
1423 then
1424 libc_cv_fno_toplevel_reorder=yes
1425 else
1426 libc_cv_fno_toplevel_reorder=no
1427 fi
1428 rm -f conftest*])
1429 if test $libc_cv_fno_toplevel_reorder = yes; then
1430 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1431 else
1432 fno_unit_at_a_time=-fno-unit-at-a-time
1433 fi
1434 AC_SUBST(fno_unit_at_a_time)
1436 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1437 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1438 [libc_cv_ssp=yes],
1439 [libc_cv_ssp=no])
1440 ])
1442 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1443 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1444 [libc_cv_ssp_strong=yes],
1445 [libc_cv_ssp_strong=no])
1446 ])
1448 stack_protector=
1449 if test "$libc_cv_ssp_strong" = "yes"; then
1450 stack_protector="-fstack-protector-strong"
1451 elif test "$libc_cv_ssp" = "yes"; then
1452 stack_protector="-fstack-protector"
1453 fi
1454 AC_SUBST(stack_protector)
1456 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1457 [dnl
1458 cat > conftest.c <<EOF
1459 __thread int i;
1460 void foo (void)
1461 {
1462 i = 10;
1463 }
1464 EOF
1465 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1466 conftest.c 1>&AS_MESSAGE_LOG_FD])
1467 then
1468 libc_cv_mtls_dialect_gnu2=yes
1469 else
1470 libc_cv_mtls_dialect_gnu2=no
1471 fi
1472 rm -f conftest*])
1473 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1474 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1476 AC_CACHE_CHECK(whether cc puts quotes around section names,
1477 libc_cv_have_section_quotes,
1478 [cat > conftest.c <<EOF
1479 static const int foo
1480 __attribute__ ((section ("bar"))) = 1;
1481 EOF
1482 if ${CC-cc} -S conftest.c -o conftest.s; then
1483 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1484 libc_cv_have_section_quotes=yes
1485 else
1486 libc_cv_have_section_quotes=no
1487 fi
1488 else
1489 libc_cv_have_section_quotes=unknown
1490 fi
1491 rm -f conftest.{c,s}
1492 ])
1493 if test $libc_cv_have_section_quotes = yes; then
1494 AC_DEFINE(HAVE_SECTION_QUOTES)
1495 fi
1497 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1498 cat > conftest.c <<\EOF
1499 void zero (void *x)
1500 {
1501 __builtin_memset (x, 0, 1000);
1502 }
1503 EOF
1504 dnl
1505 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1506 then
1507 libc_cv_gcc_builtin_memset=no
1508 else
1509 libc_cv_gcc_builtin_memset=yes
1510 fi
1511 rm -f conftest* ])
1512 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1513 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1514 fi
1516 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1517 cat > conftest.c <<\EOF
1518 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1519 char *foo (const char *a, const char *b)
1520 {
1521 return __builtin_strstr (a, b);
1522 }
1523 EOF
1524 dnl
1525 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1526 then
1527 libc_cv_gcc_builtin_redirection=yes
1528 else
1529 libc_cv_gcc_builtin_redirection=no
1530 fi
1531 rm -f conftest* ])
1532 if test "$libc_cv_gcc_builtin_redirection" = no; then
1533 AC_MSG_ERROR([support for the symbol redirection needed])
1534 fi
1536 dnl Determine how to disable generation of FMA instructions.
1537 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1538 libc_cv_cc_nofma, [dnl
1539 libc_cv_cc_nofma=
1540 for opt in -ffp-contract=off -mno-fused-madd; do
1541 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1542 done])
1543 AC_SUBST(libc_cv_cc_nofma)
1545 if test -n "$submachine"; then
1546 AC_CACHE_CHECK([for compiler option for CPU variant],
1547 libc_cv_cc_submachine, [dnl
1548 libc_cv_cc_submachine=no
1549 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1550 LIBC_TRY_CC_OPTION([$opt], [
1551 libc_cv_cc_submachine="$opt"
1552 break], [])
1553 done])
1554 if test "x$libc_cv_cc_submachine" = xno; then
1555 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1556 fi
1557 fi
1558 AC_SUBST(libc_cv_cc_submachine)
1560 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1561 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1562 cat > conftest.c <<EOF
1563 void
1564 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1565 foo (void) {}
1566 EOF
1567 libc_cv_cc_loop_to_function=no
1568 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1569 then
1570 libc_cv_cc_loop_to_function=yes
1571 fi
1572 rm -f conftest*])
1573 if test $libc_cv_cc_loop_to_function = yes; then
1574 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1575 fi
1576 AC_SUBST(libc_cv_cc_loop_to_function)
1578 dnl Check whether we have the gd library available.
1579 AC_MSG_CHECKING(for libgd)
1580 if test "$with_gd" != "no"; then
1581 old_CFLAGS="$CFLAGS"
1582 CFLAGS="$CFLAGS $libgd_include"
1583 old_LDFLAGS="$LDFLAGS"
1584 LDFLAGS="$LDFLAGS $libgd_ldflags"
1585 old_LIBS="$LIBS"
1586 LIBS="$LIBS -lgd -lpng -lz -lm"
1587 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1588 CFLAGS="$old_CFLAGS"
1589 LDFLAGS="$old_LDFLAGS"
1590 LIBS="$old_LIBS"
1591 else
1592 LIBGD=no
1593 fi
1594 AC_MSG_RESULT($LIBGD)
1595 AC_SUBST(LIBGD)
1597 # SELinux detection
1598 if test x$with_selinux = xno ; then
1599 have_selinux=no;
1600 else
1601 # See if we have the SELinux library
1602 AC_CHECK_LIB(selinux, is_selinux_enabled,
1603 have_selinux=yes, have_selinux=no)
1604 if test x$with_selinux = xyes ; then
1605 if test x$have_selinux = xno ; then
1606 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1607 fi
1608 fi
1609 fi
1610 # Check if we're building with SELinux support.
1611 if test "x$have_selinux" = xyes; then
1612 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1614 # See if we have the libaudit library
1615 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1616 have_libaudit=yes, have_libaudit=no)
1617 if test "x$have_libaudit" = xyes; then
1618 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1619 fi
1620 AC_SUBST(have_libaudit)
1622 # See if we have the libcap library
1623 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1624 if test "x$have_libcap" = xyes; then
1625 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1626 fi
1627 AC_SUBST(have_libcap)
1628 fi
1629 AC_SUBST(have_selinux)
1631 CPPUNDEFS=
1632 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1633 dnl Since we are building the implementations of the fortified functions here,
1634 dnl having the macro defined interacts very badly.
1635 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1636 [AC_TRY_COMPILE([], [
1637 #ifdef _FORTIFY_SOURCE
1638 # error bogon
1639 #endif],
1640 [libc_cv_predef_fortify_source=no],
1641 [libc_cv_predef_fortify_source=yes])])
1642 if test $libc_cv_predef_fortify_source = yes; then
1643 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1644 fi
1645 AC_SUBST(CPPUNDEFS)
1647 dnl Check for silly hacked compilers inserting -fstack-protector.
1648 dnl This breaks badly for the early startup code we compile, since
1649 dnl the compiled code can refer to a magic machine-dependent location
1650 dnl for the canary value before we have sufficient setup for that to
1651 dnl work. It's also questionable to build all of libc with this flag
1652 dnl even when you're doing that for most applications you build, since
1653 dnl libc's code is so heavily-used and performance-sensitive. If we
1654 dnl ever really want to make that work, it should be enabled explicitly
1655 dnl in the libc build, not inherited from implicit compiler settings.
1656 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1657 libc_cv_predef_stack_protector, [
1658 AC_TRY_COMPILE([extern void foobar (char *);],
1659 [char large_array[2048]; foobar (large_array);], [
1660 libc_undefs=`$NM -u conftest.o |
1661 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1662 2>&AS_MESSAGE_LOG_FD` || {
1663 AC_MSG_ERROR([confusing output from $NM -u])
1664 }
1665 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1666 # On some architectures, there are architecture-specific undefined
1667 # symbols (resolved by the linker), so filter out unknown symbols.
1668 # This will fail to produce the correct result if the compiler
1669 # defaults to -fstack-protector but this produces an undefined symbol
1670 # other than __stack_chk_fail. However, compilers like that have not
1671 # been encountered in practice.
1672 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1673 case "$libc_undefs" in
1674 foobar) libc_cv_predef_stack_protector=no ;;
1675 '__stack_chk_fail
1676 foobar') libc_cv_predef_stack_protector=yes ;;
1677 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1678 esac],
1679 [AC_MSG_ERROR([test compilation failed])])
1680 ])
1681 libc_extra_cflags=
1682 if test $libc_cv_predef_stack_protector = yes; then
1683 libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1684 fi
1685 libc_extra_cppflags=
1687 # Some linkers on some architectures support __ehdr_start but with
1688 # bugs. Make sure usage of it does not create relocations in the
1689 # output (as the linker should resolve them all for us).
1690 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1691 libc_cv_ehdr_start, [
1692 old_CFLAGS="$CFLAGS"
1693 old_LDFLAGS="$LDFLAGS"
1694 old_LIBS="$LIBS"
1695 CFLAGS="$CFLAGS -fPIC"
1696 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1697 LIBS=
1698 AC_LINK_IFELSE([AC_LANG_SOURCE([
1699 typedef struct {
1700 char foo;
1701 long val;
1702 } Ehdr;
1703 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1704 long ehdr (void) { return __ehdr_start.val; }
1705 ])],
1706 [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1707 libc_cv_ehdr_start=broken
1708 else
1709 libc_cv_ehdr_start=yes
1710 fi], [libc_cv_ehdr_start=no])
1711 CFLAGS="$old_CFLAGS"
1712 LDFLAGS="$old_LDFLAGS"
1713 LIBS="$old_LIBS"
1714 ])
1715 if test "$libc_cv_ehdr_start" = yes; then
1716 AC_DEFINE([HAVE_EHDR_START])
1717 elif test "$libc_cv_ehdr_start" = broken; then
1718 AC_MSG_WARN([linker is broken -- you should upgrade])
1719 fi
1721 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1722 libc_cv_builtin_trap, [dnl
1723 libc_cv_builtin_trap=no
1724 AC_TRY_COMPILE([], [__builtin_trap ()], [
1725 libc_undefs=`$NM -u conftest.o |
1726 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1727 2>&AS_MESSAGE_LOG_FD` || {
1728 AC_MSG_ERROR([confusing output from $NM -u])
1729 }
1730 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1731 if test -z "$libc_undefs"; then
1732 libc_cv_builtin_trap=yes
1733 fi])])
1734 if test $libc_cv_builtin_trap = yes; then
1735 AC_DEFINE([HAVE_BUILTIN_TRAP])
1736 fi
1738 dnl C++ feature tests.
1739 AC_LANG_PUSH([C++])
1741 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1742 libc_cv_cxx_thread_local, [
1743 old_CXXFLAGS="$CXXFLAGS"
1744 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1745 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1746 #include <thread>
1748 // Compiler support.
1749 struct S
1750 {
1751 S ();
1752 ~S ();
1753 };
1754 thread_local S s;
1755 S * get () { return &s; }
1757 // libstdc++ support.
1758 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1759 #error __cxa_thread_atexit_impl not supported
1760 #endif
1761 ])],
1762 [libc_cv_cxx_thread_local=yes],
1763 [libc_cv_cxx_thread_local=no])
1764 CXXFLAGS="$old_CXXFLAGS"
1765 ])
1766 AC_SUBST(libc_cv_cxx_thread_local)
1768 AC_LANG_POP([C++])
1769 dnl End of C++ feature tests.
1771 ### End of automated tests.
1772 ### Now run sysdeps configure fragments.
1774 # They also can set these variables.
1775 use_ldconfig=no
1776 ldd_rewrite_script=no
1777 libc_cv_sysconfdir=$sysconfdir
1778 libc_cv_localstatedir=$localstatedir
1779 libc_cv_gcc_unwind_find_fde=no
1780 libc_cv_idn=no
1782 # Iterate over all the sysdep directories we will use, running their
1783 # configure fragments.
1784 for dir in $sysnames; do
1785 case $dir in
1786 /*) dest=$dir ;;
1787 *) dest=$srcdir/$dir ;;
1788 esac
1789 if test -r $dest/configure; then
1790 AC_MSG_RESULT(running configure fragment for $dir)
1791 . $dest/configure
1792 fi
1793 done
1795 if test x"$build_mathvec" = xnotset; then
1796 build_mathvec=no
1797 fi
1798 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1800 AC_SUBST(libc_extra_cflags)
1801 AC_SUBST(libc_extra_cppflags)
1803 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1804 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1805 fi
1806 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1808 # A sysdeps configure fragment can reset this if IFUNC is not actually
1809 # usable even though the assembler knows how to generate the symbol type.
1810 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1811 AC_DEFINE(HAVE_IFUNC)
1812 fi
1814 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1815 AC_DEFINE(HAVE_GCC_IFUNC)
1816 fi
1818 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1819 # configure fragment can override the value to prevent this AC_DEFINE.
1820 AC_SUBST(use_nscd)
1821 if test "x$use_nscd" != xno; then
1822 AC_DEFINE([USE_NSCD])
1823 fi
1824 if test "x$build_nscd" = xdefault; then
1825 build_nscd=$use_nscd
1826 fi
1828 AC_SUBST(libc_cv_slibdir)
1829 AC_SUBST(libc_cv_rtlddir)
1830 AC_SUBST(libc_cv_complocaledir)
1831 AC_SUBST(libc_cv_sysconfdir)
1832 AC_SUBST(libc_cv_localstatedir)
1833 AC_SUBST(libc_cv_rootsbindir)
1835 if test x$use_ldconfig = xyes; then
1836 AC_DEFINE(USE_LDCONFIG)
1837 fi
1838 AC_SUBST(use_ldconfig)
1839 AC_SUBST(ldd_rewrite_script)
1841 AC_SUBST(static)
1842 AC_SUBST(shared)
1844 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1845 [libc_cv_pic_default=yes
1846 cat > conftest.c <<EOF
1847 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1848 # error PIC is default.
1849 #endif
1850 EOF
1851 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1852 libc_cv_pic_default=no
1853 fi
1854 rm -f conftest.*])
1855 AC_SUBST(libc_cv_pic_default)
1857 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1858 [libc_cv_pie_default=yes
1859 cat > conftest.c <<EOF
1860 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1861 # error PIE is default.
1862 #endif
1863 EOF
1864 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1865 libc_cv_pie_default=no
1866 fi
1867 rm -f conftest.*])
1868 AC_SUBST(libc_cv_pie_default)
1870 AC_SUBST(profile)
1871 AC_SUBST(static_nss)
1873 AC_SUBST(DEFINES)
1875 dnl See sysdeps/mach/configure.ac for this variable.
1876 AC_SUBST(mach_interface_list)
1878 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1879 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1880 AC_SUBST(VERSION)
1881 AC_SUBST(RELEASE)
1883 AC_CONFIG_FILES([config.make Makefile])
1884 AC_CONFIG_COMMANDS([default],[[
1885 case $CONFIG_FILES in *config.make*)
1886 echo "$config_vars" >> config.make;;
1887 esac
1888 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1889 AC_OUTPUT