sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999, 2002, 2004, 2005 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab <schwab@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ERRNO_H        1
  22 #include <bits/errno.h>
  23 #include <kernel-features.h>
  24
  25 /* Clone the calling process, but without copying the whole address space.
  26    The calling process is suspended until the new process exits or is
  27    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  28    and the process ID of the new process to the old process.  */
  29
  30 ENTRY (__vfork)
  31
  32 #ifdef __NR_vfork
  33
  34         /* Pop the return PC value into ECX.  */
  35         popl    %ecx
  36         cfi_adjust_cfa_offset (-4)
  37
  38 #ifdef SAVE_PID
  39         SAVE_PID
  40 #endif
  41
  42         /* Stuff the syscall number in EAX and enter into the kernel.  */
  43         movl    $SYS_ify (vfork), %eax
  44         int     $0x80
  45
  46         /* Jump to the return PC.  Don't jump directly since this
  47            disturbs the branch target cache.  Instead push the return
  48            address back on the stack.  */
  49         pushl   %ecx
  50         cfi_adjust_cfa_offset (4)
  51
  52 #ifdef RESTORE_PID
  53         RESTORE_PID
  54 #endif
  55
  56         cmpl    $-4095, %eax
  57         /* Branch forward if it failed.  */
  58 # ifdef __ASSUME_VFORK_SYSCALL
  59         jae     SYSCALL_ERROR_LABEL
  60 .Lpseudo_end:
  61 # else
  62         jae     .Lerror
  63 # endif
  64
  65         ret
  66
  67 # ifndef __ASSUME_VFORK_SYSCALL
  68 .Lerror:
  69         /* Check if vfork syscall is known at all.  */
  70         cmpl    $-ENOSYS, %eax
  71         jne     SYSCALL_ERROR_LABEL
  72 # endif
  73 #endif
  74
  75 #ifndef __ASSUME_VFORK_SYSCALL
  76         /* If we don't have vfork, fork is close enough.  */
  77
  78         movl    $SYS_ify (fork), %eax
  79         int     $0x80
  80         cmpl    $-4095, %eax
  81         jae     SYSCALL_ERROR_LABEL
  82 .Lpseudo_end:
  83         ret
  84 #endif
  85 PSEUDO_END (__vfork)
  86 libc_hidden_def (__vfork)
  87
  88 weak_alias (__vfork, vfork)