sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991, 92, 93, 94, 95, 96 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If
  16 # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 # Cambridge, MA 02139, USA.
  18
  19 # errno.texinfo contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24
  25 BEGIN {
  26     print "/* This file is generated from errno.texi by errlist.awk.  */"
  27     print "";
  28     print "#include <errno.h>";
  29     print "";
  30     print "const char *_sys_errlist[] =";
  31     print "  {";
  32     print "    [0] = N_(\"Success\"),"
  33   }
  34 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  35 errnoh == 1 && $1 == "@comment" \
  36   {
  37     ++errnoh;
  38     etext = $3;
  39     for (i = 4; i <= NF; ++i)
  40       etext = etext " " $i;
  41     next;
  42   }
  43 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  44   {
  45     e = $4; errnoh++; next;
  46   }
  47 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  48   {
  49     errno = $3 + 0;
  50     if (e == "EWOULDBLOCK")
  51       print "#if defined (EWOULDBLOCK) && EWOULDBLOCK != EAGAIN";
  52     else
  53       printf "#ifdef %s\n", e;
  54     printf "    [%s] = N_(\"%s\"),\n", e, etext;
  55     print "#endif";
  56     next;
  57   }
  58 { errnoh=0 }
  59 END {
  60   print "  };";
  61   print "";
  62   print "const int _sys_nerr = sizeof _sys_errlist / sizeof _sys_errlist[0];";
  63   print "weak_alias (_sys_errlist, sys_errlist)";
  64   print "weak_alias (_sys_nerr, sys_nerr)";
  65   }