sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991,92,93,94,95,96,97,98,99 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16 # write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18
  19 # errno.texi contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24 # Descriptive paragraph...
  25 # @end deftypevr
  26
  27 BEGIN {
  28
  29     # Here we list the E* names that might be duplicate names for the
  30     # same integer value on some systems.  This causes the code below
  31     # to generate ``#if defined (ALIAS) && ALIAS != ORIGINAL'' in the code,
  32     # so the output does not presume that these are in fact aliases.
  33     # We list here all the known potential cases on any system,
  34     # so that the C source we produce will do the right thing based
  35     # on the actual #define'd values it's compiled with.
  36     alias["EWOULDBLOCK"]= "EAGAIN";
  37     alias["EDEADLOCK"]  = "EDEADLK";
  38     alias["ENOTSUP"]    = "EOPNOTSUPP";
  39
  40     print "/* This file is generated from errno.texi by errlist.awk.  */"
  41     print "";
  42     print "#include <errno.h>";
  43     print "";
  44     print "#ifndef SYS_ERRLIST";
  45     print "# define SYS_ERRLIST _sys_errlist";
  46     print "# define SYS_ERRLIST_ALIAS sys_errlist";
  47     print "#endif";
  48     print "#ifndef SYS_NERR";
  49     print "# define SYS_NERR _sys_nerr";
  50     print "# define SYS_NERR_ALIAS sys_nerr";
  51     print "#endif";
  52     print "#ifndef ERR_REMAP";
  53     print "# define ERR_REMAP(n) n";
  54     print "#endif";
  55     print "";
  56     print "const char *const SYS_ERRLIST[] =";
  57     print "  {";
  58     print "    [0] = N_(\"Success\"),"
  59   }
  60 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  61 errnoh == 1 && $1 == "@comment" \
  62   {
  63     ++errnoh;
  64     etext = $3;
  65     for (i = 4; i <= NF; ++i)
  66       etext = etext " " $i;
  67     next;
  68   }
  69 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  70   {
  71     e = $4; errnoh++; next;
  72   }
  73 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  74   {
  75     errno = $3 + 0;
  76     if (alias[e])
  77       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  78     else
  79       printf "#ifdef %s\n", e;
  80     errnoh = 4;
  81     desc="";
  82     next;
  83   }
  84 errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
  85   {
  86     printf "/*%s */\n", desc;
  87     printf "    [ERR_REMAP (%s)] = N_(\"%s\"),\n", e, etext;
  88     print "#endif";
  89     errnoh = 0;
  90     next;
  91   }
  92 errnoh == 4 \
  93   {
  94     # This magic tag in C comments gets them copied into libc.pot.
  95     desc = desc "\nTRANS " $0; next
  96   }
  97 { errnoh=0 }
  98 END {
  99   print "  };";
 100   print "";
 101   print "const int SYS_NERR = sizeof SYS_ERRLIST / sizeof SYS_ERRLIST [0];";
 102   print "#ifdef SYS_ERRLIST_ALIAS";
 103   print "weak_alias (_sys_errlist, SYS_ERRLIST_ALIAS)";
 104   print "#endif";
 105   print "#ifdef SYS_NERR_ALIAS";
 106   print "weak_alias (_sys_nerr, SYS_NERR_ALIAS)";
 107   print "#endif";
 108   }