configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware,
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52 AC_ARG_WITH(weak-symbols, dnl
  53   --with-weak-symbols     if weak symbols are available in as and ld,
  54             weak=$withval, weak=no)
  55
  56 AC_ARG_ENABLE(libio, dnl
  57 [  --enable-libio          build in GNU libio instead of GNU stdio],
  58               [if test $enableval = yes; then
  59                  stdio=libio
  60                else
  61                  stdio=stdio
  62                fi],
  63               stdio=default)
  64
  65 dnl Arguments to enable or disable building the shared, profiled, and
  66 dnl -fomit-frame-pointer libraries.
  67 AC_ARG_ENABLE(shared, dnl
  68 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  69             shared=$enableval, shared=default)
  70 AC_ARG_ENABLE(profile, dnl
  71 [  --enable-profile        build profiled library [default=yes]],
  72             profile=$enableval, profile=yes)
  73 AC_ARG_ENABLE(omitfp, dnl
  74 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  75             omitfp=$enableval, omitfp=no)
  76
  77 AC_CANONICAL_HOST
  78 # We keep the original values in `$config_*' and never modify them, so we
  79 # can write them unchanged into config.make.  Everything else uses
  80 # $machine, $vendor, and $os, and changes them whenever convenient.
  81 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  82
  83 # Some configurations imply other options.
  84 case "$host_os" in
  85 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  86   # These systems always use GNU tools.
  87   gnu_ld=yes gnu_as=yes
  88 esac
  89 case "$host_os" in
  90 gnu* | linux* | sysv4* | solaris2*)
  91   # These systems always use the ELF format.
  92   elf=yes
  93 esac
  94
  95 # Compute the list of sysdep directories for this configuration.
  96 sysdep_dir=$srcdir/sysdeps
  97 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
  98 machine=$config_machine
  99 vendor=$config_vendor
 100 os=$config_os
 101
 102 dnl We need to use [ and ] for other purposes for a while now.
 103 changequote(,)dnl
 104 # Expand the configuration machine name into a subdirectory by architecture
 105 # type and particular chip.
 106 case "$machine" in
 107 a29k | am29000) machine=a29k ;;
 108 alpha*)         machine=alpha/$machine ;;
 109 hppa*)          machine=hppa/$machine ;;
 110 i[345]86)       machine=i386/$machine ;;
 111 m680?0)         machine=m68k/$machine ;;
 112 m68k)           machine=m68k/m68020 ;;
 113 m88???)         machine=m88k/$machine ;;
 114 m88k)           machine=m88k/m88100 ;;
 115 mips*)          machine=mips/$machine ;;
 116 mips64*)        machine=mips/mips64/$machine ;;
 117 sparc[6789])    machine=sparc/$machine ;;
 118 supersparc)     machine=sparc/sparc8 ;;
 119 esac
 120
 121 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 122 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 123
 124 case "$os" in
 125 gnu*)
 126   base_os=mach/hurd ;;
 127 netbsd* | 386bsd* | freebsd* | bsdi*)
 128   base_os=unix/bsd/bsd4.4 ;;
 129 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 130   base_os=unix/bsd ;;
 131 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 132   base_os=unix/sysv ;;
 133 solaris[2-9]*)
 134   base_os=unix/sysv/sysv4 ;;
 135 none)
 136   base_os=standalone ;;
 137 *)
 138   base_os='' ;;
 139 esac
 140
 141 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 142 tail=$os
 143 ostry=$os
 144 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 145   ostry="$ostry /$o"
 146   tail=$o
 147 done
 148 o=`echo $tail | sed 's/[0-9]*$//'`
 149 if test $o != $tail; then
 150   ostry="$ostry /$o"
 151 fi
 152
 153 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 154 base=
 155 tail=$base_os
 156 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 157   set $b
 158   base="$base /$1"
 159   tail="$2"
 160 done
 161
 162 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 163 mach=
 164 tail=$machine
 165 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 166   set $m
 167   # Prepend the machine's FPU directory unless --without-fp.
 168   if test "$with_fp" = yes; then
 169     mach="$mach /$1/fpu"
 170   fi
 171   mach="$mach /$1"
 172   tail="$2"
 173 done
 174
 175 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 176 changequote([,])dnl
 177
 178 # Find what sysdep directories exist.
 179 sysnames=
 180 for b in $base ''; do
 181   for m0 in $mach ''; do
 182     for v in /$vendor ''; do
 183       for o in /$ostry ''; do
 184         for m in $mach ''; do
 185           try="$m0$b$v$o$m"
 186           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 187           if test -d $sysdep_dir$try; then
 188             sysnames="$sysnames $try"
 189             { test -n "$o" || test -n "$b"; } && os_used=t
 190             { test -n "$m" || test -n "$m0"; } && machine_used=t
 191           fi
 192         done
 193       done
 194     done
 195   done
 196 done
 197
 198 if test -z "$os_used" && test "$os" != none; then
 199   AC_MSG_ERROR(Operating system $os is not supported.)
 200 fi
 201 if test -z "$machine_used" && test "$machine" != none; then
 202   AC_MSG_ERROR(The $machine is not supported.)
 203 fi
 204
 205 # We have now validated the configuration.
 206
 207
 208 # If using ELF, look for an `elf' subdirectory of each machine directory.
 209 # We prepend these rather than inserting them whereever the machine appears
 210 # because things specified by the machine's ELF ABI should override
 211 # OS-specific things, and should always be the same for any OS on the
 212 # machine (otherwise what's the point of an ABI?).
 213 if test "$elf" = yes; then
 214   elf_dirs=
 215   for m in $mach; do
 216     if test -d $sysdep_dir$m/elf; then
 217       elf_dirs="$elf_dirs $m/elf"
 218     fi
 219   done
 220   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 221 fi
 222
 223
 224 # Remove the leading slashes.
 225 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 226
 227
 228 # Expand the list of system names into a full list of directories
 229 # from each element's parent name and Implies file (if present).
 230 set $sysnames
 231 while test $# -gt 0; do
 232   name=$1
 233   shift
 234
 235   if test -f $sysdep_dir/$name/Implies; then
 236     # Collect more names from the `Implies' file (removing comments).
 237     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 238     for x in $implied; do
 239       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 240     done
 241   else
 242     implied=
 243   fi
 244
 245   # Add NAME to the list of names.
 246   names="$names $name"
 247
 248   # Find the parent of NAME, using the empty string if it has none.
 249 changequote(,)dnl
 250   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 251 changequote([,])dnl
 252
 253   # Add the names implied by NAME, and NAME's parent (if it has one), to
 254   # the list of names to be processed (the argument list).  We prepend the
 255   # implied names to the list and append the parent.  We want implied
 256   # directories to come before further directories inferred from the
 257   # configuration components; this ensures that for sysv4, unix/common
 258   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 259   # after sysv4).
 260   sysnames="`echo $implied $* $parent`"
 261   test -n "$sysnames" && set $sysnames
 262 done
 263
 264 # Add the default directories.
 265 names="$names generic stub"
 266
 267 # Now uniquize the list.
 268 seen=
 269 sysnames=
 270 for name in $names; do
 271   if echo "$seen" | fgrep -x $name >/dev/null; then
 272     # Already in the list.
 273     true;
 274   else
 275     # A new one.
 276     if test -z "$seen"; then
 277       seen="$name" sysnames="$name"
 278     else
 279       seen="$seen
 280 $name"
 281       sysnames="$sysnames $name"
 282     fi
 283   fi
 284 done
 285 libc_cv_sysdirs="$sysnames"])
 286 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 287
 288 AC_PROG_INSTALL
 289 if test "$INSTALL" = "${srcdir}/install-sh"; then
 290   # The makefiles need to use a different form to find it in $srcdir.
 291   INSTALL='$(..)./install-sh'
 292 fi
 293
 294 AC_CHECK_TOOL(CC, gcc)
 295 AC_CHECK_TOOL(AR, ar)
 296 AC_CHECK_TOOL(RANLIB, ranlib, :)
 297 AC_PROG_CPP
 298
 299 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 300 echo '#include <stddef.h>
 301 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 302 if eval "$ac_cpp conftest.c 2>/dev/null" \
 303 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 304   libc_cv_signed_size_t=no
 305 else
 306   libc_cv_signed_size_t=yes
 307 fi
 308 rm -f conftest*])
 309 if test $libc_cv_signed_size_t = yes; then
 310   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 311   cat >> confdefs.h <<\EOF
 312 #undef __SIZE_TYPE__
 313 #define __SIZE_TYPE__ unsigned
 314 EOF
 315 fi
 316
 317 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 318 AC_TRY_COMPILE(dnl
 319 [#define __need_size_t
 320 #define __need_wchar_t
 321 #include <stddef.h>
 322 #define __need_NULL
 323 #include <stddef.h>], [size_t size; wchar_t wchar;
 324 #ifdef offsetof
 325 #error stddef.h ignored __need_*
 326 #endif
 327 if (&size == NULL || &wchar == NULL) abort ();],
 328                libc_cv_friendly_stddef=yes,
 329                libc_cv_friendly_stddef=no)])
 330 if test $libc_cv_friendly_stddef = yes; then
 331   config_vars="$config_vars
 332 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 333 fi
 334
 335 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 336                libc_cv_need_minus_P, [dnl
 337 cat > conftest.S <<EOF
 338 #include "confdefs.h"
 339 /* Nothing whatsoever.  */
 340 EOF
 341 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 342   libc_cv_need_minus_P=no
 343 else
 344   libc_cv_need_minus_P=yes
 345 fi
 346 rm -f conftest*])
 347 if test $libc_cv_need_minus_P = yes; then
 348   config_vars="$config_vars
 349 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 350 fi
 351
 352 AC_CACHE_CHECK(for assembler global-symbol directive,
 353                libc_cv_asm_global_directive, [dnl
 354 libc_cv_asm_global_directive=UNKNOWN
 355 for ac_globl in .globl .global; do
 356   cat > conftest.s <<EOF
 357 .text
 358 ${ac_globl} foo
 359 foo: .long 0
 360 EOF
 361   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 362     libc_cv_asm_global_directive=${ac_globl}
 363   fi
 364   rm -f conftest*
 365   test $libc_cv_asm_global_directive != UNKNOWN && break
 366 done])
 367 if test $libc_cv_asm_global_directive = UNKNOWN; then
 368   AC_MSG_ERROR(cannot determine asm global directive)
 369 else
 370   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 371 fi
 372
 373 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 374 cat > conftest.s <<EOF
 375 .text
 376 foo: .long 0
 377 .set glibc_conftest_frobozz,foo
 378 $libc_cv_asm_global_directive glibc_conftest_frobozz
 379 EOF
 380 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 381 # (but it doesn't work), so we must do a linking check to be sure.
 382 cat > conftest1.c <<\EOF
 383 extern int glibc_conftest_frobozz;
 384 main () { printf ("%d\n", glibc_conftest_frobozz); }
 385 EOF
 386 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 387             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 388   libc_cv_asm_set_directive=yes
 389 else
 390   libc_cv_asm_set_directive=no
 391 fi
 392 rm -f conftest*])
 393 if test $libc_cv_asm_set_directive = yes; then
 394   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 395 fi
 396
 397 if test $elf != yes; then
 398   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 399                  [AC_TRY_COMPILE(, [asm (".section .init");
 400                                     asm (".section .fini");],
 401                                  libc_cv_have_initfini=yes,
 402                                  libc_cv_have_initfini=no)])
 403   AC_SUBST(libc_cv_have_initfini)dnl
 404   if test $libc_cv_have_initfini = yes; then
 405     AC_DEFINE(HAVE_INITFINI)
 406   fi
 407 fi
 408
 409 # sysdeps configure fragments may set these with files to be linked below.
 410 libc_link_dests=
 411 libc_link_sources=
 412
 413 # Iterate over all the sysdep directories we will use, running their
 414 # configure fragments, and looking for a uname implementation.
 415 uname=
 416 for dir in $sysnames; do
 417   if test -r $sysdep_dir/$dir/configure; then
 418     AC_MSG_RESULT(running configure fragment for $dir)
 419     . $sysdep_dir/$dir/configure
 420   fi
 421   if test -z "$uname"; then
 422     if test -r $sysdep_dir/$dir/uname.c ||
 423        test -r $sysdep_dir/$dir/uname.S ||
 424        { test -r $sysdep_dir/$dir/syscalls.list &&
 425          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 426       uname=$dir
 427   fi
 428 done
 429
 430 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 431
 432 # If we will use the generic uname implementation, we must figure out what
 433 # it will say by examining the system, and write the results in config-name.h.
 434 if test "$uname" = generic; then
 435
 436 changequote(,)dnl
 437   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 438 changequote([,])dnl
 439   if test $uname_sysname != $config_os; then
 440     config_release=`echo $config_os | sed s/$uname_sysname//`
 441   fi
 442 dnl
 443 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 444     if test -r /vmunix; then
 445       kernel_id=`strings /vmunix | grep UNIX`
 446     elif test -r /dynix; then
 447       kernel_id=`strings /dynix | grep DYNIX`
 448     else
 449       kernel_id=
 450     fi
 451 ])dnl
 452
 453   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 454 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 455 changequote(,)dnl
 456   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 457 changequote([,])dnl
 458   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 459          != x$config_release; then
 460     # The configuration release is a substring of the kernel release.
 461     libc_cv_uname_release=$kernel_release
 462   elif test x$config_release != x; then
 463     libc_cv_uname_release=$config_release
 464   elif test x$kernel_release != x; then
 465     libc_cv_uname_release=$kernel_release
 466   else
 467     libc_cv_uname_release=unknown
 468   fi])
 469   uname_release="$libc_cv_uname_release"
 470
 471   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 472 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 473 changequote(,)dnl
 474   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 475 changequote([,])dnl
 476   if test -n "$kernel_version"; then
 477     libc_cv_uname_version="$kernel_version"
 478   else
 479     libc_cv_uname_version=unknown
 480   fi])
 481   uname_version="$libc_cv_uname_version"
 482
 483 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 484   config_uname=config-name.h:config-name.in
 485 else
 486   # For non-generic uname, we don't need to create config-name.h at all.
 487   config_uname=
 488 fi
 489
 490 AC_MSG_CHECKING(stdio selection)
 491 AC_SUBST(stdio)
 492 case $stdio in
 493 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 494 default) stdio=stdio ;;
 495 esac
 496 AC_MSG_RESULT($stdio)
 497
 498 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 499 if test $gnu_ld = yes; then
 500   AC_DEFINE(HAVE_GNU_LD)
 501 fi
 502 if test $gnu_as = yes; then
 503   AC_DEFINE(HAVE_GNU_AS)
 504 fi
 505 if test $elf = yes; then
 506   AC_DEFINE(HAVE_ELF)
 507 fi
 508 if test $weak = yes; then
 509   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 510 fi
 511
 512 AC_SUBST(shared)
 513 if test $shared = default; then
 514   if test $gnu_ld = yes; then
 515     shared=$elf
 516   fi
 517 fi
 518 AC_SUBST(profile)
 519 AC_SUBST(omitfp)
 520
 521 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 522   config_makefile=
 523 else
 524   config_makefile=Makefile
 525 fi
 526
 527 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 528           [echo '$config_vars' >> config.make])