configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 AC_ARG_ENABLE([hidden-plt],
 213               AC_HELP_STRING([--disable-hidden-plt],
 214                              [do not hide internal function calls to avoid PLT]),
 215               [hidden=$enableval],
 216               [hidden=yes])
 217 if test "x$hidden" = xno; then
 218   AC_DEFINE(NO_HIDDEN)
 219 fi
 220
 221 AC_ARG_ENABLE([bind-now],
 222               AC_HELP_STRING([--enable-bind-now],
 223                              [disable lazy relocations in DSOs]),
 224               [bindnow=$enableval],
 225               [bindnow=no])
 226 AC_SUBST(bindnow)
 227 if test "x$bindnow" = xyes; then
 228   AC_DEFINE(BIND_NOW)
 229 fi
 230
 231 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 232 dnl -fstack-protector-strong.
 233 AC_ARG_ENABLE([stack-protector],
 234               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 235                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 236               [enable_stack_protector=$enableval],
 237               [enable_stack_protector=no])
 238 case "$enable_stack_protector" in
 239 all|yes|no|strong) ;;
 240 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 241 esac
 242
 243 dnl On some platforms we cannot use dynamic loading.  We must provide
 244 dnl static NSS modules.
 245 AC_ARG_ENABLE([static-nss],
 246               AC_HELP_STRING([--enable-static-nss],
 247                              [build static NSS modules @<:@default=no@:>@]),
 248               [static_nss=$enableval],
 249               [static_nss=no])
 250 dnl Enable static NSS also if we build no shared objects.
 251 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 252   static_nss=yes
 253   AC_DEFINE(DO_STATIC_NSS)
 254 fi
 255
 256 AC_ARG_ENABLE([force-install],
 257               AC_HELP_STRING([--disable-force-install],
 258                              [don't force installation of files from this package, even if they are older than the installed files]),
 259               [force_install=$enableval],
 260               [force_install=yes])
 261 AC_SUBST(force_install)
 262
 263 AC_ARG_ENABLE([maintainer-mode],
 264               AC_HELP_STRING([--enable-maintainer-mode],
 265                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 266               [maintainer=$enableval],
 267               [maintainer=no])
 268
 269 dnl On some platforms we allow dropping compatibility with all kernel
 270 dnl versions.
 271 AC_ARG_ENABLE([kernel],
 272               AC_HELP_STRING([--enable-kernel=VERSION],
 273                              [compile for compatibility with kernel not older than VERSION]),
 274               [minimum_kernel=$enableval],
 275               [])
 276 dnl Prevent unreasonable values.
 277 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 278   # Better nothing than this.
 279   minimum_kernel=""
 280 else
 281   if test "$minimum_kernel" = current; then
 282     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 283   fi
 284 fi
 285
 286 dnl For the development we sometimes want gcc to issue even more warnings.
 287 dnl This is not the default since many of the extra warnings are not
 288 dnl appropriate.
 289 AC_ARG_ENABLE([all-warnings],
 290               AC_HELP_STRING([--enable-all-warnings],
 291                              [enable all useful warnings gcc can issue]),
 292               [all_warnings=$enableval],
 293               [])
 294 AC_SUBST(all_warnings)
 295
 296 AC_ARG_ENABLE([werror],
 297               AC_HELP_STRING([--disable-werror],
 298                              [do not build with -Werror]),
 299               [enable_werror=$enableval],
 300               [enable_werror=yes])
 301 AC_SUBST(enable_werror)
 302
 303 AC_ARG_ENABLE([multi-arch],
 304               AC_HELP_STRING([--enable-multi-arch],
 305                              [enable single DSO with optimizations for multiple architectures]),
 306               [multi_arch=$enableval],
 307               [multi_arch=default])
 308
 309 AC_ARG_ENABLE([experimental-malloc],
 310               AC_HELP_STRING([--disable-experimental-malloc],
 311                              [disable experimental malloc features]),
 312               [experimental_malloc=$enableval],
 313               [experimental_malloc=yes])
 314 AC_SUBST(experimental_malloc)
 315
 316 AC_ARG_ENABLE([nss-crypt],
 317               AC_HELP_STRING([--enable-nss-crypt],
 318                              [enable libcrypt to use nss]),
 319               [nss_crypt=$enableval],
 320               [nss_crypt=no])
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 327   if test $? -ne 0; then
 328     AC_MSG_ERROR([cannot find include directory with nspr-config])
 329   fi
 330   old_CFLAGS="$CFLAGS"
 331   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 332   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 333 #include <hasht.h>
 334 #include <nsslowhash.h>
 335 void f (void) { NSSLOW_Init (); }])],
 336              libc_cv_nss_crypt=yes,
 337              AC_MSG_ERROR([
 338 cannot find NSS headers with lowlevel hash function interfaces]))
 339   old_LIBS="$LIBS"
 340   old_LDFLAGS="$LDFLAGS"
 341   LIBS="$LIBS -lfreebl3"
 342   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 343 #include <hasht.h>
 344 #include <nsslowhash.h>],
 345                                   [NSSLOW_Init();])],
 346                  libc_cv_nss_crypt=yes,
 347                  AC_MSG_ERROR([
 348 cannot link program using lowlevel NSS hash functions]))
 349   # Check to see if there is a static NSS cryptographic library.
 350   # If there isn't then we can't link anything with libcrypt.a,
 351   # and that might mean disabling some static tests.
 352   LDFLAGS="$LDFLAGS -static"
 353   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 354 #include <hasht.h>
 355 #include <nsslowhash.h>],
 356                                   [NSSLOW_Init();])],
 357                  libc_cv_static_nss_crypt=yes,
 358                  libc_cv_static_nss_crypt=no)
 359   LDFLAGS="$old_LDFLAGS"
 360   CFLAGS="$old_CFLAGS"
 361   LIBS="$old_LIBS"
 362 else
 363   libc_cv_nss_crypt=no
 364   libc_cv_static_nss_crypt=no
 365 fi
 366 AC_SUBST(libc_cv_nss_crypt)
 367 AC_SUBST(libc_cv_static_nss_crypt)
 368
 369
 370 AC_ARG_ENABLE([obsolete-rpc],
 371               AC_HELP_STRING([--enable-obsolete-rpc],
 372                              [build and install the obsolete RPC code for link-time usage]),
 373               [link_obsolete_rpc=$enableval],
 374               [link_obsolete_rpc=no])
 375 AC_SUBST(link_obsolete_rpc)
 376
 377 if test "$link_obsolete_rpc" = yes; then
 378   AC_DEFINE(LINK_OBSOLETE_RPC)
 379 fi
 380
 381 AC_ARG_ENABLE([obsolete-nsl],
 382               AC_HELP_STRING([--enable-obsolete-nsl],
 383                              [build and install the obsolete libnsl library and depending NSS modules]),
 384               [build_obsolete_nsl=$enableval],
 385               [build_obsolete_nsl=no])
 386 AC_SUBST(build_obsolete_nsl)
 387
 388 if test "$build_obsolete_nsl" = yes; then
 389   AC_DEFINE(LINK_OBSOLETE_NSL)
 390 fi
 391
 392 AC_ARG_ENABLE([systemtap],
 393               [AS_HELP_STRING([--enable-systemtap],
 394                [enable systemtap static probe points @<:@default=no@:>@])],
 395               [systemtap=$enableval],
 396               [systemtap=no])
 397 if test "x$systemtap" != xno; then
 398   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 399   old_CFLAGS="$CFLAGS"
 400   CFLAGS="-std=gnu11 $CFLAGS"
 401   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 402 void foo (int i, void *p)
 403 {
 404   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 405        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 406 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 407   CFLAGS="$old_CFLAGS"])
 408   if test $libc_cv_sdt = yes; then
 409     AC_DEFINE([USE_STAP_PROBE])
 410   elif test "x$systemtap" != xauto; then
 411     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 412   fi
 413 fi
 414
 415 AC_ARG_ENABLE([build-nscd],
 416               [AS_HELP_STRING([--disable-build-nscd],
 417                [disable building and installing the nscd daemon])],
 418               [build_nscd=$enableval],
 419               [build_nscd=default])
 420 AC_SUBST(build_nscd)
 421
 422 # Note the use of $use_nscd is near the bottom of the file.
 423 AC_ARG_ENABLE([nscd],
 424               [AS_HELP_STRING([--disable-nscd],
 425                [library functions will not contact the nscd daemon])],
 426               [use_nscd=$enableval],
 427               [use_nscd=yes])
 428
 429 AC_ARG_ENABLE([pt_chown],
 430               [AS_HELP_STRING([--enable-pt_chown],
 431                [Enable building and installing pt_chown])],
 432               [build_pt_chown=$enableval],
 433               [build_pt_chown=no])
 434 AC_SUBST(build_pt_chown)
 435 if test "$build_pt_chown" = yes; then
 436   AC_DEFINE(HAVE_PT_CHOWN)
 437 fi
 438
 439 AC_ARG_ENABLE([tunables],
 440               [AS_HELP_STRING([--enable-tunables],
 441                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 442               [have_tunables=$enableval],
 443               [have_tunables=yes])
 444 AC_SUBST(have_tunables)
 445 if test "$have_tunables" = yes; then
 446   AC_DEFINE(HAVE_TUNABLES)
 447 fi
 448
 449 # The abi-tags file uses a fairly simplistic model for name recognition that
 450 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 451 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 452 # This doesn't get used much beyond that, so it's fairly safe.
 453 case "$host_os" in
 454 linux*)
 455   ;;
 456 gnu*)
 457   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE([mathvec],
 462               [AS_HELP_STRING([--enable-mathvec],
 463               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 464               [build_mathvec=$enableval],
 465               [build_mathvec=notset])
 466
 467 # We keep the original values in `$config_*' and never modify them, so we
 468 # can write them unchanged into config.make.  Everything else uses
 469 # $machine, $vendor, and $os, and changes them whenever convenient.
 470 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 471
 472 # Don't allow vendor == "unknown"
 473 test "$config_vendor" = unknown && config_vendor=
 474 config_os="`echo $config_os | sed 's/^unknown-//'`"
 475
 476 # Some configurations imply other options.
 477 elf=yes
 478
 479 # The configure fragment of a port can modify these to supplement
 480 # or override the table in the case statement below.  No fragment should
 481 # ever change the config_* variables, however.
 482 machine=$config_machine
 483 vendor=$config_vendor
 484 os=$config_os
 485 base_os=''
 486
 487 submachine=
 488 AC_ARG_WITH([cpu],
 489             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 490             [dnl
 491   case "$withval" in
 492   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 493   no) ;;
 494   *) submachine="$withval" ;;
 495   esac
 496 ])
 497
 498 # An preconfigure script can set this when it wants to disable the sanity
 499 # check below.
 500 libc_config_ok=no
 501
 502 dnl Let sysdeps/*/preconfigure act here.
 503 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 504
 505
 506 ###
 507 ### By using the undocumented --enable-hacker-mode option for configure
 508 ### one can skip this test to make the configuration not fail for unsupported
 509 ### platforms.
 510 ###
 511 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 512   case "$machine-$host_os" in
 513   *-linux* | *-gnu*)
 514     ;;
 515   *)
 516     AC_MSG_ERROR([
 517 *** The GNU C library is currently unavailable for this platform.
 518 *** If you are interested in seeing glibc on this platform visit
 519 *** the "How to submit a new port" in the wiki:
 520 ***   https://sourceware.org/glibc/wiki/#Development
 521 *** and join the community!])
 522     ;;
 523   esac
 524 fi
 525
 526 # Set base_machine if not set by a preconfigure fragment.
 527 test -n "$base_machine" || base_machine=$machine
 528 AC_SUBST(base_machine)
 529
 530 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 531 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 532                    [libc_cv_ssp=yes],
 533                    [libc_cv_ssp=no])
 534 ])
 535
 536 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 537 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 538                    [libc_cv_ssp_strong=yes],
 539                    [libc_cv_ssp_strong=no])
 540 ])
 541
 542 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 543 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 544                    [libc_cv_ssp_all=yes],
 545                    [libc_cv_ssp_all=no])
 546 ])
 547
 548 stack_protector=
 549 no_stack_protector=
 550 if test "$libc_cv_ssp" = yes; then
 551   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 552   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 553 fi
 554
 555 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 556   stack_protector="-fstack-protector"
 557   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 558 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 559   stack_protector="-fstack-protector-all"
 560   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 561 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 562   stack_protector="-fstack-protector-strong"
 563   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 564 else
 565   stack_protector="-fno-stack-protector"
 566   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 567 fi
 568 AC_SUBST(libc_cv_ssp)
 569 AC_SUBST(stack_protector)
 570 AC_SUBST(no_stack_protector)
 571
 572 if test -n "$stack_protector"; then
 573   dnl Don't run configure tests with stack-protection on, to avoid problems with
 574   dnl bootstrapping.
 575   no_ssp=-fno-stack-protector
 576 else
 577   no_ssp=
 578
 579   if test "$enable_stack_protector" != no; then
 580     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 581   fi
 582 fi
 583
 584 # For the multi-arch option we need support in the assembler & linker.
 585 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 586                libc_cv_ld_gnu_indirect_function, [dnl
 587 cat > conftest.S <<EOF
 588 .type foo,%gnu_indirect_function
 589 foo:
 590 .globl _start
 591 _start:
 592 .globl __start
 593 __start:
 594 .data
 595 #ifdef _LP64
 596 .quad foo
 597 #else
 598 .long foo
 599 #endif
 600 EOF
 601 libc_cv_ld_gnu_indirect_function=no
 602 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 603             -nostartfiles -nostdlib $no_ssp \
 604             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 605   # Do a link to see if the backend supports IFUNC relocs.
 606   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 607   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 608     libc_cv_ld_gnu_indirect_function=yes
 609   }
 610 fi
 611 rm -f conftest*])
 612
 613 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 614 AC_CACHE_CHECK([for gcc attribute ifunc support],
 615                libc_cv_gcc_indirect_function, [dnl
 616 cat > conftest.c <<EOF
 617 extern int func (int);
 618 int used_func (int a)
 619 {
 620   return a;
 621 }
 622 static void *resolver ()
 623 {
 624   return &used_func;
 625 }
 626 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 627 EOF
 628 libc_cv_gcc_indirect_function=no
 629 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 630    2>&AS_MESSAGE_LOG_FD ; then
 631   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 632     libc_cv_gcc_indirect_function=yes
 633   fi
 634 fi
 635 rm -f conftest*])
 636
 637 # Check if gcc warns about alias for function with incompatible types.
 638 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 639                libc_cv_gcc_incompatible_alias, [dnl
 640 cat > conftest.c <<EOF
 641 int __redirect_foo (const void *s, int c);
 642
 643 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 644 __typeof (__redirect_foo) *foo_impl (void)
 645 {
 646   return 0;
 647 }
 648
 649 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 650 EOF
 651 libc_cv_gcc_incompatible_alias=yes
 652 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 653   libc_cv_gcc_incompatible_alias=no
 654 fi
 655 rm -f conftest*])
 656
 657 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 658   if test x"$multi_arch" = xyes; then
 659     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 660   else
 661     multi_arch=no
 662   fi
 663 fi
 664 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 665   # GCC 8+ emits a warning for alias with incompatible types and it might
 666   # fail to build ifunc resolvers aliases to either weak or internal
 667   # symbols.  Disables multiarch build in this case.
 668   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 669     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 670     if test x"$multi_arch" = xyes; then
 671       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 672     fi
 673     AC_MSG_WARN([Multi-arch is disabled.])
 674     multi_arch=no
 675   elif test x"$multi_arch" = xyes; then
 676     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 677 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 678   fi
 679 fi
 680 multi_arch_d=
 681 if test x"$multi_arch" != xno; then
 682   multi_arch_d=/multiarch
 683 fi
 684
 685 # Compute the list of sysdep directories for this configuration.
 686 # This can take a while to compute.
 687 sysdep_dir=$srcdir/sysdeps
 688 AC_MSG_CHECKING(sysdep dirs)
 689 dnl We need to use [ and ] for other purposes for a while now.
 690 changequote(,)dnl
 691 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 692 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 693
 694 test "x$base_os" != x || case "$os" in
 695 gnu*)
 696   base_os=mach/hurd ;;
 697 linux*)
 698   base_os=unix/sysv ;;
 699 esac
 700
 701 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 702 tail=$os
 703 ostry=$os
 704 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 705   ostry="$ostry /$o"
 706   tail=$o
 707 done
 708 o=`echo $tail | sed 's/[0-9]*$//'`
 709 if test $o != $tail; then
 710   ostry="$ostry /$o"
 711 fi
 712 # For linux-gnu, try linux-gnu, then linux.
 713 o=`echo $tail | sed 's/-.*$//'`
 714 if test $o != $tail; then
 715   ostry="$ostry /$o"
 716 fi
 717
 718 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 719 base=
 720 tail=$base_os
 721 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 722   set $b
 723   base="$base /$1"
 724   tail="$2"
 725 done
 726
 727 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 728 mach=
 729 tail=$machine${submachine:+/$submachine}
 730 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 731   set $m
 732   # Prepend the machine's FPU directory unless --without-fp.
 733   if test "$with_fp" = yes; then
 734     maybe_fpu=/fpu
 735   else
 736     maybe_fpu=/nofpu
 737   fi
 738   # For each machine term, try it with and then without /multiarch.
 739   for try_fpu in $maybe_fpu ''; do
 740     for try_multi in $multi_arch_d ''; do
 741       mach="$mach /$1$try_fpu$try_multi"
 742     done
 743   done
 744   tail="$2"
 745 done
 746
 747 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 748 changequote([,])dnl
 749
 750 # Find what sysdep directories exist.
 751 sysnames=
 752 for b in $base ''; do
 753   for m0 in $mach ''; do
 754     for v in /$vendor ''; do
 755       test "$v" = / && continue
 756       for o in /$ostry ''; do
 757         test "$o" = / && continue
 758         for m in $mach ''; do
 759           try_suffix="$m0$b$v$o$m"
 760           if test -n "$try_suffix"; then
 761             try_srcdir="${srcdir}/"
 762             try="sysdeps$try_suffix"
 763             test -n "$enable_debug_configure" &&
 764             echo "$0 [DEBUG]: try $try" >&2
 765             if test -d "$try_srcdir$try"; then
 766               sysnames="$sysnames $try"
 767               { test -n "$o" || test -n "$b"; } && os_used=t
 768               { test -n "$m" || test -n "$m0"; } && machine_used=t
 769               case x${m0:-$m} in
 770               x*/$submachine) submachine_used=t ;;
 771               esac
 772             fi
 773           fi
 774         done
 775       done
 776     done
 777   done
 778 done
 779
 780 # If the assembler supports gnu_indirect_function symbol type and the
 781 # architecture supports multi-arch, we enable multi-arch by default.
 782 case $sysnames in
 783 *"$multi_arch_d"*)
 784   ;;
 785 *)
 786   test x"$multi_arch" = xdefault && multi_arch=no
 787   ;;
 788 esac
 789 if test x"$multi_arch" != xno; then
 790   AC_DEFINE(USE_MULTIARCH)
 791 fi
 792 AC_SUBST(multi_arch)
 793
 794 if test -z "$os_used" && test "$os" != none; then
 795   AC_MSG_ERROR(Operating system $os is not supported.)
 796 fi
 797 if test -z "$machine_used" && test "$machine" != none; then
 798   AC_MSG_ERROR(The $machine is not supported.)
 799 fi
 800 if test -z "$submachine_used" && test -n "$submachine"; then
 801   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 802 fi
 803 AC_SUBST(submachine)
 804
 805 # We have now validated the configuration.
 806
 807 # Expand the list of system names into a full list of directories
 808 # from each element's parent name and Implies file (if present).
 809 set $sysnames
 810 names=
 811 while test $# -gt 0; do
 812   name=$1
 813   shift
 814
 815   case " $names " in *" $name "*)
 816     # Already in the list.
 817     continue
 818   esac
 819
 820   # Report each name as we discover it, so there is no long pause in output.
 821   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 822
 823   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 824
 825   case $name in
 826     /*) xsrcdir= ;;
 827     *)  xsrcdir=$srcdir/ ;;
 828   esac
 829   test -n "$enable_debug_configure" &&
 830   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 831
 832   for implies_file in Implies Implies-before Implies-after; do
 833     implies_type=`echo $implies_file | sed s/-/_/`
 834     eval ${implies_type}=
 835     if test -f $xsrcdir$name/$implies_file; then
 836       # Collect more names from the `Implies' file (removing comments).
 837       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 838       for x in $implied_candidate; do
 839         found=no
 840         if test -d $xsrcdir$name_base/$x; then
 841           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 842           found=yes
 843         fi
 844         try="sysdeps/$x"
 845         try_srcdir=$srcdir/
 846         test -n "$enable_debug_configure" &&
 847          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 848         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 849         then
 850           eval "${implies_type}=\"\$${implies_type} \$try\""
 851           found=yes
 852         fi
 853         if test $found = no; then
 854           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 855         fi
 856       done
 857     fi
 858   done
 859
 860   # Add NAME to the list of names.
 861   names="$names $name"
 862
 863   # Find the parent of NAME, using the empty string if it has none.
 864 changequote(,)dnl
 865   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 866 changequote([,])dnl
 867
 868   test -n "$enable_debug_configure" &&
 869     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 870 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 871
 872   # Add the names implied by NAME, and NAME's parent (if it has one), to
 873   # the list of names to be processed (the argument list).  We prepend the
 874   # implied names to the list and append the parent.  We want implied
 875   # directories to come before further directories inferred from the
 876   # configuration components; this ensures that for sysv4, unix/common
 877   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 878   # after sysv4).
 879   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 880   test -n "$sysnames" && set $sysnames
 881 done
 882
 883 # Add the default directories.
 884 default_sysnames="sysdeps/generic"
 885 sysnames="$names $default_sysnames"
 886 AC_SUBST(sysnames)
 887 # The other names were emitted during the scan.
 888 AC_MSG_RESULT($default_sysnames)
 889
 890
 891 ### Locate tools.
 892
 893 AC_PROG_INSTALL
 894 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 895   # The makefiles need to use a different form to find it in $srcdir.
 896   INSTALL='\$(..)./scripts/install-sh -c'
 897 fi
 898 AC_PROG_LN_S
 899
 900 LIBC_PROG_BINUTILS
 901
 902 # Accept binutils 2.25 or newer.
 903 AC_CHECK_PROG_VER(AS, $AS, --version,
 904                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 905                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 906                   AS=: critic_missing="$critic_missing as")
 907
 908 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 909   # Accept gold 1.14 or higher
 910   AC_CHECK_PROG_VER(LD, $LD, --version,
 911                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 912                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 913                     LD=: critic_missing="$critic_missing GNU gold")
 914 else
 915   AC_CHECK_PROG_VER(LD, $LD, --version,
 916                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 917                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 918                     LD=: critic_missing="$critic_missing GNU ld")
 919 fi
 920
 921 # These programs are version sensitive.
 922 AC_CHECK_TOOL_PREFIX
 923 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 924   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 925   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 926
 927 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 928   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 929   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 930   MSGFMT=: aux_missing="$aux_missing msgfmt")
 931 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 932   [GNU texinfo.* \([0-9][0-9.]*\)],
 933   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 934   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 935 AC_CHECK_PROG_VER(SED, sed, --version,
 936   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 937   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 938   SED=: aux_missing="$aux_missing sed")
 939 AC_CHECK_PROG_VER(AWK, gawk, --version,
 940   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 941   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 942
 943 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 944 AC_TRY_COMPILE([], [
 945 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 946 #error insufficient compiler
 947 #endif],
 948                [libc_cv_compiler_ok=yes],
 949                [libc_cv_compiler_ok=no])])
 950 AS_IF([test $libc_cv_compiler_ok != yes],
 951       [critic_missing="$critic_missing compiler"])
 952
 953 AC_CHECK_TOOL(NM, nm, false)
 954
 955 if test "x$maintainer" = "xyes"; then
 956   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 957   case "x$AUTOCONF" in
 958   xno|x|x:) AUTOCONF=no ;;
 959   *)
 960     AC_CACHE_CHECK(dnl
 961   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 962     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 963       libc_cv_autoconf_works=yes
 964     else
 965       libc_cv_autoconf_works=no
 966     fi])
 967     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 968     ;;
 969   esac
 970   if test "x$AUTOCONF" = xno; then
 971     aux_missing="$aux_missing autoconf"
 972   fi
 973 else
 974   AUTOCONF=no
 975 fi
 976
 977 # Check for python3 if available, or else python.
 978 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
 979 case "x$PYTHON_PROG" in
 980 xno|x|x:) PYTHON_PROG=no ;;
 981 *) ;;
 982 esac
 983
 984 if test "x$PYTHON_PROG" = xno; then
 985   aux_missing="$aux_missing python"
 986 else
 987   PYTHON="$PYTHON_PROG -B"
 988   AC_SUBST(PYTHON)
 989 fi
 990
 991 test -n "$critic_missing" && AC_MSG_ERROR([
 992 *** These critical programs are missing or too old:$critic_missing
 993 *** Check the INSTALL file for required versions.])
 994
 995 test -n "$aux_missing" && AC_MSG_WARN([
 996 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 997 *** some features or tests will be disabled.
 998 *** Check the INSTALL file for required versions.])
 999
1000 # if using special system headers, find out the compiler's sekrit
1001 # header directory and add that to the list.  NOTE: Only does the right
1002 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1003 if test -n "$sysheaders"; then
1004   SYSINCLUDES=-nostdinc
1005   for d in include include-fixed; do
1006     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1007     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1008   done
1009   SYSINCLUDES="$SYSINCLUDES \
1010 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1011   if test -n "$CXX"; then
1012     CXX_SYSINCLUDES=
1013     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1014     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1015       test "x$cxxheaders" != x &&
1016       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1017     done
1018   fi
1019 fi
1020 AC_SUBST(SYSINCLUDES)
1021 AC_SUBST(CXX_SYSINCLUDES)
1022
1023 # Obtain some C++ header file paths.  This is used to make a local
1024 # copy of those headers in Makerules.
1025 if test -n "$CXX"; then
1026   find_cxx_header () {
1027     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1028          | sed -n "\,$1:,{s/:\$//;p}"
1029   }
1030   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1031   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1032   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1033 fi
1034 AC_SUBST(CXX_CSTDLIB_HEADER)
1035 AC_SUBST(CXX_CMATH_HEADER)
1036 AC_SUBST(CXX_BITS_STD_ABS_H)
1037
1038 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1039 # since this would lead to problems installing/building glibc.
1040 # LD_LIBRARY_PATH contains the current directory if one of the following
1041 # is true:
1042 # - one of the terminals (":" and ";") is the first or last sign
1043 # - two terminals occur directly after each other
1044 # - the path contains an element with a dot in it
1045 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1046 changequote(,)dnl
1047 case ${LD_LIBRARY_PATH} in
1048   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1049     ld_library_path_setting="contains current directory"
1050     ;;
1051   *)
1052     ld_library_path_setting="ok"
1053     ;;
1054 esac
1055 changequote([,])dnl
1056 AC_MSG_RESULT($ld_library_path_setting)
1057 if test "$ld_library_path_setting" != "ok"; then
1058 AC_MSG_ERROR([
1059 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1060 *** building glibc. Please change the environment variable
1061 *** and run configure again.])
1062 fi
1063
1064 AC_PATH_PROG(BASH_SHELL, bash, no)
1065
1066 AC_PATH_PROG(PERL, perl, no)
1067 if test "$PERL" != no &&
1068    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1069   PERL=no
1070 fi
1071 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1072              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1073 AC_CHECK_PROG_VER(BISON, bison, --version,
1074                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1075                   [2.7*|[3-9].*|[1-9][0-9]*],
1076                   BISON=no)
1077
1078 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1079 cat > conftest.s <<EOF
1080 .text
1081 foo:
1082 .set glibc_conftest_frobozz,foo
1083 .globl glibc_conftest_frobozz
1084 EOF
1085 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1086 # (but it doesn't work), so we must do a linking check to be sure.
1087 cat > conftest1.c <<\EOF
1088 extern int glibc_conftest_frobozz;
1089 void _start() { glibc_conftest_frobozz = 1; }
1090 EOF
1091 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1092             -nostartfiles -nostdlib $no_ssp \
1093             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1094   libc_cv_asm_set_directive=yes
1095 else
1096   libc_cv_asm_set_directive=no
1097 fi
1098 rm -f conftest*])
1099 if test $libc_cv_asm_set_directive = yes; then
1100   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1101 fi
1102
1103 AC_CACHE_CHECK(linker support for protected data symbol,
1104                libc_cv_protected_data,
1105                [cat > conftest.c <<EOF
1106                 int bar __attribute__ ((visibility ("protected"))) = 1;
1107 EOF
1108                 libc_cv_protected_data=no
1109                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1110                   cat > conftest.c <<EOF
1111                   extern int bar;
1112                   int main (void) { return bar; }
1113 EOF
1114                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1115                     libc_cv_protected_data=yes
1116                   fi
1117                 fi
1118                 rm -f conftest.*
1119                ])
1120 AC_SUBST(libc_cv_protected_data)
1121
1122 AC_CACHE_CHECK(linker support for INSERT in linker script,
1123                libc_cv_insert,
1124                [cat > conftest.c <<EOF
1125                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1126                 int test (void) { return bar; }
1127 EOF
1128                 cat > conftest.t <<EOF
1129                 SECTIONS
1130                 {
1131                   .bar : { *(.bar) }
1132                 }
1133                 INSERT AFTER .rela.dyn;
1134 EOF
1135                 libc_cv_insert=no
1136                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1137                   libc_cv_insert=yes
1138                 fi
1139                 rm -f conftest.*
1140                ])
1141 AC_SUBST(libc_cv_insert)
1142
1143 AC_CACHE_CHECK(for broken __attribute__((alias())),
1144                libc_cv_broken_alias_attribute,
1145                [cat > conftest.c <<EOF
1146                extern int foo (int x) __asm ("xyzzy");
1147                int bar (int x) { return x; }
1148                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1149                extern int dfoo;
1150                extern __typeof (dfoo) dfoo __asm ("abccb");
1151                int dfoo = 1;
1152 EOF
1153                libc_cv_broken_alias_attribute=yes
1154                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1155                  if grep 'xyzzy' conftest.s >/dev/null &&
1156                     grep 'abccb' conftest.s >/dev/null; then
1157                    libc_cv_broken_alias_attribute=no
1158                  fi
1159                fi
1160                rm -f conftest.c conftest.s
1161                ])
1162 if test $libc_cv_broken_alias_attribute = yes; then
1163   AC_MSG_ERROR(working alias attribute support required)
1164 fi
1165
1166 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1167                libc_cv_have_sdata_section,
1168                [echo "int i;" > conftest.c
1169                 libc_cv_have_sdata_section=no
1170                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1171                    | grep '\.sdata' >/dev/null; then
1172                   libc_cv_have_sdata_section=yes
1173                 fi
1174                 rm -f conftest.c conftest.so
1175                ])
1176 if test $libc_cv_have_sdata_section = yes; then
1177   AC_DEFINE(HAVE_SDATA_SECTION)
1178 fi
1179
1180 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1181                libc_cv_ctors_header, [dnl
1182   libc_cv_ctors_header=yes
1183   LIBC_TRY_LINK_STATIC([
1184 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1185 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1186 ],
1187               [dnl
1188       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1189         { gsub(/\@<:@ */, "@<:@") }
1190         $2 == ".ctors" || $2 == ".dtors" {
1191           size = strtonum("0x" $6)
1192           align = strtonum("0x" $NF)
1193           seen@<:@$2@:>@ = 1
1194           stub@<:@$2@:>@ = size == align * 2
1195         }
1196         END {
1197           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1198           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1199           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1200         }
1201       '], [libc_cv_ctors_header=no])
1202     ], [dnl
1203       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1204     ])
1205 ])
1206 if test $libc_cv_ctors_header = no; then
1207   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1208 fi
1209
1210 AC_CACHE_CHECK(for libunwind-support in compiler,
1211                libc_cv_cc_with_libunwind, [
1212   cat > conftest.c <<EOF
1213 int main (void) { return 0; }
1214 EOF
1215   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1216      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1217     libc_cv_cc_with_libunwind=yes
1218   else
1219     libc_cv_cc_with_libunwind=no
1220   fi
1221   rm -f conftest*])
1222 AC_SUBST(libc_cv_cc_with_libunwind)
1223 if test $libc_cv_cc_with_libunwind = yes; then
1224   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1225 fi
1226
1227 ASFLAGS_config=
1228 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1229                libc_cv_as_noexecstack, [dnl
1230 cat > conftest.c <<EOF
1231 void foo (void) { }
1232 EOF
1233 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1234                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1235    && grep .note.GNU-stack conftest.s >/dev/null \
1236    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1237                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1238 then
1239   libc_cv_as_noexecstack=yes
1240 else
1241   libc_cv_as_noexecstack=no
1242 fi
1243 rm -f conftest*])
1244 if test $libc_cv_as_noexecstack = yes; then
1245   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1246 fi
1247 AC_SUBST(ASFLAGS_config)
1248
1249 AC_CACHE_CHECK(for -z combreloc,
1250                libc_cv_z_combreloc, [dnl
1251 cat > conftest.c <<EOF
1252 extern int bar (int);
1253 extern int mumble;
1254 int foo (void) { return bar (mumble); }
1255 EOF
1256 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1257                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1258                         -nostdlib -nostartfiles
1259                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1260 then
1261 dnl The following test is a bit weak.  We must use a tool which can test
1262 dnl cross-platform since the gcc used can be a cross compiler.  Without
1263 dnl introducing new options this is not easily doable.  Instead use a tool
1264 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1265 dnl look for a section named .rel.dyn or .rela.dyn.
1266   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1267     libc_cv_z_combreloc=yes
1268   else
1269     libc_cv_z_combreloc=no
1270   fi
1271 else
1272   libc_cv_z_combreloc=no
1273 fi
1274 rm -f conftest*])
1275 if test "$libc_cv_z_combreloc" = yes; then
1276   AC_DEFINE(HAVE_Z_COMBRELOC)
1277 fi
1278 AC_SUBST(libc_cv_z_combreloc)
1279
1280 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1281                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1282 AC_SUBST(libc_cv_z_execstack)
1283
1284 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1285 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1286 ])
1287
1288 AC_SUBST(libc_cv_fpie)
1289
1290 AC_CACHE_CHECK(for --hash-style option,
1291                libc_cv_hashstyle, [dnl
1292 cat > conftest.c <<EOF
1293 int _start (void) { return 42; }
1294 EOF
1295 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1296                             -fPIC -shared -o conftest.so conftest.c
1297                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1298 then
1299   libc_cv_hashstyle=yes
1300 else
1301   libc_cv_hashstyle=no
1302 fi
1303 rm -f conftest*])
1304 AC_SUBST(libc_cv_hashstyle)
1305
1306 # The linker's default -shared behavior is good enough if it
1307 # does these things that our custom linker scripts ensure that
1308 # all allocated NOTE sections come first.
1309 if test "$use_default_link" = default; then
1310   AC_CACHE_CHECK([for sufficient default -shared layout],
1311                   libc_cv_use_default_link, [dnl
1312   libc_cv_use_default_link=no
1313   cat > conftest.s <<\EOF
1314           .section .note.a,"a",%note
1315           .balign 4
1316           .long 4,4,9
1317           .string "GNU"
1318           .string "foo"
1319           .section .note.b,"a",%note
1320           .balign 4
1321           .long 4,4,9
1322           .string "GNU"
1323           .string "bar"
1324 EOF
1325   if AC_TRY_COMMAND([dnl
1326   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1327        ac_try=`$READELF -S conftest.so | sed -n \
1328          ['${x;p;}
1329           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1330           t a
1331           b
1332           : a
1333           H']`
1334   then
1335     libc_seen_a=no libc_seen_b=no
1336     set -- $ac_try
1337     while test $# -ge 2 -a "$1" = NOTE; do
1338       case "$2" in
1339       .note.a) libc_seen_a=yes ;;
1340       .note.b) libc_seen_b=yes ;;
1341       esac
1342       shift 2
1343     done
1344     case "$libc_seen_a$libc_seen_b" in
1345     yesyes)
1346       libc_cv_use_default_link=yes
1347       ;;
1348     *)
1349       echo >&AS_MESSAGE_LOG_FD "\
1350 $libc_seen_a$libc_seen_b from:
1351 $ac_try"
1352       ;;
1353     esac
1354   fi
1355   rm -f conftest*])
1356   use_default_link=$libc_cv_use_default_link
1357 fi
1358
1359 AC_CACHE_CHECK(for GLOB_DAT reloc,
1360                libc_cv_has_glob_dat, [dnl
1361 cat > conftest.c <<EOF
1362 extern int mumble;
1363 int foo (void) { return mumble; }
1364 EOF
1365 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1366                         -fPIC -shared -o conftest.so conftest.c
1367                         -nostdlib -nostartfiles $no_ssp
1368                         1>&AS_MESSAGE_LOG_FD])
1369 then
1370 dnl look for GLOB_DAT relocation.
1371   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1372     libc_cv_has_glob_dat=yes
1373   else
1374     libc_cv_has_glob_dat=no
1375   fi
1376 else
1377   libc_cv_has_glob_dat=no
1378 fi
1379 rm -f conftest*])
1380 AC_SUBST(libc_cv_has_glob_dat)
1381
1382 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1383 if libc_cv_output_format=`
1384 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1385 then
1386   :
1387 else
1388   libc_cv_output_format=
1389 fi
1390 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1391 AC_SUBST(libc_cv_output_format)
1392
1393 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1394 cat > conftest.c <<EOF
1395 int foo;
1396 EOF
1397 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1398                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1399 then
1400   libc_cv_fno_toplevel_reorder=yes
1401 else
1402   libc_cv_fno_toplevel_reorder=no
1403 fi
1404 rm -f conftest*])
1405 if test $libc_cv_fno_toplevel_reorder = yes; then
1406   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1407 else
1408   fno_unit_at_a_time=-fno-unit-at-a-time
1409 fi
1410 AC_SUBST(fno_unit_at_a_time)
1411
1412 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1413 [dnl
1414 cat > conftest.c <<EOF
1415 __thread int i;
1416 void foo (void)
1417 {
1418   i = 10;
1419 }
1420 EOF
1421 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1422                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1423 then
1424   libc_cv_mtls_dialect_gnu2=yes
1425 else
1426   libc_cv_mtls_dialect_gnu2=no
1427 fi
1428 rm -f conftest*])
1429 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1430 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1431
1432 AC_CACHE_CHECK(whether cc puts quotes around section names,
1433                libc_cv_have_section_quotes,
1434                [cat > conftest.c <<EOF
1435                 static const int foo
1436                 __attribute__ ((section ("bar"))) = 1;
1437 EOF
1438                 if ${CC-cc} -S conftest.c -o conftest.s; then
1439                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1440                     libc_cv_have_section_quotes=yes
1441                   else
1442                     libc_cv_have_section_quotes=no
1443                   fi
1444                 else
1445                   libc_cv_have_section_quotes=unknown
1446                 fi
1447                 rm -f conftest.{c,s}
1448                 ])
1449 if test $libc_cv_have_section_quotes = yes; then
1450   AC_DEFINE(HAVE_SECTION_QUOTES)
1451 fi
1452
1453 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1454 cat > conftest.c <<\EOF
1455 void zero (void *x)
1456 {
1457   __builtin_memset (x, 0, 1000);
1458 }
1459 EOF
1460 dnl
1461 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1462 then
1463   libc_cv_gcc_builtin_memset=no
1464 else
1465   libc_cv_gcc_builtin_memset=yes
1466 fi
1467 rm -f conftest* ])
1468 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1469   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1470 fi
1471
1472 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1473 cat > conftest.c <<\EOF
1474 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1475 char *foo (const char *a, const char *b)
1476 {
1477   return __builtin_strstr (a, b);
1478 }
1479 EOF
1480 dnl
1481 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1482 then
1483   libc_cv_gcc_builtin_redirection=yes
1484 else
1485   libc_cv_gcc_builtin_redirection=no
1486 fi
1487 rm -f conftest* ])
1488 if test "$libc_cv_gcc_builtin_redirection" = no; then
1489   AC_MSG_ERROR([support for the symbol redirection needed])
1490 fi
1491
1492 dnl Determine how to disable generation of FMA instructions.
1493 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1494                libc_cv_cc_nofma, [dnl
1495 libc_cv_cc_nofma=
1496 for opt in -ffp-contract=off -mno-fused-madd; do
1497   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1498 done])
1499 AC_SUBST(libc_cv_cc_nofma)
1500
1501 if test -n "$submachine"; then
1502   AC_CACHE_CHECK([for compiler option for CPU variant],
1503                  libc_cv_cc_submachine, [dnl
1504   libc_cv_cc_submachine=no
1505   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1506     LIBC_TRY_CC_OPTION([$opt], [
1507       libc_cv_cc_submachine="$opt"
1508       break], [])
1509   done])
1510   if test "x$libc_cv_cc_submachine" = xno; then
1511     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1512   fi
1513 fi
1514 AC_SUBST(libc_cv_cc_submachine)
1515
1516 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1517 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1518 cat > conftest.c <<EOF
1519 void
1520 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1521 foo (void) {}
1522 EOF
1523 libc_cv_cc_loop_to_function=no
1524 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1525 then
1526   libc_cv_cc_loop_to_function=yes
1527 fi
1528 rm -f conftest*])
1529 if test $libc_cv_cc_loop_to_function = yes; then
1530   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1531 fi
1532 AC_SUBST(libc_cv_cc_loop_to_function)
1533
1534 dnl Check whether we have the gd library available.
1535 AC_MSG_CHECKING(for libgd)
1536 if test "$with_gd" != "no"; then
1537   old_CFLAGS="$CFLAGS"
1538   CFLAGS="$CFLAGS $libgd_include"
1539   old_LDFLAGS="$LDFLAGS"
1540   LDFLAGS="$LDFLAGS $libgd_ldflags"
1541   old_LIBS="$LIBS"
1542   LIBS="$LIBS -lgd -lpng -lz -lm"
1543   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1544   CFLAGS="$old_CFLAGS"
1545   LDFLAGS="$old_LDFLAGS"
1546   LIBS="$old_LIBS"
1547 else
1548   LIBGD=no
1549 fi
1550 AC_MSG_RESULT($LIBGD)
1551 AC_SUBST(LIBGD)
1552
1553 # SELinux detection
1554 if test x$with_selinux = xno ; then
1555   have_selinux=no;
1556 else
1557   # See if we have the SELinux library
1558   AC_CHECK_LIB(selinux, is_selinux_enabled,
1559                have_selinux=yes, have_selinux=no)
1560   if test x$with_selinux = xyes ; then
1561     if test x$have_selinux = xno ; then
1562       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1563     fi
1564   fi
1565 fi
1566 # Check if we're building with SELinux support.
1567 if test "x$have_selinux" = xyes; then
1568   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1569
1570   # See if we have the libaudit library
1571   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1572                have_libaudit=yes, have_libaudit=no)
1573   if test "x$have_libaudit" = xyes; then
1574     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1575   fi
1576   AC_SUBST(have_libaudit)
1577
1578   # See if we have the libcap library
1579   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1580   if test "x$have_libcap" = xyes; then
1581     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1582   fi
1583   AC_SUBST(have_libcap)
1584 fi
1585 AC_SUBST(have_selinux)
1586
1587 CPPUNDEFS=
1588 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1589 dnl Since we are building the implementations of the fortified functions here,
1590 dnl having the macro defined interacts very badly.
1591 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1592 [AC_TRY_COMPILE([], [
1593 #ifdef _FORTIFY_SOURCE
1594 # error bogon
1595 #endif],
1596                 [libc_cv_predef_fortify_source=no],
1597                 [libc_cv_predef_fortify_source=yes])])
1598 if test $libc_cv_predef_fortify_source = yes; then
1599   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1600 fi
1601 AC_SUBST(CPPUNDEFS)
1602
1603 # Some linkers on some architectures support __ehdr_start but with
1604 # bugs.  Make sure usage of it does not create relocations in the
1605 # output (as the linker should resolve them all for us).
1606 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1607                libc_cv_ehdr_start, [
1608 old_CFLAGS="$CFLAGS"
1609 old_LDFLAGS="$LDFLAGS"
1610 old_LIBS="$LIBS"
1611 CFLAGS="$CFLAGS -fPIC"
1612 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1613 LIBS=
1614 AC_LINK_IFELSE([AC_LANG_SOURCE([
1615 typedef struct {
1616   char foo;
1617   long val;
1618 } Ehdr;
1619 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1620 long ehdr (void) { return __ehdr_start.val; }
1621 ])],
1622                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1623                   libc_cv_ehdr_start=broken
1624                 else
1625                   libc_cv_ehdr_start=yes
1626                 fi], [libc_cv_ehdr_start=no])
1627 CFLAGS="$old_CFLAGS"
1628 LDFLAGS="$old_LDFLAGS"
1629 LIBS="$old_LIBS"
1630 ])
1631 if test "$libc_cv_ehdr_start" = yes; then
1632   AC_DEFINE([HAVE_EHDR_START])
1633 elif test "$libc_cv_ehdr_start" = broken; then
1634   AC_MSG_WARN([linker is broken -- you should upgrade])
1635 fi
1636
1637 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1638                libc_cv_builtin_trap, [dnl
1639 libc_cv_builtin_trap=no
1640 AC_TRY_COMPILE([], [__builtin_trap ()], [
1641 libc_undefs=`$NM -u conftest.o |
1642   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1643     2>&AS_MESSAGE_LOG_FD` || {
1644   AC_MSG_ERROR([confusing output from $NM -u])
1645 }
1646 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1647 if test -z "$libc_undefs"; then
1648   libc_cv_builtin_trap=yes
1649 fi])])
1650 if test $libc_cv_builtin_trap = yes; then
1651   AC_DEFINE([HAVE_BUILTIN_TRAP])
1652 fi
1653
1654 dnl C++ feature tests.
1655 AC_LANG_PUSH([C++])
1656
1657 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1658                libc_cv_cxx_thread_local, [
1659 old_CXXFLAGS="$CXXFLAGS"
1660 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1661 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1662 #include <thread>
1663
1664 // Compiler support.
1665 struct S
1666 {
1667   S ();
1668   ~S ();
1669 };
1670 thread_local S s;
1671 S * get () { return &s; }
1672
1673 // libstdc++ support.
1674 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1675 #error __cxa_thread_atexit_impl not supported
1676 #endif
1677 ])],
1678                [libc_cv_cxx_thread_local=yes],
1679                [libc_cv_cxx_thread_local=no])
1680 CXXFLAGS="$old_CXXFLAGS"
1681 ])
1682 AC_SUBST(libc_cv_cxx_thread_local)
1683
1684 AC_LANG_POP([C++])
1685 dnl End of C++ feature tests.
1686
1687 ### End of automated tests.
1688 ### Now run sysdeps configure fragments.
1689
1690 # They also can set these variables.
1691 use_ldconfig=no
1692 ldd_rewrite_script=no
1693 libc_cv_sysconfdir=$sysconfdir
1694 libc_cv_localstatedir=$localstatedir
1695 libc_cv_gcc_unwind_find_fde=no
1696 libc_cv_idn=no
1697
1698 # Iterate over all the sysdep directories we will use, running their
1699 # configure fragments.
1700 for dir in $sysnames; do
1701   case $dir in
1702     /*) dest=$dir ;;
1703     *)  dest=$srcdir/$dir ;;
1704   esac
1705   if test -r $dest/configure; then
1706     AC_MSG_RESULT(running configure fragment for $dir)
1707     . $dest/configure
1708   fi
1709 done
1710
1711 if test x"$build_mathvec" = xnotset; then
1712   build_mathvec=no
1713 fi
1714 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1715
1716 AC_SUBST(libc_extra_cflags)
1717 AC_SUBST(libc_extra_cppflags)
1718
1719 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1720   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1721 fi
1722 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1723
1724 # A sysdeps configure fragment can reset this if IFUNC is not actually
1725 # usable even though the assembler knows how to generate the symbol type.
1726 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1727   AC_DEFINE(HAVE_IFUNC)
1728 fi
1729
1730 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1731   AC_DEFINE(HAVE_GCC_IFUNC)
1732 fi
1733
1734 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1735 # configure fragment can override the value to prevent this AC_DEFINE.
1736 AC_SUBST(use_nscd)
1737 if test "x$use_nscd" != xno; then
1738   AC_DEFINE([USE_NSCD])
1739 fi
1740 if test "x$build_nscd" = xdefault; then
1741   build_nscd=$use_nscd
1742 fi
1743
1744 AC_SUBST(libc_cv_slibdir)
1745 AC_SUBST(libc_cv_rtlddir)
1746 AC_SUBST(libc_cv_complocaledir)
1747 AC_SUBST(libc_cv_sysconfdir)
1748 AC_SUBST(libc_cv_localstatedir)
1749 AC_SUBST(libc_cv_rootsbindir)
1750
1751 if test x$use_ldconfig = xyes; then
1752   AC_DEFINE(USE_LDCONFIG)
1753 fi
1754 AC_SUBST(use_ldconfig)
1755 AC_SUBST(ldd_rewrite_script)
1756
1757 AC_SUBST(static)
1758 AC_SUBST(shared)
1759
1760 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1761 [libc_cv_pic_default=yes
1762 cat > conftest.c <<EOF
1763 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1764 # error PIC is default.
1765 #endif
1766 EOF
1767 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1768   libc_cv_pic_default=no
1769 fi
1770 rm -f conftest.*])
1771 AC_SUBST(libc_cv_pic_default)
1772
1773 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1774 [libc_cv_pie_default=yes
1775 cat > conftest.c <<EOF
1776 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1777 # error PIE is default.
1778 #endif
1779 EOF
1780 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1781   libc_cv_pie_default=no
1782 fi
1783 rm -f conftest.*])
1784 AC_SUBST(libc_cv_pie_default)
1785
1786 # Set the `multidir' variable by grabbing the variable from the compiler.
1787 # We do it once and save the result in a generated makefile.
1788 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1789 AC_SUBST(libc_cv_multidir)
1790
1791 AC_SUBST(profile)
1792 AC_SUBST(static_nss)
1793
1794 AC_SUBST(DEFINES)
1795
1796 dnl See sysdeps/mach/configure.ac for this variable.
1797 AC_SUBST(mach_interface_list)
1798
1799 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1800 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1801 AC_SUBST(VERSION)
1802 AC_SUBST(RELEASE)
1803
1804 AC_CONFIG_FILES([config.make Makefile])
1805 AC_CONFIG_COMMANDS([default],[[
1806 case $CONFIG_FILES in *config.make*)
1807 echo "$config_vars" >> config.make;;
1808 esac
1809 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1810 AC_OUTPUT