sysdeps/m68k/start.S

   1 /* Startup code compliant to the ELF m68k ABI.
   2    Copyright (C) 1996-2022 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library.  If not, see
  34    <https://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The SVR4/m68k ABI says that when the entry point runs,
  38    most registers' values are unspecified, except for:
  39
  40    %a1          Contains a function pointer to be registered with `atexit'.
  41                 This is how the dynamic linker arranges to have DT_FINI
  42                 functions called for shared libraries that have been loaded
  43                 before this code runs.
  44
  45    %sp          The stack contains the arguments and environment:
  46                 0(%sp)                  argc
  47                 4(%sp)                  argv[0]
  48                 ...
  49                 (4*argc)(%sp)           NULL
  50                 (4*(argc+1))(%sp)       envp[0]
  51                 ...
  52                                         NULL
  53 */
  54
  55 #include <sysdep.h>
  56
  57         .text
  58         .globl _start
  59         .type _start,@function
  60 _start:
  61         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  62            the outermost frame obviously.  */
  63         sub.l %fp, %fp
  64
  65         /* Extract the arguments as encoded on the stack and set up the
  66            arguments for `main': argc, argv.  envp will be determined
  67            later in __libc_start_main.  */
  68         move.l (%sp)+, %d0      /* Pop the argument count.  */
  69         move.l %sp, %a0         /* The argument vector starts just at the
  70                                    current stack top.  */
  71
  72         /* Provide the highest stack address to the user code (for stacks
  73            which grow downward).  */
  74         pea (%sp)
  75
  76         pea (%a1)               /* Push address of the shared library
  77                                    termination function.  */
  78
  79         /* These used to be addresses of the .fini and .init entry points.  */
  80         clr.l -(%sp)
  81         clr.l -(%sp)
  82
  83 #ifdef PIC
  84         /* Load PIC register.  */
  85         LOAD_GOT (%a5)
  86
  87         pea (%a0)               /* Push second argument: argv.  */
  88         move.l %d0, -(%sp)      /* Push first argument: argc.  */
  89
  90         move.l main@GOT(%a5), -(%sp)
  91
  92         /* Call the user's main function, and exit with its value.  But
  93            let the libc call main.  */
  94         jbsr __libc_start_main@PLTPC
  95 #else
  96
  97         pea (%a0)               /* Push second argument: argv.  */
  98         move.l %d0, -(%sp)      /* Push first argument: argc.  */
  99
 100         pea main
 101
 102         /* Call the user's main function, and exit with its value.  But
 103            let the libc call main.  */
 104         jbsr __libc_start_main
 105 #endif
 106
 107         illegal                 /* Crash if somehow `exit' does return.  */
 108
 109 /* Define a symbol for the first piece of initialized data.  */
 110         .data
 111         .globl __data_start
 112 __data_start:
 113         .long 0
 114         .weak data_start
 115         data_start = __data_start