sysdeps/i386/strcspn.S

   1 /* strcspn (str, ss) -- Return the length of the initial segment of STR
   2                         which contains no characters from SS.
   3    For Intel 80x86, x>=3.
   4    Copyright (C) 1994-1997,2000,2003,2005 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6    Contributed by Ulrich Drepper <drepper@gnu.ai.mit.edu>
   7    Bug fixes by Alan Modra <Alan@SPRI.Levels.UniSA.Edu.Au>
   8
   9    The GNU C Library is free software; you can redistribute it and/or
  10    modify it under the terms of the GNU Lesser General Public
  11    License as published by the Free Software Foundation; either
  12    version 2.1 of the License, or (at your option) any later version.
  13
  14    The GNU C Library is distributed in the hope that it will be useful,
  15    but WITHOUT ANY WARRANTY; without even the implied warranty of
  16    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17    Lesser General Public License for more details.
  18
  19    You should have received a copy of the GNU Lesser General Public
  20    License along with the GNU C Library; if not, see
  21    <http://www.gnu.org/licenses/>.  */
  22
  23 #include <sysdep.h>
  24 #include "asm-syntax.h"
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27
  28 #define PARMS   LINKAGE         /* no space for saved regs */
  29 #define STR     PARMS
  30 #define STOP    STR+PTR_SIZE
  31
  32         .text
  33 ENTRY (BP_SYM (strcspn))
  34         ENTER
  35
  36         movl STR(%esp), %edx
  37         movl STOP(%esp), %eax
  38         CHECK_BOUNDS_LOW (%edx, STR(%esp))
  39
  40         /* First we create a table with flags for all possible characters.
  41            For the ASCII (7bit/8bit) or ISO-8859-X character sets which are
  42            supported by the C string functions we have 256 characters.
  43            Before inserting marks for the stop characters we clear the whole
  44            table.  The unrolled form is much faster than a loop.  */
  45         xorl %ecx, %ecx         /* %ecx = 0 !!! */
  46
  47         pushl %ecx              /* make a 256 bytes long block filled with 0 */
  48         cfi_adjust_cfa_offset (4)
  49         pushl %ecx
  50         cfi_adjust_cfa_offset (4)
  51         pushl %ecx
  52         cfi_adjust_cfa_offset (4)
  53         pushl %ecx
  54         cfi_adjust_cfa_offset (4)
  55         pushl %ecx
  56         cfi_adjust_cfa_offset (4)
  57         pushl %ecx
  58         cfi_adjust_cfa_offset (4)
  59         pushl %ecx
  60         cfi_adjust_cfa_offset (4)
  61         pushl %ecx
  62         cfi_adjust_cfa_offset (4)
  63         pushl %ecx
  64         cfi_adjust_cfa_offset (4)
  65         pushl %ecx
  66         cfi_adjust_cfa_offset (4)
  67         pushl %ecx
  68         cfi_adjust_cfa_offset (4)
  69         pushl %ecx
  70         cfi_adjust_cfa_offset (4)
  71         pushl %ecx
  72         cfi_adjust_cfa_offset (4)
  73         pushl %ecx
  74         cfi_adjust_cfa_offset (4)
  75         pushl %ecx
  76         cfi_adjust_cfa_offset (4)
  77         pushl %ecx
  78         cfi_adjust_cfa_offset (4)
  79         pushl %ecx
  80         cfi_adjust_cfa_offset (4)
  81         pushl %ecx
  82         cfi_adjust_cfa_offset (4)
  83         pushl %ecx
  84         cfi_adjust_cfa_offset (4)
  85         pushl %ecx
  86         cfi_adjust_cfa_offset (4)
  87         pushl %ecx
  88         cfi_adjust_cfa_offset (4)
  89         pushl %ecx
  90         cfi_adjust_cfa_offset (4)
  91         pushl %ecx
  92         cfi_adjust_cfa_offset (4)
  93         pushl %ecx
  94         cfi_adjust_cfa_offset (4)
  95         pushl %ecx
  96         cfi_adjust_cfa_offset (4)
  97         pushl %ecx
  98         cfi_adjust_cfa_offset (4)
  99         pushl %ecx
 100         cfi_adjust_cfa_offset (4)
 101         pushl %ecx
 102         cfi_adjust_cfa_offset (4)
 103         pushl %ecx
 104         cfi_adjust_cfa_offset (4)
 105         pushl %ecx
 106         cfi_adjust_cfa_offset (4)
 107         pushl %ecx
 108         cfi_adjust_cfa_offset (4)
 109         pushl %ecx
 110         cfi_adjust_cfa_offset (4)
 111         pushl %ecx
 112         cfi_adjust_cfa_offset (4)
 113         pushl %ecx
 114         cfi_adjust_cfa_offset (4)
 115         pushl %ecx
 116         cfi_adjust_cfa_offset (4)
 117         pushl %ecx
 118         cfi_adjust_cfa_offset (4)
 119         pushl %ecx
 120         cfi_adjust_cfa_offset (4)
 121         pushl %ecx
 122         cfi_adjust_cfa_offset (4)
 123         pushl %ecx
 124         cfi_adjust_cfa_offset (4)
 125         pushl %ecx
 126         cfi_adjust_cfa_offset (4)
 127         pushl %ecx
 128         cfi_adjust_cfa_offset (4)
 129         pushl %ecx
 130         cfi_adjust_cfa_offset (4)
 131         pushl %ecx
 132         cfi_adjust_cfa_offset (4)
 133         pushl %ecx
 134         cfi_adjust_cfa_offset (4)
 135         pushl %ecx
 136         cfi_adjust_cfa_offset (4)
 137         pushl %ecx
 138         cfi_adjust_cfa_offset (4)
 139         pushl %ecx
 140         cfi_adjust_cfa_offset (4)
 141         pushl %ecx
 142         cfi_adjust_cfa_offset (4)
 143         pushl %ecx
 144         cfi_adjust_cfa_offset (4)
 145         pushl %ecx
 146         cfi_adjust_cfa_offset (4)
 147         pushl %ecx
 148         cfi_adjust_cfa_offset (4)
 149         pushl %ecx
 150         cfi_adjust_cfa_offset (4)
 151         pushl %ecx
 152         cfi_adjust_cfa_offset (4)
 153         pushl %ecx
 154         cfi_adjust_cfa_offset (4)
 155         pushl %ecx
 156         cfi_adjust_cfa_offset (4)
 157         pushl %ecx
 158         cfi_adjust_cfa_offset (4)
 159         pushl %ecx
 160         cfi_adjust_cfa_offset (4)
 161         pushl %ecx
 162         cfi_adjust_cfa_offset (4)
 163         pushl $0                /* These immediate values make the label 2 */
 164         cfi_adjust_cfa_offset (4)
 165         pushl $0                /* to be aligned on a 16 byte boundary to */
 166         cfi_adjust_cfa_offset (4)
 167         pushl $0                /* get a better performance of the loop.  */
 168         cfi_adjust_cfa_offset (4)
 169         pushl $0
 170         cfi_adjust_cfa_offset (4)
 171         pushl $0
 172         cfi_adjust_cfa_offset (4)
 173         pushl $0
 174         cfi_adjust_cfa_offset (4)
 175
 176 /* For understanding the following code remember that %ecx == 0 now.
 177    Although all the following instruction only modify %cl we always
 178    have a correct zero-extended 32-bit value in %ecx.  */
 179
 180 /* Don't change the "testb $0xff,%%cl" to "testb %%cl,%%cl".  We want
 181    longer instructions so that the next loop aligns without adding nops.  */
 182
 183 L(2):   movb (%eax), %cl        /* get byte from stopset */
 184         testb %cl, %cl          /* is NUL char? */
 185         jz L(1)                 /* yes => start compare loop */
 186         movb %cl, (%esp,%ecx)   /* set corresponding byte in stopset table */
 187
 188         movb 1(%eax), %cl       /* get byte from stopset */
 189         testb $0xff, %cl        /* is NUL char? */
 190         jz L(1)                 /* yes => start compare loop */
 191         movb %cl, (%esp,%ecx)   /* set corresponding byte in stopset table */
 192
 193         movb 2(%eax), %cl       /* get byte from stopset */
 194         testb $0xff, %cl        /* is NUL char? */
 195         jz L(1)                 /* yes => start compare loop */
 196         movb %cl, (%esp,%ecx)   /* set corresponding byte in stopset table */
 197
 198         movb 3(%eax), %cl       /* get byte from stopset */
 199         addl $4, %eax           /* increment stopset pointer */
 200         movb %cl, (%esp,%ecx)   /* set corresponding byte in stopset table */
 201         testb $0xff, %cl        /* is NUL char? */
 202         jnz L(2)                /* no => process next dword from stopset */
 203
 204 L(1):   leal -4(%edx), %eax     /* prepare loop */
 205
 206         /* We use a neat trick for the following loop.  Normally we would
 207            have to test for two termination conditions
 208            1. a character in the stopset was found
 209            and
 210            2. the end of the string was found
 211            But as a sign that the character is in the stopset we store its
 212            value in the table.  But the value of NUL is NUL so the loop
 213            terminates for NUL in every case.  */
 214
 215 L(3):   addl $4, %eax           /* adjust pointer for full loop round */
 216
 217         movb (%eax), %cl        /* get byte from string */
 218         cmpb %cl, (%esp,%ecx)   /* is it contained in stopset? */
 219         je L(4)                 /* yes => return */
 220
 221         movb 1(%eax), %cl       /* get byte from string */
 222         cmpb %cl, (%esp,%ecx)   /* is it contained in stopset? */
 223         je L(5)                 /* yes => return */
 224
 225         movb 2(%eax), %cl       /* get byte from string */
 226         cmpb %cl, (%esp,%ecx)   /* is it contained in stopset? */
 227         je L(6)                 /* yes => return */
 228
 229         movb 3(%eax), %cl       /* get byte from string */
 230         cmpb %cl, (%esp,%ecx)   /* is it contained in stopset? */
 231         jne L(3)                /* yes => return */
 232
 233         incl %eax               /* adjust pointer */
 234 L(6):   incl %eax
 235 L(5):   incl %eax
 236
 237 L(4):   addl $256, %esp         /* remove stopset */
 238         cfi_adjust_cfa_offset (-256)
 239         CHECK_BOUNDS_HIGH (%eax, STR(%esp), jb)
 240         subl %edx, %eax         /* we have to return the number of valid
 241                                    characters, so compute distance to first
 242                                    non-valid character */
 243         LEAVE
 244         ret
 245 END (BP_SYM (strcspn))
 246 libc_hidden_builtin_def (strcspn)