sysdeps/unix/sysv/linux/arm/vfork.S

   1 /* Copyright (C) 1999-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Philip Blundell <philb@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22
  23 /* Clone the calling process, but without copying the whole address space.
  24    The calling process is suspended until the new process exits or is
  25    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  26    and the process ID of the new process to the old process.  */
  27
  28 ENTRY (__vfork)
  29 #ifdef SAVE_PID
  30         SAVE_PID
  31 #endif
  32         /* The DO_CALL macro saves r7 on the stack, to enable generation
  33            of ARM unwind info.  Since the stack is initially shared between
  34            parent and child of vfork, that saved value could be corrupted.
  35            To avoid this problem, we save r7 into ip as well, and restore
  36            from there.  */
  37         mov     ip, r7
  38         cfi_register (r7, ip)
  39         .fnstart
  40         push    { r7 }
  41         cfi_adjust_cfa_offset (4)
  42         .save { r7 }
  43         ldr     r7, =SYS_ify (vfork)
  44         swi     0x0
  45         .fnend
  46         add     sp, sp, #4
  47         cfi_adjust_cfa_offset (-4)
  48         mov     r7, ip
  49         cfi_restore (r7);
  50 #ifdef RESTORE_PID
  51         RESTORE_PID
  52 #endif
  53         cmn     a1, #4096
  54         it      cc
  55         RETINSTR(cc, lr)
  56
  57         b       PLTJMP(SYSCALL_ERROR)
  58 PSEUDO_END (__vfork)
  59 libc_hidden_def (__vfork)
  60
  61 weak_alias (__vfork, vfork)