sysdeps/unix/sysv/linux/mips/swapcontext.S

   1 /* Save and set current context.
   2    Copyright (C) 2009 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Maciej W. Rozycki <macro@codesourcery.com>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <sys/asm.h>
  22 #include <sys/fpregdef.h>
  23 #include <sys/regdef.h>
  24
  25 #include "ucontext_i.h"
  26
  27 /* int swapcontext (ucontext_t *oucp, const ucontext_t *ucp) */
  28
  29         .text
  30 LOCALSZ = 0
  31 ARGSZ = 0
  32 MASK = 0x00000000
  33 #ifdef __PIC__
  34 LOCALSZ = 1                                             /* save gp */
  35 #endif
  36 #if _MIPS_SIM != _ABIO32
  37 ARGSZ = 1                                               /* save a1 */
  38 # ifdef __PIC__
  39 MASK = 0x10000000
  40 # endif
  41 #endif
  42 FRAMESZ = (((ARGSZ + LOCALSZ) * SZREG) + ALSZ) & ALMASK
  43 GPOFF = FRAMESZ - ((ARGSZ + 1) * SZREG)
  44 #if _MIPS_SIM != _ABIO32
  45 A1OFF = FRAMESZ - (1 * SZREG)                           /* callee-allocated */
  46 #else
  47 A1OFF = FRAMESZ + (1 * SZREG)                           /* caller-allocated */
  48 #endif
  49
  50 NESTED (__swapcontext, FRAMESZ, ra)
  51         .mask   MASK, -(ARGSZ * SZREG)
  52         .fmask  0x00000000, 0
  53
  54 #ifdef __PIC__
  55         SETUP_GP
  56
  57         move    a2, sp
  58 # define _SP a2
  59
  60 # if _MIPS_SIM != _ABIO32
  61         move    a3, gp
  62 #  define _GP a3
  63 # endif
  64
  65         PTR_ADDIU sp, -FRAMESZ
  66         SETUP_GP64 (GPOFF, __swapcontext)
  67         SAVE_GP (GPOFF)
  68
  69 #else  /* ! __PIC__ */
  70 # define _SP sp
  71 # define _GP gp
  72
  73 #endif /* ! __PIC__ */
  74
  75 #ifdef PROF
  76         .set    noat
  77         move    AT, ra
  78         jal     _mcount
  79         .set    at
  80 #endif
  81
  82         /* Store a magic flag.  */
  83         li      v1, 1
  84         REG_S   v1, (0 * SZREG + MCONTEXT_GREGS)(a0)    /* zero */
  85
  86         REG_S   s0, (16 * SZREG + MCONTEXT_GREGS)(a0)
  87         REG_S   s1, (17 * SZREG + MCONTEXT_GREGS)(a0)
  88         REG_S   s2, (18 * SZREG + MCONTEXT_GREGS)(a0)
  89         REG_S   s3, (19 * SZREG + MCONTEXT_GREGS)(a0)
  90         REG_S   s4, (20 * SZREG + MCONTEXT_GREGS)(a0)
  91         REG_S   s5, (21 * SZREG + MCONTEXT_GREGS)(a0)
  92         REG_S   s6, (22 * SZREG + MCONTEXT_GREGS)(a0)
  93         REG_S   s7, (23 * SZREG + MCONTEXT_GREGS)(a0)
  94 #if ! defined (__PIC__) || _MIPS_SIM != _ABIO32
  95         REG_S   _GP, (28 * SZREG + MCONTEXT_GREGS)(a0)
  96 #endif
  97         REG_S   _SP, (29 * SZREG + MCONTEXT_GREGS)(a0)
  98         REG_S   fp, (30 * SZREG + MCONTEXT_GREGS)(a0)
  99         REG_S   ra, (31 * SZREG + MCONTEXT_GREGS)(a0)
 100         REG_S   ra, MCONTEXT_PC(a0)
 101
 102 #ifdef __mips_hard_float
 103 # if _MIPS_SIM == _ABI64
 104         s.d     fs0, (24 * SZREG + MCONTEXT_FPREGS)(a0)
 105         s.d     fs1, (25 * SZREG + MCONTEXT_FPREGS)(a0)
 106         s.d     fs2, (26 * SZREG + MCONTEXT_FPREGS)(a0)
 107         s.d     fs3, (27 * SZREG + MCONTEXT_FPREGS)(a0)
 108         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 109         s.d     fs5, (29 * SZREG + MCONTEXT_FPREGS)(a0)
 110         s.d     fs6, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 111         s.d     fs7, (31 * SZREG + MCONTEXT_FPREGS)(a0)
 112
 113 # else  /* _MIPS_SIM != _ABI64 */
 114         s.d     fs0, (20 * SZREG + MCONTEXT_FPREGS)(a0)
 115         s.d     fs1, (22 * SZREG + MCONTEXT_FPREGS)(a0)
 116         s.d     fs2, (24 * SZREG + MCONTEXT_FPREGS)(a0)
 117         s.d     fs3, (26 * SZREG + MCONTEXT_FPREGS)(a0)
 118         s.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(a0)
 119         s.d     fs5, (30 * SZREG + MCONTEXT_FPREGS)(a0)
 120
 121 # endif /* _MIPS_SIM != _ABI64 */
 122
 123         cfc1    v1, fcr31
 124         sw      v1, MCONTEXT_FPC_CSR(a0)
 125 #endif /* __mips_hard_float */
 126
 127         REG_S   a1, A1OFF(sp)
 128
 129 /* rt_sigprocmask (SIG_SETMASK, &ucp->uc_sigmask, &oucp->uc_sigmask, _NSIG8) */
 130         li      a3, _NSIG8
 131         PTR_ADDU a2, a0, UCONTEXT_SIGMASK
 132         PTR_ADDU a1, a1, UCONTEXT_SIGMASK
 133         li      a0, SIG_SETMASK
 134
 135         li      v0, SYS_ify (rt_sigprocmask)
 136         syscall
 137         bnez    a3, 99f
 138
 139         REG_L   v0, A1OFF(sp)
 140
 141 #ifdef __mips_hard_float
 142 # if _MIPS_SIM == _ABI64
 143         l.d     fs0, (24 * SZREG + MCONTEXT_FPREGS)(v0)
 144         l.d     fs1, (25 * SZREG + MCONTEXT_FPREGS)(v0)
 145         l.d     fs2, (26 * SZREG + MCONTEXT_FPREGS)(v0)
 146         l.d     fs3, (27 * SZREG + MCONTEXT_FPREGS)(v0)
 147         l.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(v0)
 148         l.d     fs5, (29 * SZREG + MCONTEXT_FPREGS)(v0)
 149         l.d     fs6, (30 * SZREG + MCONTEXT_FPREGS)(v0)
 150         l.d     fs7, (31 * SZREG + MCONTEXT_FPREGS)(v0)
 151
 152 # else  /* _MIPS_SIM != _ABI64 */
 153         l.d     fs0, (20 * SZREG + MCONTEXT_FPREGS)(v0)
 154         l.d     fs1, (22 * SZREG + MCONTEXT_FPREGS)(v0)
 155         l.d     fs2, (24 * SZREG + MCONTEXT_FPREGS)(v0)
 156         l.d     fs3, (26 * SZREG + MCONTEXT_FPREGS)(v0)
 157         l.d     fs4, (28 * SZREG + MCONTEXT_FPREGS)(v0)
 158         l.d     fs5, (30 * SZREG + MCONTEXT_FPREGS)(v0)
 159
 160 # endif /* _MIPS_SIM != _ABI64 */
 161
 162         lw      v1, MCONTEXT_FPC_CSR(v0)
 163         ctc1    v1, fcr31
 164 #endif /* __mips_hard_float */
 165
 166         /* Note the contents of argument registers will be random
 167            unless makecontext() has been called.  */
 168         REG_L   a0, (4 * SZREG + MCONTEXT_GREGS)(v0)
 169         REG_L   a1, (5 * SZREG + MCONTEXT_GREGS)(v0)
 170         REG_L   a2, (6 * SZREG + MCONTEXT_GREGS)(v0)
 171         REG_L   a3, (7 * SZREG + MCONTEXT_GREGS)(v0)
 172 #if _MIPS_SIM != _ABIO32
 173         REG_L   a4, (8 * SZREG + MCONTEXT_GREGS)(v0)
 174         REG_L   a5, (9 * SZREG + MCONTEXT_GREGS)(v0)
 175         REG_L   a6, (10 * SZREG + MCONTEXT_GREGS)(v0)
 176         REG_L   a7, (11 * SZREG + MCONTEXT_GREGS)(v0)
 177 #endif
 178
 179         REG_L   s0, (16 * SZREG + MCONTEXT_GREGS)(v0)
 180         REG_L   s1, (17 * SZREG + MCONTEXT_GREGS)(v0)
 181         REG_L   s2, (18 * SZREG + MCONTEXT_GREGS)(v0)
 182         REG_L   s3, (19 * SZREG + MCONTEXT_GREGS)(v0)
 183         REG_L   s4, (20 * SZREG + MCONTEXT_GREGS)(v0)
 184         REG_L   s5, (21 * SZREG + MCONTEXT_GREGS)(v0)
 185         REG_L   s6, (22 * SZREG + MCONTEXT_GREGS)(v0)
 186         REG_L   s7, (23 * SZREG + MCONTEXT_GREGS)(v0)
 187 #if ! defined (__PIC__) || _MIPS_SIM != _ABIO32
 188         REG_L   gp, (28 * SZREG + MCONTEXT_GREGS)(v0)
 189 #endif
 190         REG_L   sp, (29 * SZREG + MCONTEXT_GREGS)(v0)
 191         REG_L   fp, (30 * SZREG + MCONTEXT_GREGS)(v0)
 192         REG_L   ra, (31 * SZREG + MCONTEXT_GREGS)(v0)
 193         REG_L   t9, MCONTEXT_PC(v0)
 194
 195         move    v0, zero
 196         jr      t9
 197
 198 99:
 199 #ifdef __PIC__
 200         PTR_LA  t9, JUMPTARGET (__syscall_error)
 201         RESTORE_GP64
 202         PTR_ADDIU sp, FRAMESZ
 203         jr      t9
 204
 205 #else  /* ! __PIC__ */
 206
 207         j       JUMPTARGET (__syscall_error)
 208 #endif /* ! __PIC__ */
 209 PSEUDO_END (__swapcontext)
 210
 211 weak_alias (__swapcontext, swapcontext)