ports/sysdeps/arm/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* ??? Needs more rearrangement for the LDM to handle thumb mode.  */
  20 #define NO_THUMB
  21 #include <sysdep.h>
  22 #include <bits/setjmp.h>
  23 #include <rtld-global-offsets.h>
  24 #include <arm-features.h>
  25
  26 /* __longjmp(jmpbuf, val) */
  27
  28 ENTRY (__longjmp)
  29         mov     ip, r0
  30         movs    r0, r1          /* get the return value in place */
  31         moveq   r0, #1          /* can't let setjmp() return zero! */
  32
  33 #ifdef CHECK_SP
  34         sfi_breg ip, \
  35         ldr     r4, [\B, #32]   /* jmpbuf's sp */
  36         cfi_undefined (r4)
  37         CHECK_SP (r4)
  38 #endif
  39         sfi_sp sfi_breg ip, \
  40         ldmia   \B!, JMP_BUF_REGLIST
  41         cfi_restore (v1)
  42         cfi_restore (v2)
  43         cfi_restore (v3)
  44         cfi_restore (v4)
  45         cfi_restore (v5)
  46         cfi_restore (v6)
  47         cfi_restore (sl)
  48         cfi_restore (fp)
  49         cfi_restore (sp)
  50         cfi_restore (lr)
  51
  52 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  53 # define NEED_HWCAP 1
  54 #endif
  55
  56 #ifdef NEED_HWCAP
  57 # ifdef IS_IN_rtld
  58         ldr     a2, 1f
  59         ldr     a3, .Lrtld_local_ro
  60 0:      add     a2, pc, a2
  61         add     a2, a2, a3
  62         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  63 # else
  64 #  ifdef PIC
  65         ldr     a2, 1f
  66         ldr     a3, .Lrtld_global_ro
  67 0:      add     a2, pc, a2
  68         ldr     a2, [a2, a3]
  69         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  70 #  else
  71         ldr     a2, .Lhwcap
  72         ldr     a2, [a2, #0]
  73 #  endif
  74 # endif
  75 #endif
  76
  77 #ifdef __SOFTFP__
  78         tst     a2, #HWCAP_ARM_VFP
  79         beq     .Lno_vfp
  80 #endif
  81
  82         /* Restore the VFP registers.  */
  83         /* Following instruction is vldmia ip!, {d8-d15}.  */
  84         sfi_breg r12, \
  85         ldc     p11, cr8, [\B], #64
  86 .Lno_vfp:
  87
  88 #ifndef ARM_ASSUME_NO_IWMMXT
  89         tst     a2, #HWCAP_ARM_IWMMXT
  90         beq     .Lno_iwmmxt
  91
  92         /* Restore the call-preserved iWMMXt registers.  */
  93         /* Following instructions are wldrd wr10, [ip], #8 (etc.)  */
  94         sfi_breg r12, \
  95         ldcl    p1, cr10, [\B], #8
  96         sfi_breg r12, \
  97         ldcl    p1, cr11, [\B], #8
  98         sfi_breg r12, \
  99         ldcl    p1, cr12, [\B], #8
 100         sfi_breg r12, \
 101         ldcl    p1, cr13, [\B], #8
 102         sfi_breg r12, \
 103         ldcl    p1, cr14, [\B], #8
 104         sfi_breg r12, \
 105         ldcl    p1, cr15, [\B], #8
 106 .Lno_iwmmxt:
 107 #endif
 108
 109         DO_RET(lr)
 110
 111 #ifdef NEED_HWCAP
 112 # ifdef IS_IN_rtld
 113 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 114 .Lrtld_local_ro:
 115         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
 116 # else
 117 #  ifdef PIC
 118 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 119 .Lrtld_global_ro:
 120         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
 121 #  else
 122 .Lhwcap:
 123         .long   C_SYMBOL_NAME(_dl_hwcap)
 124 #  endif
 125 # endif
 126 #endif
 127
 128 END (__longjmp)