sysdeps/unix/sysv/linux/mips/makecontext.S

   1 /* Modify saved context.
   2    Copyright (C) 2009-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Maciej W. Rozycki <macro@codesourcery.com>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <sys/asm.h>
  22 #include <sys/fpregdef.h>
  23 #include <sys/regdef.h>
  24
  25 #include "ucontext_i.h"
  26
  27 /* int makecontext (ucontext_t *ucp, (void *func) (), int argc, ...) */
  28
  29         .text
  30         .set    nomips16
  31 LOCALSZ = 0
  32 ARGSZ = 0
  33 MASK = 0x00000000
  34 #ifdef __PIC__
  35 LOCALSZ = 1                                             /* save gp */
  36 #endif
  37 #if _MIPS_SIM != _ABIO32
  38 ARGSZ = 5                                               /* save a3-a7 */
  39 # ifdef __PIC__
  40 MASK = 0x10000000
  41 # endif
  42 #endif
  43 FRAMESZ = (((ARGSZ + LOCALSZ) * SZREG) + ALSZ) & ALMASK
  44 GPOFF = FRAMESZ - ((ARGSZ + 1) * SZREG)
  45 #if _MIPS_SIM != _ABIO32
  46 A3OFF = FRAMESZ - (5 * SZREG)                           /* callee-allocated */
  47 A4OFF = FRAMESZ - (4 * SZREG)
  48 A5OFF = FRAMESZ - (3 * SZREG)
  49 A6OFF = FRAMESZ - (2 * SZREG)
  50 A7OFF = FRAMESZ - (1 * SZREG)
  51 NARGREGS = 8
  52 #else
  53 A3OFF = FRAMESZ + (3 * SZREG)                           /* caller-allocated */
  54 NARGREGS = 4
  55 #endif
  56 MCONTEXT_GREGSZ = 8
  57 #if _MIPS_SIM == _ABIO32 && __BYTE_ORDER__ == __ORDER_BIG_ENDIAN__
  58 MCONTEXT_GREGOFF = 4
  59 #else
  60 MCONTEXT_GREGOFF = 0
  61 #endif
  62
  63 NESTED (__makecontext, FRAMESZ, ra)
  64         .mask   MASK, -(ARGSZ * SZREG)
  65         .fmask  0x00000000, 0
  66
  67 98:
  68 #ifdef __PIC__
  69         SETUP_GP
  70 #endif
  71
  72         PTR_ADDIU sp, -FRAMESZ
  73         cfi_adjust_cfa_offset (FRAMESZ)
  74
  75 #ifdef __PIC__
  76         SETUP_GP64_STACK (GPOFF, __makecontext)
  77         SAVE_GP (GPOFF)
  78 #endif
  79
  80 #ifdef PROF
  81         .set    noat
  82         move    AT, ra
  83         jal     _mcount
  84         .set    at
  85 #endif
  86
  87         /* Store args to be passed.  */
  88         REG_S   a3, A3OFF(sp)
  89 #if _MIPS_SIM != _ABIO32
  90         REG_S   a4, A4OFF(sp)
  91         REG_S   a5, A5OFF(sp)
  92         REG_S   a6, A6OFF(sp)
  93         REG_S   a7, A7OFF(sp)
  94 #endif
  95
  96         /* Store a magic flag.  */
  97         li      v1, 1
  98         /* zero */
  99         REG_S   v1, (MCONTEXT_GREGOFF + 0 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 100
 101         /* Set up the stack.  */
 102         PTR_L   t0, STACK_SP(a0)
 103         PTR_L   t2, STACK_SIZE(a0)
 104         PTR_ADDIU t1, sp, A3OFF
 105         PTR_ADDU t0, t2
 106         and     t0, ALMASK
 107         blez    a2, 2f                                  /* no arguments */
 108
 109         /* Store register arguments.  */
 110         PTR_ADDIU t2, a0, MCONTEXT_GREGS + 4 * MCONTEXT_GREGSZ + MCONTEXT_GREGOFF
 111         move    t3, zero
 112 0:
 113         addiu   t3, 1
 114         REG_L   v1, (t1)
 115         PTR_ADDIU t1, SZREG
 116         REG_S   v1, (t2)
 117         PTR_ADDIU t2, MCONTEXT_GREGSZ
 118         bgeu    t3, a2, 2f                              /* all done */
 119         bltu    t3, NARGREGS, 0b                        /* next */
 120
 121         /* Make room for stack arguments.  */
 122         PTR_SUBU t2, a2, t3
 123         PTR_SLL t2, 3
 124         PTR_SUBU t0, t2
 125         and     t0, ALMASK
 126
 127         /* Store stack arguments.  */
 128         move    t2, t0
 129 1:
 130         addiu   t3, 1
 131         REG_L   v1, (t1)
 132         PTR_ADDIU t1, SZREG
 133         REG_S   v1, (t2)
 134         PTR_ADDIU t2, SZREG
 135         bltu    t3, a2, 1b                              /* next */
 136
 137 2:
 138 #if _MIPS_SIM == _ABIO32
 139         /* Make room for a0-a3 storage.  */
 140         PTR_ADDIU t0, -(NARGSAVE * SZREG)
 141 #endif
 142         PTR_L   v1, UCONTEXT_LINK(a0)
 143 #ifdef __PIC__
 144         PTR_ADDIU t9, 99f - 98b
 145 #else
 146         PTR_LA  t9, 99f
 147 #endif
 148         /* sp */
 149         REG_S   t0, (MCONTEXT_GREGOFF + 29 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 150         /* s0 */
 151         REG_S   v1, (MCONTEXT_GREGOFF + 16 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 152 #ifdef __PIC__
 153         /* s1 */
 154         REG_S   gp, (MCONTEXT_GREGOFF + 17 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 155 #endif
 156         /* ra */
 157         REG_S   t9, (MCONTEXT_GREGOFF + 31 * MCONTEXT_GREGSZ + MCONTEXT_GREGS)(a0)
 158         REG_S   a1, (MCONTEXT_GREGOFF + MCONTEXT_PC)(a0)
 159
 160 #ifdef __PIC__
 161         RESTORE_GP64_STACK
 162         PTR_ADDIU sp, FRAMESZ
 163         cfi_adjust_cfa_offset (-FRAMESZ)
 164 #endif
 165         jr      ra
 166
 167         /* We need to terminate the FDE to stop unwinding if backtrace was
 168            called within a context created by makecontext.  */
 169         cfi_endproc
 170         nop
 171
 172 99:
 173 #ifdef __PIC__
 174         move    gp, s1
 175 #endif
 176         move    a0, zero
 177         beqz    s0, 0f
 178
 179         /* setcontext (ucp) */
 180         move    a0, s0
 181 #ifdef __PIC__
 182         PTR_LA  t9, JUMPTARGET (__setcontext)
 183         jalr    t9
 184 # if _MIPS_SIM == _ABIO32
 185         move    gp, s1
 186 # endif
 187 #else
 188         jal     JUMPTARGET (__setcontext)
 189 #endif
 190         move    a0, v0
 191
 192 0:
 193         /* exit (a0) */
 194 #ifdef __PIC__
 195         PTR_LA  t9, HIDDEN_JUMPTARGET (exit)
 196         jalr    t9
 197 #else
 198         jal     HIDDEN_JUMPTARGET (exit)
 199 #endif
 200
 201         /* You don't exist, you won't feel anything.  */
 202 1:
 203         lb      zero, (zero)
 204         b       1b
 205
 206         cfi_startproc
 207 PSEUDO_END (__makecontext)
 208
 209 weak_alias (__makecontext, makecontext)