sysdeps/i386/__longjmp.S

   1 /* longjmp for i386.
   2    Copyright (C) 1995-1998,2000,2002,2005,2006,2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <jmpbuf-offsets.h>
  23 #include <asm-syntax.h>
  24 #include <bp-sym.h>
  25 #include <bp-asm.h>
  26
  27 #define PARMS   LINKAGE         /* no space for saved regs */
  28 #define JBUF    PARMS
  29 #define VAL     JBUF+PTR_SIZE
  30
  31 ENTRY (BP_SYM (__longjmp))
  32         ENTER
  33
  34 #ifdef PTR_DEMANGLE
  35         movl JBUF(%esp), %eax   /* User's jmp_buf in %eax.  */
  36         CHECK_BOUNDS_BOTH_WIDE (%eax, JBUF(%esp), $JB_SIZE)
  37
  38         /* Save the return address now.  */
  39         movl (JB_PC*4)(%eax), %edx
  40         /* Get the stack pointer.  */
  41         movl (JB_SP*4)(%eax), %ecx
  42         PTR_DEMANGLE (%edx)
  43         PTR_DEMANGLE (%ecx)
  44 # ifdef CHECK_ESP
  45         CHECK_ESP (%ecx)
  46 # endif
  47         cfi_def_cfa(%eax, 0)
  48         cfi_register(%eip, %edx)
  49         cfi_register(%esp, %ecx)
  50         cfi_offset(%ebx, JB_BX*4)
  51         cfi_offset(%esi, JB_SI*4)
  52         cfi_offset(%edi, JB_DI*4)
  53         cfi_offset(%ebp, JB_BP*4)
  54         /* Restore registers.  */
  55         movl (JB_BX*4)(%eax), %ebx
  56         movl (JB_SI*4)(%eax), %esi
  57         movl (JB_DI*4)(%eax), %edi
  58         movl (JB_BP*4)(%eax), %ebp
  59         cfi_restore(%ebx)
  60         cfi_restore(%esi)
  61         cfi_restore(%edi)
  62         cfi_restore(%ebp)
  63
  64         movl VAL(%esp), %eax    /* Second argument is return value.  */
  65         movl %ecx, %esp
  66 #else
  67         movl JBUF(%esp), %ecx   /* User's jmp_buf in %ecx.  */
  68         CHECK_BOUNDS_BOTH_WIDE (%ecx, JBUF(%esp), $JB_SIZE)
  69
  70 # ifdef CHECK_ESP
  71         movl (JB_SP*4)(%ecx), %eax
  72         CHECK_ESP (%eax)
  73 # endif
  74
  75         movl VAL(%esp), %eax    /* Second argument is return value.  */
  76         /* Save the return address now.  */
  77         movl (JB_PC*4)(%ecx), %edx
  78         /* Restore registers.  */
  79         movl (JB_BX*4)(%ecx), %ebx
  80         movl (JB_SI*4)(%ecx), %esi
  81         movl (JB_DI*4)(%ecx), %edi
  82         movl (JB_BP*4)(%ecx), %ebp
  83         movl (JB_SP*4)(%ecx), %esp
  84 #endif
  85         /* Jump to saved PC.  */
  86         jmp *%edx
  87 END (BP_SYM (__longjmp))