sysdeps/vax/strcmp.s

   1 /*
   2  * Copyright (c) 1983 Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by the University of
  16  *      California, Berkeley and its contributors.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  */
  33
  34 #if defined(LIBC_SCCS) && !defined(lint)
  35         .asciz "@(#)strcmp.s    5.6 (Berkeley) 6/1/90"
  36 #endif /* LIBC_SCCS and not lint */
  37
  38 /*
  39  * Compare string s1 lexicographically to string s2.
  40  * Return:
  41  *      0       s1 == s2
  42  *      > 0     s1 > s2
  43  *      < 0     s2 < s2
  44  *
  45  * strcmp(s1, s2)
  46  *      char *s1, *s2;
  47  */
  48 #include "DEFS.h"
  49
  50 ENTRY(strcmp, 0)
  51         movl    4(ap),r1        # r1 = s1
  52         movl    8(ap),r3        # r3 = s2
  53         subb3   (r3),(r1),r0    # quick check for first char different
  54         beql    1f              # have to keep checking
  55         cvtbl   r0,r0
  56         ret
  57 1:
  58         clrl    r5              # calculate min bytes to next page boundary
  59         subb3   r1,$255,r5      # r5 = (bytes - 1) to end of page for s1
  60         subb3   r3,$255,r0      # r0 = (bytes - 1) to end of page for s2
  61         cmpb    r0,r5           # r5 = min(r0, r5);
  62         bgtru   2f
  63         movb    r0,r5
  64 2:
  65         incl    r5              # r5 = min bytes to next page boundary
  66         cmpc3   r5,(r1),(r3)    # compare strings
  67         bneq    3f
  68         subl2   r5,r1           # check if found null yet
  69         locc    $0,r5,(r1)
  70         beql    1b              # not yet done, continue checking
  71         subl2   r0,r3
  72         mnegb   (r3),r0         # r0 = '\0' - *s2
  73         cvtbl   r0,r0
  74         ret
  75 3:
  76         subl2   r0,r5           # check for null in matching string
  77         subl2   r5,r1
  78         locc    $0,r5,(r1)
  79         bneq    4f
  80         subb3   (r3),(r1),r0    # r0 = *s1 - *s2
  81         cvtbl   r0,r0
  82         ret
  83 4:
  84         clrl    r0              # both the same to null
  85         ret