configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(binutils, dnl
  40   --with-binutils=PATH    specify location of binutils (as and ld),
  41             path_binutils=$withval, path_binutils='')
  42 AC_ARG_WITH(elf, dnl
  43   --with-elf              if using the ELF object format,
  44             elf=$withval, elf=no)
  45 AC_ARG_WITH(cvs, dnl
  46 [  --without-cvs          if CVS should not be used],
  47             with_cvs=$withval, with_cvs=yes)
  48 AC_SUBST(with_cvs)
  49
  50 AC_ARG_ENABLE(libio, dnl
  51 [  --enable-libio          build in GNU libio instead of GNU stdio],
  52               [if test $enableval = yes; then
  53                  stdio=libio
  54                else
  55                  stdio=stdio
  56                fi],
  57               stdio=default)
  58
  59 AC_ARG_ENABLE(sanity-checks, dnl
  60 [  --disable-sanity-checks really do not use threads (should not be used
  61                           except in special situations) [default=yes]],
  62               enable_sanity=$enableval, enable_sanity=yes)
  63
  64 dnl Arguments to enable or disable building the static, shared, profiled,
  65 dnl and -fomit-frame-pointer libraries.
  66 AC_ARG_ENABLE(static, dnl
  67 [  --enable-static         build static library [default=yes]],
  68               static=$enableval, static=yes)
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81 AC_ARG_ENABLE(versioning, dnl
  82 [  --disable-versioning    do not include versioning information in the
  83                           library objects [default=yes if supported]],
  84              enable_versioning=$enableval, enable_versioning=yes)
  85
  86 dnl Generic infrastructure for drop-in additions to libc.
  87 AC_ARG_ENABLE(add-ons, dnl
  88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  89                                   search for add-ons if no parameter given],
  90   [case "$enableval" in
  91     yes) if test "$srcdir" = "."; then
  92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  93          else
  94            add_ons=`echo $srcdir/*/configure | \
  95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
  96          fi;;
  97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  98    esac],
  99   [add_ons=])
 100
 101 AC_CONFIG_SUBDIRS($add_ons)
 102 add_ons_pfx=
 103 if test x"$add_ons" != x; then
 104   for f in $add_ons; do
 105     # Test whether such a subdir really exists.
 106     if test -d $srcdir/$f; then
 107       add_ons_pfx="$add_ons_pfx $f/"
 108     else
 109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 110     fi
 111   done
 112 fi
 113
 114 dnl On some platforms we cannot use dynamic loading.  We must provide
 115 dnl static NSS modules.
 116 AC_ARG_ENABLE(static-nss, dnl
 117 [  --enable-static-nss     build static NSS modules [default=no]],
 118               static_nss=$enableval, static_nss=no)
 119 if test x"$static_nss" = xyes; then
 120   AC_DEFINE(DO_STATIC_NSS)
 121 fi
 122
 123 AC_CANONICAL_HOST
 124
 125 # The way shlib-versions is used to generate soversions.mk uses a
 126 # fairly simplistic model for name recognition that can't distinguish
 127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 130 case "$host_os" in
 131 linux*)
 132   ;;
 133 gnu*)
 134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 135   ;;
 136 esac
 137
 138 ###
 139 ### I put this here to prevent those annoying emails from people who cannot
 140 ### read and try to compile glibc on unsupported platforms.  --drepper
 141 ###
 142 ### By using the undocumented --enable-hacker-mode option for configure
 143 ### one can skip this test to make the configuration not fail for unsupported
 144 ### platforms.
 145 ###
 146 if test -z "$enable_hacker_mode"; then
 147   case "$machine-$host_os" in
 148   *-linux* | *-gnu* | arm*-none*)
 149     ;;
 150   *)
 151     echo "*** The GNU C library is currently not available for this platform."
 152     echo "*** So far nobody cared to port it and if there is no volunteer it"
 153     echo "*** might never happen.  So, if you have interest to see glibc on"
 154     echo "*** this platform visit"
 155     echo "***   http://www.gnu.org/software/libc/porting.html"
 156     echo "*** and join the group of porters"
 157     exit 1
 158     ;;
 159   esac
 160 fi
 161
 162 # We keep the original values in `$config_*' and never modify them, so we
 163 # can write them unchanged into config.make.  Everything else uses
 164 # $machine, $vendor, and $os, and changes them whenever convenient.
 165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 166
 167 # Some configurations imply other options.
 168 case "$host_os" in
 169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 170   # These systems always use GNU tools.
 171   gnu_ld=yes gnu_as=yes ;;
 172 esac
 173 case "$host_os" in
 174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 176   ;;
 177 gnu* | linux* | sysv4* | solaris2*)
 178   # These systems (almost) always use the ELF format.
 179   elf=yes
 180   ;;
 181 esac
 182
 183 machine=$config_machine
 184 vendor=$config_vendor
 185 os=$config_os
 186
 187 dnl We need to use [ and ] for other purposes for a while now.
 188 changequote(,)dnl
 189 # Expand the configuration machine name into a subdirectory by architecture
 190 # type and particular chip.
 191 case "$machine" in
 192 a29k | am29000) base_machine=a29k machine=a29k ;;
 193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 194 arm*)           base_machine=arm machine=arm/$machine ;;
 195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 201 m88???)         base_machine=m88k machine=m88k/$machine ;;
 202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 204 mips*)          base_machine=mips machine=mips/$machine ;;
 205 sparc | sparcv[67])
 206                 base_machine=sparc machine=sparc/sparc32 ;;
 207 sparcv8 | supersparc | hypersparc)
 208                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 209 sparc64 | ultrasparc)
 210                 base_machine=sparc machine=sparc/sparc64 ;;
 211 esac
 212 changequote([,])dnl
 213 AC_SUBST(base_machine)
 214
 215 if test "$base_machine" = "i386"; then
 216   AC_DEFINE(USE_REGPARMS)
 217 fi
 218
 219 # Compute the list of sysdep directories for this configuration.
 220 # This can take a while to compute.
 221 sysdep_dir=$srcdir/sysdeps
 222 AC_MSG_CHECKING(sysdep dirs)
 223 dnl We need to use [ and ] for other purposes for a while now.
 224 changequote(,)dnl
 225 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 226 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 227
 228 case "$os" in
 229 gnu*)
 230   base_os=mach/hurd ;;
 231 netbsd* | 386bsd* | freebsd* | bsdi*)
 232   base_os=unix/bsd/bsd4.4 ;;
 233 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 234   base_os=unix/bsd ;;
 235 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 236   base_os=unix/sysv ;;
 237 solaris[2-9]*)
 238   base_os=unix/sysv/sysv4 ;;
 239 none)
 240   base_os=standalone ;;
 241 *)
 242   base_os='' ;;
 243 esac
 244
 245 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 246 tail=$os
 247 ostry=$os
 248 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 249   ostry="$ostry /$o"
 250   tail=$o
 251 done
 252 o=`echo $tail | sed 's/[0-9]*$//'`
 253 if test $o != $tail; then
 254   ostry="$ostry /$o"
 255 fi
 256 # For linux-gnu, try linux-gnu, then linux.
 257 o=`echo $tail | sed 's/-.*$//'`
 258 if test $o != $tail; then
 259   ostry="$ostry /$o"
 260 fi
 261
 262 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 263 base=
 264 tail=$base_os
 265 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 266   set $b
 267   base="$base /$1"
 268   tail="$2"
 269 done
 270
 271 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 272 mach=
 273 tail=$machine
 274 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 275   set $m
 276   # Prepend the machine's FPU directory unless --without-fp.
 277   if test "$with_fp" = yes; then
 278     mach="$mach /$1/fpu"
 279   fi
 280   mach="$mach /$1"
 281   tail="$2"
 282 done
 283
 284 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 285 changequote([,])dnl
 286
 287 # Find what sysdep directories exist.
 288 sysnames=
 289 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 290 for d in $add_ons_pfx ''; do
 291   for b in $base ''; do
 292     for m0 in $mach ''; do
 293       for v in /$vendor ''; do
 294         test "$v" = / && continue
 295         for o in /$ostry ''; do
 296           test "$o" = / && continue
 297           for m in $mach ''; do
 298             if test "$m0$b$v$o$m"; then
 299               try="${d}sysdeps$m0$b$v$o$m"
 300               test -n "$enable_debug_configure" &&
 301               echo "$0 [DEBUG]: try $try" >&2
 302               case $try in
 303                 /*) dest=$try ;;
 304                 *)  dest=$srcdir/$try ;;
 305               esac
 306               if test -d $dest; then
 307                 sysnames="$sysnames $try"
 308                 { test -n "$o" || test -n "$b"; } && os_used=t
 309                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 310               fi
 311             fi
 312           done
 313         done
 314       done
 315     done
 316   done
 317 done
 318 IFS="$ac_save_ifs"
 319
 320 if test -z "$os_used" && test "$os" != none; then
 321   AC_MSG_ERROR(Operating system $os is not supported.)
 322 fi
 323 if test -z "$machine_used" && test "$machine" != none; then
 324   AC_MSG_ERROR(The $machine is not supported.)
 325 fi
 326
 327 # We have now validated the configuration.
 328
 329
 330 # If using ELF, look for an `elf' subdirectory of each machine directory.
 331 # We prepend these rather than inserting them whereever the machine appears
 332 # because things specified by the machine's ELF ABI should override
 333 # OS-specific things, and should always be the same for any OS on the
 334 # machine (otherwise what's the point of an ABI?).
 335 if test "$elf" = yes; then
 336   elf_dirs=
 337   for d in $add_ons_pfx ''; do
 338     case $d in
 339       /*) xsrcdir= ;;
 340       *)  xsrcdir=$srcdir/ ;;
 341     esac
 342     for m in $mach; do
 343       if test -d $xsrcdir${d}sysdeps$m/elf; then
 344         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 345       fi
 346     done
 347   done
 348   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 349 fi
 350
 351
 352 # Expand the list of system names into a full list of directories
 353 # from each element's parent name and Implies file (if present).
 354 set $sysnames
 355 names=
 356 while test $# -gt 0; do
 357   name=$1
 358   shift
 359
 360   case " $names " in *" $name "*)
 361     # Already in the list.
 362     continue
 363   esac
 364
 365   # Report each name as we discover it, so there is no long pause in output.
 366   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 367
 368   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 369
 370   case $name in
 371     /*) xsrcdir= ;;
 372     *)  xsrcdir=$srcdir/ ;;
 373   esac
 374   test -n "$enable_debug_configure" &&
 375   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 376
 377   if test -f $xsrcdir$name/Implies; then
 378     # Collect more names from the `Implies' file (removing comments).
 379     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 380     implied=
 381     for x in $implied_candidate; do
 382       if test -d $xsrcdir$name_base/$x; then
 383         implied="$implied $name_base/$x";
 384       else
 385         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 386       fi
 387     done
 388   else
 389     implied=
 390   fi
 391
 392   # Add NAME to the list of names.
 393   names="$names $name"
 394
 395   # Find the parent of NAME, using the empty string if it has none.
 396 changequote(,)dnl
 397   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 398 changequote([,])dnl
 399
 400   # Add the names implied by NAME, and NAME's parent (if it has one), to
 401   # the list of names to be processed (the argument list).  We prepend the
 402   # implied names to the list and append the parent.  We want implied
 403   # directories to come before further directories inferred from the
 404   # configuration components; this ensures that for sysv4, unix/common
 405   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 406   # after sysv4).
 407   sysnames="`echo $implied $* $parent`"
 408   test -n "$sysnames" && set $sysnames
 409 done
 410
 411 # Add the default directories.
 412 sysnames="$names sysdeps/generic"
 413 AC_SUBST(sysnames)
 414 # The other names were emitted during the scan.
 415 AC_MSG_RESULT(sysdeps/generic)
 416
 417
 418 ### Locate tools.
 419
 420 AC_PROG_INSTALL
 421 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 422   # The makefiles need to use a different form to find it in $srcdir.
 423   INSTALL='\$(..)./install-sh -c'
 424 fi
 425 AC_PROG_LN_S
 426 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 427 if test "$MSGFMT" != ":"; then
 428 changequote(,)dnl Need [] for regexps.
 429   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
 430 changequote([,])dnl
 431   then : # msgfmt from gettext 0.10 or greater, works.
 432   else
 433     AC_MSG_WARN([
 434 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
 435     MSGFMT=":"
 436   fi
 437 fi
 438
 439 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
 440 if test "$MAKEINFO"; then
 441 changequote(,)dnl Need [] for regexps.
 442   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
 443 changequote([,])dnl
 444   then : # Makeinfo 3.11 or greater, works.
 445   else
 446     AC_MSG_WARN([
 447 *** makeinfo is too old (need version 3.11 or better).
 448 *** You should install the needed version and re-configure since otherwise
 449 *** you won't get the info pages installed.])
 450     MAKEINFO=
 451   fi
 452 fi
 453
 454 AC_PROG_CC_LOCAL
 455 AC_CANONICAL_BUILD
 456 if test $host != $build; then
 457   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 458 fi
 459 AC_SUBST(cross_compiling)
 460 AC_PROG_CPP
 461 LIBC_PROG_BINUTILS
 462 AC_CHECK_TOOL(AR, ar)
 463 AC_CHECK_TOOL(RANLIB, ranlib, :)
 464
 465 AC_PATH_PROG(BASH, bash, no)
 466 if test "$BASH" != no &&
 467    $BASH -c 'test "$BASH_VERSINFO" \
 468              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 469   libc_cv_have_bash2=yes
 470 else
 471   libc_cv_have_bash2=no
 472 fi
 473 AC_SUBST(libc_cv_have_bash2)
 474
 475 dnl We need a ksh compatible shell for tzselect.
 476 if test "$BASH" = no; then
 477   AC_PATH_PROG(KSH, ksh, no)
 478   if test "$KSH" = no; then
 479     libc_cv_have_ksh=no
 480   else
 481     libc_cv_have_ksh=yes
 482   fi
 483 else
 484   KSH="$BASH"
 485   AC_SUBST(KSH)
 486   libc_cv_have_ksh=yes
 487 fi
 488 AC_SUBST(libc_cv_have_ksh)
 489
 490 AC_PATH_PROGS(PERL, perl, no)
 491 AC_SUBST(PERL)
 492
 493 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 494 echo '#include <stddef.h>
 495 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 496 if eval "$ac_cpp conftest.c 2>/dev/null" \
 497 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 498   libc_cv_signed_size_t=no
 499 else
 500   libc_cv_signed_size_t=yes
 501 fi
 502 rm -f conftest*])
 503 if test $libc_cv_signed_size_t = yes; then
 504   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 505   cat >> confdefs.h <<\EOF
 506 #undef __SIZE_TYPE__
 507 #define __SIZE_TYPE__ unsigned
 508 EOF
 509 fi
 510
 511 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 512 AC_TRY_COMPILE(dnl
 513 [#define __need_size_t
 514 #define __need_wchar_t
 515 #include <stddef.h>
 516 #define __need_NULL
 517 #include <stddef.h>], [size_t size; wchar_t wchar;
 518 #ifdef offsetof
 519 #error stddef.h ignored __need_*
 520 #endif
 521 if (&size == NULL || &wchar == NULL) abort ();],
 522                libc_cv_friendly_stddef=yes,
 523                libc_cv_friendly_stddef=no)])
 524 if test $libc_cv_friendly_stddef = yes; then
 525   config_vars="$config_vars
 526 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 527 fi
 528
 529 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 530                libc_cv_need_minus_P, [dnl
 531 cat > conftest.S <<EOF
 532 #include "confdefs.h"
 533 /* Nothing whatsoever.  */
 534 EOF
 535 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 536   libc_cv_need_minus_P=no
 537 else
 538   libc_cv_need_minus_P=yes
 539 fi
 540 rm -f conftest*])
 541 if test $libc_cv_need_minus_P = yes; then
 542   config_vars="$config_vars
 543 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 544 fi
 545
 546 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 547 # be told to read stdin.  This causes the compiler to hang when fed an
 548 # .s file.
 549 if test $ac_cv_prog_gcc = yes; then
 550  case `${CC-cc} -v 2>&1` in
 551   *2.7*)
 552   # We must check this even if -pipe is not given here, because the user
 553   # might do `make CFLAGS=-pipe'.
 554   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 555    cp /dev/null conftest.s
 556    cat >conftest1.s <<EOF
 557 .nosuchdirective
 558 EOF
 559    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 560     libc_cv_gcc_pipe_bug=no
 561    else
 562     libc_cv_gcc_pipe_bug=yes
 563    fi
 564    rm -f conftest*])
 565   if test $libc_cv_gcc_pipe_bug = yes; then
 566    makeCC="${CC-cc} -B\$(common-objpfx)"
 567    makeCFLAGS=$CFLAGS
 568    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 569   fi;;
 570  *) libc_cv_gcc_pipe_bug=no;;
 571  esac
 572 else
 573  libc_cv_gcc_pipe_bug=no
 574 fi
 575
 576 AC_CACHE_CHECK(for assembler global-symbol directive,
 577                libc_cv_asm_global_directive, [dnl
 578 libc_cv_asm_global_directive=UNKNOWN
 579 for ac_globl in .globl .global; do
 580   cat > conftest.s <<EOF
 581 .text
 582 ${ac_globl} foo
 583 foo:
 584 EOF
 585   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 586     libc_cv_asm_global_directive=${ac_globl}
 587   fi
 588   rm -f conftest*
 589   test $libc_cv_asm_global_directive != UNKNOWN && break
 590 done])
 591 if test $libc_cv_asm_global_directive = UNKNOWN; then
 592   AC_MSG_ERROR(cannot determine asm global directive)
 593 else
 594   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 595 fi
 596
 597 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 598 cat > conftest.s <<EOF
 599 .text
 600 foo:
 601 .set glibc_conftest_frobozz,foo
 602 $libc_cv_asm_global_directive glibc_conftest_frobozz
 603 EOF
 604 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 605 # (but it doesn't work), so we must do a linking check to be sure.
 606 cat > conftest1.c <<\EOF
 607 extern int glibc_conftest_frobozz;
 608 main () { printf ("%d\n", glibc_conftest_frobozz); }
 609 EOF
 610 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 611             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 612   libc_cv_asm_set_directive=yes
 613 else
 614   libc_cv_asm_set_directive=no
 615 fi
 616 rm -f conftest*])
 617 if test $libc_cv_asm_set_directive = yes; then
 618   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 619 fi
 620
 621 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 622 [cat > conftest.s <<EOF
 623 .text
 624 _sym:
 625 .symver _sym,sym@VERS
 626 EOF
 627 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 628   libc_cv_asm_symver_directive=yes
 629 else
 630   libc_cv_asm_symver_directive=no
 631 fi
 632 rm -f conftest*])
 633 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 634 if test $libc_cv_asm_symver_directive = yes; then
 635   cat > conftest.s <<EOF
 636 .text
 637 _sym:
 638 .symver _sym,sym@VERS
 639 EOF
 640   cat > conftest.map <<EOF
 641 VERS_1 {
 642         global: sym;
 643 };
 644
 645 VERS_2 {
 646         global: sym;
 647 } VERS_1;
 648 EOF
 649   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 650     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 651                                         -nostartfiles -nostdlib
 652                                         -Wl,--version-script,conftest.map
 653                        1>&AC_FD_CC]);
 654     then
 655       libc_cv_ld_version_script_option=yes
 656     else
 657       libc_cv_ld_version_script_option=no
 658     fi
 659   else
 660     libc_cv_ld_version_script_option=no
 661   fi
 662 else
 663   libc_cv_ld_version_script_option=no
 664 fi
 665 rm -f conftest*])
 666 if test $libc_cv_asm_symver_directive = yes &&
 667    test $libc_cv_ld_version_script_option = yes &&
 668    test $enable_versioning = yes; then
 669   VERSIONING=yes
 670   AC_DEFINE(DO_VERSIONING)
 671 else
 672   VERSIONING=no
 673 fi
 674 AC_SUBST(VERSIONING)
 675
 676 if test $VERSIONING = no; then
 677   echo "\
 678 *** WARNING: You should not compile GNU libc without versioning. Not using
 679 *** versioning will introduce incompatibilities so that old binaries
 680 *** will not run anymore.
 681 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
 682 fi
 683 if test $elf = yes; then
 684   AC_CACHE_CHECK(for .previous assembler directive,
 685                  libc_cv_asm_previous_directive, [dnl
 686   cat > conftest.s <<EOF
 687 .section foo_section
 688 .previous
 689 EOF
 690   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 691     libc_cv_asm_previous_directive=yes
 692   else
 693     libc_cv_asm_previous_directive=no
 694   fi
 695   rm -f conftest*])
 696   if test $libc_cv_asm_previous_directive = yes; then
 697     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 698   else
 699     AC_CACHE_CHECK(for .popsection assembler directive,
 700                    libc_cv_asm_popsection_directive, [dnl
 701     cat > conftest.s <<EOF
 702 .pushsection foo_section
 703 .popsection
 704 EOF
 705     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 706       libc_cv_asm_popsection_directive=yes
 707     else
 708       libc_cv_asm_popsection_directive=no
 709     fi
 710     rm -f conftest*])
 711     if test $libc_cv_asm_popsection_directive = yes; then
 712       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 713     fi
 714   fi
 715 fi
 716
 717 if test $elf != yes; then
 718   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 719                  [AC_TRY_COMPILE(, [asm (".section .init");
 720                                     asm (".section .fini");
 721                                     asm (".text");],
 722                                  libc_cv_have_initfini=yes,
 723                                  libc_cv_have_initfini=no)])
 724   AC_SUBST(libc_cv_have_initfini)dnl
 725   if test $libc_cv_have_initfini = yes; then
 726     AC_DEFINE(HAVE_INITFINI)
 727   fi
 728 fi
 729
 730 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 731 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 732 [cat > conftest.$ac_ext <<EOF
 733 dnl This sometimes fails to find confdefs.h, for some reason.
 734 dnl [#]line __oline__ "[$]0"
 735 [#]line __oline__ "configure"
 736 #include "confdefs.h"
 737 void underscore_test(void) {
 738 return; }
 739 EOF
 740 if AC_TRY_EVAL(ac_compile); then
 741   if grep _underscore_test conftest* >/dev/null; then
 742     ifelse([$1], , :, [rm -f conftest*
 743     $1])
 744   else
 745     ifelse([$2], , , [rm -f conftest*
 746     $2])
 747   fi
 748 else
 749   echo "configure: failed program was:" >&AC_FD_CC
 750   cat conftest.$ac_ext >&AC_FD_CC
 751   ifelse([$2], , , [rm -f conftest*
 752   $2])
 753 fi
 754 rm -f conftest*])
 755
 756 if test $elf = yes; then
 757   libc_cv_asm_underscores=no
 758 else
 759   if test $ac_cv_prog_cc_works = yes; then
 760     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 761                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 762                                 libc_cv_asm_underscores=yes,
 763                                 libc_cv_asm_underscores=no)])
 764   else
 765     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 766                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 767                                             libc_cv_asm_underscores=no)])
 768   fi
 769 fi
 770 if test $libc_cv_asm_underscores = no; then
 771   AC_DEFINE(NO_UNDERSCORES)
 772 fi
 773
 774 if test $elf = yes; then
 775   libc_cv_weak_symbols=yes
 776   libc_cv_asm_weak_directive=yes
 777   libc_cv_asm_weakext_directive=no
 778 else
 779   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 780                  [dnl
 781 cat > conftest.s <<EOF
 782 .text
 783 ${libc_cv_asm_global_directive} foo
 784 foo:
 785 .weak foo
 786 .weak bar; bar = foo
 787 EOF
 788   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 789     libc_cv_asm_weak_directive=yes
 790   else
 791     libc_cv_asm_weak_directive=no
 792   fi
 793   rm -f conftest*])
 794
 795 if test $libc_cv_asm_weak_directive = no; then
 796   AC_CACHE_CHECK(for assembler .weakext directive,
 797                  libc_cv_asm_weakext_directive,
 798                  [dnl
 799 cat > conftest.s <<EOF
 800 .text
 801 ${libc_cv_asm_global_directive} foo
 802 foo:
 803 .weakext foo
 804 .weakext foo, bar
 805 EOF
 806   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 807     libc_cv_asm_weakext_directive=yes
 808   else
 809     libc_cv_asm_weakext_directive=no
 810   fi
 811   rm -f conftest*])
 812
 813   fi # no .weak
 814 fi # not ELF
 815
 816 if test $libc_cv_asm_weak_directive = yes; then
 817   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 818 elif test $libc_cv_asm_weakext_directive = yes; then
 819   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 820 fi
 821
 822 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 823 cat > conftest.c <<\EOF
 824 _start () {}
 825 int __eh_pc;
 826 __throw () {}
 827 EOF
 828 dnl No \ in command here because it ends up inside ''.
 829 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 830                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 831                             -o conftest conftest.c 1>&AC_FD_CC]); then
 832   libc_cv_ld_no_whole_archive=yes
 833 else
 834   libc_cv_ld_no_whole_archive=no
 835 fi
 836 rm -f conftest*])
 837 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 838
 839 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 840 cat > conftest.c <<\EOF
 841 _start () {}
 842 int __eh_pc;
 843 __throw () {}
 844 EOF
 845 dnl No \ in command here because it ends up inside ''.
 846 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 847                             -nostdlib -nostartfiles -fno-exceptions
 848                             -o conftest conftest.c 1>&AC_FD_CC]); then
 849   libc_cv_gcc_no_exceptions=yes
 850 else
 851   libc_cv_gcc_no_exceptions=no
 852 fi
 853 rm -f conftest*])
 854 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 855
 856 if test "$base_machine" = alpha ; then
 857 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 858 cat > conftest.c <<\EOF
 859 foo () { }
 860 EOF
 861 dnl
 862 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 863 then
 864   libc_cv_gcc_alpha_ng_prefix=yes
 865 else
 866   libc_cv_gcc_alpha_ng_prefix=no
 867 fi
 868 rm -f conftest* ])
 869 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 870   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 871 else
 872   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 873 fi
 874 fi
 875
 876 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 877 [cat > conftest.c <<EOF
 878 #line __oline__ "configure"
 879 static char __EH_FRAME_BEGIN__[];
 880 _start ()
 881 {
 882 #ifdef CHECK__register_frame
 883   __register_frame (__EH_FRAME_BEGIN__);
 884   __deregister_frame (__EH_FRAME_BEGIN__);
 885 #endif
 886 #ifdef CHECK__register_frame_info
 887   __register_frame_info (__EH_FRAME_BEGIN__);
 888   __deregister_frame_info (__EH_FRAME_BEGIN__);
 889 #endif
 890 }
 891 int __eh_pc;
 892 __throw () {}
 893 /* FIXME: this is fragile.  */
 894 malloc () {}
 895 strcmp () {}
 896 strlen () {}
 897 memcpy () {}
 898 memset () {}
 899 free () {}
 900 abort () {}
 901 __bzero () {}
 902 EOF
 903 dnl No \ in command here because it ends up inside ''.
 904 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 905                             -nostdlib -nostartfiles
 906                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 907   libc_cv_gcc_dwarf2_unwind_info=static
 908 else
 909   libc_cv_gcc_dwarf2_unwind_info=no
 910 fi
 911 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 912   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 913                               -nostdlib -nostartfiles
 914                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 915     libc_cv_gcc_dwarf2_unwind_info=yes
 916   else
 917     libc_cv_gcc_dwarf2_unwind_info=no
 918   fi
 919 fi
 920 rm -f conftest*])
 921 case $libc_cv_gcc_dwarf2_unwind_info in
 922 yes)
 923   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 924   ;;
 925 static)
 926   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 927   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 928   ;;
 929 esac
 930
 931 ### End of automated tests.
 932 ### Now run sysdeps configure fragments.
 933
 934 # sysdeps configure fragments may set these with files to be linked below.
 935 libc_link_dests=
 936 libc_link_sources=
 937
 938 # Iterate over all the sysdep directories we will use, running their
 939 # configure fragments, and looking for a uname implementation.
 940 uname=
 941 for dir in $sysnames; do
 942   case $dir in
 943     /*) dest=$dir ;;
 944     *)  dest=$srcdir/$dir ;;
 945   esac
 946   if test -r $dest/configure; then
 947     AC_MSG_RESULT(running configure fragment for $dest)
 948     . $dest/configure
 949   fi
 950 [
 951   if test -z "$uname"; then
 952     if test -r $dest/uname.c ||
 953        test -r $dest/uname.S ||
 954        { test -r $dest/syscalls.list &&
 955          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
 956       uname=$dir
 957     fi
 958   fi
 959 ]dnl
 960 done
 961
 962 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 963
 964 # If we will use the generic uname implementation, we must figure out what
 965 # it will say by examining the system, and write the results in config-name.h.
 966 if test "$uname" = "sysdeps/generic"; then
 967
 968 changequote(,)dnl
 969   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 970 changequote([,])dnl
 971   if test $uname_sysname != $config_os; then
 972     config_release=`echo $config_os | sed s/$uname_sysname//`
 973   fi
 974 dnl
 975 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 976     if test -r /vmunix; then
 977       kernel_id=`strings /vmunix | grep UNIX`
 978     elif test -r /dynix; then
 979       kernel_id=`strings /dynix | grep DYNIX`
 980     else
 981       kernel_id=
 982     fi
 983 ])dnl
 984
 985   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 986 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 987 changequote(,)dnl
 988   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 989 changequote([,])dnl
 990   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 991          != x$config_release; then
 992     # The configuration release is a substring of the kernel release.
 993     libc_cv_uname_release=$kernel_release
 994   elif test x$config_release != x; then
 995     libc_cv_uname_release=$config_release
 996   elif test x$kernel_release != x; then
 997     libc_cv_uname_release=$kernel_release
 998   else
 999     libc_cv_uname_release=unknown
1000   fi])
1001   uname_release="$libc_cv_uname_release"
1002
1003   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1004 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1005 changequote(,)dnl
1006   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1007 changequote([,])dnl
1008   if test -n "$kernel_version"; then
1009     libc_cv_uname_version="$kernel_version"
1010   else
1011     libc_cv_uname_version=unknown
1012   fi])
1013   uname_version="$libc_cv_uname_version"
1014
1015 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1016   config_uname=config-name.h:config-name.in
1017 else
1018   # For non-generic uname, we don't need to create config-name.h at all.
1019   config_uname=
1020 fi
1021
1022 AC_MSG_CHECKING(stdio selection)
1023 AC_SUBST(stdio)
1024 case $stdio in
1025 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1026 default) stdio=stdio ;;
1027 esac
1028 AC_MSG_RESULT($stdio)
1029
1030 AC_MSG_CHECKING(ldap selection)
1031 AC_SUBST(LDAP)
1032 case $add_ons in
1033 *ldap*)
1034    ldap=yes
1035    LDAP=ldap ;;
1036 *) ldap=no
1037    LDAP= ;;
1038 esac
1039 AC_MSG_RESULT($ldap)
1040
1041 AC_SUBST(libc_cv_slibdir)
1042 AC_SUBST(libc_cv_sysconfdir)
1043 AC_SUBST(libc_cv_rootsbindir)
1044
1045 AC_SUBST(has_ldconfig)
1046
1047 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1048 if test $gnu_ld = yes; then
1049   AC_DEFINE(HAVE_GNU_LD)
1050 fi
1051 if test $gnu_as = yes; then
1052   AC_DEFINE(HAVE_GNU_AS)
1053 fi
1054 if test $elf = yes; then
1055   AC_DEFINE(HAVE_ELF)
1056 fi
1057
1058 AC_SUBST(static)
1059 AC_SUBST(shared)
1060 if test $shared = default; then
1061   if test $gnu_ld = yes; then
1062     shared=$elf
1063   else
1064     # For now we do not assume shared libs are available.  In future more
1065     # tests might become available.
1066     shared=no
1067   fi
1068 fi
1069
1070 dnl We must not allow compilation without static library on some platforms.
1071 if test $static = no && test $shared = yes; then
1072   case "$host_os" in
1073   linux* | gnu*)
1074     AC_MSG_ERROR([
1075 *** You must compile with support for the static library since the shared
1076 *** library uses it.  Restart configure without \`--disable-static'.])
1077     ;;
1078   *)
1079     ;;
1080   esac
1081 fi
1082
1083 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1084 [pic_default=yes
1085 cat > conftest.c <<EOF
1086 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1087 # error PIC is default.
1088 #endif
1089 EOF
1090 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1091   pic_default=no
1092 fi
1093 rm -f conftest.*])
1094 AC_SUBST(pic_default)
1095
1096 AC_SUBST(profile)
1097 AC_SUBST(omitfp)
1098 AC_SUBST(bounded)
1099 AC_SUBST(static_nss)
1100 AC_SUBST(nopic_initfini)
1101
1102 AC_SUBST(DEFINES)
1103
1104 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1105   config_makefile=
1106 else
1107   config_makefile=Makefile
1108 fi
1109
1110 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1111 AC_SUBST(VERSION)
1112
1113 if test $libc_cv_gcc_pipe_bug = yes; then
1114  realCC=$CC
1115  CC=$makeCC
1116  CFLAGS=$makeCFLAGS
1117 fi
1118 AC_OUTPUT_COMMANDS([
1119 if test "$realCC"; then
1120  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1121  mv specsT specs
1122 fi], [realCC=$realCC])
1123
1124 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1125           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])