configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_ARG_WITH(binutils, dnl
  63   --with-binutils=PATH    specify location of binutils (as and ld),
  64             path_binutils=$withval, path_binutils='')
  65 AC_ARG_WITH(elf, dnl
  66   --with-elf              if using the ELF object format,
  67             elf=$withval, elf=no)
  68 AC_ARG_WITH(cvs, dnl
  69 [  --without-cvs          if CVS should not be used],
  70             with_cvs=$withval, with_cvs=yes)
  71 AC_SUBST(with_cvs)
  72
  73 AC_ARG_WITH(headers, dnl
  74 [  --with-headers=PATH     location of system headers to use
  75                           [e.g. /usr/src/linux/include]
  76                           [default=compiler default]],
  77             sysheaders=$withval, sysheaders='')
  78
  79 AC_ARG_ENABLE(libio, dnl
  80 [  --enable-libio          build in GNU libio instead of GNU stdio],
  81               [if test $enableval = yes; then
  82                  stdio=libio
  83                else
  84                  stdio=stdio
  85                fi],
  86               stdio=default)
  87
  88 AC_ARG_ENABLE(sanity-checks, dnl
  89 [  --disable-sanity-checks really do not use threads (should not be used
  90                           except in special situations) [default=yes]],
  91               enable_sanity=$enableval, enable_sanity=yes)
  92
  93 dnl Arguments to enable or disable building the static, shared, profiled,
  94 dnl and -fomit-frame-pointer libraries.
  95 dnl I've disabled this for now since we cannot build glibc without static
  96 dnl libraries built in the moment.
  97 dnl AC_ARG_ENABLE(static, dnl
  98 dnl [  --enable-static         build static library [default=yes]],
  99 dnl           static=$enableval, static=yes)
 100 static=yes
 101 AC_ARG_ENABLE(shared, dnl
 102 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 103               shared=$enableval, shared=default)
 104 AC_ARG_ENABLE(profile, dnl
 105 [  --enable-profile        build profiled library [default=yes]],
 106               profile=$enableval, profile=yes)
 107 AC_ARG_ENABLE(omitfp, dnl
 108 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 109               omitfp=$enableval, omitfp=no)
 110 AC_ARG_ENABLE(bounded, dnl
 111 [  --enable-bounded        build with runtime bounds checking [default=no]],
 112               bounded=$enableval, bounded=no)
 113 AC_ARG_ENABLE(versioning, dnl
 114 [  --disable-versioning    do not include versioning information in the
 115                           library objects [default=yes if supported]],
 116              enable_versioning=$enableval, enable_versioning=yes)
 117
 118 dnl Generic infrastructure for drop-in additions to libc.
 119 AC_ARG_ENABLE(add-ons, dnl
 120 [  --enable-add-ons[=DIR1,DIR2]...
 121                           configure and build add-ons in DIR1,DIR2,...
 122                           search for add-ons if no parameter given],
 123   [case "$enableval" in
 124     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 125          test "$add_ons" = "*" && add_ons= ;;
 126     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 127    esac],
 128   [add_ons=])
 129
 130 AC_CONFIG_SUBDIRS($add_ons)
 131 add_ons_pfx=
 132 if test x"$add_ons" != x; then
 133   for f in $add_ons; do
 134     # Test whether such a subdir really exists.
 135     if test -d $srcdir/$f; then
 136       add_ons_pfx="$add_ons_pfx $f/"
 137     else
 138       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 139     fi
 140   done
 141 fi
 142
 143 dnl On some platforms we cannot use dynamic loading.  We must provide
 144 dnl static NSS modules.
 145 AC_ARG_ENABLE(static-nss, dnl
 146 [  --enable-static-nss     build static NSS modules [default=no]],
 147               static_nss=$enableval, static_nss=no)
 148 if test x"$static_nss" = xyes; then
 149   AC_DEFINE(DO_STATIC_NSS)
 150 fi
 151
 152 AC_ARG_ENABLE(force-install,
 153 [  --disable-force-install don't force installation of files from this package,
 154                           even if they are older than the installed files],
 155               force_install=$enableval, force_install=yes)
 156 AC_SUBST(force_install)
 157
 158 dnl On some platforms we allow dropping compatibility with all kernel
 159 dnl versions.
 160 AC_ARG_ENABLE(kernel,
 161 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 162                            than VERSION],
 163               minimum_kernel=$enableval)
 164 dnl Prevent unreasonable values.
 165 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 166   # Better nothing than this.
 167   minimum_kernel=""
 168 else
 169   if test "$minimum_kernel" = current; then
 170     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 171   fi
 172 fi
 173
 174 AC_CANONICAL_HOST
 175
 176 # The way shlib-versions is used to generate soversions.mk uses a
 177 # fairly simplistic model for name recognition that can't distinguish
 178 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 179 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 180 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 181 case "$host_os" in
 182 linux*)
 183   ;;
 184 gnu*)
 185   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 186   ;;
 187 esac
 188
 189 # We keep the original values in `$config_*' and never modify them, so we
 190 # can write them unchanged into config.make.  Everything else uses
 191 # $machine, $vendor, and $os, and changes them whenever convenient.
 192 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 193
 194 # Some configurations imply other options.
 195 case "$host_os" in
 196 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 197   # These systems always use GNU tools.
 198   gnu_ld=yes gnu_as=yes ;;
 199 esac
 200 case "$host_os" in
 201 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 202 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 203   ;;
 204 gnu* | linux* | sysv4* | solaris2* | irix6*)
 205   # These systems (almost) always use the ELF format.
 206   elf=yes
 207   ;;
 208 esac
 209
 210 machine=$config_machine
 211 vendor=$config_vendor
 212 os=$config_os
 213
 214 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 215 # Unify this here.
 216 if test "$machine" = rs6000; then
 217   machine="powerpc"
 218 fi
 219
 220 ###
 221 ### I put this here to prevent those annoying emails from people who cannot
 222 ### read and try to compile glibc on unsupported platforms.  --drepper
 223 ###
 224 ### By using the undocumented --enable-hacker-mode option for configure
 225 ### one can skip this test to make the configuration not fail for unsupported
 226 ### platforms.
 227 ###
 228 if test -z "$enable_hacker_mode"; then
 229   case "$machine-$host_os" in
 230   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 231     ;;
 232   *)
 233     echo "*** The GNU C library is currently not available for this platform."
 234     echo "*** So far nobody cared to port it and if there is no volunteer it"
 235     echo "*** might never happen.  So, if you have interest to see glibc on"
 236     echo "*** this platform visit"
 237     echo "***   http://www.gnu.org/software/libc/porting.html"
 238     echo "*** and join the group of porters"
 239     exit 1
 240     ;;
 241   esac
 242 fi
 243
 244 dnl We need to use [ and ] for other purposes for a while now.
 245 changequote(,)dnl
 246 # Expand the configuration machine name into a subdirectory by architecture
 247 # type and particular chip.
 248 case "$machine" in
 249 a29k | am29000) base_machine=a29k machine=a29k ;;
 250 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 251 arm*)           base_machine=arm machine=arm/$machine ;;
 252 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 253 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 254 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 255 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 256 ia64)           base_machine=ia64 machine=ia64 ;;
 257 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 258 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 259 m88???)         base_machine=m88k machine=m88k/$machine ;;
 260 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 261 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 262 mips*)          base_machine=mips
 263                 case "`uname -m`" in
 264                 IP22) machine=mips/mips3 ;;
 265                 *)    machine=mips/$machine ;;
 266                 esac ;;
 267 sh3*)           base_machine=sh machine=sh/sh3 ;;
 268 sh4*)           base_machine=sh machine=sh/sh4 ;;
 269 sparc | sparcv[67])
 270                 base_machine=sparc machine=sparc/sparc32 ;;
 271 sparcv8 | supersparc | hypersparc)
 272                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 273 sparcv8plus | sparcv8plusa | sparcv9)
 274                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 275 sparc64 | ultrasparc)
 276                 base_machine=sparc machine=sparc/sparc64 ;;
 277 esac
 278 changequote([,])dnl
 279 AC_SUBST(base_machine)
 280
 281 if test "$base_machine" = "i386"; then
 282   AC_DEFINE(USE_REGPARMS)
 283 fi
 284
 285 # Compute the list of sysdep directories for this configuration.
 286 # This can take a while to compute.
 287 sysdep_dir=$srcdir/sysdeps
 288 AC_MSG_CHECKING(sysdep dirs)
 289 dnl We need to use [ and ] for other purposes for a while now.
 290 changequote(,)dnl
 291 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 292 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 293
 294 case "$os" in
 295 gnu*)
 296   base_os=mach/hurd ;;
 297 netbsd* | 386bsd* | freebsd* | bsdi*)
 298   base_os=unix/bsd/bsd4.4 ;;
 299 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 300   base_os=unix/bsd ;;
 301 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 302   base_os=unix/sysv ;;
 303 irix6*)
 304   base_os=unix/sysv/irix6/$os ;;
 305 solaris[2-9]*)
 306   base_os=unix/sysv/sysv4 ;;
 307 hpux*)
 308   base_os=unix/sysv/hpux/$os ;;
 309 aix4.3*)
 310   base_os=unix/sysv/aix/aix4.3 ;;
 311 none)
 312   base_os=standalone ;;
 313 *)
 314   base_os='' ;;
 315 esac
 316
 317 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 318 tail=$os
 319 ostry=$os
 320 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 321   ostry="$ostry /$o"
 322   tail=$o
 323 done
 324 o=`echo $tail | sed 's/[0-9]*$//'`
 325 if test $o != $tail; then
 326   ostry="$ostry /$o"
 327 fi
 328 # For linux-gnu, try linux-gnu, then linux.
 329 o=`echo $tail | sed 's/-.*$//'`
 330 if test $o != $tail; then
 331   ostry="$ostry /$o"
 332 fi
 333
 334 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 335 base=
 336 tail=$base_os
 337 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 338   set $b
 339   base="$base /$1"
 340   tail="$2"
 341 done
 342
 343 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 344 mach=
 345 tail=$machine
 346 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 347   set $m
 348   # Prepend the machine's FPU directory unless --without-fp.
 349   if test "$with_fp" = yes; then
 350     mach="$mach /$1/fpu"
 351   fi
 352   mach="$mach /$1"
 353   tail="$2"
 354 done
 355
 356 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 357 changequote([,])dnl
 358
 359 # Find what sysdep directories exist.
 360 sysnames=
 361 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 362 for d in $add_ons_pfx ''; do
 363   for b in $base ''; do
 364     for m0 in $mach ''; do
 365       for v in /$vendor ''; do
 366         test "$v" = / && continue
 367         for o in /$ostry ''; do
 368           test "$o" = / && continue
 369           for m in $mach ''; do
 370             if test "$m0$b$v$o$m"; then
 371               try="${d}sysdeps$m0$b$v$o$m"
 372               test -n "$enable_debug_configure" &&
 373               echo "$0 [DEBUG]: try $try" >&2
 374               if test -d $srcdir/$try; then
 375                 sysnames="$sysnames $try"
 376                 { test -n "$o" || test -n "$b"; } && os_used=t
 377                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 378               fi
 379             fi
 380           done
 381         done
 382       done
 383     done
 384   done
 385 done
 386 IFS="$ac_save_ifs"
 387
 388 if test -z "$os_used" && test "$os" != none; then
 389   AC_MSG_ERROR(Operating system $os is not supported.)
 390 fi
 391 if test -z "$machine_used" && test "$machine" != none; then
 392   AC_MSG_ERROR(The $machine is not supported.)
 393 fi
 394
 395 # We have now validated the configuration.
 396
 397
 398 # If using ELF, look for an `elf' subdirectory of each machine directory.
 399 # We prepend these rather than inserting them whereever the machine appears
 400 # because things specified by the machine's ELF ABI should override
 401 # OS-specific things, and should always be the same for any OS on the
 402 # machine (otherwise what's the point of an ABI?).
 403 if test "$elf" = yes; then
 404   elf_dirs=
 405   for d in $add_ons_pfx ''; do
 406     for m in $mach; do
 407       if test -d $srcdir/${d}sysdeps$m/elf; then
 408         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 409       fi
 410     done
 411   done
 412   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 413 fi
 414
 415
 416 # Expand the list of system names into a full list of directories
 417 # from each element's parent name and Implies file (if present).
 418 set $sysnames
 419 names=
 420 while test $# -gt 0; do
 421   name=$1
 422   shift
 423
 424   case " $names " in *" $name "*)
 425     # Already in the list.
 426     continue
 427   esac
 428
 429   # Report each name as we discover it, so there is no long pause in output.
 430   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 431
 432   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 433
 434   case $name in
 435     /*) xsrcdir= ;;
 436     *)  xsrcdir=$srcdir/ ;;
 437   esac
 438   test -n "$enable_debug_configure" &&
 439   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 440
 441   if test -f $xsrcdir$name/Implies; then
 442     # Collect more names from the `Implies' file (removing comments).
 443     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 444     implied=
 445     for x in $implied_candidate; do
 446       if test -d $xsrcdir$name_base/$x; then
 447         implied="$implied $name_base/$x";
 448       else
 449         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 450       fi
 451     done
 452   else
 453     implied=
 454   fi
 455
 456   # Add NAME to the list of names.
 457   names="$names $name"
 458
 459   # Find the parent of NAME, using the empty string if it has none.
 460 changequote(,)dnl
 461   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 462 changequote([,])dnl
 463
 464   # Add the names implied by NAME, and NAME's parent (if it has one), to
 465   # the list of names to be processed (the argument list).  We prepend the
 466   # implied names to the list and append the parent.  We want implied
 467   # directories to come before further directories inferred from the
 468   # configuration components; this ensures that for sysv4, unix/common
 469   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 470   # after sysv4).
 471   sysnames="`echo $implied $* $parent`"
 472   test -n "$sysnames" && set $sysnames
 473 done
 474
 475 # Add the default directories.
 476 default_sysnames=sysdeps/generic
 477 if test "$elf" = yes; then
 478   default_sysnames="sysdeps/generic/elf $default_sysnames"
 479 fi
 480 sysnames="$names $default_sysnames"
 481 AC_SUBST(sysnames)
 482 # The other names were emitted during the scan.
 483 AC_MSG_RESULT($default_sysnames)
 484
 485
 486 ### Locate tools.
 487
 488 AC_PROG_INSTALL
 489 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 490   # The makefiles need to use a different form to find it in $srcdir.
 491   INSTALL='\$(..)./scripts/install-sh -c'
 492 fi
 493 AC_PROG_LN_S
 494
 495 # We need the physical current working directory.  We cannot use the
 496 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 497 # find a pwd binary.  Note that assigning to the PWD environment
 498 # variable might have some interesting side effects, so we don't do
 499 # that.
 500 AC_PATH_PROG(PWD_P, pwd, no)
 501 if test "$PWD_P" = no; then
 502   AC_MSG_ERROR(*** A pwd binary could not be found.)
 503 fi
 504
 505 # These programs are version sensitive.
 506 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 507 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 508   [version \([egcygnustpi-]*[0-9.]*\)],
 509   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 510   critic_missing=t)
 511 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 512   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 513   [3.79* | 3.[89]*], critic_missing=t)
 514
 515 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 516   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 517   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 518 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 519   [GNU texinfo.* \([0-9][0-9.]*\)],
 520   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 521 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 522   [GNU sed version \([0-9]*\.[0-9.]*\)],
 523   [3.0[2-9]*|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 524
 525 if test -n "$critic_missing"; then
 526 AC_MSG_ERROR([
 527 *** Some critical program is missing or too old.
 528 *** Check the INSTALL file for required versions.])
 529 fi
 530
 531 test -n "$aux_missing" && AC_MSG_WARN([
 532 *** An auxiliary program is missing or too old;
 533 *** some features will be disabled.
 534 *** Check the INSTALL file for required versions.])
 535
 536 # glibcbug.in wants to know the compiler version.
 537 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 538 AC_SUBST(CCVERSION)
 539
 540 AC_PROG_CC_LOCAL
 541 AC_CANONICAL_BUILD
 542 if test $host != $build; then
 543   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 544 fi
 545 AC_SUBST(cross_compiling)
 546 AC_PROG_CPP
 547 LIBC_PROG_BINUTILS
 548 AC_CHECK_TOOL(MIG, mig)
 549
 550 # if using special system headers, find out the compiler's sekrit
 551 # header directory and add that to the list.  NOTE: Only does the right
 552 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 553 if test -n "$sysheaders"; then
 554   ccheaders=`$CC -print-file-name=include`
 555   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 556 fi
 557 AC_SUBST(SYSINCLUDES)
 558
 559 # check if ranlib is necessary
 560 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 561 cat > conftest.c <<EOF
 562 int a;
 563 char b;
 564 void c(void) {}
 565 EOF
 566 $CC $CFLAGS -c conftest.c
 567 $AR cr conftest.a conftest.c
 568 cp conftest.a conftest2.a
 569 $RANLIB conftest.a
 570 if cmp -s conftest.a conftest2.a; then
 571   libc_cv_ranlib_necessary=no
 572 else
 573   libc_cv_ranlib_necessary=yes
 574 fi
 575 rm -rf conftest*])
 576 if test "$libc_cv_ranlib_necessary" = no; then
 577  RANLIB=:
 578 fi
 579
 580 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 581 # since this would lead to problems installing/building glibc.
 582 # LD_LIBRARY_PATH contains the current directory if one of the following
 583 # is true:
 584 # - one of the terminals (":" and ";") is the first or last sign
 585 # - two terminals occur directly after each other
 586 # - the path contains an element with a dot in it
 587 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 588 changequote(,)dnl
 589 case ${LD_LIBRARY_PATH} in
 590   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 591     ld_library_path_setting="contains current directory"
 592     ;;
 593   *)
 594     ld_library_path_setting="ok"
 595     ;;
 596 esac
 597 changequote([,])dnl
 598 AC_MSG_RESULT($ld_library_path_setting)
 599 if test "$ld_library_path_setting" != "ok"; then
 600 AC_MSG_ERROR([
 601 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 602 *** building glibc. Please change the environment variable
 603 *** and run configure again.])
 604 fi
 605
 606 AC_PATH_PROG(BASH, bash, no)
 607 if test "$BASH" != no &&
 608    $BASH -c 'test "$BASH_VERSINFO" \
 609              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 610   libc_cv_have_bash2=yes
 611 else
 612   libc_cv_have_bash2=no
 613 fi
 614 AC_SUBST(libc_cv_have_bash2)
 615
 616 dnl We need a ksh compatible shell for tzselect.
 617 if test "$BASH" = no; then
 618   AC_PATH_PROG(KSH, ksh, no)
 619   if test "$KSH" = no; then
 620     libc_cv_have_ksh=no
 621   else
 622     libc_cv_have_ksh=yes
 623   fi
 624 else
 625   KSH="$BASH"
 626   AC_SUBST(KSH)
 627   libc_cv_have_ksh=yes
 628 fi
 629 AC_SUBST(libc_cv_have_ksh)
 630
 631 AC_PROG_AWK
 632 AC_PATH_PROG(PERL, perl, no)
 633 if test "$PERL" != no &&
 634    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 635   PERL=no
 636 fi
 637 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 638              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 639 if test "$INSTALL_INFO" != "no"; then
 640 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 641  [mkdir conftest.d
 642   # There is a hard ^_ on the next line.  I am open to better ideas.
 643   (echo '\x1f'
 644   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 645   echo '* Menu:') >conftest.d/dir
 646   (echo 'INFO-DIR-SECTION i-d-s works'
 647   echo 'START-INFO-DIR-ENTRY'
 648   echo '* Prog: (prog).   Program.'
 649   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 650   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 651   then
 652     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 653     then libc_cv_old_debian_install_info=no
 654     else libc_cv_old_debian_install_info=yes
 655     fi
 656   else libc_cv_old_debian_install_info=no testfailed=t
 657   fi
 658   rm -fr conftest.d])
 659 if test -n "$testfailed"
 660 then AC_MSG_WARN([install-info errored out, check config.log])
 661 fi
 662 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 663 fi
 664 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 665
 666 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 667 echo '#include <stddef.h>
 668 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 669 if eval "$ac_cpp conftest.c 2>/dev/null" \
 670 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 671   libc_cv_signed_size_t=no
 672 else
 673   libc_cv_signed_size_t=yes
 674 fi
 675 rm -f conftest*])
 676 if test $libc_cv_signed_size_t = yes; then
 677   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 678   cat >> confdefs.h <<\EOF
 679 #undef __SIZE_TYPE__
 680 #define __SIZE_TYPE__ unsigned
 681 EOF
 682 fi
 683
 684 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 685 AC_TRY_COMPILE(dnl
 686 [#define __need_size_t
 687 #define __need_wchar_t
 688 #include <stddef.h>
 689 #define __need_NULL
 690 #include <stddef.h>], [size_t size; wchar_t wchar;
 691 #ifdef offsetof
 692 #error stddef.h ignored __need_*
 693 #endif
 694 if (&size == NULL || &wchar == NULL) abort ();],
 695                libc_cv_friendly_stddef=yes,
 696                libc_cv_friendly_stddef=no)])
 697 if test $libc_cv_friendly_stddef = yes; then
 698   config_vars="$config_vars
 699 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 700 fi
 701
 702 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 703                libc_cv_need_minus_P, [dnl
 704 cat > conftest.S <<EOF
 705 #include "confdefs.h"
 706 /* Nothing whatsoever.  */
 707 EOF
 708 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 709   libc_cv_need_minus_P=no
 710 else
 711   libc_cv_need_minus_P=yes
 712 fi
 713 rm -f conftest*])
 714 if test $libc_cv_need_minus_P = yes; then
 715   config_vars="$config_vars
 716 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 717 fi
 718
 719 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 720 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 721 cat > conftest.s <<EOF
 722 .text
 723 EOF
 724 libc_cv_dot_text=
 725 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 726   libc_cv_dot_text=.text
 727 fi
 728 rm -f conftest*])
 729 if test -z "$libc_cv_dot_text"; then
 730   AC_MSG_RESULT(no)
 731 else
 732   AC_MSG_RESULT(yes)
 733 fi
 734
 735 AC_CACHE_CHECK(for assembler global-symbol directive,
 736                libc_cv_asm_global_directive, [dnl
 737 libc_cv_asm_global_directive=UNKNOWN
 738 for ac_globl in .globl .global .EXPORT; do
 739   cat > conftest.s <<EOF
 740         ${libc_cv_dot_text}
 741         ${ac_globl} foo
 742 foo:
 743 EOF
 744   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 745     libc_cv_asm_global_directive=${ac_globl}
 746   fi
 747   rm -f conftest*
 748   test $libc_cv_asm_global_directive != UNKNOWN && break
 749 done])
 750 if test $libc_cv_asm_global_directive = UNKNOWN; then
 751   AC_MSG_ERROR(cannot determine asm global directive)
 752 else
 753   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 754 fi
 755
 756 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 757 cat > conftest.s <<EOF
 758 ${libc_cv_dot_text}
 759 foo:
 760 .set glibc_conftest_frobozz,foo
 761 $libc_cv_asm_global_directive glibc_conftest_frobozz
 762 EOF
 763 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 764 # (but it doesn't work), so we must do a linking check to be sure.
 765 cat > conftest1.c <<\EOF
 766 extern int glibc_conftest_frobozz;
 767 main () { printf ("%d\n", glibc_conftest_frobozz); }
 768 EOF
 769 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 770             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 771   libc_cv_asm_set_directive=yes
 772 else
 773   libc_cv_asm_set_directive=no
 774 fi
 775 rm -f conftest*])
 776 if test $libc_cv_asm_set_directive = yes; then
 777   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 778 fi
 779
 780 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 781 [cat > conftest.s <<EOF
 782 ${libc_cv_dot_text}
 783 _sym:
 784 .symver _sym,sym@VERS
 785 EOF
 786 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 787   libc_cv_asm_symver_directive=yes
 788 else
 789   libc_cv_asm_symver_directive=no
 790 fi
 791 rm -f conftest*])
 792 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 793 if test $libc_cv_asm_symver_directive = yes; then
 794   cat > conftest.s <<EOF
 795 ${libc_cv_dot_text}
 796 _sym:
 797 .symver _sym,sym@VERS
 798 EOF
 799   cat > conftest.map <<EOF
 800 VERS_1 {
 801         global: sym;
 802 };
 803
 804 VERS_2 {
 805         global: sym;
 806 } VERS_1;
 807 EOF
 808   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 809     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 810                                         -nostartfiles -nostdlib
 811                                         -Wl,--version-script,conftest.map
 812                        1>&AC_FD_CC]);
 813     then
 814       libc_cv_ld_version_script_option=yes
 815     else
 816       libc_cv_ld_version_script_option=no
 817     fi
 818   else
 819     libc_cv_ld_version_script_option=no
 820   fi
 821 else
 822   libc_cv_ld_version_script_option=no
 823 fi
 824 rm -f conftest*])
 825 if test $shared != no &&
 826    test $libc_cv_asm_symver_directive = yes &&
 827    test $libc_cv_ld_version_script_option = yes &&
 828    test $enable_versioning = yes; then
 829   VERSIONING=yes
 830   AC_DEFINE(DO_VERSIONING)
 831 else
 832   VERSIONING=no
 833 fi
 834 AC_SUBST(VERSIONING)
 835
 836 if test $shared != no && test $VERSIONING = no; then
 837   echo "\
 838 *** WARNING: You should not compile GNU libc without versioning. Not using
 839 *** versioning will introduce incompatibilities so that old binaries
 840 *** will not run anymore.
 841 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 842 fi
 843 if test $elf = yes; then
 844   AC_CACHE_CHECK(for .previous assembler directive,
 845                  libc_cv_asm_previous_directive, [dnl
 846   cat > conftest.s <<EOF
 847 .section foo_section
 848 .previous
 849 EOF
 850   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 851     libc_cv_asm_previous_directive=yes
 852   else
 853     libc_cv_asm_previous_directive=no
 854   fi
 855   rm -f conftest*])
 856   if test $libc_cv_asm_previous_directive = yes; then
 857     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 858   else
 859     AC_CACHE_CHECK(for .popsection assembler directive,
 860                    libc_cv_asm_popsection_directive, [dnl
 861     cat > conftest.s <<EOF
 862 .pushsection foo_section
 863 .popsection
 864 EOF
 865     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 866       libc_cv_asm_popsection_directive=yes
 867     else
 868       libc_cv_asm_popsection_directive=no
 869     fi
 870     rm -f conftest*])
 871     if test $libc_cv_asm_popsection_directive = yes; then
 872       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 873     fi
 874   fi
 875   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 876                  libc_cv_asm_protected_directive, [dnl
 877   cat > conftest.s <<EOF
 878 .protected foo
 879 foo:
 880 .hidden bar
 881 bar:
 882 EOF
 883   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 884     libc_cv_asm_protected_directive=yes
 885   else
 886     libc_cv_asm_protected_directive=no
 887   fi
 888   rm -f conftest*])
 889   AC_SUBST(libc_cv_asm_protected_directive)
 890
 891   AC_CACHE_CHECK(for -z nodelete option,
 892                  libc_cv_z_nodelete, [dnl
 893   cat > conftest.c <<EOF
 894 int _start (void) { return 42; }
 895 EOF
 896   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
 897   then
 898     libc_cv_z_nodelete=yes
 899   else
 900     libc_cv_z_nodelete=no
 901   fi
 902   rm -f conftest*])
 903   AC_SUBST(libc_cv_z_nodelete)
 904
 905   AC_CACHE_CHECK(for -z nodlopen option,
 906                  libc_cv_z_nodlopen, [dnl
 907   cat > conftest.c <<EOF
 908 int _start (void) { return 42; }
 909 EOF
 910   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
 911   then
 912     libc_cv_z_nodlopen=yes
 913   else
 914     libc_cv_z_nodlopen=no
 915   fi
 916   rm -f conftest*])
 917   AC_SUBST(libc_cv_z_nodlopen)
 918 fi
 919
 920 if test $elf != yes; then
 921   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 922                  [AC_TRY_COMPILE(, [asm (".section .init");
 923                                     asm (".section .fini");
 924                                     asm ("${libc_cv_dot_text}");],
 925                                  libc_cv_have_initfini=yes,
 926                                  libc_cv_have_initfini=no)])
 927   AC_SUBST(libc_cv_have_initfini)dnl
 928   if test $libc_cv_have_initfini = yes; then
 929     AC_DEFINE(HAVE_INITFINI)
 930   fi
 931 fi
 932
 933 if test $elf = yes -a $gnu_ld = yes; then
 934   AC_CACHE_CHECK(whether cc puts quotes around section names,
 935                  libc_cv_have_section_quotes,
 936                  [cat > conftest.c <<EOF
 937                   static const int foo
 938                   __attribute__ ((section ("bar"))) = 1;
 939 EOF
 940                   if ${CC-cc} -S conftest.c -o conftest.s; then
 941                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
 942                       libc_cv_have_section_quotes=yes
 943                     else
 944                       libc_cv_have_section_quotes=no
 945                     fi
 946                   else
 947                     libc_cv_have_section_quotes=unknown
 948                   fi
 949                   rm -f conftest.[cs]
 950                  ])
 951   if test $libc_cv_have_section_quotes = yes; then
 952     AC_DEFINE(HAVE_SECTION_QUOTES)
 953   fi
 954 fi
 955
 956 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 957 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 958 [cat > conftest.$ac_ext <<EOF
 959 dnl This sometimes fails to find confdefs.h, for some reason.
 960 dnl [#]line __oline__ "[$]0"
 961 [#]line __oline__ "configure"
 962 #include "confdefs.h"
 963 void underscore_test(void) {
 964 return; }
 965 EOF
 966 if AC_TRY_EVAL(ac_compile); then
 967   if grep _underscore_test conftest* >/dev/null; then
 968     ifelse([$1], , :, [rm -f conftest*
 969     $1])
 970   else
 971     ifelse([$2], , , [rm -f conftest*
 972     $2])
 973   fi
 974 else
 975   echo "configure: failed program was:" >&AC_FD_CC
 976   cat conftest.$ac_ext >&AC_FD_CC
 977   ifelse([$2], , , [rm -f conftest*
 978   $2])
 979 fi
 980 rm -f conftest*])
 981
 982 if test $elf = yes; then
 983   libc_cv_asm_underscores=no
 984 else
 985   if test $ac_cv_prog_cc_works = yes; then
 986     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 987                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 988                                 libc_cv_asm_underscores=yes,
 989                                 libc_cv_asm_underscores=no)])
 990   else
 991     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 992                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 993                                             libc_cv_asm_underscores=no)])
 994   fi
 995 fi
 996 if test $libc_cv_asm_underscores = no; then
 997   AC_DEFINE(NO_UNDERSCORES)
 998 fi
 999
1000 if test $elf = yes; then
1001   libc_cv_weak_symbols=yes
1002 fi
1003
1004 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1005                [dnl
1006 cat > conftest.s <<EOF
1007 ${libc_cv_dot_text}
1008 ${libc_cv_asm_global_directive} foo
1009 foo:
1010 .weak foo
1011 .weak bar; bar = foo
1012 EOF
1013 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1014   libc_cv_asm_weak_directive=yes
1015 else
1016   libc_cv_asm_weak_directive=no
1017 fi
1018 rm -f conftest*])
1019
1020 if test $libc_cv_asm_weak_directive = no; then
1021   AC_CACHE_CHECK(for assembler .weakext directive,
1022                  libc_cv_asm_weakext_directive,
1023                  [dnl
1024 cat > conftest.s <<EOF
1025 ${libc_cv_dot_text}
1026 ${libc_cv_asm_global_directive} foo
1027 foo:
1028 .weakext bar foo
1029 .weakext baz
1030 ${libc_cv_asm_global_directive} baz
1031 baz:
1032 EOF
1033   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1034     libc_cv_asm_weakext_directive=yes
1035   else
1036     libc_cv_asm_weakext_directive=no
1037   fi
1038   rm -f conftest*])
1039
1040 fi # no .weak
1041
1042 if test $libc_cv_asm_weak_directive = yes; then
1043   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1044 elif test $libc_cv_asm_weakext_directive = yes; then
1045   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1046 fi
1047
1048 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1049 cat > conftest.c <<\EOF
1050 _start () {}
1051 int __eh_pc;
1052 __throw () {}
1053 EOF
1054 dnl No \ in command here because it ends up inside ''.
1055 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1056                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1057                             -o conftest conftest.c 1>&AC_FD_CC]); then
1058   libc_cv_ld_no_whole_archive=yes
1059 else
1060   libc_cv_ld_no_whole_archive=no
1061 fi
1062 rm -f conftest*])
1063 if test $libc_cv_ld_no_whole_archive = yes; then
1064   no_whole_archive=-Wl,--no-whole-archive
1065 fi
1066 AC_SUBST(no_whole_archive)dnl
1067
1068 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1069 cat > conftest.c <<\EOF
1070 _start () {}
1071 int __eh_pc;
1072 __throw () {}
1073 EOF
1074 dnl No \ in command here because it ends up inside ''.
1075 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1076                             -nostdlib -nostartfiles -fexceptions
1077                             -o conftest conftest.c 1>&AC_FD_CC]); then
1078   libc_cv_gcc_exceptions=yes
1079 else
1080   libc_cv_gcc_exceptions=no
1081 fi
1082 rm -f conftest*])
1083 if test $libc_cv_gcc_exceptions = yes; then
1084   exceptions=-fexceptions
1085 fi
1086 AC_SUBST(exceptions)dnl
1087
1088 if test "$base_machine" = alpha ; then
1089 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1090 cat > conftest.c <<\EOF
1091 foo () { }
1092 EOF
1093 dnl
1094 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1095 then
1096   libc_cv_gcc_alpha_ng_prefix=yes
1097 else
1098   libc_cv_gcc_alpha_ng_prefix=no
1099 fi
1100 rm -f conftest* ])
1101 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1102   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1103 else
1104   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1105 fi
1106 fi
1107
1108 if test "$host_cpu" = powerpc ; then
1109 # Check for a bug present in at least versions 2.8.x of GCC
1110 # and versions 1.0.x of EGCS.
1111 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1112 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1113                libc_cv_c_asmcr0_bug='no',
1114                libc_cv_c_asmcr0_bug='yes')])
1115 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1116   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1117 fi
1118 fi
1119
1120 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1121 [cat > conftest.c <<EOF
1122 #line __oline__ "configure"
1123 static char __EH_FRAME_BEGIN__[];
1124 _start ()
1125 {
1126 #ifdef CHECK__register_frame
1127   __register_frame (__EH_FRAME_BEGIN__);
1128   __deregister_frame (__EH_FRAME_BEGIN__);
1129 #endif
1130 #ifdef CHECK__register_frame_info
1131   __register_frame_info (__EH_FRAME_BEGIN__);
1132   __deregister_frame_info (__EH_FRAME_BEGIN__);
1133 #endif
1134 }
1135 int __eh_pc;
1136 __throw () {}
1137 /* FIXME: this is fragile.  */
1138 malloc () {}
1139 strcmp () {}
1140 strlen () {}
1141 memcpy () {}
1142 memset () {}
1143 free () {}
1144 abort () {}
1145 __bzero () {}
1146 EOF
1147 dnl No \ in command here because it ends up inside ''.
1148 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1149                             -nostdlib -nostartfiles
1150                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1151   libc_cv_gcc_dwarf2_unwind_info=static
1152 else
1153   libc_cv_gcc_dwarf2_unwind_info=no
1154 fi
1155 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1156   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1157                               -nostdlib -nostartfiles
1158                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1159     libc_cv_gcc_dwarf2_unwind_info=yes
1160   else
1161     libc_cv_gcc_dwarf2_unwind_info=no
1162   fi
1163 fi
1164 rm -f conftest*])
1165 case $libc_cv_gcc_dwarf2_unwind_info in
1166 yes)
1167   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1168   ;;
1169 static)
1170   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1171   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1172   ;;
1173 esac
1174
1175 dnl Check whether compiler understands __builtin_expect.
1176 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1177 [cat > conftest.c <<EOF
1178 #line __oline__ "configure"
1179 int foo (int a)
1180 {
1181   a = __builtin_expect (a, 10);
1182   return a == 10 ? 0 : 1;
1183 }
1184 EOF
1185 dnl No \ in command here because it ends up inside ''.
1186 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1187                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1188   libc_cv_gcc_builtin_expect=yes
1189 else
1190   libc_cv_gcc_builtin_expect=no
1191 fi
1192 rm -f conftest*])
1193 if test "$libc_cv_gcc_builtin_expect" = yes; then
1194   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1195 fi
1196
1197 dnl Check whether the compiler supports subtraction of local labels.
1198 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1199 [cat > conftest.c <<EOF
1200 changequote(,)dnl
1201 #line __oline__ "configure"
1202 int foo (int a)
1203 {
1204   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1205   void *p = &&l1 + ar[a];
1206   goto *p;
1207  l1:
1208   return 1;
1209  l2:
1210   return 2;
1211 }
1212 changequote([,])dnl
1213 EOF
1214 dnl No \ in command here because it ends up inside ''.
1215 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1216                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1217   libc_cv_gcc_subtract_local_labels=yes
1218 else
1219   libc_cv_gcc_subtract_local_labels=no
1220 fi
1221 rm -f conftest*])
1222 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1223   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1224 fi
1225
1226 dnl Check whether we have the gd library available.
1227 AC_MSG_CHECKING(for libgd)
1228 old_CFLAGS="$CFLAGS"
1229 CFLAGS="$CFLAGS $libgd_include"
1230 old_LDFLAGS="$LDFLAGS"
1231 LDFLAGS="$LDFLAGS $libgd_ldflags"
1232 old_LIBS="$LIBS"
1233 LIBS="$LIBS -lgd -lpng -lz -lm"
1234 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1235 CFLAGS="$old_CFLAGS"
1236 LDFLAGS="$old_LDFLAGS"
1237 LIBS="$old_LIBS"
1238 AC_MSG_RESULT($LIBGD)
1239 AC_SUBST(LIBGD)
1240
1241 dnl check for the size of 'long double'.
1242 AC_CHECK_SIZEOF(long double, 0)
1243 sizeof_long_double=$ac_cv_sizeof_long_double
1244 AC_SUBST(sizeof_long_double)
1245
1246 ### End of automated tests.
1247 ### Now run sysdeps configure fragments.
1248
1249 # sysdeps configure fragments may set these with files to be linked below.
1250 libc_link_dests=
1251 libc_link_sources=
1252
1253 # They also can set these variables.
1254 use_ldconfig=no
1255 ldd_rewrite_script=no
1256
1257 # Iterate over all the sysdep directories we will use, running their
1258 # configure fragments, and looking for a uname implementation.
1259 uname=
1260 for dir in $sysnames; do
1261   case $dir in
1262     /*) dest=$dir ;;
1263     *)  dest=$srcdir/$dir ;;
1264   esac
1265   if test -r $dest/configure; then
1266     AC_MSG_RESULT(running configure fragment for $dest)
1267     . $dest/configure
1268   fi
1269 [
1270   if test -z "$uname"; then
1271     if test -r $dest/uname.c ||
1272        test -r $dest/uname.S ||
1273        { test -r $dest/syscalls.list &&
1274          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1275       uname=$dir
1276     fi
1277   fi
1278 ]dnl
1279 done
1280
1281 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1282
1283 # If we will use the generic uname implementation, we must figure out what
1284 # it will say by examining the system, and write the results in config-name.h.
1285 if test "$uname" = "sysdeps/generic"; then
1286
1287 changequote(,)dnl
1288   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1289 changequote([,])dnl
1290   if test $uname_sysname != $config_os; then
1291     config_release=`echo $config_os | sed s/$uname_sysname//`
1292   fi
1293 dnl
1294 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1295     if test -r /vmunix; then
1296       kernel_id=`strings /vmunix | grep UNIX`
1297     elif test -r /dynix; then
1298       kernel_id=`strings /dynix | grep DYNIX`
1299     else
1300       kernel_id=
1301     fi
1302 ])dnl
1303
1304   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1305 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1306 changequote(,)dnl
1307   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1308 changequote([,])dnl
1309   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1310          != x$config_release; then
1311     # The configuration release is a substring of the kernel release.
1312     libc_cv_uname_release=$kernel_release
1313   elif test x$config_release != x; then
1314     libc_cv_uname_release=$config_release
1315   elif test x$kernel_release != x; then
1316     libc_cv_uname_release=$kernel_release
1317   else
1318     libc_cv_uname_release=unknown
1319   fi])
1320   uname_release="$libc_cv_uname_release"
1321
1322   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1323 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1324 changequote(,)dnl
1325   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1326 changequote([,])dnl
1327   if test -n "$kernel_version"; then
1328     libc_cv_uname_version="$kernel_version"
1329   else
1330     libc_cv_uname_version=unknown
1331   fi])
1332   uname_version="$libc_cv_uname_version"
1333
1334 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1335   config_uname=config-name.h:config-name.in
1336 else
1337   # For non-generic uname, we don't need to create config-name.h at all.
1338   config_uname=
1339 fi
1340
1341 AC_MSG_CHECKING(stdio selection)
1342 AC_SUBST(stdio)
1343 case $stdio in
1344 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1345 default) stdio=stdio ;;
1346 esac
1347 AC_MSG_RESULT($stdio)
1348
1349 # Test for old glibc 2.0.x headers so that they can be removed properly
1350 # Search only in includedir.
1351 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1352 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1353 then
1354   old_glibc_headers=yes
1355 else
1356   old_glibc_headers=no
1357 fi
1358 AC_MSG_RESULT($old_glibc_headers)
1359 if test ${old_glibc_headers} = yes; then
1360   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1361   AC_MSG_WARN(*** be removed.)
1362 fi
1363 AC_SUBST(old_glibc_headers)
1364
1365 AC_SUBST(libc_cv_slibdir)
1366 AC_SUBST(libc_cv_localedir)
1367 AC_SUBST(libc_cv_sysconfdir)
1368 AC_SUBST(libc_cv_rootsbindir)
1369
1370 AC_SUBST(use_ldconfig)
1371 AC_SUBST(ldd_rewrite_script)
1372
1373 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1374 if test $gnu_ld = yes; then
1375   AC_DEFINE(HAVE_GNU_LD)
1376 fi
1377 if test $gnu_as = yes; then
1378   AC_DEFINE(HAVE_GNU_AS)
1379 fi
1380 if test $elf = yes; then
1381   AC_DEFINE(HAVE_ELF)
1382 fi
1383
1384 AC_SUBST(static)
1385 AC_SUBST(shared)
1386 if test $shared = default; then
1387   if test $gnu_ld = yes; then
1388     shared=$elf
1389   else
1390     # For now we do not assume shared libs are available.  In future more
1391     # tests might become available.
1392     shared=no
1393   fi
1394 fi
1395
1396 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1397 [pic_default=yes
1398 cat > conftest.c <<EOF
1399 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1400 # error PIC is default.
1401 #endif
1402 EOF
1403 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1404   pic_default=no
1405 fi
1406 rm -f conftest.*])
1407 AC_SUBST(pic_default)
1408
1409 AC_SUBST(profile)
1410 AC_SUBST(omitfp)
1411 AC_SUBST(bounded)
1412 AC_SUBST(static_nss)
1413 AC_SUBST(nopic_initfini)
1414
1415 AC_SUBST(DEFINES)
1416
1417 case "$add_ons" in
1418   *door*) linux_doors=yes ;;
1419   *) linux_doors=no ;;
1420 esac
1421 AC_SUBST(linux_doors)
1422
1423 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1424   config_makefile=
1425 else
1426   config_makefile=Makefile
1427 fi
1428
1429 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1430 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1431 AC_SUBST(VERSION)
1432 AC_SUBST(RELEASE)
1433
1434 echo '*** Do NOT install this release on any production system!'
1435 echo '*** We are in early testing stages.'
1436
1437 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1438 case $CONFIG_FILES in *config.make*)
1439 echo "$config_vars" >> config.make;;
1440 esac
1441 test -d bits || mkdir bits], [config_vars='$config_vars'])